git.chise.org Git - elisp/gnus.git-/blob - lisp/tls.el

   1 ;;; tls.el --- TLS/SSL support via wrapper around GnuTLS
   2
   3 ;; Copyright (C) 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6 ;; Keywords: comm, tls, gnutls, ssl
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package implements a simple wrapper around "gnutls-cli" to
  28 ;; make Emacs support TLS/SSL.
  29 ;;
  30 ;; Usage is the same as `open-network-stream', i.e.:
  31 ;;
  32 ;; (setq tmp (open-tls-stream "test" (current-buffer) "news.mozilla.org" 563))
  33 ;; ...
  34 ;; #<process test>
  35 ;; (process-send-string tmp "mode reader\n")
  36 ;; 200 secnews.netscape.com Netscape-Collabra/3.52 03615 NNRP ready ...
  37 ;; nil
  38 ;; (process-send-string tmp "quit\n")
  39 ;; 205
  40 ;; nil
  41
  42 ;; To use this package as a replacement for ssl.el by William M. Perry
  43 ;; <wmperry@cs.indiana.edu>, you need to evaluate the following:
  44 ;;
  45 ;; (defalias 'open-ssl-stream 'open-tls-stream)
  46
  47 ;;; Code:
  48
  49 (require 'pces)
  50
  51 (eval-and-compile
  52   (autoload 'format-spec "format-spec")
  53   (autoload 'format-spec-make "format-spec"))
  54
  55 (defgroup tls nil
  56   "Transport Layer Security (TLS) parameters."
  57   :group 'comm)
  58
  59 (defcustom tls-program '("gnutls-cli -p %p %h"
  60                          "gnutls-cli -p %p %h --protocols ssl3")
  61   "List of strings containing commands to start TLS stream to a host.
  62 Each entry in the list is tried until a connection is successful.
  63 %s is replaced with server hostname, %p with port to connect to.
  64 The program should read input on stdin and write output to
  65 stdout.  Also see `tls-success' for what the program should output
  66 after successful negotiation."
  67   :type '(repeat string)
  68   :group 'tls)
  69
  70 (defcustom tls-process-connection-type nil
  71   "*Value for `process-connection-type' to use when starting TLS process."
  72   :type 'boolean
  73   :group 'tls)
  74
  75 (defcustom tls-success "- Handshake was completed"
  76   "*Regular expression indicating completed TLS handshakes.
  77 The default is what GNUTLS's \"gnutls-cli\" outputs."
  78   :type 'regexp
  79   :group 'tls)
  80
  81 (defun open-tls-stream (name buffer host service)
  82   "Open a TLS connection for a service to a host.
  83 Returns a subprocess-object to represent the connection.
  84 Input and output work as for subprocesses; `delete-process' closes it.
  85 Args are NAME BUFFER HOST SERVICE.
  86 NAME is name for process.  It is modified if necessary to make it unique.
  87 BUFFER is the buffer (or buffer-name) to associate with the process.
  88  Process output goes at end of that buffer, unless you specify
  89  an output stream or filter function to handle the output.
  90  BUFFER may be also nil, meaning that this process is not associated
  91  with any buffer
  92 Third arg is name of the host to connect to, or its IP address.
  93 Fourth arg SERVICE is name of the service desired, or an integer
  94 specifying a port number to connect to."
  95   (let ((cmds tls-program) cmd done)
  96     (message "Opening TLS connection to `%s'..." host)
  97     (while (and (not done) (setq cmd (pop cmds)))
  98       (message "Opening TLS connection with `%s'..." cmd)
  99       (let* ((process-connection-type tls-process-connection-type)
 100              (process (as-binary-process
 101                        (start-process
 102                         name buffer shell-file-name shell-command-switch
 103                         (format-spec
 104                          cmd
 105                          (format-spec-make
 106                           ?h host
 107                           ?p (if (integerp service)
 108                                  (int-to-string service)
 109                                service))))))
 110              response)
 111         (while (and process
 112                     (memq (process-status process) '(open run))
 113                     (save-excursion
 114                       (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 115                       (goto-char (point-min))
 116                       (not (setq done (re-search-forward tls-success nil t)))))
 117           (accept-process-output process 1)
 118           (sit-for 1))
 119         (message "Opening TLS connection with `%s'...%s" cmd
 120                  (if done "done" "failed"))
 121         (if done
 122             (setq done process)
 123           (delete-process process))))
 124     (message "Opening TLS connection to `%s'...%s"
 125              host (if done "done" "failed"))
 126     done))
 127
 128 (provide 'tls)
 129
 130 ;;; tls.el ends here