git.chise.org Git - elisp/gnus.git-/blob - lisp/time-date.el

   1 ;;; time-date.el --- Date and time handling functions
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2004, 2005
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu Umeda <umerin@mse.kyutech.ac.jp>
   7 ;; Keywords: mail news util
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Time values come in three formats.  The oldest format is a cons
  29 ;; cell of the form (HIGH . LOW).  This format is obsolete, but still
  30 ;; supported.  The two other formats are the lists (HIGH LOW) and
  31 ;; (HIGH LOW MICRO).  The first two formats specify HIGH * 2^16 + LOW
  32 ;; seconds; the third format specifies HIGH * 2^16 + LOW + MICRO /
  33 ;; 1000000 seconds.  We should have 0 <= MICRO < 1000000 and 0 <= LOW
  34 ;; < 2^16.  If the time value represents a point in time, then HIGH is
  35 ;; nonnegative.  If the time value is a time difference, then HIGH can
  36 ;; be negative as well.  The macro `with-decoded-time-value' and the
  37 ;; function `encode-time-value' make it easier to deal with these
  38 ;; three formats.  See `time-subtract' for an example of how to use
  39 ;; them.
  40
  41 ;;; Code:
  42
  43 (defmacro with-decoded-time-value (varlist &rest body)
  44   "Decode a time value and bind it according to VARLIST, then eval BODY.
  45
  46 The value of the last form in BODY is returned.
  47
  48 Each element of the list VARLIST is a list of the form
  49 \(HIGH-SYMBOL LOW-SYMBOL MICRO-SYMBOL [TYPE-SYMBOL] TIME-VALUE).
  50 The time value TIME-VALUE is decoded and the result it bound to
  51 the symbols HIGH-SYMBOL, LOW-SYMBOL and MICRO-SYMBOL.
  52
  53 The optional TYPE-SYMBOL is bound to the type of the time value.
  54 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH
  55 LOW), and type 3 is the list (HIGH LOW MICRO)."
  56   (declare (indent 1)
  57            (debug ((&rest (symbolp symbolp symbolp &or [symbolp form] form))
  58                    body)))
  59   (if varlist
  60       (let* ((elt (pop varlist))
  61              (high (pop elt))
  62              (low (pop elt))
  63              (micro (pop elt))
  64              (type (unless (eq (length elt) 1)
  65                      (pop elt)))
  66              (time-value (car elt))
  67              (gensym (make-symbol "time")))
  68         `(let* ,(append `((,gensym ,time-value)
  69                           (,high (pop ,gensym))
  70                           ,low ,micro)
  71                         (when type `(,type)))
  72            (if (consp ,gensym)
  73                (progn
  74                  (setq ,low (pop ,gensym))
  75                  (if ,gensym
  76                      ,(append `(setq ,micro (car ,gensym))
  77                               (when type `(,type 2)))
  78                    ,(append `(setq ,micro 0)
  79                             (when type `(,type 1)))))
  80              ,(append `(setq ,low ,gensym ,micro 0)
  81                       (when type `(,type 0))))
  82            (with-decoded-time-value ,varlist ,@body)))
  83     `(progn ,@body)))
  84
  85 (defun encode-time-value (high low micro type)
  86   "Encode HIGH, LOW, and MICRO into a time value of type TYPE.
  87 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH LOW),
  88 and type 3 is the list (HIGH LOW MICRO)."
  89   (cond
  90    ((eq type 0) (cons high low))
  91    ((eq type 1) (list high low))
  92    ((eq type 2) (list high low micro))))
  93
  94 (autoload 'timezone-make-date-arpa-standard "timezone")
  95
  96 ;;;###autoload
  97 (defun date-to-time (date)
  98   "Parse a string that represents a date-time and return a time value."
  99   (condition-case ()
 100       (apply 'encode-time
 101              (parse-time-string
 102               ;; `parse-time-string' isn't sufficiently general or
 103               ;; robust.  It fails to grok some of the formats that
 104               ;; timezone does (e.g. dodgy post-2000 stuff from some
 105               ;; Elms) and either fails or returns bogus values.  Lars
 106               ;; reverted this change, but that loses non-trivially
 107               ;; often for me.  -- fx
 108               (timezone-make-date-arpa-standard date)))
 109     (error (error "Invalid date: %s" date))))
 110
 111 (defun time-to-seconds (time)
 112   "Convert time value TIME to a floating point number.
 113 You can use `float-time' instead."
 114   (with-decoded-time-value ((high low micro time))
 115     (+ (* 1.0 high 65536)
 116        low
 117        (/ micro 1000000.0))))
 118
 119 ;;;###autoload
 120 (defun seconds-to-time (seconds)
 121   "Convert SECONDS (a floating point number) to a time value."
 122   (list (floor seconds 65536)
 123         (floor (mod seconds 65536))
 124         (floor (* (- seconds (ffloor seconds)) 1000000))))
 125
 126 ;;;###autoload
 127 (defun time-less-p (t1 t2)
 128   "Say whether time value T1 is less than time value T2."
 129   (with-decoded-time-value ((high1 low1 micro1 t1)
 130                             (high2 low2 micro2 t2))
 131     (or (< high1 high2)
 132         (and (= high1 high2)
 133              (or (< low1 low2)
 134                  (and (= low1 low2)
 135                       (< micro1 micro2)))))))
 136
 137 ;;;###autoload
 138 (defun days-to-time (days)
 139   "Convert DAYS into a time value."
 140   (let* ((seconds (* 1.0 days 60 60 24))
 141          (high (condition-case nil (floor (/ seconds 65536))
 142                  (range-error most-positive-fixnum))))
 143     (list high (condition-case nil (floor (- seconds (* 1.0 high 65536)))
 144                  (range-error 65535)))))
 145
 146 ;;;###autoload
 147 (defun time-since (time)
 148   "Return the time elapsed since TIME.
 149 TIME should be either a time value or a date-time string."
 150   (when (stringp time)
 151     ;; Convert date strings to internal time.
 152     (setq time (date-to-time time)))
 153   (time-subtract (current-time) time))
 154
 155 ;;;###autoload
 156 (defalias 'subtract-time 'time-subtract)
 157
 158 ;;;###autoload
 159 (defun time-subtract (t1 t2)
 160   "Subtract two time values.
 161 Return the difference in the format of a time value."
 162   (with-decoded-time-value ((high low micro type t1)
 163                             (high2 low2 micro2 type2 t2))
 164     (setq high (- high high2)
 165           low (- low low2)
 166           micro (- micro micro2)
 167           type (max type type2))
 168     (when (< micro 0)
 169       (setq low (1- low)
 170             micro (+ micro 1000000)))
 171     (when (< low 0)
 172       (setq high (1- high)
 173             low (+ low 65536)))
 174     (encode-time-value high low micro type)))
 175
 176 ;;;###autoload
 177 (defun time-add (t1 t2)
 178   "Add two time values.  One should represent a time difference."
 179   (with-decoded-time-value ((high low micro type t1)
 180                             (high2 low2 micro2 type2 t2))
 181     (setq high (+ high high2)
 182           low (+ low low2)
 183           micro (+ micro micro2)
 184           type (max type type2))
 185     (when (>= micro 1000000)
 186       (setq low (1+ low)
 187             micro (- micro 1000000)))
 188     (when (>= low 65536)
 189       (setq high (1+ high)
 190             low (- low 65536)))
 191     (encode-time-value high low micro type)))
 192
 193 ;;;###autoload
 194 (defun date-to-day (date)
 195   "Return the number of days between year 1 and DATE.
 196 DATE should be a date-time string."
 197   (time-to-days (date-to-time date)))
 198
 199 ;;;###autoload
 200 (defun days-between (date1 date2)
 201   "Return the number of days between DATE1 and DATE2.
 202 DATE1 and DATE2 should be date-time strings."
 203   (- (date-to-day date1) (date-to-day date2)))
 204
 205 ;;;###autoload
 206 (defun date-leap-year-p (year)
 207   "Return t if YEAR is a leap year."
 208   (or (and (zerop (% year 4))
 209            (not (zerop (% year 100))))
 210       (zerop (% year 400))))
 211
 212 ;;;###autoload
 213 (defun time-to-day-in-year (time)
 214   "Return the day number within the year of the date month/day/year."
 215   (let* ((tim (decode-time time))
 216          (month (nth 4 tim))
 217          (day (nth 3 tim))
 218          (year (nth 5 tim))
 219          (day-of-year (+ day (* 31 (1- month)))))
 220     (when (> month 2)
 221       (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 222       (when (date-leap-year-p year)
 223         (setq day-of-year (1+ day-of-year))))
 224     day-of-year))
 225
 226 ;;;###autoload
 227 (defun time-to-days (time)
 228   "The number of days between the Gregorian date 0001-12-31bce and TIME.
 229 TIME should be a time value.
 230 The Gregorian date Sunday, December 31, 1bce is imaginary."
 231   (let* ((tim (decode-time time))
 232          (month (nth 4 tim))
 233          (day (nth 3 tim))
 234          (year (nth 5 tim)))
 235     (+ (time-to-day-in-year time)       ;       Days this year
 236        (* 365 (1- year))                ;       + Days in prior years
 237        (/ (1- year) 4)                  ;       + Julian leap years
 238        (- (/ (1- year) 100))            ;       - century years
 239        (/ (1- year) 400))))             ;       + Gregorian leap years
 240
 241 (defun time-to-number-of-days (time)
 242   "Return the number of days represented by TIME.
 243 The number of days will be returned as a floating point number."
 244   (/ (time-to-seconds time) (* 60 60 24)))
 245
 246 ;;;###autoload
 247 (defun safe-date-to-time (date)
 248   "Parse a string that represents a date-time and return a time value.
 249 If DATE is malformed, return a time value of zeros."
 250   (condition-case ()
 251       (date-to-time date)
 252     (error '(0 0))))
 253
 254 (provide 'time-date)
 255
 256 ;;; arch-tag: addcf07b-b20a-465b-af72-550b8ac5190f
 257 ;;; time-date.el ends here