git.chise.org Git - elisp/gnus.git-/blob - lisp/spam.el

   1 ;;; spam.el --- Identifying spam
   2 ;; Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam control under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; The integration with Gnus is not yet complete.  See various `FIXME'
  31 ;;; comments, below, for supplementary explanations or discussions.
  32
  33 ;;; Several TODO items are marked as such
  34
  35 ;;; Code:
  36
  37 (require 'gnus-sum)
  38
  39 (require 'gnus-uu)                      ; because of key prefix issues
  40 (require 'gnus) ; for the definitions of group content classification and spam processors
  41 (require 'message)                      ;for the message-fetch-field functions
  42
  43 ;; for nnimap-split-download-body-default
  44 (eval-when-compile (require 'nnimap))
  45
  46 ;; autoload executable-find
  47 (eval-and-compile
  48   ;; executable-find is not autoloaded in Emacs 20
  49   (autoload 'executable-find "executable"))
  50
  51 ;; autoload query-dig
  52 (eval-and-compile
  53   (autoload 'query-dig "dig"))
  54
  55 ;; autoload query-dns
  56 (eval-and-compile
  57   (autoload 'query-dns "dns"))
  58
  59 ;;; Main parameters.
  60
  61 (defgroup spam nil
  62   "Spam configuration.")
  63
  64 (defcustom spam-directory "~/News/spam/"
  65   "Directory for spam whitelists and blacklists."
  66   :type 'directory
  67   :group 'spam)
  68
  69 (defcustom spam-move-spam-nonspam-groups-only t
  70   "Whether spam should be moved in non-spam groups only.
  71 When nil, only ham and unclassified groups will have their spam moved
  72 to the spam-process-destination.  When t, spam will also be moved from
  73 spam groups."
  74   :type 'boolean
  75   :group 'spam)
  76
  77 (defcustom spam-mark-ham-unread-before-move-from-spam-group nil
  78   "Whether ham should be marked unread before it's moved out of a spam
  79 group according to ham-process-destination.  This variable is an
  80 official entry in the international Longest Variable Name
  81 Competition."
  82   :type 'boolean
  83   :group 'spam)
  84
  85 (defcustom spam-whitelist (expand-file-name "whitelist" spam-directory)
  86   "The location of the whitelist.
  87 The file format is one regular expression per line.
  88 The regular expression is matched against the address."
  89   :type 'file
  90   :group 'spam)
  91
  92 (defcustom spam-blacklist (expand-file-name "blacklist" spam-directory)
  93   "The location of the blacklist.
  94 The file format is one regular expression per line.
  95 The regular expression is matched against the address."
  96   :type 'file
  97   :group 'spam)
  98
  99 (defcustom spam-use-dig t
 100   "Whether query-dig should be used instead of query-dns."
 101   :type 'boolean
 102   :group 'spam)
 103
 104 (defcustom spam-use-blacklist nil
 105   "Whether the blacklist should be used by spam-split."
 106   :type 'boolean
 107   :group 'spam)
 108
 109 (defcustom spam-use-whitelist nil
 110   "Whether the whitelist should be used by spam-split."
 111   :type 'boolean
 112   :group 'spam)
 113
 114 (defcustom spam-use-whitelist-exclusive nil
 115   "Whether whitelist-exclusive should be used by spam-split.
 116 Exclusive whitelisting means that all messages from senders not in the whitelist
 117 are considered spam."
 118   :type 'boolean
 119   :group 'spam)
 120
 121 (defcustom spam-use-blackholes nil
 122   "Whether blackholes should be used by spam-split."
 123   :type 'boolean
 124   :group 'spam)
 125
 126 (defcustom spam-use-hashcash nil
 127   "Whether hashcash payments should be detected by spam-split."
 128   :type 'boolean
 129   :group 'spam)
 130
 131 (defcustom spam-use-regex-headers nil
 132   "Whether a header regular expression match should be used by spam-split.
 133 Also see the variable `spam-spam-regex-headers' and `spam-ham-regex-headers'."
 134   :type 'boolean
 135   :group 'spam)
 136
 137 (defcustom spam-use-bogofilter-headers nil
 138   "Whether bogofilter headers should be used by spam-split.
 139 Enable this if you pre-process messages with Bogofilter BEFORE Gnus sees them."
 140   :type 'boolean
 141   :group 'spam)
 142
 143 (defcustom spam-use-bogofilter nil
 144   "Whether bogofilter should be invoked by spam-split.
 145 Enable this if you want Gnus to invoke Bogofilter on new messages."
 146   :type 'boolean
 147   :group 'spam)
 148
 149 (defcustom spam-use-BBDB nil
 150   "Whether BBDB should be used by spam-split."
 151   :type 'boolean
 152   :group 'spam)
 153
 154 (defcustom spam-use-BBDB-exclusive nil
 155   "Whether BBDB-exclusive should be used by spam-split.
 156 Exclusive BBDB means that all messages from senders not in the BBDB are
 157 considered spam."
 158   :type 'boolean
 159   :group 'spam)
 160
 161 (defcustom spam-use-ifile nil
 162   "Whether ifile should be used by spam-split."
 163   :type 'boolean
 164   :group 'spam)
 165
 166 (defcustom spam-use-stat nil
 167   "Whether spam-stat should be used by spam-split."
 168   :type 'boolean
 169   :group 'spam)
 170
 171 (defcustom spam-split-group "spam"
 172   "Group name where incoming spam should be put by spam-split."
 173   :type 'string
 174   :group 'spam)
 175
 176 (defcustom spam-junk-mailgroups (cons spam-split-group '("mail.junk" "poste.pourriel"))
 177   "Mailgroups with spam contents.
 178 All unmarked article in such group receive the spam mark on group entry."
 179   :type '(repeat (string :tag "Group"))
 180   :group 'spam)
 181
 182 (defcustom spam-blackhole-servers '("bl.spamcop.net" "relays.ordb.org"
 183                                     "dev.null.dk" "relays.visi.com")
 184   "List of blackhole servers."
 185   :type '(repeat (string :tag "Server"))
 186   :group 'spam)
 187
 188 (defcustom spam-blackhole-good-server-regex nil
 189   "String matching IP addresses that should not be checked in the blackholes"
 190   :type 'regexp
 191   :group 'spam)
 192
 193 (defcustom spam-face 'gnus-splash-face
 194   "Face for spam-marked articles"
 195   :type 'face
 196   :group 'spam)
 197
 198 (defcustom spam-regex-headers-spam '("^X-Spam-Flag: YES")
 199   "Regular expression for positive header spam matches"
 200   :type '(repeat (regexp :tag "Regular expression to match spam header"))
 201   :group 'spam)
 202
 203 (defcustom spam-regex-headers-ham '("^X-Spam-Flag: NO")
 204   "Regular expression for positive header ham matches"
 205   :type '(repeat (regexp :tag "Regular expression to match ham header"))
 206   :group 'spam)
 207
 208 (defgroup spam-ifile nil
 209   "Spam ifile configuration."
 210   :group 'spam)
 211
 212 (defcustom spam-ifile-path (executable-find "ifile")
 213   "File path of the ifile executable program."
 214   :type '(choice (file :tag "Location of ifile")
 215                  (const :tag "ifile is not installed"))
 216   :group 'spam-ifile)
 217
 218 (defcustom spam-ifile-database-path nil
 219   "File path of the ifile database."
 220   :type '(choice (file :tag "Location of the ifile database")
 221                  (const :tag "Use the default"))
 222   :group 'spam-ifile)
 223
 224 (defcustom spam-ifile-spam-category "spam"
 225   "Name of the spam ifile category."
 226   :type 'string
 227   :group 'spam-ifile)
 228
 229 (defcustom spam-ifile-ham-category nil
 230   "Name of the ham ifile category.  If nil, the current group name will
 231 be used."
 232   :type '(choice (string :tag "Use a fixed category")
 233                 (const :tag "Use the current group name"))
 234   :group 'spam-ifile)
 235
 236 (defcustom spam-ifile-all-categories nil
 237   "Whether the ifile check will return all categories, or just spam.
 238 Set this to t if you want to use the spam-split invocation of ifile as
 239 your main source of newsgroup names."
 240   :type 'boolean
 241   :group 'spam-ifile)
 242
 243 (defgroup spam-bogofilter nil
 244   "Spam bogofilter configuration."
 245   :group 'spam)
 246
 247 (defcustom spam-bogofilter-path (executable-find "bogofilter")
 248   "File path of the Bogofilter executable program."
 249   :type '(choice (file :tag "Location of bogofilter")
 250                  (const :tag "Bogofilter is not installed"))
 251   :group 'spam-bogofilter)
 252
 253 (defcustom spam-bogofilter-header "X-Bogosity"
 254   "The header that Bogofilter inserts in messages."
 255   :type 'string
 256   :group 'spam-bogofilter)
 257
 258 (defcustom spam-bogofilter-spam-switch "-s"
 259   "The switch that Bogofilter uses to register spam messages."
 260   :type 'string
 261   :group 'spam-bogofilter)
 262
 263 (defcustom spam-bogofilter-ham-switch "-n"
 264   "The switch that Bogofilter uses to register ham messages."
 265   :type 'string
 266   :group 'spam-bogofilter)
 267
 268 (defcustom spam-bogofilter-bogosity-positive-spam-header "^\\(Yes\\|Spam\\)"
 269   "The regex on `spam-bogofilter-header' for positive spam identification."
 270   :type 'regexp
 271   :group 'spam-bogofilter)
 272
 273 (defcustom spam-bogofilter-database-directory nil
 274   "Directory path of the Bogofilter databases."
 275   :type '(choice (directory :tag "Location of the Bogofilter database directory")
 276                  (const :tag "Use the default"))
 277   :group 'spam-ifile)
 278
 279 ;;; Key bindings for spam control.
 280
 281 (gnus-define-keys gnus-summary-mode-map
 282   "St" spam-bogofilter-score
 283   "Sx" gnus-summary-mark-as-spam
 284   "Mst" spam-bogofilter-score
 285   "Msx" gnus-summary-mark-as-spam
 286   "\M-d" gnus-summary-mark-as-spam)
 287
 288 ;;; How to highlight a spam summary line.
 289
 290 ;; TODO: How do we redo this every time spam-face is customized?
 291
 292 (push '((eq mark gnus-spam-mark) . spam-face)
 293       gnus-summary-highlight)
 294
 295 ;; convenience functions
 296 (defun spam-group-ham-mark-p (group mark &optional spam)
 297   (when (stringp group)
 298     (let* ((marks (spam-group-ham-marks group spam))
 299            (marks (if (symbolp mark)
 300                       marks
 301                     (mapcar 'symbol-value marks))))
 302       (memq mark marks))))
 303
 304 (defun spam-group-spam-mark-p (group mark)
 305   (spam-group-ham-mark-p group mark t))
 306
 307 (defun spam-group-ham-marks (group &optional spam)
 308   (when (stringp group)
 309     (let* ((marks (if spam
 310                      (gnus-parameter-spam-marks group)
 311                    (gnus-parameter-ham-marks group)))
 312            (marks (car marks))
 313            (marks (if (listp (car marks)) (car marks) marks)))
 314       marks)))
 315
 316 (defun spam-group-spam-marks (group)
 317   (spam-group-ham-marks group t))
 318
 319 (defun spam-group-spam-contents-p (group)
 320   (if (stringp group)
 321       (or (member group spam-junk-mailgroups)
 322           (memq 'gnus-group-spam-classification-spam
 323                 (gnus-parameter-spam-contents group)))
 324     nil))
 325
 326 (defun spam-group-ham-contents-p (group)
 327   (if (stringp group)
 328       (memq 'gnus-group-spam-classification-ham
 329             (gnus-parameter-spam-contents group))
 330     nil))
 331
 332 (defun spam-group-processor-p (group processor)
 333   (if (and (stringp group)
 334            (symbolp processor))
 335       (member processor (car (gnus-parameter-spam-process group)))
 336     nil))
 337
 338 (defun spam-group-spam-processor-bogofilter-p (group)
 339   (spam-group-processor-p group 'gnus-group-spam-exit-processor-bogofilter))
 340
 341 (defun spam-group-spam-processor-blacklist-p (group)
 342   (spam-group-processor-p group 'gnus-group-spam-exit-processor-blacklist))
 343
 344 (defun spam-group-spam-processor-ifile-p (group)
 345   (spam-group-processor-p group 'gnus-group-spam-exit-processor-ifile))
 346
 347 (defun spam-group-ham-processor-ifile-p (group)
 348   (spam-group-processor-p group 'gnus-group-ham-exit-processor-ifile))
 349
 350 (defun spam-group-ham-processor-bogofilter-p (group)
 351   (spam-group-processor-p group 'gnus-group-ham-exit-processor-bogofilter))
 352
 353 (defun spam-group-spam-processor-stat-p (group)
 354   (spam-group-processor-p group 'gnus-group-spam-exit-processor-stat))
 355
 356 (defun spam-group-ham-processor-stat-p (group)
 357   (spam-group-processor-p group 'gnus-group-ham-exit-processor-stat))
 358
 359 (defun spam-group-ham-processor-whitelist-p (group)
 360   (spam-group-processor-p group 'gnus-group-ham-exit-processor-whitelist))
 361
 362 (defun spam-group-ham-processor-BBDB-p (group)
 363   (spam-group-processor-p group 'gnus-group-ham-exit-processor-BBDB))
 364
 365 (defun spam-group-ham-processor-copy-p (group)
 366   (spam-group-processor-p group 'gnus-group-ham-exit-processor-copy))
 367
 368 ;;; Summary entry and exit processing.
 369
 370 (defun spam-summary-prepare ()
 371   (spam-mark-junk-as-spam-routine))
 372
 373 (add-hook 'gnus-summary-prepare-hook 'spam-summary-prepare)
 374
 375 ;; The spam processors are invoked for any group, spam or ham or neither
 376 (defun spam-summary-prepare-exit ()
 377   (unless gnus-group-is-exiting-without-update-p
 378     (gnus-message 6 "Exiting summary buffer and applying spam rules")
 379     (when (and spam-bogofilter-path
 380                (spam-group-spam-processor-bogofilter-p gnus-newsgroup-name))
 381       (gnus-message 5 "Registering spam with bogofilter")
 382       (spam-bogofilter-register-spam-routine))
 383
 384     (when (and spam-ifile-path
 385                (spam-group-spam-processor-ifile-p gnus-newsgroup-name))
 386       (gnus-message 5 "Registering spam with ifile")
 387       (spam-ifile-register-spam-routine))
 388
 389     (when (spam-group-spam-processor-stat-p gnus-newsgroup-name)
 390       (gnus-message 5 "Registering spam with spam-stat")
 391       (spam-stat-register-spam-routine))
 392
 393     (when (spam-group-spam-processor-blacklist-p gnus-newsgroup-name)
 394       (gnus-message 5 "Registering spam with the blacklist")
 395       (spam-blacklist-register-routine))
 396
 397     (if spam-move-spam-nonspam-groups-only
 398         (when (not (spam-group-spam-contents-p gnus-newsgroup-name))
 399           (spam-mark-spam-as-expired-and-move-routine
 400            (gnus-parameter-spam-process-destination gnus-newsgroup-name)))
 401       (gnus-message 5 "Marking spam as expired and moving it to %s" gnus-newsgroup-name)
 402       (spam-mark-spam-as-expired-and-move-routine
 403        (gnus-parameter-spam-process-destination gnus-newsgroup-name)))
 404
 405     ;; now we redo spam-mark-spam-as-expired-and-move-routine to only
 406     ;; expire spam, in case the above did not expire them
 407     (gnus-message 5 "Marking spam as expired without moving it")
 408     (spam-mark-spam-as-expired-and-move-routine nil)
 409
 410     (when (spam-group-ham-contents-p gnus-newsgroup-name)
 411       (when (spam-group-ham-processor-whitelist-p gnus-newsgroup-name)
 412         (gnus-message 5 "Registering ham with the whitelist")
 413         (spam-whitelist-register-routine))
 414       (when (spam-group-ham-processor-ifile-p gnus-newsgroup-name)
 415         (gnus-message 5 "Registering ham with ifile")
 416         (spam-ifile-register-ham-routine))
 417       (when (spam-group-ham-processor-bogofilter-p gnus-newsgroup-name)
 418         (gnus-message 5 "Registering ham with Bogofilter")
 419         (spam-bogofilter-register-ham-routine))
 420       (when (spam-group-ham-processor-stat-p gnus-newsgroup-name)
 421         (gnus-message 5 "Registering ham with spam-stat")
 422         (spam-stat-register-ham-routine))
 423       (when (spam-group-ham-processor-BBDB-p gnus-newsgroup-name)
 424         (gnus-message 5 "Registering ham with the BBDB")
 425         (spam-BBDB-register-routine)))
 426
 427     (when (spam-group-ham-processor-copy-p gnus-newsgroup-name)
 428       (gnus-message 5 "Copying ham")
 429       (spam-ham-move-routine
 430        (gnus-parameter-ham-process-destination gnus-newsgroup-name) t))
 431
 432     ;; now move all ham articles out of spam groups
 433     (when (spam-group-spam-contents-p gnus-newsgroup-name)
 434       (gnus-message 5 "Moving ham messages from spam group")
 435       (spam-ham-move-routine
 436        (gnus-parameter-ham-process-destination gnus-newsgroup-name)))))
 437
 438 (add-hook 'gnus-summary-prepare-exit-hook 'spam-summary-prepare-exit)
 439
 440 (defun spam-mark-junk-as-spam-routine ()
 441   ;; check the global list of group names spam-junk-mailgroups and the
 442   ;; group parameters
 443   (when (spam-group-spam-contents-p gnus-newsgroup-name)
 444     (gnus-message 5 "Marking unread articles as spam")
 445     (let ((articles gnus-newsgroup-articles)
 446           article)
 447       (while articles
 448         (setq article (pop articles))
 449         (when (eq (gnus-summary-article-mark article) gnus-unread-mark)
 450           (gnus-summary-mark-article article gnus-spam-mark))))))
 451
 452 (defun spam-mark-spam-as-expired-and-move-routine (&optional group)
 453   (gnus-summary-kill-process-mark)
 454   (let ((articles gnus-newsgroup-articles)
 455         article tomove)
 456     (dolist (article articles)
 457       (when (eq (gnus-summary-article-mark article) gnus-spam-mark)
 458         (gnus-summary-mark-article article gnus-expirable-mark)
 459         (push article tomove)))
 460
 461     ;; now do the actual move
 462     (when (and tomove
 463                (stringp group))
 464       (dolist (article tomove)
 465         (gnus-summary-set-process-mark article))
 466       (when tomove (gnus-summary-move-article nil group))))
 467   (gnus-summary-yank-process-mark))
 468
 469 (defun spam-ham-move-routine (&optional group copy)
 470   (gnus-summary-kill-process-mark)
 471   (let ((articles gnus-newsgroup-articles)
 472         article mark tomove)
 473     (when (stringp group)               ; this routine will do nothing
 474                                         ; without a valid group
 475       (dolist (article articles)
 476         (when (spam-group-spam-mark-p gnus-newsgroup-name
 477                                       (gnus-summary-article-mark article))
 478           (push article tomove)))
 479
 480       ;; now do the actual move
 481       (when tomove
 482         (dolist (article tomove)
 483           (when spam-mark-ham-unread-before-move-from-spam-group
 484             (gnus-summary-mark-article article gnus-unread-mark))
 485           (gnus-summary-set-process-mark article))
 486         (if copy
 487             (gnus-summary-copy-article nil group)
 488           (gnus-summary-move-article nil group)))))
 489   (gnus-summary-yank-process-mark))
 490
 491 (defun spam-generic-register-routine (spam-func ham-func)
 492   (let ((articles gnus-newsgroup-articles)
 493         article mark ham-articles spam-articles)
 494
 495     (while articles
 496       (setq article (pop articles)
 497             mark (gnus-summary-article-mark article))
 498       (cond ((spam-group-spam-mark-p gnus-newsgroup-name mark)
 499              (push article spam-articles))
 500             ((memq article gnus-newsgroup-saved))
 501             ((spam-group-ham-mark-p gnus-newsgroup-name mark)
 502              (push article ham-articles))))
 503
 504     (when (and ham-articles ham-func)
 505       (mapc ham-func ham-articles))     ; we use mapc because unlike
 506                                         ; mapcar it discards the
 507                                         ; return values
 508     (when (and spam-articles spam-func)
 509       (mapc spam-func spam-articles)))) ; we use mapc because unlike
 510                                         ; mapcar it discards the
 511                                         ; return values
 512
 513 (eval-and-compile
 514   (defalias 'spam-point-at-eol (if (fboundp 'point-at-eol)
 515                                    'point-at-eol
 516                                  'line-end-position)))
 517
 518 (defun spam-get-article-as-string (article)
 519   (let ((article-buffer (spam-get-article-as-buffer article))
 520                         article-string)
 521     (when article-buffer
 522       (save-window-excursion
 523         (set-buffer article-buffer)
 524         (setq article-string (buffer-string))))
 525   article-string))
 526
 527 (defun spam-get-article-as-buffer (article)
 528   (let ((article-buffer))
 529     (when (numberp article)
 530       (save-window-excursion
 531         (gnus-summary-goto-subject article)
 532         (gnus-summary-show-article t)
 533         (setq article-buffer (get-buffer gnus-article-buffer))))
 534     article-buffer))
 535
 536 ;; disabled for now
 537 ;; (defun spam-get-article-as-filename (article)
 538 ;;   (let ((article-filename))
 539 ;;     (when (numberp article)
 540 ;;       (nnml-possibly-change-directory (gnus-group-real-name gnus-newsgroup-name))
 541 ;;       (setq article-filename (expand-file-name (int-to-string article) nnml-current-directory)))
 542 ;;     (if (file-exists-p article-filename)
 543 ;;      article-filename
 544 ;;       nil)))
 545
 546 (defun spam-fetch-field-from-fast (article)
 547   "Fetch the `from' field quickly, using the internal gnus-data-list function"
 548   (if (and (numberp article)
 549            (assoc article (gnus-data-list nil)))
 550       (mail-header-from (gnus-data-header (assoc article (gnus-data-list nil))))
 551     nil))
 552
 553 (defun spam-fetch-field-subject-fast (article)
 554   "Fetch the `subject' field quickly, using the internal gnus-data-list function"
 555   (if (and (numberp article)
 556            (assoc article (gnus-data-list nil)))
 557       (mail-header-subject (gnus-data-header (assoc article (gnus-data-list nil))))
 558     nil))
 559
 560 \f
 561 ;;;; Spam determination.
 562
 563 (defvar spam-list-of-checks
 564   '((spam-use-blacklist                 .       spam-check-blacklist)
 565     (spam-use-regex-headers             .       spam-check-regex-headers)
 566     (spam-use-whitelist                 .       spam-check-whitelist)
 567     (spam-use-BBDB                      .       spam-check-BBDB)
 568     (spam-use-ifile                     .       spam-check-ifile)
 569     (spam-use-stat                      .       spam-check-stat)
 570     (spam-use-blackholes                .       spam-check-blackholes)
 571     (spam-use-hashcash                  .       spam-check-hashcash)
 572     (spam-use-bogofilter-headers        .       spam-check-bogofilter-headers)
 573     (spam-use-bogofilter                .       spam-check-bogofilter))
 574 "The spam-list-of-checks list contains pairs associating a parameter
 575 variable with a spam checking function.  If the parameter variable is
 576 true, then the checking function is called, and its value decides what
 577 happens.  Each individual check may return nil, t, or a mailgroup
 578 name.  The value nil means that the check does not yield a decision,
 579 and so, that further checks are needed.  The value t means that the
 580 message is definitely not spam, and that further spam checks should be
 581 inhibited.  Otherwise, a mailgroup name is returned where the mail
 582 should go, and further checks are also inhibited.  The usual mailgroup
 583 name is the value of `spam-split-group', meaning that the message is
 584 definitely a spam.")
 585
 586 (defvar spam-list-of-statistical-checks
 587   '(spam-use-ifile spam-use-stat spam-use-bogofilter)
 588 "The spam-list-of-statistical-checks list contains all the mail
 589 splitters that need to have the full message body available.")
 590
 591 (defun spam-split ()
 592   "Split this message into the `spam' group if it is spam.
 593 This function can be used as an entry in `nnmail-split-fancy', for
 594 example like this: (: spam-split)
 595
 596 See the Info node `(gnus)Fancy Mail Splitting' for more details."
 597   (interactive)
 598
 599   (dolist (check spam-list-of-statistical-checks)
 600     (when (symbol-value check)
 601       (widen)
 602       (gnus-message 8 "spam-split: widening the buffer (%s requires it)"
 603                     (symbol-name check))
 604       (return)))
 605 ;;   (progn (widen) (debug (buffer-string)))
 606   (let ((list-of-checks spam-list-of-checks)
 607         decision)
 608     (while (and list-of-checks (not decision))
 609       (let ((pair (pop list-of-checks)))
 610         (when (symbol-value (car pair))
 611           (gnus-message 5 "spam-split: calling the %s function" (symbol-name (cdr pair)))
 612           (setq decision (funcall (cdr pair))))))
 613     (if (eq decision t)
 614         nil
 615       decision)))
 616
 617 (defun spam-setup-widening ()
 618   (dolist (check spam-list-of-statistical-checks)
 619     (when (symbol-value check)
 620       (setq nnimap-split-download-body-default t))))
 621
 622 (add-hook 'gnus-get-new-news-hook 'spam-setup-widening)
 623
 624 \f
 625 ;;;; Regex headers
 626
 627 (defun spam-check-regex-headers ()
 628   (let (ret found)
 629     (dolist (h-regex spam-regex-headers-ham)
 630       (unless found
 631         (goto-char (point-min))
 632         (when (re-search-forward h-regex nil t)
 633           (message "Ham regex header search positive.")
 634           (setq found t))))
 635     (dolist (s-regex spam-regex-headers-spam)
 636       (unless found
 637         (goto-char (point-min))
 638         (when (re-search-forward s-regex nil t)
 639           (message "Spam regex header search positive." (match-string 1))
 640           (setq found t)
 641           (setq ret spam-split-group))))
 642     ret))
 643
 644 \f
 645 ;;;; Blackholes.
 646
 647 (defun spam-check-blackholes ()
 648   "Check the Received headers for blackholed relays."
 649   (let ((headers (message-fetch-field "received"))
 650         ips matches)
 651     (when headers
 652       (with-temp-buffer
 653         (insert headers)
 654         (goto-char (point-min))
 655         (gnus-message 5 "Checking headers for relay addresses")
 656         (while (re-search-forward
 657                 "\\[\\([0-9]+.[0-9]+.[0-9]+.[0-9]+\\)\\]" nil t)
 658           (gnus-message 9 "Blackhole search found host IP %s." (match-string 1))
 659           (push (mapconcat 'identity
 660                            (nreverse (split-string (match-string 1) "\\."))
 661                            ".")
 662                 ips)))
 663       (dolist (server spam-blackhole-servers)
 664         (dolist (ip ips)
 665           (unless (and spam-blackhole-good-server-regex
 666                        (string-match spam-blackhole-good-server-regex ip))
 667             (let ((query-string (concat ip "." server)))
 668               (if spam-use-dig
 669                   (let ((query-result (query-dig query-string)))
 670                     (when query-result
 671                       (gnus-message 5 "(DIG): positive blackhole check '%s'"
 672                                     query-result)
 673                       (push (list ip server query-result)
 674                             matches)))
 675                 ;; else, if not using dig.el
 676                 (when (query-dns query-string)
 677                   (gnus-message 5 "positive blackhole check")
 678                   (push (list ip server (query-dns query-string 'TXT))
 679                         matches))))))))
 680     (when matches
 681       spam-split-group)))
 682 \f
 683 ;;;; Hashcash.
 684
 685 (condition-case nil
 686     (progn
 687       (require 'hashcash)
 688
 689       (defun spam-check-hashcash ()
 690         "Check the headers for hashcash payments."
 691         (mail-check-payment)))          ;mail-check-payment returns a boolean
 692
 693   (file-error (progn
 694                 (defalias 'mail-check-payment 'ignore)
 695                 (defalias 'spam-check-hashcash 'ignore))))
 696 \f
 697 ;;;; BBDB
 698
 699 ;;; original idea for spam-check-BBDB from Alexander Kotelnikov
 700 ;;; <sacha@giotto.sj.ru>
 701
 702 ;; all this is done inside a condition-case to trap errors
 703
 704 (condition-case nil
 705     (progn
 706       (require 'bbdb)
 707       (require 'bbdb-com)
 708
 709   (defun spam-enter-ham-BBDB (from)
 710     "Enter an address into the BBDB; implies ham (non-spam) sender"
 711     (when (stringp from)
 712       (let* ((parsed-address (gnus-extract-address-components from))
 713              (name (or (car parsed-address) "Ham Sender"))
 714              (net-address (car (cdr parsed-address))))
 715         (gnus-message 5 "Adding address %s to BBDB" from)
 716         (when (and net-address
 717                    (not (bbdb-search-simple nil net-address)))
 718           (bbdb-create-internal name nil net-address nil nil
 719                                 "ham sender added by spam.el")))))
 720
 721   (defun spam-BBDB-register-routine ()
 722     (spam-generic-register-routine
 723      ;; spam function
 724      nil
 725      ;; ham function
 726      (lambda (article)
 727        (spam-enter-ham-BBDB (spam-fetch-field-from-fast article)))))
 728
 729   (defun spam-check-BBDB ()
 730     "Mail from people in the BBDB is classified as ham or non-spam"
 731     (let ((who (message-fetch-field "from")))
 732       (when who
 733         (setq who (cadr (gnus-extract-address-components who)))
 734         (if (bbdb-search-simple nil who)
 735             t
 736           (if spam-use-BBDB-exclusive
 737               spam-split-group
 738             nil))))))
 739
 740   (file-error (progn
 741                 (defalias 'bbdb-search-simple 'ignore)
 742                 (defalias 'spam-check-BBDB 'ignore)
 743                 (defalias 'spam-BBDB-register-routine 'ignore)
 744                 (defalias 'spam-enter-ham-BBDB 'ignore)
 745                 (defalias 'bbdb-create-internal 'ignore)
 746                 (defalias 'bbdb-records 'ignore))))
 747
 748 \f
 749 ;;;; ifile
 750
 751 ;;; check the ifile backend; return nil if the mail was NOT classified
 752 ;;; as spam
 753
 754 (defun spam-get-ifile-database-parameter ()
 755   "Get the command-line parameter for ifile's database from spam-ifile-database-path."
 756   (if spam-ifile-database-path
 757       (format "--db-file=%s" spam-ifile-database-path)
 758     nil))
 759
 760 (defun spam-check-ifile ()
 761   "Check the ifile backend for the classification of this message"
 762   (let ((article-buffer-name (buffer-name))
 763         category return)
 764     (with-temp-buffer
 765       (let ((temp-buffer-name (buffer-name))
 766             (db-param (spam-get-ifile-database-parameter)))
 767         (save-excursion
 768           (set-buffer article-buffer-name)
 769           (if db-param
 770               (call-process-region (point-min) (point-max) spam-ifile-path
 771                                    nil temp-buffer-name nil "-q" "-c" db-param)
 772             (call-process-region (point-min) (point-max) spam-ifile-path
 773                                  nil temp-buffer-name nil "-q" "-c")))
 774         (goto-char (point-min))
 775         (if (not (eobp))
 776             (setq category (buffer-substring (point) (spam-point-at-eol))))
 777         (when (not (zerop (length category))) ; we need a category here
 778           (if spam-ifile-all-categories
 779               (setq return category)
 780             ;; else, if spam-ifile-all-categories is not set...
 781             (when (string-equal spam-ifile-spam-category category)
 782               (setq return spam-split-group))))))
 783     return))
 784
 785 (defun spam-ifile-register-with-ifile (article-string category)
 786   "Register an article, given as a string, with a category.
 787 Uses `gnus-newsgroup-name' if category is nil (for ham registration)."
 788   (when (stringp article-string)
 789     (let ((category (or category gnus-newsgroup-name))
 790           (db-param (spam-get-ifile-database-parameter)))
 791       (with-temp-buffer
 792         (insert article-string)
 793         (if db-param
 794             (call-process-region (point-min) (point-max) spam-ifile-path
 795                                  nil nil nil
 796                                  "-h" "-i" category db-param)
 797           (call-process-region (point-min) (point-max) spam-ifile-path
 798                                nil nil nil
 799                                "-h" "-i" category))))))
 800
 801 (defun spam-ifile-register-spam-routine ()
 802   (spam-generic-register-routine
 803    (lambda (article)
 804      (spam-ifile-register-with-ifile
 805       (spam-get-article-as-string article) spam-ifile-spam-category))
 806    nil))
 807
 808 (defun spam-ifile-register-ham-routine ()
 809   (spam-generic-register-routine
 810    nil
 811    (lambda (article)
 812      (spam-ifile-register-with-ifile
 813       (spam-get-article-as-string article) spam-ifile-ham-category))))
 814
 815 \f
 816 ;;;; spam-stat
 817
 818 (condition-case nil
 819     (progn
 820       (let ((spam-stat-install-hooks nil))
 821         (require 'spam-stat))
 822
 823       (defun spam-check-stat ()
 824         "Check the spam-stat backend for the classification of this message"
 825         (let ((spam-stat-split-fancy-spam-group spam-split-group) ; override
 826               (spam-stat-buffer (buffer-name)) ; stat the current buffer
 827               category return)
 828           (spam-stat-split-fancy)))
 829
 830       (defun spam-stat-register-spam-routine ()
 831         (spam-generic-register-routine
 832          (lambda (article)
 833            (let ((article-string (spam-get-article-as-string article)))
 834              (with-temp-buffer
 835                (insert article-string)
 836                (spam-stat-buffer-is-spam))))
 837          nil))
 838
 839       (defun spam-stat-register-ham-routine ()
 840         (spam-generic-register-routine
 841          nil
 842          (lambda (article)
 843            (let ((article-string (spam-get-article-as-string article)))
 844              (with-temp-buffer
 845                (insert article-string)
 846                (spam-stat-buffer-is-non-spam))))))
 847
 848       (defun spam-maybe-spam-stat-load ()
 849         (when spam-use-stat (spam-stat-load)))
 850
 851       (defun spam-maybe-spam-stat-save ()
 852         (when spam-use-stat (spam-stat-save)))
 853
 854       ;; Add hooks for loading and saving the spam stats
 855       (add-hook 'gnus-save-newsrc-hook 'spam-maybe-spam-stat-save)
 856       (add-hook 'gnus-get-top-new-news-hook 'spam-maybe-spam-stat-load)
 857       (add-hook 'gnus-startup-hook 'spam-maybe-spam-stat-load))
 858
 859   (file-error (progn
 860                 (defalias 'spam-stat-register-ham-routine 'ignore)
 861                 (defalias 'spam-stat-register-spam-routine 'ignore)
 862                 (defalias 'spam-stat-buffer-is-spam 'ignore)
 863                 (defalias 'spam-stat-buffer-is-non-spam 'ignore)
 864                 (defalias 'spam-stat-split-fancy 'ignore)
 865                 (defalias 'spam-stat-load 'ignore)
 866                 (defalias 'spam-stat-save 'ignore)
 867                 (defalias 'spam-check-stat 'ignore))))
 868
 869 \f
 870
 871 ;;;; Blacklists and whitelists.
 872
 873 (defvar spam-whitelist-cache nil)
 874 (defvar spam-blacklist-cache nil)
 875
 876 (defun spam-enter-whitelist (address)
 877   "Enter ADDRESS into the whitelist."
 878   (interactive "sAddress: ")
 879   (spam-enter-list address spam-whitelist)
 880   (setq spam-whitelist-cache nil))
 881
 882 (defun spam-enter-blacklist (address)
 883   "Enter ADDRESS into the blacklist."
 884   (interactive "sAddress: ")
 885   (spam-enter-list address spam-blacklist)
 886   (setq spam-blacklist-cache nil))
 887
 888 (defun spam-enter-list (address file)
 889   "Enter ADDRESS into the given FILE, either the whitelist or the blacklist."
 890   (unless (file-exists-p (file-name-directory file))
 891     (make-directory (file-name-directory file) t))
 892   (save-excursion
 893     (set-buffer
 894      (find-file-noselect file))
 895     (goto-char (point-max))
 896     (unless (bobp)
 897       (insert "\n"))
 898     (insert address "\n")
 899     (save-buffer)))
 900
 901 ;;; returns t if the sender is in the whitelist, nil or spam-split-group otherwise
 902 (defun spam-check-whitelist ()
 903   ;; FIXME!  Should it detect when file timestamps change?
 904   (unless spam-whitelist-cache
 905     (setq spam-whitelist-cache (spam-parse-list spam-whitelist)))
 906   (if (spam-from-listed-p spam-whitelist-cache)
 907       t
 908     (if spam-use-whitelist-exclusive
 909         spam-split-group
 910       nil)))
 911
 912 (defun spam-check-blacklist ()
 913   ;; FIXME!  Should it detect when file timestamps change?
 914   (unless spam-blacklist-cache
 915     (setq spam-blacklist-cache (spam-parse-list spam-blacklist)))
 916   (and (spam-from-listed-p spam-blacklist-cache) spam-split-group))
 917
 918 (defun spam-parse-list (file)
 919   (when (file-readable-p file)
 920     (let (contents address)
 921       (with-temp-buffer
 922         (insert-file-contents file)
 923         (while (not (eobp))
 924           (setq address (buffer-substring (point) (spam-point-at-eol)))
 925           (forward-line 1)
 926           (unless (zerop (length address))
 927             (setq address (regexp-quote address))
 928             (while (string-match "\\\\\\*" address)
 929               (setq address (replace-match ".*" t t address)))
 930             (push address contents))))
 931       (nreverse contents))))
 932
 933 (defun spam-from-listed-p (cache)
 934   (let ((from (message-fetch-field "from"))
 935         found)
 936     (while cache
 937       (when (string-match (pop cache) from)
 938         (setq found t
 939               cache nil)))
 940     found))
 941
 942 (defun spam-blacklist-register-routine ()
 943   (spam-generic-register-routine
 944    ;; the spam function
 945    (lambda (article)
 946      (let ((from (spam-fetch-field-from-fast article)))
 947        (when (stringp from)
 948            (spam-enter-blacklist from))))
 949    ;; the ham function
 950    nil))
 951
 952 (defun spam-whitelist-register-routine ()
 953   (spam-generic-register-routine
 954    ;; the spam function
 955    nil
 956    ;; the ham function
 957    (lambda (article)
 958      (let ((from (spam-fetch-field-from-fast article)))
 959        (when (stringp from)
 960            (spam-enter-whitelist from))))))
 961
 962 \f
 963 ;;;; Bogofilter
 964
 965 (defun spam-check-bogofilter-headers (&optional score)
 966   (let ((header (message-fetch-field spam-bogofilter-header)))
 967       (when (and header
 968                  (string-match spam-bogofilter-bogosity-positive-spam-header
 969                                header))
 970           (if score
 971               (when (string-match "spamicity=\\([0-9.]+\\)" header)
 972                 (match-string 1 header))
 973             spam-split-group))))
 974
 975 ;; return something sensible if the score can't be determined
 976 (defun spam-bogofilter-score ()
 977   "Get the Bogofilter spamicity score"
 978   (interactive)
 979   (save-window-excursion
 980     (gnus-summary-show-article t)
 981     (set-buffer gnus-article-buffer)
 982     (let ((score (spam-check-bogofilter t)))
 983       (message "Spamicity score %s" score)
 984       (or score "0"))))
 985
 986 (defun spam-check-bogofilter (&optional score)
 987   "Check the Bogofilter backend for the classification of this message"
 988   (let ((article-buffer-name (buffer-name))
 989         return)
 990     (with-temp-buffer
 991       (let ((temp-buffer-name (buffer-name)))
 992         (save-excursion
 993           (set-buffer article-buffer-name)
 994           (if spam-bogofilter-database-directory
 995               (call-process-region (point-min) (point-max)
 996                                    spam-bogofilter-path
 997                                    nil temp-buffer-name nil "-v"
 998                                    "-d" spam-bogofilter-database-directory)
 999             (call-process-region (point-min) (point-max) spam-bogofilter-path
1000                                  nil temp-buffer-name nil "-v")))
1001         (setq return (spam-check-bogofilter-headers score))))
1002     return))
1003
1004 (defun spam-bogofilter-register-with-bogofilter (article-string spam)
1005   "Register an article, given as a string, as spam or non-spam."
1006   (when (stringp article-string)
1007     (let ((switch (if spam spam-bogofilter-spam-switch
1008                     spam-bogofilter-ham-switch)))
1009       (with-temp-buffer
1010         (insert article-string)
1011         (if spam-bogofilter-database-directory
1012             (call-process-region (point-min) (point-max)
1013                                  spam-bogofilter-path
1014                                  nil nil nil "-v" switch
1015                                  "-d" spam-bogofilter-database-directory)
1016           (call-process-region (point-min) (point-max) spam-bogofilter-path
1017                                nil nil nil "-v" switch))))))
1018
1019 (defun spam-bogofilter-register-spam-routine ()
1020   (spam-generic-register-routine
1021    (lambda (article)
1022      (spam-bogofilter-register-with-bogofilter
1023       (spam-get-article-as-string article) t))
1024    nil))
1025
1026 (defun spam-bogofilter-register-ham-routine ()
1027   (spam-generic-register-routine
1028    nil
1029    (lambda (article)
1030      (spam-bogofilter-register-with-bogofilter
1031       (spam-get-article-as-string article) nil))))
1032
1033 (provide 'spam)
1034
1035 ;;; spam.el ends here.