git.chise.org Git - elisp/gnus.git-/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- Functions for encoding and decoding rfc2047 messages
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-and-compile
  28   (eval
  29    '(unless (fboundp 'base64-decode-string)
  30       (require 'base64))))
  31
  32 (require 'qp)
  33 (require 'mm-util)
  34 (require 'ietf-drums)
  35 (require 'mail-prsvr)
  36
  37 (defvar rfc2047-header-encoding-alist
  38   '(("Newsgroups" . nil)
  39     ("Message-ID" . nil)
  40     (t . mime))
  41   "*Header/encoding method alist.
  42 The list is traversed sequentially.  The keys can either be
  43 header regexps or `t'.
  44
  45 The values can be:
  46
  47 1) nil, in which case no encoding is done;
  48 2) `mime', in which case the header will be encoded according to RFC2047;
  49 3) a charset, in which case it will be encoded as that charse;
  50 4) `default', in which case the field will be encoded as the rest
  51    of the article.")
  52
  53 (defvar rfc2047-charset-encoding-alist
  54   '((us-ascii . nil)
  55     (iso-8859-1 . Q)
  56     (iso-8859-2 . Q)
  57     (iso-8859-3 . Q)
  58     (iso-8859-4 . Q)
  59     (iso-8859-5 . B)
  60     (koi8-r . B)
  61     (iso-8859-7 . Q)
  62     (iso-8859-8 . Q)
  63     (iso-8859-9 . Q)
  64     (iso-2022-jp . B)
  65     (iso-2022-kr . B)
  66     (gb2312 . B)
  67     (cn-gb . B)
  68     (cn-gb-2312 . B)
  69     (euc-kr . B)
  70     (iso-2022-jp-2 . B)
  71     (iso-2022-int-1 . B))
  72   "Alist of MIME charsets to RFC2047 encodings.
  73 Valid encodings are nil, `Q' and `B'.")
  74
  75 (defvar rfc2047-encoding-function-alist
  76   '((Q . rfc2047-q-encode-region)
  77     (B . rfc2047-b-encode-region)
  78     (nil . ignore))
  79   "Alist of RFC2047 encodings to encoding functions.")
  80
  81 (defvar rfc2047-q-encoding-alist
  82   '(("\\(From\\|Cc\\|To\\|Bcc\||Reply-To\\):" . "-A-Za-z0-9!*+/=_")
  83     ("." . "^\000-\007\013\015-\037\200-\377=_?"))
  84   "Alist of header regexps and valid Q characters.")
  85
  86 ;;;
  87 ;;; Functions for encoding RFC2047 messages
  88 ;;;
  89
  90 (defun rfc2047-narrow-to-field ()
  91   "Narrow the buffer to the header on the current line."
  92   (beginning-of-line)
  93   (narrow-to-region
  94    (point)
  95    (progn
  96      (forward-line 1)
  97      (if (re-search-forward "^[^ \n\t]" nil t)
  98          (progn
  99            (beginning-of-line)
 100            (point))
 101        (point-max))))
 102   (goto-char (point-min)))
 103
 104 (defun rfc2047-encode-message-header ()
 105   "Encode the message header according to `rfc2047-header-encoding-alist'.
 106 Should be called narrowed to the head of the message."
 107   (interactive "*")
 108   (when (featurep 'mule)
 109     (save-excursion
 110       (goto-char (point-min))
 111       (let ((alist rfc2047-header-encoding-alist)
 112             elem method)
 113         (while (not (eobp))
 114           (save-restriction
 115             (rfc2047-narrow-to-field)
 116             (when (rfc2047-encodable-p)
 117               ;; We found something that may perhaps be encoded.
 118               (while (setq elem (pop alist))
 119                 (when (or (and (stringp (car elem))
 120                                (looking-at (car elem)))
 121                           (eq (car elem) t))
 122                   (setq alist nil
 123                         method (cdr elem))))
 124               (when method
 125                 (cond
 126                  ((eq method 'mime)
 127                   (rfc2047-encode-region (point-min) (point-max))
 128                   (rfc2047-fold-region (point-min) (point-max)))
 129                  ;; Hm.
 130                  (t))))
 131             (goto-char (point-max)))))
 132       (when mail-parse-charset
 133         (encode-coding-region (point-min) (point-max)
 134                               mail-parse-charset)))))
 135
 136 (defun rfc2047-encodable-p ()
 137   "Say whether the current (narrowed) buffer contains characters that need encoding."
 138   (let ((charsets
 139          (mapcar
 140           'mm-mime-charset
 141           (mm-find-charset-region (point-min) (point-max))))
 142         (cs (list 'us-ascii mail-parse-charset))
 143         found)
 144     (while charsets
 145       (unless (memq (pop charsets) cs)
 146         (setq found t)))
 147     found))
 148
 149 (defun rfc2047-dissect-region (b e)
 150   "Dissect the region between B and E into words."
 151   (let (words)
 152     (save-restriction
 153       (narrow-to-region b e)
 154       (goto-char (point-min))
 155       (while (re-search-forward
 156               (concat "[^" ietf-drums-tspecials " \t\n]+") nil t)
 157         (push
 158          (list (match-beginning 0) (match-end 0)
 159                (car (delq 'ascii (mm-find-charset-region
 160                                   (match-beginning 0) (match-end 0)))))
 161          words))
 162       words)))
 163
 164 (defun rfc2047-encode-region (b e)
 165   "Encode all encodable words in REGION."
 166   (let ((words (rfc2047-dissect-region b e))
 167         beg end current word)
 168     (while (setq word (pop words))
 169       (if (equal (nth 2 word) current)
 170           (setq beg (nth 0 word))
 171         (when current
 172           (rfc2047-encode beg end current))
 173         (setq current (nth 2 word)
 174               beg (nth 0 word)
 175               end (nth 1 word))))
 176     (when current
 177       (rfc2047-encode beg end current))))
 178
 179 (defun rfc2047-encode-string (string)
 180   "Encode words in STRING."
 181   (with-temp-buffer
 182     (insert string)
 183     (rfc2047-encode-region (point-min) (point-max))
 184     (buffer-string)))
 185
 186 (defun rfc2047-encode (b e charset)
 187   "Encode the word in the region with CHARSET."
 188   (let* ((mime-charset (mm-mime-charset charset))
 189          (encoding (or (cdr (assq mime-charset
 190                                   rfc2047-charset-encoding-alist))
 191                        'B))
 192          (start (concat
 193                  "=?" (downcase (symbol-name mime-charset)) "?"
 194                  (downcase (symbol-name encoding)) "?"))
 195          (first t))
 196     (save-restriction
 197       (narrow-to-region b e)
 198       (mm-encode-coding-region b e mime-charset)
 199       (funcall (cdr (assq encoding rfc2047-encoding-function-alist))
 200                (point-min) (point-max))
 201       (goto-char (point-min))
 202       (while (not (eobp))
 203         (unless first
 204           (insert " "))
 205         (setq first nil)
 206         (insert start)
 207         (end-of-line)
 208         (insert "?=")
 209         (forward-line 1)))))
 210
 211 (defun rfc2047-fold-region (b e)
 212   "Fold the long lines in the region."
 213   (save-restriction
 214     (narrow-to-region b e)
 215     (goto-char (point-min))
 216     (let ((break nil))
 217       (while (not (eobp))
 218         (cond
 219          ((memq (char-after) '(?  ?\t))
 220           (setq break (point)))
 221          ((and (not break)
 222                (looking-at "=\\?"))
 223           (setq break (point)))
 224          ((and (looking-at "\\?=")
 225                (> (- (point) (save-excursion (beginning-of-line) (point))) 76))
 226           (goto-char break)
 227           (insert "\n ")
 228           (forward-line 1)))
 229         (unless (eobp)
 230           (forward-char 1))))))
 231
 232 (defun rfc2047-b-encode-region (b e)
 233   "Encode the header contained in REGION with the B encoding."
 234   (base64-encode-region b e t)
 235   (goto-char (point-min))
 236   (while (not (eobp))
 237     (goto-char (min (point-max) (+ 64 (point))))
 238     (unless (eobp)
 239       (insert "\n"))))
 240
 241 (defun rfc2047-q-encode-region (b e)
 242   "Encode the header contained in REGION with the Q encoding."
 243   (save-excursion
 244     (save-restriction
 245       (narrow-to-region (goto-char b) e)
 246       (let ((alist rfc2047-q-encoding-alist))
 247         (while alist
 248           (when (looking-at (caar alist))
 249             (quoted-printable-encode-region b e nil (cdar alist))
 250             (subst-char-in-region (point-min) (point-max) ?  ?_)
 251             (setq alist nil))
 252           (pop alist))
 253         (goto-char (point-min))
 254         (while (not (eobp))
 255           (goto-char (min (point-max) (+ 64 (point))))
 256           (search-backward "=" (- (point) 2) t)
 257           (unless (eobp)
 258             (insert "\n")))))))
 259
 260 ;;;
 261 ;;; Functions for decoding RFC2047 messages
 262 ;;;
 263
 264 (defvar rfc2047-encoded-word-regexp
 265   "=\\?\\([^][\000-\040()<>@,\;:\\\"/?.=]+\\)\\?\\(B\\|Q\\)\\?\\([!->@-~ +]+\\)\\?=")
 266
 267 (defun rfc2047-decode-region (start end)
 268   "Decode MIME-encoded words in region between START and END."
 269   (interactive "r")
 270   (let ((case-fold-search t)
 271         b e)
 272     (save-excursion
 273       (save-restriction
 274         (narrow-to-region start end)
 275         (goto-char (point-min))
 276         ;; Remove whitespace between encoded words.
 277         (while (re-search-forward
 278                 (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 279                         "\\(\n?[ \t]\\)+"
 280                         "\\(" rfc2047-encoded-word-regexp "\\)")
 281                 nil t)
 282           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 283         ;; Decode the encoded words.
 284         (setq b (goto-char (point-min)))
 285         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 286           (setq e (match-beginning 0))
 287           (insert (rfc2047-parse-and-decode
 288                    (prog1
 289                        (match-string 0)
 290                      (delete-region (match-beginning 0) (match-end 0)))))
 291           (when (and (mm-multibyte-p)
 292                      mail-parse-charset)
 293             (mm-decode-coding-region b e mail-parse-charset))
 294           (setq b (point)))
 295         (when (and (mm-multibyte-p)
 296                    mail-parse-charset
 297                    (not (eq mail-parse-charset 'us-ascii)))
 298           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 299
 300 (defun rfc2047-decode-string (string)
 301   "Decode the quoted-printable-encoded STRING and return the results."
 302   (let ((m (mm-multibyte-p)))
 303     (with-temp-buffer
 304       (when m
 305         (mm-enable-multibyte))
 306       (insert string)
 307       (inline
 308         (rfc2047-decode-region (point-min) (point-max)))
 309       (buffer-string))))
 310
 311 (defun rfc2047-parse-and-decode (word)
 312   "Decode WORD and return it if it is an encoded word.
 313 Return WORD if not."
 314   (if (not (string-match rfc2047-encoded-word-regexp word))
 315       word
 316     (or
 317      (condition-case nil
 318          (rfc2047-decode
 319           (match-string 1 word)
 320           (upcase (match-string 2 word))
 321           (match-string 3 word))
 322        (error word))
 323      word)))
 324
 325 (defun rfc2047-decode (charset encoding string)
 326   "Decode STRING that uses CHARSET with ENCODING.
 327 Valid ENCODINGs are \"B\" and \"Q\".
 328 If your Emacs implementation can't decode CHARSET, it returns nil."
 329   (if (stringp charset)
 330     (setq charset (intern (downcase charset))))
 331   (if (or (not charset) (memq charset mail-parse-ignored-charsets))
 332       (setq charset mail-parse-charset))
 333   (let ((cs (mm-charset-to-coding-system charset)))
 334     (when cs
 335       (when (and (eq cs 'ascii)
 336                  mail-parse-charset)
 337         (setq cs mail-parse-charset))
 338       (mm-decode-coding-string
 339        (cond
 340         ((equal "B" encoding)
 341          (base64-decode-string string))
 342         ((equal "Q" encoding)
 343          (quoted-printable-decode-string
 344           (mm-replace-chars-in-string string ?_ ? )))
 345         (t (error "Invalid encoding: %s" encoding)))
 346        cs))))
 347
 348 (provide 'rfc2047)
 349
 350 ;;; rfc2047.el ends here