git.chise.org Git - elisp/gnus.git-/blob - lisp/smiley-ems.el

   1 ;;; smiley-ems.el --- displaying smiley faces
   2
   3 ;; Copyright (C) 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;; Keywords: news mail multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; A re-written, simplified version of Wes Hardaker's XEmacs smiley.el
  28 ;; which might be merged back to smiley.el if we get an assignment for
  29 ;; that.  We don't have assignments for the images smiley.el uses, but
  30 ;; I'm not sure we need that degree of rococoness and defaults like a
  31 ;; yellow background.  Also, using PBM means we can display the images
  32 ;; more generally.  -- fx
  33
  34 ;;; Test smileys:  :-) :-\ :-( :-/
  35
  36 ;;; Code:
  37
  38 (eval-when-compile (require 'cl))
  39 (require 'nnheader)
  40
  41 (defgroup smiley nil
  42   "Turn :-)'s into real images."
  43   :group 'gnus-visual)
  44
  45 ;; Maybe this should go.
  46 (defcustom smiley-data-directory (nnheader-find-etc-directory "smilies")
  47   "*Location of the smiley faces files."
  48   :type 'directory
  49   :group 'smiley)
  50
  51 ;; The XEmacs version has a baroque, if not rococo, set of these.
  52 (defcustom smiley-regexp-alist
  53   ;; Perhaps :-) should be distinct -- it does appear in the Jargon File.
  54   '(("\\([:;]-?)\\)\\W" 1 "smile.pbm")
  55     ("\\(:-[/\\]\\)\\W" 1 "wry.pbm")
  56     ("\\(:-[({]\\)\\W" 1 "frown.pbm"))
  57   "*A list of regexps to map smilies to images.
  58 The elements are (REGEXP MATCH FILE), where MATCH is the submatch in
  59 rgexp to replace with IMAGE.  IMAGE is the name of a PBM file in
  60 `smiley-data-directory'."
  61   :type '(repeat (list regexp
  62                        (integer :tag "Regexp match number")
  63                        (string :tag "Image name")))
  64   :set (lambda (symbol value)
  65          (set-default symbol value)
  66          (smiley-update-cache))
  67   :initialize 'custom-initialize-default
  68   :group 'smiley)
  69
  70 (defvar smiley-cached-regexp-alist nil)
  71
  72 (defun smiley-update-cache ()
  73   (dolist (elt (if (symbolp smiley-regexp-alist)
  74                    (symbol-value smiley-regexp-alist)
  75                  smiley-regexp-alist))
  76     (let* ((data-directory smiley-data-directory)
  77            (image (find-image (list (list :type 'pbm
  78                                           :file (nth 2 elt)
  79                                           :ascent 'center)))))
  80       (if image
  81           (push (list (car elt) (cadr elt) image)
  82                 smiley-cached-regexp-alist)))))
  83
  84 (defvar smiley-active nil
  85   "Non-nil means smilies in the buffer will be displayed.")
  86 (make-variable-buffer-local 'smiley-active)
  87
  88 (defvar smiley-mouse-map
  89   (let ((map (make-sparse-keymap)))
  90     (define-key map [down-mouse-2] 'ignore) ; override widget
  91     (define-key map [mouse-2]
  92       'smiley-mouse-toggle-buffer)
  93     map))
  94
  95 (defun smiley-region (start end)
  96   "Replace in the region `smiley-regexp-alist' matches with corresponding images."
  97   (interactive "r")
  98   (when (and (fboundp 'display-graphic-p)
  99              (display-graphic-p))
 100     (mapcar (lambda (o)
 101               (if (eq 'smiley (overlay-get o 'smiley))
 102                   (delete-overlay o)))
 103             (overlays-in start end))
 104     (unless smiley-cached-regexp-alist
 105       (smiley-update-cache))
 106     (save-excursion
 107       (let ((beg (or start (point-min)))
 108             group overlay image)
 109         (dolist (entry smiley-cached-regexp-alist)
 110           (setq group (nth 1 entry)
 111                 image (nth 2 entry))
 112           (goto-char beg)
 113           (while (re-search-forward (car entry) end t)
 114             (when image
 115               (setq overlay (make-overlay (match-beginning group)
 116                                           (match-end group)))
 117               (overlay-put overlay
 118                            'display `(when smiley-active ,@image))
 119               (overlay-put overlay 'mouse-face 'highlight)
 120               (overlay-put overlay 'smiley t)
 121               (overlay-put overlay
 122                            'help-echo "mouse-2: toggle smilies in buffer")
 123               (overlay-put overlay 'keymap smiley-mouse-map))))))
 124     (setq smiley-active t)))
 125
 126 (defun smiley-toggle-buffer (&optional arg)
 127   "Toggle displaying smiley faces.
 128 With arg, turn displaying on if and only if arg is positive."
 129   (interactive "P")
 130   (if (numberp arg)
 131       (setq smiley-active (> arg 0))
 132     (setq smiley-active (not smiley-active))))
 133
 134 (defun smiley-mouse-toggle-buffer (event)
 135   "Toggle displaying smiley faces.
 136 With arg, turn displaying on if and only if arg is positive."
 137   (interactive "e")
 138   (save-excursion
 139     (save-window-excursion
 140       (mouse-set-point event)
 141       (smiley-toggle-buffer))))
 142
 143 (eval-when-compile (defvar gnus-article-buffer))
 144
 145 (defun gnus-smiley-display (&optional arg)
 146   "Display textual emoticaons (\"smilies\") as small graphical icons.
 147 With arg, turn displaying on if and only if arg is positive."
 148   (interactive "P")
 149   (save-excursion
 150     (article-goto-body)
 151     (smiley-region (point) (point-max))
 152     (if (and (numberp arg) (<= arg 0))
 153         (smiley-toggle-buffer arg))))
 154
 155 (provide 'smiley)
 156
 157 ;;; smiley-ems.el ends here