git.chise.org Git - elisp/gnus.git-/blob - lisp/uudecode.el

   1 ;;; uudecode.el -- elisp native uudecode
   2
   3 ;; Copyright (c) 1998, 1999, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   6 ;; Keywords: uudecode news
   7
   8 ;; This file is a part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;     Lots of codes are stolen from mm-decode.el, gnus-uu.el and
  28 ;;     base64.el
  29
  30 ;; This looks as though it could be made rather more efficient for
  31 ;; internal working.  Encoding could use a lookup table and decoding
  32 ;; should presumably use a vector or list buffer for partial results
  33 ;; rather than with-current-buffer.  -- fx
  34
  35 ;; Only `uudecode-decode-region' should be advertised, and whether or
  36 ;; not that uses a program should be customizable, but I guess it's
  37 ;; too late now.  -- fx
  38
  39 ;;; Code:
  40
  41 (eval-when-compile (require 'cl))
  42
  43 (eval-and-compile
  44   (defalias 'uudecode-char-int
  45     (if (fboundp 'char-int)
  46         'char-int
  47       'identity))
  48
  49   (if (featurep 'xemacs)
  50       (defalias 'uudecode-insert-char 'insert-char)
  51     (defun uudecode-insert-char (char &optional count ignored buffer)
  52       (if (or (null buffer) (eq buffer (current-buffer)))
  53           (insert-char char count)
  54         (with-current-buffer buffer
  55           (insert-char char count))))))
  56
  57 (defcustom uudecode-decoder-program "uudecode"
  58   "*Non-nil value should be a string that names a uu decoder.
  59 The program should expect to read uu data on its standard
  60 input and write the converted data to its standard output."
  61   :type 'string
  62   :group 'gnus-extract)
  63
  64 (defcustom uudecode-decoder-switches nil
  65   "*List of command line flags passed to `uudecode-decoder-program'."
  66   :group 'gnus-extract
  67   :type '(repeat string))
  68
  69 (defconst uudecode-alphabet "\040-\140")
  70
  71 (defconst uudecode-begin-line "^begin[ \t]+[0-7][0-7][0-7][ \t]+\\(.*\\)$")
  72 (defconst uudecode-end-line "^end[ \t]*$")
  73
  74 (defconst uudecode-body-line
  75   (let ((i 61) (str "^M"))
  76     (while (> (setq i (1- i)) 0)
  77       (setq str (concat str "[^a-z]")))
  78     (concat str ".?$")))
  79
  80 (defvar uudecode-temporary-file-directory
  81   (cond ((fboundp 'temp-directory) (temp-directory))
  82         ((boundp 'temporary-file-directory) temporary-file-directory)
  83         ("/tmp")))
  84
  85 ;;;###autoload
  86 (defun uudecode-decode-region-external (start end &optional file-name)
  87   "Uudecode region between START and END using external program.
  88 If FILE-NAME is non-nil, save the result to FILE-NAME.  The program
  89 used is specified by `uudecode-decoder-program'."
  90   (interactive "r\nP")
  91   (let ((cbuf (current-buffer)) tempfile firstline status)
  92     (save-excursion
  93       (goto-char start)
  94       (when (re-search-forward uudecode-begin-line nil t)
  95         (forward-line 1)
  96         (setq firstline (point))
  97         (cond ((null file-name))
  98               ((stringp file-name))
  99               (t
 100                (setq file-name (read-file-name "File to Name:"
 101                                                nil nil nil
 102                                                (match-string 1)))))
 103         (setq tempfile (if file-name
 104                            (expand-file-name file-name)
 105                            (if (fboundp 'make-temp-file)
 106                                (let ((temporary-file-directory
 107                                       uudecode-temporary-file-directory))
 108                                  (make-temp-file "uu"))
 109                              (expand-file-name
 110                               (make-temp-name "uu")
 111                               uudecode-temporary-file-directory))))
 112         (let ((cdir default-directory)
 113               default-process-coding-system)
 114           (unwind-protect
 115               (with-temp-buffer
 116                 (insert "begin 600 " (file-name-nondirectory tempfile) "\n")
 117                 (insert-buffer-substring cbuf firstline end)
 118                 (cd (file-name-directory tempfile))
 119                 (apply 'call-process-region
 120                        (point-min)
 121                        (point-max)
 122                        uudecode-decoder-program
 123                        nil
 124                        nil
 125                        nil
 126                        uudecode-decoder-switches))
 127             (cd cdir) (set-buffer cbuf)))
 128         (if (file-exists-p tempfile)
 129             (unless file-name
 130               (goto-char start)
 131               (delete-region start end)
 132               (let (format-alist)
 133                 (insert-file-contents-literally tempfile)))
 134           (message "Can not uudecode")))
 135       (ignore-errors (or file-name (delete-file tempfile))))))
 136
 137 ;;;###autoload
 138 (defun uudecode-decode-region (start end &optional file-name)
 139   "Uudecode region between START and END without using an external program.
 140 If FILE-NAME is non-nil, save the result to FILE-NAME."
 141   (interactive "r\nP")
 142   (let ((work-buffer nil)
 143         (done nil)
 144         (counter 0)
 145         (remain 0)
 146         (bits 0)
 147         (lim 0) inputpos
 148         (non-data-chars (concat "^" uudecode-alphabet)))
 149     (unwind-protect
 150         (save-excursion
 151           (goto-char start)
 152           (when (re-search-forward uudecode-begin-line nil t)
 153             (cond ((null file-name))
 154                   ((stringp file-name))
 155                   (t
 156                    (setq file-name (expand-file-name
 157                                     (read-file-name "File to Name:"
 158                                                     nil nil nil
 159                                                     (match-string 1))))))
 160             (setq work-buffer (generate-new-buffer " *uudecode-work*"))
 161             (forward-line 1)
 162             (skip-chars-forward non-data-chars end)
 163             (while (not done)
 164               (setq inputpos (point))
 165               (setq remain 0 bits 0 counter 0)
 166               (cond
 167                ((> (skip-chars-forward uudecode-alphabet end) 0)
 168                 (setq lim (point))
 169                 (setq remain
 170                       (logand (- (uudecode-char-int (char-after inputpos)) 32)
 171                               63))
 172                 (setq inputpos (1+ inputpos))
 173                 (if (= remain 0) (setq done t))
 174                 (while (and (< inputpos lim) (> remain 0))
 175                   (setq bits (+ bits
 176                                 (logand
 177                                  (-
 178                                   (uudecode-char-int (char-after inputpos)) 32)
 179                                  63)))
 180                   (if (/= counter 0) (setq remain (1- remain)))
 181                   (setq counter (1+ counter)
 182                         inputpos (1+ inputpos))
 183                   (cond ((= counter 4)
 184                          (uudecode-insert-char
 185                           (lsh bits -16) 1 nil work-buffer)
 186                          (uudecode-insert-char
 187                           (logand (lsh bits -8) 255) 1 nil work-buffer)
 188                          (uudecode-insert-char (logand bits 255) 1 nil
 189                                                work-buffer)
 190                          (setq bits 0 counter 0))
 191                         (t (setq bits (lsh bits 6)))))))
 192               (cond
 193                (done)
 194                ((> 0 remain)
 195                 (error "uucode line ends unexpectly")
 196                 (setq done t))
 197                ((and (= (point) end) (not done))
 198                 ;;(error "uucode ends unexpectly")
 199                 (setq done t))
 200                ((= counter 3)
 201                 (uudecode-insert-char (logand (lsh bits -16) 255) 1 nil
 202                                       work-buffer)
 203                 (uudecode-insert-char (logand (lsh bits -8) 255) 1 nil
 204                                       work-buffer))
 205                ((= counter 2)
 206                 (uudecode-insert-char (logand (lsh bits -10) 255) 1 nil
 207                                       work-buffer)))
 208               (skip-chars-forward non-data-chars end))
 209             (if file-name
 210                 (save-excursion
 211                   (set-buffer work-buffer)
 212                   (write-file file-name))
 213               (or (markerp end) (setq end (set-marker (make-marker) end)))
 214               (goto-char start)
 215               (insert-buffer-substring work-buffer)
 216               (delete-region (point) end))))
 217       (and work-buffer (kill-buffer work-buffer)))))
 218
 219 (provide 'uudecode)
 220
 221 ;;; uudecode.el ends here