git.chise.org Git - elisp/gnus.git-/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- functions for encoding and decoding rfc2047 messages
   2 ;; Copyright (C) 1998, 1999, 2000, 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; RFC 2047 is "MIME (Multipurpose Internet Mail Extensions) Part
  26 ;; Three:  Message Header Extensions for Non-ASCII Text".
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   (defvar message-posting-charset)
  33   (unless (fboundp 'with-syntax-table)  ; not in Emacs 20
  34     (defmacro with-syntax-table (table &rest body)
  35       "Evaluate BODY with syntax table of current buffer set to TABLE.
  36 The syntax table of the current buffer is saved, BODY is evaluated, and the
  37 saved table is restored, even in case of an abnormal exit.
  38 Value is what BODY returns."
  39       (let ((old-table (make-symbol "table"))
  40             (old-buffer (make-symbol "buffer")))
  41         `(let ((,old-table (syntax-table))
  42                (,old-buffer (current-buffer)))
  43            (unwind-protect
  44                (progn
  45                  (set-syntax-table ,table)
  46                  ,@body)
  47              (save-current-buffer
  48                (set-buffer ,old-buffer)
  49                (set-syntax-table ,old-table))))))))
  50
  51 (require 'qp)
  52 (require 'mm-util)
  53 ;; Fixme: Avoid this (used for mail-parse-charset) mm dependence on gnus.
  54 (require 'mail-prsvr)
  55 (require 'base64)
  56 (autoload 'mm-body-7-or-8 "mm-bodies")
  57
  58 (eval-and-compile
  59   ;; Avoid gnus-util for mm- code.
  60   (defalias 'rfc2047-point-at-bol
  61     (if (fboundp 'point-at-bol)
  62         'point-at-bol
  63       'line-beginning-position))
  64
  65   (defalias 'rfc2047-point-at-eol
  66     (if (fboundp 'point-at-eol)
  67         'point-at-eol
  68       'line-end-position)))
  69
  70 (defvar rfc2047-header-encoding-alist
  71   '(("Newsgroups" . nil)
  72     ("Followup-To" . nil)
  73     ("Message-ID" . nil)
  74     ("\\(Resent-\\)?\\(From\\|Cc\\|To\\|Bcc\\|Reply-To\\|Sender\
  75 \\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\)" . address-mime)
  76     (t . mime))
  77   "*Header/encoding method alist.
  78 The list is traversed sequentially.  The keys can either be
  79 header regexps or t.
  80
  81 The values can be:
  82
  83 1) nil, in which case no encoding is done;
  84 2) `mime', in which case the header will be encoded according to RFC2047;
  85 3) `address-mime', like `mime', but takes account of the rules for address
  86    fields (where quoted strings and comments must be treated separately);
  87 4) a charset, in which case it will be encoded as that charset;
  88 5) `default', in which case the field will be encoded as the rest
  89    of the article.")
  90
  91 (defvar rfc2047-charset-encoding-alist
  92   '((us-ascii . nil)
  93     (iso-8859-1 . Q)
  94     (iso-8859-2 . Q)
  95     (iso-8859-3 . Q)
  96     (iso-8859-4 . Q)
  97     (iso-8859-5 . B)
  98     (koi8-r . B)
  99     (iso-8859-7 . B)
 100     (iso-8859-8 . B)
 101     (iso-8859-9 . Q)
 102     (iso-8859-14 . Q)
 103     (iso-8859-15 . Q)
 104     (iso-2022-jp . B)
 105     (iso-2022-kr . B)
 106     (gb2312 . B)
 107     (big5 . B)
 108     (cn-big5 . B)
 109     (cn-gb . B)
 110     (cn-gb-2312 . B)
 111     (euc-kr . B)
 112     (iso-2022-jp-2 . B)
 113     (iso-2022-int-1 . B)
 114     (viscii . Q))
 115   "Alist of MIME charsets to RFC2047 encodings.
 116 Valid encodings are nil, `Q' and `B'.  These indicate binary (no) encoding,
 117 quoted-printable and base64 respectively.")
 118
 119 (defvar rfc2047-encoding-function-alist
 120   '((Q . rfc2047-q-encode-region)
 121     (B . rfc2047-b-encode-region)
 122     (nil . ignore))
 123   "Alist of RFC2047 encodings to encoding functions.")
 124
 125 ;;;
 126 ;;; Functions for encoding RFC2047 messages
 127 ;;;
 128
 129 (defun rfc2047-narrow-to-field ()
 130   "Narrow the buffer to the header on the current line."
 131   (beginning-of-line)
 132   (narrow-to-region
 133    (point)
 134    (progn
 135      (forward-line 1)
 136      (if (re-search-forward "^[^ \n\t]" nil t)
 137          (rfc2047-point-at-bol)
 138        (point-max))))
 139   (goto-char (point-min)))
 140
 141 (defun rfc2047-field-value ()
 142   "Return the value of the field at point."
 143   (save-excursion
 144     (save-restriction
 145       (rfc2047-narrow-to-field)
 146       (re-search-forward ":[ \t\n]*" nil t)
 147       (buffer-substring (point) (point-max)))))
 148
 149 (defvar rfc2047-encoding-type 'address-mime
 150   "The type of encoding done by `rfc2047-encode-region'.
 151 This should be dynamically bound around calls to
 152 `rfc2047-encode-region' to either `mime' or `address-mime'.  See
 153 `rfc2047-header-encoding-alist', for definitions.")
 154
 155 (defun rfc2047-encode-message-header ()
 156   "Encode the message header according to `rfc2047-header-encoding-alist'.
 157 Should be called narrowed to the head of the message."
 158   (interactive "*")
 159   (save-excursion
 160     (goto-char (point-min))
 161     (let (alist elem method)
 162       (while (not (eobp))
 163         (save-restriction
 164           (rfc2047-narrow-to-field)
 165           (if (not (rfc2047-encodable-p))
 166               (prog1
 167                 (if (and (eq (mm-body-7-or-8) '8bit)
 168                          (mm-multibyte-p)
 169                          (mm-coding-system-p
 170                           (car message-posting-charset)))
 171                     ;; 8 bit must be decoded.
 172                     (mm-encode-coding-region
 173                      (point-min) (point-max)
 174                      (mm-charset-to-coding-system
 175                       (car message-posting-charset))))
 176                 ;; No encoding necessary, but folding is nice
 177                 (rfc2047-fold-region
 178                  (save-excursion
 179                    (goto-char (point-min))
 180                    (skip-chars-forward "^:")
 181                    (when (looking-at ": ")
 182                      (forward-char 2))
 183                    (point))
 184                  (point-max)))
 185             ;; We found something that may perhaps be encoded.
 186             (setq method nil
 187                   alist rfc2047-header-encoding-alist)
 188             (while (setq elem (pop alist))
 189               (when (or (and (stringp (car elem))
 190                              (looking-at (car elem)))
 191                         (eq (car elem) t))
 192                 (setq alist nil
 193                       method (cdr elem))))
 194             (goto-char (point-min))
 195             (re-search-forward "^[^:]+: *" nil t)
 196             (cond
 197              ((eq method 'address-mime)
 198               (rfc2047-encode-region (point) (point-max)))
 199              ((eq method 'mime)
 200               (let ((rfc2047-encoding-type 'mime))
 201                 (rfc2047-encode-region (point) (point-max))))
 202              ((eq method 'default)
 203               (if (and (featurep 'mule)
 204                        (if (boundp 'default-enable-multibyte-characters)
 205                            default-enable-multibyte-characters)
 206                        mail-parse-charset)
 207                   (mm-encode-coding-region (point) (point-max)
 208                                            mail-parse-charset)))
 209              ;; We get this when CC'ing messsages to newsgroups with
 210              ;; 8-bit names.  The group name mail copy just got
 211              ;; unconditionally encoded.  Previously, it would ask
 212              ;; whether to encode, which was quite confusing for the
 213              ;; user.  If the new behaviour is wrong, tell me. I have
 214              ;; left the old code commented out below.
 215              ;; -- Per Abrahamsen <abraham@dina.kvl.dk> Date: 2001-10-07.
 216              ;; Modified by Dave Love, with the commented-out code changed
 217              ;; in accordance with changes elsewhere.
 218              ((null method)
 219               (rfc2047-encode-region (point) (point-max)))
 220 ;;;          ((null method)
 221 ;;;           (if (or (message-options-get
 222 ;;;                    'rfc2047-encode-message-header-encode-any)
 223 ;;;                   (message-options-set
 224 ;;;                    'rfc2047-encode-message-header-encode-any
 225 ;;;                    (y-or-n-p
 226 ;;;                     "Some texts are not encoded. Encode anyway?")))
 227 ;;;               (rfc2047-encode-region (point-min) (point-max))
 228 ;;;             (error "Cannot send unencoded text")))
 229              ((mm-coding-system-p method)
 230               (if (and (featurep 'mule)
 231                        (if (boundp 'default-enable-multibyte-characters)
 232                            default-enable-multibyte-characters))
 233                   (mm-encode-coding-region (point) (point-max) method)))
 234              ;; Hm.
 235              (t)))
 236           (goto-char (point-max)))))))
 237
 238 ;; Fixme: This, and the require below may not be the Right Thing, but
 239 ;; should be safe just before release.  -- fx 2001-02-08
 240 (eval-when-compile (defvar message-posting-charset))
 241
 242 (defun rfc2047-encodable-p ()
 243   "Return non-nil if any characters in current buffer need encoding in headers.
 244 The buffer may be narrowed."
 245   (require 'message)                    ; for message-posting-charset
 246   (let ((charsets
 247          (mm-find-mime-charset-region (point-min) (point-max))))
 248     (and charsets
 249          (not (equal charsets (list (car message-posting-charset)))))))
 250
 251 ;; Use this syntax table when parsing into regions that may need
 252 ;; encoding.  Double quotes are string delimiters, backslash is
 253 ;; character quoting, and all other RFC 2822 special characters are
 254 ;; treated as punctuation so we can use forward-sexp/forward-word to
 255 ;; skip to the end of regions appropriately.  Nb. ietf-drums does
 256 ;; things differently.
 257 (defconst rfc2047-syntax-table
 258   ;; (make-char-table 'syntax-table '(2)) only works in Emacs.
 259   (let ((table (make-syntax-table)))
 260     ;; The following is done to work for setting all elements of the table
 261     ;; in Emacs 21 and 22 and XEmacs; it appears to be the cleanest way.
 262     ;; Play safe and don't assume the form of the word syntax entry --
 263     ;; copy it from ?a.
 264     (if (fboundp 'set-char-table-range) ; Emacs
 265         (funcall (intern "set-char-table-range")
 266                  table t (aref (standard-syntax-table) ?a))
 267       (if (fboundp 'put-char-table)
 268           (if (fboundp 'get-char-table) ; warning avoidance
 269               (put-char-table t (get-char-table ?a (standard-syntax-table))
 270                               table))))
 271     (modify-syntax-entry ?\\ "\\" table)
 272     (modify-syntax-entry ?\" "\"" table)
 273     (modify-syntax-entry ?\( "." table)
 274     (modify-syntax-entry ?\) "." table)
 275     (modify-syntax-entry ?\< "." table)
 276     (modify-syntax-entry ?\> "." table)
 277     (modify-syntax-entry ?\[ "." table)
 278     (modify-syntax-entry ?\] "." table)
 279     (modify-syntax-entry ?: "." table)
 280     (modify-syntax-entry ?\; "." table)
 281     (modify-syntax-entry ?, "." table)
 282     (modify-syntax-entry ?@ "." table)
 283     table))
 284
 285 (defun rfc2047-encode-region (b e)
 286   "Encode words in region B to E that need encoding.
 287 By default, the region is treated as containing RFC2822 addresses.
 288 Dynamically bind `rfc2047-encoding-type' to change that."
 289   (save-restriction
 290     (narrow-to-region b e)
 291     (if (eq 'mime rfc2047-encoding-type)
 292         ;; Simple case.  Treat as single word after any initial ASCII
 293         ;; part and before any tailing ASCII part.  The leading ASCII
 294         ;; is relevant for instance in Subject headers with `Re:' for
 295         ;; interoperability with non-MIME clients, and we might as
 296         ;; well avoid the tail too.
 297         (progn
 298           (goto-char (point-min))
 299           ;; Does it need encoding?
 300           (skip-chars-forward "\000-\177")
 301           (unless (eobp)
 302             (skip-chars-backward "^ \n") ; beginning of space-delimited word
 303             (rfc2047-encode (point) (progn
 304                                       (goto-char e)
 305                                       (skip-chars-backward "\000-\177")
 306                                       (skip-chars-forward "^ \n")
 307                                       ;; end of space-delimited word
 308                                       (point)))))
 309       ;; `address-mime' case -- take care of quoted words, comments.
 310       (with-syntax-table rfc2047-syntax-table
 311         (let ((start)                   ; start of current token
 312               end                       ; end of current token
 313               ;; Whether there's an encoded word before the current
 314               ;; token, either immediately or separated by space.
 315               last-encoded)
 316           (goto-char (point-min))
 317           (condition-case nil           ; in case of unbalanced quotes
 318               ;; Look for rfc2822-style: sequences of atoms, quoted
 319               ;; strings, specials, whitespace.  (Specials mustn't be
 320               ;; encoded.)
 321               (while (not (eobp))
 322                 (setq start (point))
 323                 ;; Skip whitespace.
 324                 (unless (= 0 (skip-chars-forward " \t\n"))
 325                   (setq start (point)))
 326                 (cond
 327                  ((not (char-after)))   ; eob
 328                  ;; else token start
 329                  ((eq ?\" (char-syntax (char-after)))
 330                   ;; Quoted word.
 331                   (forward-sexp)
 332                   (setq end (point))
 333                   ;; Does it need encoding?
 334                   (goto-char start)
 335                   (skip-chars-forward "\000-\177" end)
 336                   (if (= end (point))
 337                       (setq last-encoded  nil)
 338                     ;; It needs encoding.  Strip the quotes first,
 339                     ;; since encoded words can't occur in quotes.
 340                     (goto-char end)
 341                     (delete-backward-char 1)
 342                     (goto-char start)
 343                     (delete-char 1)
 344                     (when last-encoded
 345                       ;; There was a preceding quoted word.  We need
 346                       ;; to include any separating whitespace in this
 347                       ;; word to avoid it getting lost.
 348                       (skip-chars-backward " \t")
 349                       ;; A space is needed between the encoded words.
 350                       (insert ? )
 351                       (setq start (point)
 352                             end (1+ end)))
 353                     ;; Adjust the end position for the deleted quotes.
 354                     (rfc2047-encode start (- end 2))
 355                     (setq last-encoded t))) ; record that it was encoded
 356                  ((eq ?. (char-syntax (char-after)))
 357                   ;; Skip other delimiters, but record that they've
 358                   ;; potentially separated quoted words.
 359                   (forward-char)
 360                   (setq last-encoded nil))
 361                  (t                 ; normal token/whitespace sequence
 362                   ;; Find the end.
 363                   (forward-word 1)
 364                   (skip-chars-backward " \t")
 365                   (setq end (point))
 366                   ;; Deal with encoding and leading space as for
 367                   ;; quoted words.
 368                   (goto-char start)
 369                   (skip-chars-forward "\000-\177" end)
 370                   (if (= end (point))
 371                       (setq last-encoded  nil)
 372                     (when last-encoded
 373                       (goto-char start)
 374                       (skip-chars-backward " \t")
 375                       (insert ? )
 376                       (setq start (point)
 377                             end (1+ end)))
 378                     (rfc2047-encode start end)
 379                     (setq last-encoded t)))))
 380             (error
 381              (error "Invalid data for rfc2047 encoding: %s"
 382                     (buffer-substring b e)))))))
 383     (rfc2047-fold-region b (point))))
 384
 385 (defun rfc2047-encode-string (string)
 386   "Encode words in STRING.
 387 By default, the string is treated as containing addresses (see
 388 `rfc2047-encoding-type')."
 389   (with-temp-buffer
 390     (insert string)
 391     (rfc2047-encode-region (point-min) (point-max))
 392     (buffer-string)))
 393
 394 (defun rfc2047-encode (b e)
 395   "Encode the word(s) in the region B to E.
 396 By default, the region is treated as containing addresses (see
 397 `rfc2047-encoding-type')."
 398   (let* ((mime-charset (mm-find-mime-charset-region b e))
 399          (cs (if (> (length mime-charset) 1)
 400                  ;; Fixme: Instead of this, try to break region into
 401                  ;; parts that can be encoded separately.
 402                  (error "Can't rfc2047-encode `%s'"
 403                         (buffer-substring b e))
 404                (setq mime-charset (car mime-charset))
 405                (mm-charset-to-coding-system mime-charset)))
 406          ;; Fixme: Better, calculate the number of non-ASCII
 407          ;; characters, at least for 8-bit charsets.
 408          (encoding (or (cdr (assq mime-charset
 409                                   rfc2047-charset-encoding-alist))
 410                        ;; For the charsets that don't have a preferred
 411                        ;; encoding, choose the one that's shorter.
 412                        (save-restriction
 413                          (narrow-to-region b e)
 414                          (if (eq (mm-qp-or-base64) 'base64)
 415                              'B
 416                            'Q))))
 417          (start (concat
 418                  "=?" (downcase (symbol-name mime-charset)) "?"
 419                  (downcase (symbol-name encoding)) "?"))
 420          (factor (case mime-charset
 421                    ((iso-8859-5 iso-8859-7 iso-8859-8 koi8-r) 1)
 422                    ((big5 gb2312 euc-kr) 2)
 423                    (utf-8 4)
 424                    (t 8)))
 425          (pre (- b (save-restriction
 426                      (widen)
 427                      (rfc2047-point-at-bol))))
 428          ;; encoded-words must not be longer than 75 characters,
 429          ;; including charset, encoding etc.  This leaves us with
 430          ;; 75 - (length start) - 2 - 2 characters.  The last 2 is for
 431          ;; possible base64 padding.  In the worst case (iso-2022-*)
 432          ;; each character expands to 8 bytes which is expanded by a
 433          ;; factor of 4/3 by base64 encoding.
 434          (length (floor (- 75 (length start) 4) (* factor (/ 4.0 3.0))))
 435          ;; Limit line length to 76 characters.
 436          (length1 (max 1 (floor (- 76 (length start) 4 pre)
 437                                 (* factor (/ 4.0 3.0)))))
 438          (first t))
 439     (if mime-charset
 440         (save-restriction
 441           (narrow-to-region b e)
 442           (when (eq encoding 'B)
 443             ;; break into lines before encoding
 444             (goto-char (point-min))
 445             (while (not (eobp))
 446               (if first
 447                   (progn
 448                     (goto-char (min (point-max) (+ length1 (point))))
 449                     (setq first nil))
 450                 (goto-char (min (point-max) (+ length (point)))))
 451               (unless (eobp)
 452                 (insert ?\n)))
 453             (setq first t))
 454           (if (and (mm-multibyte-p)
 455                    (mm-coding-system-p cs))
 456               (mm-encode-coding-region (point-min) (point-max) cs))
 457           (funcall (cdr (assq encoding rfc2047-encoding-function-alist))
 458                    (point-min) (point-max))
 459           (goto-char (point-min))
 460           (while (not (eobp))
 461             (unless first
 462               (insert ? ))
 463             (setq first nil)
 464             (insert start)
 465             (end-of-line)
 466             (insert "?=")
 467             (forward-line 1))))))
 468
 469 (defun rfc2047-fold-field ()
 470   "Fold the current header field."
 471   (save-excursion
 472     (save-restriction
 473       (rfc2047-narrow-to-field)
 474       (rfc2047-fold-region (point-min) (point-max)))))
 475
 476 (defun rfc2047-fold-region (b e)
 477   "Fold long lines in region B to E."
 478   (save-restriction
 479     (narrow-to-region b e)
 480     (goto-char (point-min))
 481     (let ((break nil)
 482           (qword-break nil)
 483           (first t)
 484           (bol (save-restriction
 485                  (widen)
 486                  (rfc2047-point-at-bol))))
 487       (while (not (eobp))
 488         (when (and (or break qword-break)
 489                    (> (- (point) bol) 76))
 490           (goto-char (or break qword-break))
 491           (setq break nil
 492                 qword-break nil)
 493           (if (looking-at "[ \t]")
 494               (insert ?\n)
 495             (insert "\n "))
 496           (setq bol (1- (point)))
 497           ;; Don't break before the first non-LWSP characters.
 498           (skip-chars-forward " \t")
 499           (unless (eobp)
 500             (forward-char 1)))
 501         (cond
 502          ((eq (char-after) ?\n)
 503           (forward-char 1)
 504           (setq bol (point)
 505                 break nil
 506                 qword-break nil)
 507           (skip-chars-forward " \t")
 508           (unless (or (eobp) (eq (char-after) ?\n))
 509             (forward-char 1)))
 510          ((eq (char-after) ?\r)
 511           (forward-char 1))
 512          ((memq (char-after) '(?  ?\t))
 513           (skip-chars-forward " \t")
 514           (if first
 515               ;; Don't break just after the header name.
 516               (setq first nil)
 517             (setq break (1- (point)))))
 518          ((not break)
 519           (if (not (looking-at "=\\?[^=]"))
 520               (if (eq (char-after) ?=)
 521                   (forward-char 1)
 522                 (skip-chars-forward "^ \t\n\r="))
 523             ;; Don't break at the start of the field.
 524             (unless (= (point) b)
 525               (setq qword-break (point)))
 526             (skip-chars-forward "^ \t\n\r")))
 527          (t
 528           (skip-chars-forward "^ \t\n\r"))))
 529       (when (and (or break qword-break)
 530                  (> (- (point) bol) 76))
 531         (goto-char (or break qword-break))
 532         (setq break nil
 533               qword-break nil)
 534           (if (looking-at "[ \t]")
 535               (insert ?\n)
 536             (insert "\n "))
 537         (setq bol (1- (point)))
 538         ;; Don't break before the first non-LWSP characters.
 539         (skip-chars-forward " \t")
 540         (unless (eobp)
 541           (forward-char 1))))))
 542
 543 (defun rfc2047-unfold-field ()
 544   "Fold the current line."
 545   (save-excursion
 546     (save-restriction
 547       (rfc2047-narrow-to-field)
 548       (rfc2047-unfold-region (point-min) (point-max)))))
 549
 550 (defun rfc2047-unfold-region (b e)
 551   "Unfold lines in region B to E."
 552   (save-restriction
 553     (narrow-to-region b e)
 554     (goto-char (point-min))
 555     (let ((bol (save-restriction
 556                  (widen)
 557                  (rfc2047-point-at-bol)))
 558           (eol (rfc2047-point-at-eol)))
 559       (forward-line 1)
 560       (while (not (eobp))
 561         (if (and (looking-at "[ \t]")
 562                  (< (- (rfc2047-point-at-eol) bol) 76))
 563             (delete-region eol (progn
 564                                  (goto-char eol)
 565                                  (skip-chars-forward "\r\n")
 566                                  (point)))
 567           (setq bol (rfc2047-point-at-bol)))
 568         (setq eol (rfc2047-point-at-eol))
 569         (forward-line 1)))))
 570
 571 (defun rfc2047-b-encode-region (b e)
 572   "Base64-encode the header contained in region B to E."
 573   (save-restriction
 574     (narrow-to-region (goto-char b) e)
 575     (while (not (eobp))
 576       (base64-encode-region (point) (progn (end-of-line) (point)) t)
 577       (if (and (bolp) (eolp))
 578           (delete-backward-char 1))
 579       (forward-line))))
 580
 581 (defun rfc2047-q-encode-region (b e)
 582   "Quoted-printable-encode the header in region B to E."
 583   (save-excursion
 584     (save-restriction
 585       (narrow-to-region (goto-char b) e)
 586       (let ((bol (save-restriction
 587                    (widen)
 588                    (rfc2047-point-at-bol))))
 589         (quoted-printable-encode-region
 590          b e nil
 591          ;; = (\075), _ (\137), ? (\077) are used in the encoded word.
 592          ;; Avoid using 8bit characters.
 593          ;; This list excludes `especials' (see the RFC2047 syntax),
 594          ;; meaning that some characters in non-structured fields will
 595          ;; get encoded when they con't need to be.  The following is
 596          ;; what it used to be.
 597 ;;;      ;; Equivalent to "^\000-\007\011\013\015-\037\200-\377=_?"
 598 ;;;      "\010\012\014\040-\074\076\100-\136\140-\177")
 599          "-\b\n\f !#-'*+0-9A-Z\\^`-~\d")
 600         (subst-char-in-region (point-min) (point-max) ?  ?_)
 601         ;; The size of QP encapsulation is about 20, so set limit to
 602         ;; 56=76-20.
 603         (unless (< (- (point-max) (point-min)) 56)
 604           ;; Don't break if it could fit in one line.
 605           ;; Let rfc2047-encode-region break it later.
 606           (goto-char (1+ (point-min)))
 607           (while (and (not (bobp)) (not (eobp)))
 608             (goto-char (min (point-max) (+ 56 bol)))
 609             (search-backward "=" (- (point) 2) t)
 610             (unless (or (bobp) (eobp))
 611               (insert ?\n)
 612               (setq bol (point)))))))))
 613
 614 ;;;
 615 ;;; Functions for decoding RFC2047 messages
 616 ;;;
 617
 618 (eval-and-compile
 619   (defconst rfc2047-encoded-word-regexp
 620     "=\\?\\([^][\000-\040()<>@,\;:\\\"/?.=]+\\)\\?\\(B\\|Q\\)\
 621 \\?\\([!->@-~ +]*\\)\\?="))
 622
 623 ;; Fixme: This should decode in place, not cons intermediate strings.
 624 ;; Also check whether it needs to worry about delimiting fields like
 625 ;; encoding.
 626
 627 ;; In fact it's reported that (invalid) encoding of mailboxes in
 628 ;; addr-specs is in use, so delimiting fields might help.  Probably
 629 ;; not decoding a word which isn't properly delimited is good enough
 630 ;; and worthwhile (is it more correct or not?), e.g. something like
 631 ;; `=?iso-8859-1?q?foo?=@'.
 632
 633 (defun rfc2047-decode-region (start end)
 634   "Decode MIME-encoded words in region between START and END."
 635   (interactive "r")
 636   (let ((case-fold-search t)
 637         b e)
 638     (save-excursion
 639       (save-restriction
 640         (narrow-to-region start end)
 641         (goto-char (point-min))
 642         ;; Remove whitespace between encoded words.
 643         (while (re-search-forward
 644                 (eval-when-compile
 645                   (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 646                           "\\(\n?[ \t]\\)+"
 647                           "\\(" rfc2047-encoded-word-regexp "\\)"))
 648                 nil t)
 649           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 650         ;; Decode the encoded words.
 651         (setq b (goto-char (point-min)))
 652         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 653           (setq e (match-beginning 0))
 654           (insert (rfc2047-parse-and-decode
 655                    (prog1
 656                        (match-string 0)
 657                      (delete-region (match-beginning 0) (match-end 0)))))
 658           ;; Remove newlines between decoded words, though such things
 659           ;; essentially must not be there.
 660           (save-restriction
 661             (narrow-to-region e (point))
 662             (goto-char e)
 663             (while (re-search-forward "[\n\r]+" nil t)
 664               (replace-match " "))
 665             (goto-char (point-max)))
 666           (when (and (mm-multibyte-p)
 667                      mail-parse-charset
 668                      (not (eq mail-parse-charset 'us-ascii))
 669                      (not (eq mail-parse-charset 'gnus-decoded)))
 670             (mm-decode-coding-region b e mail-parse-charset))
 671           (setq b (point)))
 672         (when (and (mm-multibyte-p)
 673                    mail-parse-charset
 674                    (not (eq mail-parse-charset 'us-ascii))
 675                    (not (eq mail-parse-charset 'gnus-decoded)))
 676           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 677
 678 (defun rfc2047-decode-string (string)
 679   "Decode the quoted-printable-encoded STRING and return the results."
 680   (let ((m (mm-multibyte-p)))
 681     (if (string-match "=\\?" string)
 682         (with-temp-buffer
 683           ;; Fixme: This logic is wrong, but seems to be required by
 684           ;; Gnus summary buffer generation.  The value of `m' depends
 685           ;; on the current buffer, not global multibyteness or that
 686           ;; of the string.  Also the string returned should always be
 687           ;; multibyte in a multibyte session, i.e. the buffer should
 688           ;; be multibyte before `buffer-string' is called.
 689           (when m
 690             (mm-enable-multibyte))
 691           (insert string)
 692           (inline
 693             (rfc2047-decode-region (point-min) (point-max)))
 694           (buffer-string))
 695       ;; Fixme: As above, `m' here is inappropriate.
 696       (if (and m
 697                mail-parse-charset
 698                (not (eq mail-parse-charset 'us-ascii))
 699                (not (eq mail-parse-charset 'gnus-decoded)))
 700           (mm-decode-coding-string string mail-parse-charset)
 701         (mm-string-as-multibyte string)))))
 702
 703 (defun rfc2047-parse-and-decode (word)
 704   "Decode WORD and return it if it is an encoded word.
 705 Return WORD if it is not not an encoded word or if the charset isn't
 706 decodable."
 707   (if (not (string-match rfc2047-encoded-word-regexp word))
 708       word
 709     (or
 710      (condition-case nil
 711          (rfc2047-decode
 712           (match-string 1 word)
 713           (upcase (match-string 2 word))
 714           (match-string 3 word))
 715        (error word))
 716      word)))                            ; un-decodable
 717
 718 (defun rfc2047-pad-base64 (string)
 719   "Pad STRING to quartets."
 720   ;; Be more liberal to accept buggy base64 strings. If
 721   ;; base64-decode-string accepts buggy strings, this function could
 722   ;; be aliased to identity.
 723   (case (mod (length string) 4)
 724     (0 string)
 725     (1 string) ;; Error, don't pad it.
 726     (2 (concat string "=="))
 727     (3 (concat string "="))))
 728
 729 (defun rfc2047-decode (charset encoding string)
 730   "Decode STRING from the given MIME CHARSET in the given ENCODING.
 731 Valid ENCODINGs are \"B\" and \"Q\".
 732 If your Emacs implementation can't decode CHARSET, return nil."
 733   (if (stringp charset)
 734       (setq charset (intern (downcase charset))))
 735   (if (or (not charset)
 736           (eq 'gnus-all mail-parse-ignored-charsets)
 737           (memq 'gnus-all mail-parse-ignored-charsets)
 738           (memq charset mail-parse-ignored-charsets))
 739       (setq charset mail-parse-charset))
 740   (let ((cs (mm-charset-to-coding-system charset)))
 741     (if (and (not cs) charset
 742              (listp mail-parse-ignored-charsets)
 743              (memq 'gnus-unknown mail-parse-ignored-charsets))
 744         (setq cs (mm-charset-to-coding-system mail-parse-charset)))
 745     (when cs
 746       (when (and (eq cs 'ascii)
 747                  mail-parse-charset)
 748         (setq cs mail-parse-charset))
 749       (mm-decode-coding-string
 750        (cond
 751         ((equal "B" encoding)
 752          (base64-decode-string
 753           (rfc2047-pad-base64 string)))
 754         ((equal "Q" encoding)
 755          (quoted-printable-decode-string
 756           (mm-replace-chars-in-string string ?_ ? )))
 757         (t (error "Invalid encoding: %s" encoding)))
 758        cs))))
 759
 760 (provide 'rfc2047)
 761
 762 ;;; rfc2047.el ends here