lsdb.el

   1 ;;; lsdb.el --- the Lovely Sister Database
   2
   3 ;; Copyright (C) 2002 Daiki Ueno
   4
   5 ;; Author: Daiki Ueno <ueno@unixuser.org>
   6 ;; Keywords: adress book
   7
   8 ;; This file is part of the Lovely Sister Database.
   9
  10 ;; This program is free software; you can redistribute it and/or
  11 ;; modify it under the terms of the GNU General Public License as
  12 ;; published by the Free Software Foundation; either version 2, or (at
  13 ;; your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful, but
  16 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 ;; General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; For Semi-gnus:
  28 ;;; (autoload 'lsdb-gnus-insinuate "lsdb")
  29 ;;; (autoload 'lsdb-gnus-insinuate-message "lsdb")
  30 ;;; (add-hook 'gnus-startup-hook 'lsdb-gnus-insinuate)
  31 ;;; (add-hook 'message-setup-hook
  32 ;;;           (lambda ()
  33 ;;;             (define-key message-mode-map "\M-\t" 'lsdb-complete-name)))
  34 ;;; (add-hook 'gnus-summary-mode-hook
  35 ;;;           (lambda ()
  36 ;;;             (define-key gnus-summary-mode-map ":" 'lsdb-toggle-buffer)))
  37
  38 ;;; For Wanderlust, put the following lines into your ~/.wl:
  39 ;;; (require 'lsdb)
  40 ;;; (lsdb-wl-insinuate)
  41 ;;; (add-hook 'wl-draft-mode-hook
  42 ;;;           (lambda ()
  43 ;;;             (define-key wl-draft-mode-map "\M-\t" 'lsdb-complete-name)))
  44 ;;; (add-hook 'wl-summary-mode-hook
  45 ;;;           (lambda ()
  46 ;;;             (define-key wl-summary-mode-map ":" 'lsdb-wl-toggle-buffer)))
  47
  48 ;;; For Mew, put the following lines into your ~/.mew:
  49 ;;; (autoload 'lsdb-mew-insinuate "lsdb")
  50 ;;; (add-hook 'mew-init-hook 'lsdb-mew-insinuate)
  51 ;;; (add-hook 'mew-draft-mode-hook
  52 ;;;           (lambda ()
  53 ;;;             (define-key mew-draft-header-map "\M-I" 'lsdb-complete-name)))
  54 ;;; (add-hook 'mew-summary-mode-hook
  55 ;;;           (lambda ()
  56 ;;;             (define-key mew-summary-mode-map ":" 'lsdb-toggle-buffer)))
  57
  58 ;;; Code:
  59
  60 (require 'poem)
  61 (require 'pces)
  62 (require 'mime)
  63 (require 'static)
  64
  65 ;;;_* USER CUSTOMIZATION VARIABLES:
  66 (defgroup lsdb nil
  67   "The Lovely Sister Database."
  68   :group 'news
  69   :group 'mail)
  70
  71 (defcustom lsdb-file (expand-file-name "~/.lsdb")
  72   "The name of the Lovely Sister Database file."
  73   :group 'lsdb
  74   :type 'file)
  75
  76 (defcustom lsdb-file-coding-system (find-coding-system 'iso-2022-jp)
  77   "Coding system for `lsdb-file'."
  78   :group 'lsdb
  79   :type 'symbol)
  80
  81 (defcustom lsdb-sender-headers
  82   "From\\|Resent-From"
  83   "List of headers to search for senders."
  84   :group 'lsdb
  85   :type 'list)
  86
  87 (defcustom lsdb-recipients-headers
  88   "Resent-To\\|Resent-Cc\\|Reply-To\\|To\\|Cc\\|Bcc"
  89   "List of headers to search for recipients."
  90   :group 'lsdb
  91   :type 'list)
  92
  93 (defcustom lsdb-interesting-header-alist
  94   '(("Organization" nil organization)
  95     ("\\(X-\\)?User-Agent\\|X-Mailer\\|X-Newsreader" nil user-agent)
  96     ("\\(X-\\)?ML-Name" nil mailing-list)
  97     ("List-Id" "\\(.*\\)[ \t]+<[^>]+>\\'" mailing-list "\\1")
  98     ("X-Sequence" "\\(.*\\)[ \t]+[0-9]+\\'" mailing-list "\\1")
  99     ("Delivered-To" "mailing list[ \t]+\\([^@]+\\)@.*" mailing-list "\\1")
 100     ("\\(X-URL\\|X-URI\\)" nil www)
 101     ("X-Attribution\\|X-cite-me" nil attribution)
 102     ("X-Face" nil x-face))
 103   "Alist of headers we are interested in.
 104 The format of elements of this list should be
 105      (FIELD-NAME REGEXP ENTRY STRING)
 106 where the last three elements are optional."
 107   :group 'lsdb
 108   :type 'list)
 109
 110 (defcustom lsdb-entry-type-alist
 111   '((net 5 ?,)
 112     (creation-date 2 ?. t)
 113     (last-modified 3 ?. t)
 114     (mailing-list 4 ?,)
 115     (attribution 4 ?.)
 116     (organization 4)
 117     (www 4)
 118     (aka 4 ?,)
 119     (score -1)
 120     (x-face -1))
 121   "Alist of entry types for presentation.
 122 The format of elements of this list should be
 123      (ENTRY SCORE [CLASS READ-ONLY])
 124 where the last two elements are optional.
 125 Possible values for CLASS are `?.' and '?,'.  If CLASS is `?.', the
 126 entry takes a unique value which is overridden by newly assigned one
 127 by `lsdb-mode-edit-entry' or such a command.  If CLASS is `?,', the
 128 entry can have multiple values separated by commas.
 129 If the fourth element READ-ONLY is non-nil, it is assumed that the
 130 entry cannot be modified."
 131   :group 'lsdb
 132   :type 'list)
 133
 134 (defcustom lsdb-decode-field-body-function #'lsdb-decode-field-body
 135   "Field body decoder."
 136   :group 'lsdb
 137   :type 'function)
 138
 139 (defcustom lsdb-canonicalize-full-name-function
 140   #'lsdb-canonicalize-spaces-and-dots
 141   "Way to canonicalize full name."
 142   :group 'lsdb
 143   :type 'function)
 144
 145 (defcustom lsdb-lookup-full-name-functions
 146   '(lsdb-lookup-full-name-from-address-cache)
 147   "List of functions to pick up the existing full-name of the sender.
 148 The sender is passed to each function as the argument."
 149   :group 'lsdb
 150   :type 'hook)
 151
 152 (defcustom lsdb-update-record-functions
 153   '(lsdb-update-address-cache)
 154   "List of functions called after a record is updated.
 155 The updated record is passed to each function as the argument."
 156   :group 'lsdb
 157   :type 'hook)
 158
 159 (defcustom lsdb-secondary-hash-tables
 160   '(lsdb-address-cache)
 161   "List of the hash tables for reverse lookup"
 162   :group 'lsdb
 163   :type 'list)
 164
 165 (defcustom lsdb-window-max-height 7
 166   "Maximum number of lines used to display LSDB record."
 167   :group 'lsdb
 168   :type 'integer)
 169
 170 (defcustom lsdb-x-face-command-alist
 171   '((pbm "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pnmscale 0.5")
 172     (xpm "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | pnmscale 0.5 | ppmtoxpm"))
 173   "An alist from an image type to a command to be executed to display an X-Face header.
 174 The command will be executed in a sub-shell asynchronously.
 175 The compressed face will be piped to this command."
 176   :group 'lsdb
 177   :type 'list)
 178
 179 (defcustom lsdb-insert-x-face-function
 180   (if (static-if (featurep 'xemacs)
 181           (featurep 'xpm)
 182         (and (>= emacs-major-version 21)
 183              (fboundp 'image-type-available-p)
 184              (or (image-type-available-p 'pbm)
 185                  (image-type-available-p 'xpm))))
 186       #'lsdb-insert-x-face-asynchronously)
 187   "Function to display X-Face."
 188   :group 'lsdb
 189   :type 'function)
 190
 191 (defcustom lsdb-print-record-hook '(lsdb-expose-x-face)
 192   "A hook called after a record is displayed."
 193   :group 'lsdb
 194   :type 'hook)
 195
 196 (defcustom lsdb-display-records-sort-predicate nil
 197   "A predicate to sort records."
 198   :group 'lsdb
 199   :type 'function)
 200
 201 (defcustom lsdb-pop-up-windows t
 202   "Non-nil means LSDB should make new windows to display records."
 203   :group 'lsdb
 204   :type 'boolean)
 205
 206 (defgroup lsdb-edit-form nil
 207   "A mode for editing forms."
 208   :group 'lsdb)
 209
 210 (defcustom lsdb-edit-form-mode-hook nil
 211   "Hook run in `lsdb-edit-form-mode' buffers."
 212   :group 'lsdb-edit-form
 213   :type 'hook)
 214
 215 (defcustom lsdb-shell-file-name "/bin/sh"
 216   "File name to load inferior shells from.
 217 Bourne shell or its equivalent \(not tcsh) is needed for \"2>\"."
 218   :group 'lsdb
 219   :type 'string)
 220
 221 (defcustom lsdb-shell-command-switch "-c"
 222   "Switch used to have the shell execute its command line argument."
 223   :group 'lsdb
 224   :type 'string)
 225
 226 ;;;_. Faces
 227 (defface lsdb-header-face
 228   '((t (:underline t)))
 229   "Face for the file header line in `lsdb-mode'."
 230   :group 'lsdb)
 231 (defvar lsdb-header-face 'lsdb-header-face)
 232
 233 (defface lsdb-field-name-face
 234   '((((class color) (background dark))
 235      (:foreground "PaleTurquoise" :bold t))
 236     (t (:bold t)))
 237   "Face for the message header line in `lsdb-mode'."
 238   :group 'lsdb)
 239 (defvar lsdb-field-name-face 'lsdb-field-name-face)
 240
 241 (defface lsdb-field-body-face
 242   '((((class color) (background dark))
 243      (:foreground "turquoise" :italic t))
 244     (t (:italic t)))
 245   "Face for the message header line in `lsdb-mode'."
 246   :group 'lsdb)
 247 (defvar lsdb-field-body-face 'lsdb-field-body-face)
 248
 249 (defconst lsdb-font-lock-keywords
 250   '(("^\\sw[^\r\n]*"
 251      (0 lsdb-header-face))
 252     ("^\t\t.*$"
 253      (0 lsdb-field-body-face))
 254     ("^\t\\([^\t:]+:\\)[ \t]*\\(.*\\)$"
 255      (1 lsdb-field-name-face)
 256      (2 lsdb-field-body-face))))
 257
 258 (put 'lsdb-mode 'font-lock-defaults '(lsdb-font-lock-keywords t))
 259
 260 ;;;_* CODE - no user customizations below
 261 ;;;_. Internal Variables
 262 (defvar lsdb-hash-table nil
 263   "Internal hash table to hold LSDB records.")
 264
 265 (defvar lsdb-address-cache nil
 266   "The reverse lookup table for `lsdb-hash-table'.
 267 It represents address to full-name mapping.")
 268
 269 (defvar lsdb-buffer-name "*LSDB*"
 270   "Buffer name to display LSDB record.")
 271
 272 (defvar lsdb-hash-tables-are-dirty nil
 273   "Flag to indicate whether the internal hash tables need to be saved.")
 274
 275 (defvar lsdb-known-entry-names
 276   (make-vector 29 0)
 277   "An obarray used to complete an entry name.")
 278
 279 (defvar lsdb-temp-buffer-show-function
 280   #'lsdb-temp-buffer-show-function
 281   "Non-nil means call as function to display a help buffer.
 282 The function is called with one argument, the buffer to be displayed.
 283 Overrides `temp-buffer-show-function'.")
 284
 285 ;;;_. Hash Table Emulation
 286 (if (and (fboundp 'make-hash-table)
 287          (subrp (symbol-function 'make-hash-table)))
 288     (progn
 289       (defalias 'lsdb-puthash 'puthash)
 290       (defalias 'lsdb-gethash 'gethash)
 291       (defalias 'lsdb-remhash 'remhash)
 292       (defalias 'lsdb-maphash 'maphash)
 293       (defalias 'lsdb-hash-table-size 'hash-table-size)
 294       (defalias 'lsdb-hash-table-count 'hash-table-count)
 295       (defalias 'lsdb-make-hash-table 'make-hash-table))
 296   (defun lsdb-puthash (key value hash-table)
 297     "Hash KEY to VALUE in HASH-TABLE."
 298     ;; Obarray is regarded as an open hash table, as a matter of
 299     ;; fact, rehashing doesn't make sense.
 300     (let (new-obarray)
 301       (when (> (car hash-table)
 302                (* (length (nth 1 hash-table)) 0.7))
 303         (setq new-obarray (make-vector (* (length (nth 1 hash-table)) 2) 0))
 304         (mapatoms
 305          (lambda (symbol)
 306            (set (intern (symbol-name symbol) new-obarray)
 307                 (symbol-value symbol)))
 308          (nth 1 hash-table))
 309         (setcdr hash-table (list new-obarray)))
 310       (set (intern key (nth 1 hash-table)) value)
 311       (setcar hash-table (1+ (car hash-table)))))
 312   (defun lsdb-gethash (key hash-table &optional default)
 313     "Find hash value for KEY in HASH-TABLE.
 314 If there is no corresponding value, return DEFAULT (which defaults to nil)."
 315     (let ((symbol (intern-soft key (nth 1 hash-table))))
 316       (if symbol
 317           (symbol-value symbol)
 318         default)))
 319   (defun lsdb-remhash (key hash-table)
 320     "Remove the entry for KEY from HASH-TABLE.
 321 Do nothing if there is no entry for KEY in HASH-TABLE."
 322     (unintern key (nth 1 hash-table))
 323     (setcar hash-table (1- (car hash-table))))
 324   (defun lsdb-maphash (function hash-table)
 325     "Map FUNCTION over entries in HASH-TABLE, calling it with two args,
 326 each key and value in HASH-TABLE.
 327
 328 FUNCTION may not modify HASH-TABLE, with the one exception that FUNCTION
 329 may remhash or puthash the entry currently being processed by FUNCTION."
 330     (mapatoms
 331      (lambda (symbol)
 332        (funcall function (symbol-name symbol) (symbol-value symbol)))
 333      (nth 1 hash-table)))
 334   (defun lsdb-hash-table-size (hash-table)
 335     "Return the size of HASH-TABLE.
 336 This is the current number of slots in HASH-TABLE, whether occupied or not."
 337     (length (nth 1 hash-table)))
 338   (defalias 'lsdb-hash-table-count 'car)
 339   (defun lsdb-make-hash-table (&rest args)
 340     "Return a new empty hash table object."
 341     (list 0 (make-vector (or (plist-get args :size) 29) 0))))
 342
 343 ;;;_. Hash Table Reader/Writer
 344 (defconst lsdb-secondary-hash-table-start-format
 345   ";;; %S\n")
 346
 347 (defsubst lsdb-secondary-hash-table-start (hash-table)
 348   (format lsdb-secondary-hash-table-start-format hash-table))
 349
 350 (eval-and-compile
 351   (condition-case nil
 352       (progn
 353         ;; In XEmacs, hash tables can also be created by the lisp reader
 354         ;; using structure syntax.
 355         (read-from-string "#s(hash-table)")
 356         (defalias 'lsdb-read 'read))
 357     (invalid-read-syntax
 358      (defun lsdb-read (&optional marker)
 359        "Read one Lisp expression as text from MARKER, return as Lisp object."
 360        (save-excursion
 361          (goto-char marker)
 362          (if (looking-at "^#s(")
 363              (with-temp-buffer
 364                (buffer-disable-undo)
 365                (insert-buffer-substring (marker-buffer marker) marker)
 366                (goto-char (point-min))
 367                (delete-char 2)
 368                (let ((object (read (current-buffer)))
 369                      hash-table data)
 370                  (if (eq 'hash-table (car object))
 371                      (progn
 372                        (setq hash-table
 373                              (lsdb-make-hash-table
 374                               :size (plist-get (cdr object) 'size)
 375                               :test 'equal)
 376                              data (plist-get (cdr object) 'data))
 377                        (while data
 378                          (lsdb-puthash (pop data) (pop data) hash-table))
 379                        hash-table)
 380                    object)))))))))
 381
 382 (defun lsdb-load-hash-tables ()
 383   "Read the contents of `lsdb-file' into the internal hash tables."
 384   (let ((buffer (find-file-noselect lsdb-file))
 385         tables)
 386     (unwind-protect
 387         (save-excursion
 388           (set-buffer buffer)
 389           (goto-char (point-min))
 390           (re-search-forward "^#s(")
 391           (goto-char (match-beginning 0))
 392           (setq lsdb-hash-table (lsdb-read (point-marker)))
 393           ;; Load the secondary hash tables following.
 394           (setq tables lsdb-secondary-hash-tables)
 395           (while tables
 396             (if (re-search-forward
 397                  (concat "^" (lsdb-secondary-hash-table-start
 398                               (car tables)))
 399                  nil t)
 400                 (set (car tables) (lsdb-read (point-marker))))
 401             (setq tables (cdr tables))))
 402       (kill-buffer buffer))))
 403
 404 (defun lsdb-insert-hash-table (hash-table)
 405   (insert "#s(hash-table size "
 406           ;; Reduce the actual size of the close hash table, because
 407           ;; XEmacs doesn't have a distinction between index-size and
 408           ;; hash-table-size.
 409           (number-to-string (lsdb-hash-table-count hash-table))
 410           " test equal data (")
 411   (lsdb-maphash
 412    (lambda (key value)
 413      (insert (prin1-to-string key) " " (prin1-to-string value) " "))
 414    hash-table)
 415   (insert "))"))
 416
 417 (defun lsdb-save-hash-tables ()
 418   "Write the records within the internal hash tables into `lsdb-file'."
 419   (let ((coding-system-for-write lsdb-file-coding-system)
 420         tables)
 421     (with-temp-file lsdb-file
 422       (if (and (or (featurep 'mule)
 423                    (featurep 'file-coding))
 424                lsdb-file-coding-system)
 425           (let ((coding-system-name
 426                  (if (symbolp lsdb-file-coding-system)
 427                      (symbol-name lsdb-file-coding-system)
 428                    ;; XEmacs
 429                    (static-if (featurep 'xemacs)
 430                        (symbol-name (coding-system-name
 431                                      lsdb-file-coding-system))))))
 432             (if coding-system-name
 433                 (insert ";;; -*- coding: " coding-system-name " -*-\n"))))
 434       (lsdb-insert-hash-table lsdb-hash-table)
 435       ;; Save the secondary hash tables following.
 436       (setq tables lsdb-secondary-hash-tables)
 437       (while tables
 438         (insert "\n" (lsdb-secondary-hash-table-start
 439                       (car tables)))
 440         (lsdb-insert-hash-table (symbol-value (car tables)))
 441         (setq tables (cdr tables))))))
 442
 443 ;;;_. Mail Header Extraction
 444 (defun lsdb-fetch-field-bodies (regexp)
 445   (save-excursion
 446     (goto-char (point-min))
 447     (let ((case-fold-search t)
 448           field-bodies)
 449       (while (re-search-forward (concat "^\\(" regexp "\\):[ \t]*")
 450                                 nil t)
 451         (push (funcall lsdb-decode-field-body-function
 452                              (buffer-substring (point) (std11-field-end))
 453                              (match-string 1))
 454                     field-bodies))
 455       (nreverse field-bodies))))
 456
 457 (defun lsdb-canonicalize-spaces-and-dots (string)
 458   (while (string-match "  +\\|[\f\t\n\r\v]+\\|\\." string)
 459     (setq string (replace-match " " nil t string)))
 460   string)
 461
 462 (defun lsdb-extract-address-components (string)
 463   (let ((components (std11-extract-address-components string)))
 464     (if (and (nth 1 components)
 465              ;; When parsing a group address,
 466              ;; std11-extract-address-components is likely to return
 467              ;; the ("GROUP" "") form.
 468              (not (equal (nth 1 components) "")))
 469         (if (car components)
 470             (list (funcall lsdb-canonicalize-full-name-function
 471                            (car components))
 472                   (nth 1 components))
 473           (list (nth 1 components) (nth 1 components))))))
 474
 475 ;; stolen (and renamed) from nnheader.el
 476 (defun lsdb-decode-field-body (field-body field-name
 477                                           &optional mode max-column)
 478   (let ((multibyte enable-multibyte-characters))
 479     (unwind-protect
 480         (progn
 481           (set-buffer-multibyte t)
 482           (mime-decode-field-body field-body
 483                                   (if (stringp field-name)
 484                                       (intern (capitalize field-name))
 485                                     field-name)
 486                                   mode max-column))
 487       (set-buffer-multibyte multibyte))))
 488
 489 ;;;_. Record Management
 490 (defun lsdb-maybe-load-secondary-hash-tables ()
 491   (let ((tables lsdb-secondary-hash-tables))
 492     (while tables
 493       (unless (symbol-value (car tables))
 494         (set (car tables) (lsdb-make-hash-table :test 'equal))
 495         (lsdb-maphash
 496          (lambda (key value)
 497            (run-hook-with-args
 498             'lsdb-update-record-functions
 499             (cons key value)))
 500          lsdb-hash-table)
 501         (setq lsdb-hash-tables-are-dirty t))
 502       (setq tables (cdr tables)))))
 503
 504 (defun lsdb-maybe-load-hash-tables ()
 505   (unless lsdb-hash-table
 506     (if (file-exists-p lsdb-file)
 507         (lsdb-load-hash-tables)
 508       (setq lsdb-hash-table (lsdb-make-hash-table :test 'equal)))
 509     (lsdb-maybe-load-secondary-hash-tables)))
 510
 511 ;;;_ : Fallback Lookup Functions
 512 ;;;_  , #1 Address Cache
 513 (defun lsdb-lookup-full-name-from-address-cache (sender)
 514   (lsdb-gethash (nth 1 sender) lsdb-address-cache))
 515
 516 (defun lsdb-update-address-cache (record)
 517   (let ((net (cdr (assq 'net record))))
 518     (while net
 519       (lsdb-puthash (pop net) (car record) lsdb-address-cache))))
 520
 521 ;;;_  , #2 Iterate on the All Records (very slow)
 522 (defun lsdb-lookup-full-name-by-fuzzy-matching (sender)
 523   (let ((names
 524          (if (string-match
 525               "\\`\\(.+\\)[ \t]+\\(/[ \t]+\\|(\\([^)]+\\))\\)"
 526               (car sender))
 527              (if (match-beginning 3)
 528                  (list (match-string 1 (car sender))
 529                        (match-string 3 (car sender)))
 530                (list (match-string 1 (car sender))
 531                      (substring (car sender) (match-end 0))))
 532            (list (car sender))))
 533         (case-fold-search t))
 534     (catch 'found
 535       (lsdb-maphash
 536        (lambda (key value)
 537          (while names
 538            (if (or (string-match
 539                     (concat "\\<" (regexp-quote (car names)) "\\>")
 540                     key)
 541                    (string-match
 542                     (concat
 543                      "\\<"
 544                      (regexp-quote
 545                       (mapconcat #'identity
 546                                  (nreverse (split-string (car names)))
 547                                  " "))
 548                      "\\>")
 549                     key)
 550                    ;; Don't assume that we are using address cache.
 551                    (member (nth 1 sender) (cdr (assq 'net value))))
 552                (throw 'found key))
 553            (setq names (cdr names))))
 554        lsdb-hash-table))))
 555
 556 ;;;_ : Update Records
 557 (defun lsdb-update-record (sender &optional interesting)
 558   (let ((old (lsdb-gethash (car sender) lsdb-hash-table))
 559         (new (cons (cons 'net (list (nth 1 sender)))
 560                    interesting))
 561         merged
 562         record
 563         full-name)
 564     ;; Look for the existing record from the reverse hash table.
 565     ;; If it is found, regsiter the current full-name as AKA.
 566     (unless old
 567       (setq full-name
 568             (run-hook-with-args-until-success
 569              'lsdb-lookup-full-name-functions
 570              sender))
 571       (when full-name
 572         (setq old (lsdb-gethash full-name lsdb-hash-table)
 573               new (cons (list 'aka (car sender)) new))
 574         (setcar sender full-name)))
 575     (unless old
 576       (setq new (cons (cons 'creation-date (format-time-string "%Y-%m-%d"))
 577                       new)))
 578     (setq merged (lsdb-merge-record-entries old new)
 579           record (cons (car sender) merged))
 580     (unless (equal merged old)
 581       (let ((entry (assq 'last-modified (cdr record)))
 582             (last-modified (format-time-string "%Y-%m-%d")))
 583         (if entry
 584             (setcdr entry last-modified)
 585           (setcdr record (cons (cons 'last-modified last-modified)
 586                                (cdr record)))))
 587       (lsdb-puthash (car record) (cdr record)
 588                     lsdb-hash-table)
 589       (run-hook-with-args 'lsdb-update-record-functions record)
 590       (setq lsdb-hash-tables-are-dirty t))
 591     record))
 592
 593 (defun lsdb-update-records ()
 594   (lsdb-maybe-load-hash-tables)
 595   (let (senders recipients interesting alist records bodies entry)
 596     (save-restriction
 597       (std11-narrow-to-header)
 598       (setq senders
 599             (delq nil (mapcar #'lsdb-extract-address-components
 600                               (lsdb-fetch-field-bodies
 601                                lsdb-sender-headers)))
 602             recipients
 603             (delq nil (mapcar #'lsdb-extract-address-components
 604                               (lsdb-fetch-field-bodies
 605                                lsdb-recipients-headers))))
 606       (setq alist lsdb-interesting-header-alist)
 607       (while alist
 608         (setq bodies
 609               (delq nil (mapcar
 610                          (lambda (field-body)
 611                            (if (nth 1 (car alist))
 612                                (and (string-match (nth 1 (car alist))
 613                                                   field-body)
 614                                     (replace-match (nth 3 (car alist))
 615                                                    nil nil field-body))
 616                              field-body))
 617                          (lsdb-fetch-field-bodies (car (car alist))))))
 618         (when bodies
 619           (setq entry (or (nth 2 (car alist))
 620                           'notes))
 621           (push (cons entry
 622                       (if (eq ?. (nth 2 (assq entry lsdb-entry-type-alist)))
 623                           (car bodies)
 624                         bodies))
 625                 interesting))
 626         (setq alist (cdr alist))))
 627     (if senders
 628         (setq records (list (lsdb-update-record (pop senders) interesting))))
 629     (setq alist (nconc senders recipients))
 630     (while alist
 631       (setq records (cons (lsdb-update-record (pop alist)) records)))
 632     (nreverse records)))
 633
 634 (defun lsdb-merge-record-entries (old new)
 635   (setq old (copy-sequence old))
 636   (while new
 637     (let ((entry (assq (car (car new)) old))
 638           list pointer)
 639       (if (null entry)
 640           (setq old (nconc old (list (car new))))
 641         (if (listp (cdr entry))
 642             (progn
 643               (setq list (cdr (car new)) pointer list)
 644               (while pointer
 645                 (if (member (car pointer) (cdr entry))
 646                     (setq list (delq (car pointer) list)))
 647                 (setq pointer (cdr pointer)))
 648               (setcdr entry (nconc (cdr entry) list)))
 649           (setcdr entry (cdr (car new))))))
 650     (setq new (cdr new)))
 651   old)
 652
 653 ;;;_. Display Management
 654 (defun lsdb-fit-window-to-buffer (&optional window)
 655   (save-selected-window
 656     (if window
 657         (select-window window))
 658     (unless (pos-visible-in-window-p (point-max))
 659       (enlarge-window (- lsdb-window-max-height (window-height))))
 660     (shrink-window-if-larger-than-buffer)
 661     (let ((height (window-height)))
 662       (if (> height lsdb-window-max-height)
 663           (shrink-window (- height lsdb-window-max-height)))
 664       (set-window-start window (point-min)))))
 665
 666 (defun lsdb-temp-buffer-show-function (buffer)
 667   (when lsdb-pop-up-windows
 668     (save-selected-window
 669       (let ((window (or (get-buffer-window lsdb-buffer-name)
 670                         (progn
 671                           (select-window (get-largest-window))
 672                           (split-window-vertically)))))
 673         (set-window-buffer window buffer)
 674         (lsdb-fit-window-to-buffer window)))))
 675
 676 (defun lsdb-display-record (record)
 677   "Display only one RECORD, then shrink the window as possible."
 678   (let ((temp-buffer-show-function lsdb-temp-buffer-show-function))
 679     (lsdb-display-records (list record))))
 680
 681 (defun lsdb-display-records (records)
 682   (with-output-to-temp-buffer lsdb-buffer-name
 683     (set-buffer standard-output)
 684     (setq records
 685           (sort (copy-sequence records)
 686                 (or lsdb-display-records-sort-predicate
 687                     (lambda (record1 record2)
 688                       (string-lessp (car record1) (car record2))))))
 689     (while records
 690       (save-restriction
 691         (narrow-to-region (point) (point))
 692         (lsdb-print-record (car records)))
 693       (goto-char (point-max))
 694       (setq records (cdr records)))
 695     (lsdb-mode)))
 696
 697 (defsubst lsdb-entry-score (entry)
 698   (or (nth 1 (assq (car entry) lsdb-entry-type-alist)) 0))
 699
 700 (defun lsdb-insert-entry (entry)
 701   (let ((entry-name (capitalize (symbol-name (car entry)))))
 702     (intern entry-name lsdb-known-entry-names)
 703     (if (>= (lsdb-entry-score entry) 0)
 704         (insert "\t" entry-name ": "
 705                 (if (listp (cdr entry))
 706                     (mapconcat
 707                      #'identity (cdr entry)
 708                      (if (eq ?, (nth 2 (assq (car entry)
 709                                              lsdb-entry-type-alist)))
 710                          ", "
 711                        "\n\t\t"))
 712                   (cdr entry))
 713                 "\n"))))
 714
 715 (defun lsdb-print-record (record)
 716   (insert (car record) "\n")
 717   (let ((entries
 718          (sort (copy-sequence (cdr record))
 719                (lambda (entry1 entry2)
 720                  (> (lsdb-entry-score entry1) (lsdb-entry-score entry2))))))
 721     (while entries
 722       (lsdb-insert-entry (car entries))
 723       (setq entries (cdr entries))))
 724   (add-text-properties (point-min) (point-max)
 725                        (list 'lsdb-record record))
 726   (run-hooks 'lsdb-print-record-hook))
 727
 728 ;;;_. Completion
 729 (defvar lsdb-last-completion nil)
 730 (defvar lsdb-last-candidates nil)
 731 (defvar lsdb-last-candidates-pointer nil)
 732
 733 ;;;_ : Matching Highlight
 734 (defvar lsdb-last-highlight-overlay nil)
 735
 736 (defun lsdb-complete-name-highlight (start end)
 737   (make-local-hook 'pre-command-hook)
 738   (add-hook 'pre-command-hook 'lsdb-complete-name-highlight-update nil t)
 739   (save-excursion
 740     (goto-char start)
 741     (search-forward lsdb-last-completion end)
 742     (setq lsdb-last-highlight-overlay
 743           (make-overlay (match-beginning 0) (match-end 0)))
 744     (overlay-put lsdb-last-highlight-overlay 'face
 745                  (or (find-face 'isearch-secondary)
 746                      (find-face 'isearch-lazy-highlight-face)
 747                      'underline))))
 748
 749 (defun lsdb-complete-name-highlight-update ()
 750   (unless (eq 'this-command 'lsdb-complete-name)
 751     (if lsdb-last-highlight-overlay
 752         (delete-overlay lsdb-last-highlight-overlay))
 753     (remove-hook 'pre-command-hook
 754                  'lsdb-complete-name-highlight-update t)))
 755
 756 ;;;_ : Name Completion
 757 (defun lsdb-complete-name ()
 758   "Complete the user full-name or net-address before point"
 759   (interactive)
 760   (lsdb-maybe-load-hash-tables)
 761   (let* ((start
 762           (save-excursion
 763             (re-search-backward "\\(\\`\\|[\n:,]\\)[ \t]*")
 764             (goto-char (match-end 0))
 765             (point)))
 766          pattern
 767          (case-fold-search t)
 768          (completion-ignore-case t))
 769     (unless (eq last-command this-command)
 770       (setq lsdb-last-candidates nil
 771             lsdb-last-candidates-pointer nil
 772             lsdb-last-completion (buffer-substring start (point))
 773             pattern (concat "\\<" (regexp-quote lsdb-last-completion)))
 774       (lsdb-maphash
 775        (lambda (key value)
 776          (let ((net (cdr (assq 'net value))))
 777            (if (string-match pattern key)
 778                (setq lsdb-last-candidates
 779                      (nconc lsdb-last-candidates
 780                             (mapcar (lambda (address)
 781                                       (if (equal key address)
 782                                           key
 783                                         (concat key " <" address ">")))
 784                                     net)))
 785              (while net
 786                (if (string-match pattern (car net))
 787                    (push (car net) lsdb-last-candidates))
 788                (setq net (cdr net))))))
 789        lsdb-hash-table)
 790       ;; Sort candidates by the position where the pattern occurred.
 791       (setq lsdb-last-candidates
 792             (sort lsdb-last-candidates
 793                   (lambda (cand1 cand2)
 794                     (< (if (string-match pattern cand1)
 795                            (match-beginning 0))
 796                        (if (string-match pattern cand2)
 797                            (match-beginning 0)))))))
 798     (unless lsdb-last-candidates-pointer
 799       (setq lsdb-last-candidates-pointer lsdb-last-candidates))
 800     (when lsdb-last-candidates-pointer
 801       (delete-region start (point))
 802       (insert (pop lsdb-last-candidates-pointer))
 803       (lsdb-complete-name-highlight start (point)))))
 804
 805 ;;;_. Major Mode (`lsdb-mode') Implementation
 806 ;;;_ : Modeline Buffer Identification
 807 (defconst lsdb-pointer-xpm
 808   "/* XPM */
 809 static char * lsdb_pointer_xpm[] = {
 810 \"14 14 5 1\",
 811 \"      c None\",
 812 \"+     c #FF9696\",
 813 \"@     c #FF0000\",
 814 \"#     c #FF7575\",
 815 \"$     c #FF5959\",
 816 \"              \",
 817 \"  +++   @@@   \",
 818 \" +++## @@@@@  \",
 819 \" ++### @@@@@  \",
 820 \" +#####@@@@@  \",
 821 \" +###$$@@@@@  \",
 822 \" +###$$@@@@@  \",
 823 \"  ##$$$@@@@   \",
 824 \"   #$$$@@@    \",
 825 \"    $$@@@     \",
 826 \"     $@@      \",
 827 \"      @       \",
 828 \"              \",
 829 \"              \"};")
 830
 831 (static-if (featurep 'xemacs)
 832     (progn
 833       (defvar lsdb-xemacs-modeline-left-extent
 834         (copy-extent modeline-buffer-id-left-extent))
 835
 836       (defvar lsdb-xemacs-modeline-right-extent
 837         (copy-extent modeline-buffer-id-right-extent))
 838
 839       (defun lsdb-modeline-buffer-identification (line)
 840         "Decorate 1st element of `mode-line-buffer-identification' LINE.
 841 Modify whole identification by side effect."
 842         (let ((id (car line)) chopped)
 843           (if (and (stringp id) (string-match "^LSDB:" id))
 844               (progn
 845                 (setq chopped (substring id 0 (match-end 0))
 846                       id (substring id (match-end 0)))
 847                 (nconc
 848                  (list
 849                   (let ((glyph
 850                          (make-glyph
 851                           (nconc
 852                            (if (featurep 'xpm)
 853                                (list (vector 'xpm :data lsdb-pointer-xpm)))
 854                            (list (vector 'string :data chopped))))))
 855                     (set-glyph-face glyph 'modeline-buffer-id)
 856                     (cons lsdb-xemacs-modeline-left-extent glyph))
 857                   (cons lsdb-xemacs-modeline-right-extent id))
 858                  (cdr line)))
 859             line))))
 860   (condition-case nil
 861       (progn
 862         (require 'image)
 863         (defun lsdb-modeline-buffer-identification (line)
 864           "Decorate 1st element of `mode-line-buffer-identification' LINE.
 865 Modify whole identification by side effect."
 866           (let ((id (copy-sequence (car line)))
 867                 (image
 868                  (if (image-type-available-p 'xpm)
 869                      (create-image lsdb-pointer-xpm 'xpm t :ascent 'center))))
 870             (when (and image
 871                        (stringp id) (string-match "^LSDB:" id))
 872               (add-text-properties 0 (length id)
 873                                    (list 'display image
 874                                          'rear-nonsticky (list 'display))
 875                                    id)
 876               (setcar line id))
 877             line)))
 878     (error
 879      (defalias 'lsdb-modeline-buffer-identification 'identity))))
 880
 881 (defvar lsdb-mode-map
 882   (let ((keymap (make-sparse-keymap)))
 883     (define-key keymap "a" 'lsdb-mode-add-entry)
 884     (define-key keymap "d" 'lsdb-mode-delete-entry)
 885     (define-key keymap "e" 'lsdb-mode-edit-entry)
 886     (define-key keymap "s" 'lsdb-mode-save)
 887     (define-key keymap "q" 'lsdb-mode-quit-window)
 888     (define-key keymap "g" 'lsdb-mode-lookup)
 889     (define-key keymap "p" 'lsdb-mode-previous-record)
 890     (define-key keymap "n" 'lsdb-mode-next-record)
 891     (define-key keymap " " 'scroll-up)
 892     (define-key keymap [delete] 'scroll-down)
 893     (define-key keymap "\177" 'scroll-down)
 894     (define-key keymap [backspace] 'scroll-down)
 895     keymap)
 896   "LSDB's keymap.")
 897
 898 (defvar lsdb-modeline-string "")
 899
 900 (define-derived-mode lsdb-mode fundamental-mode "LSDB"
 901   "Major mode for browsing LSDB records."
 902   (setq buffer-read-only t)
 903   (static-if (featurep 'xemacs)
 904       ;; In XEmacs, setting `font-lock-defaults' only affects on
 905       ;; `find-file-hooks'.
 906       (font-lock-set-defaults)
 907     (set (make-local-variable 'font-lock-defaults)
 908          '(lsdb-font-lock-keywords t)))
 909   (make-local-hook 'post-command-hook)
 910   (add-hook 'post-command-hook 'lsdb-modeline-update nil t)
 911   (make-local-variable 'lsdb-modeline-string)
 912   (setq mode-line-buffer-identification
 913         (lsdb-modeline-buffer-identification
 914          '("LSDB: " lsdb-modeline-string)))
 915   (lsdb-modeline-update)
 916   (force-mode-line-update))
 917
 918 (defun lsdb-modeline-update ()
 919   (let ((record
 920          (get-text-property (if (eobp) (point-min) (point)) 'lsdb-record))
 921         net)
 922     (if record
 923         (progn
 924           (setq net (car (cdr (assq 'net (cdr record)))))
 925           (if (equal net (car record))
 926               (setq lsdb-modeline-string net)
 927             (setq lsdb-modeline-string (concat (car record) " <" net ">"))))
 928       (setq lsdb-modeline-string ""))))
 929
 930 (defun lsdb-narrow-to-record ()
 931   "Narrow to the current record."
 932   (let ((end (next-single-property-change (point) 'lsdb-record nil
 933                                           (point-max))))
 934     (narrow-to-region
 935      (previous-single-property-change (point) 'lsdb-record nil (point-min))
 936      end)
 937     (goto-char (point-min))))
 938
 939 (defun lsdb-current-record ()
 940   "Return the current record name."
 941   (let ((record (get-text-property (point) 'lsdb-record)))
 942     (unless record
 943       (error "There is nothing to follow here"))
 944     record))
 945
 946 (defun lsdb-current-entry ()
 947   "Return the current entry name.
 948 If the point is not on a entry line, it prompts to select a entry in
 949 the current record."
 950   (save-excursion
 951     (beginning-of-line)
 952     (if (looking-at "^[^\t]")
 953         (let ((record (lsdb-current-record))
 954               (completion-ignore-case t))
 955           (completing-read
 956            "Which entry to modify: "
 957            (mapcar (lambda (entry)
 958                      (list (capitalize (symbol-name (car entry)))))
 959                    (cdr record))))
 960       (end-of-line)
 961       (re-search-backward "^\t\\([^\t][^:]+\\):")
 962       (match-string 1))))
 963
 964 (defun lsdb-mode-add-entry (entry-name)
 965   "Add an entry on the current line."
 966   (interactive
 967    (let ((completion-ignore-case t))
 968      (list (completing-read "Entry name: " lsdb-known-entry-names))))
 969   (beginning-of-line)
 970   (unless (symbolp entry-name)
 971     (setq entry-name (intern (downcase entry-name))))
 972   (when (assq entry-name (cdr (lsdb-current-record)))
 973     (error "The entry already exists"))
 974   (let ((marker (point-marker)))
 975     (lsdb-edit-form
 976      nil "Editing the entry."
 977      `(lambda (form)
 978         (when form
 979           (save-excursion
 980             (set-buffer lsdb-buffer-name)
 981             (goto-char ,marker)
 982             (let ((record (lsdb-current-record))
 983                   (inhibit-read-only t)
 984                   buffer-read-only)
 985               (setcdr record (cons (cons ',entry-name form) (cdr record)))
 986               (lsdb-puthash (car record) (cdr record)
 987                             lsdb-hash-table)
 988               (run-hook-with-args 'lsdb-update-record-functions record)
 989               (setq lsdb-hash-tables-are-dirty t)
 990               (beginning-of-line 2)
 991               (add-text-properties
 992                (point)
 993                (progn
 994                  (lsdb-insert-entry (cons ',entry-name form))
 995                  (point))
 996                (list 'lsdb-record record)))))))))
 997
 998 (defun lsdb-mode-delete-entry (&optional entry-name dont-update)
 999   "Delete the entry on the current line."
1000   (interactive)
1001   (let ((record (lsdb-current-record))
1002         entry)
1003     (or entry-name
1004         (setq entry-name (lsdb-current-entry)))
1005     (setq entry (assq (intern (downcase entry-name)) (cdr record)))
1006     (when (and entry
1007                (not dont-update))
1008       (setcdr record (delq entry (cdr record)))
1009       (lsdb-puthash (car record) (cdr record)
1010                     lsdb-hash-table)
1011       (run-hook-with-args 'lsdb-update-record-functions record)
1012       (setq lsdb-hash-tables-are-dirty t))
1013     (save-restriction
1014       (lsdb-narrow-to-record)
1015       (let ((case-fold-search t)
1016             (inhibit-read-only t)
1017             buffer-read-only)
1018         (goto-char (point-min))
1019         (if (re-search-forward
1020              (concat "^\t" (or entry-name
1021                                (lsdb-current-entry))
1022                      ":")
1023              nil t)
1024             (delete-region (match-beginning 0)
1025                            (if (re-search-forward
1026                                 "^\t[^\t][^:]+:" nil t)
1027                                (match-beginning 0)
1028                              (point-max))))))))
1029
1030 (defun lsdb-mode-edit-entry ()
1031   "Edit the entry on the current line."
1032   (interactive)
1033   (let* ((record (lsdb-current-record))
1034          (entry-name (intern (downcase (lsdb-current-entry))))
1035          (entry (assq entry-name (cdr record)))
1036          (marker (point-marker)))
1037     (lsdb-edit-form
1038      (cdr entry) "Editing the entry."
1039      `(lambda (form)
1040         (unless (equal form ',(cdr entry))
1041           (save-excursion
1042             (set-buffer lsdb-buffer-name)
1043             (goto-char ,marker)
1044             (let* ((record (lsdb-current-record))
1045                    (entry (assq ',entry-name (cdr record)))
1046                    (inhibit-read-only t)
1047                    buffer-read-only)
1048               (setcdr entry form)
1049               (run-hook-with-args 'lsdb-update-record-functions record)
1050               (setq lsdb-hash-tables-are-dirty t)
1051               (lsdb-mode-delete-entry (symbol-name ',entry-name) t)
1052               (beginning-of-line)
1053               (add-text-properties
1054                (point)
1055                (progn
1056                  (lsdb-insert-entry (cons ',entry-name form))
1057                  (point))
1058                (list 'lsdb-record record)))))))))
1059
1060 (defun lsdb-mode-save (&optional dont-ask)
1061   "Save LSDB hash table into `lsdb-file'."
1062   (interactive)
1063   (if (not lsdb-hash-tables-are-dirty)
1064       (message "(No changes need to be saved)")
1065     (when (or (interactive-p)
1066               dont-ask
1067               (y-or-n-p "Save the LSDB now?"))
1068       (lsdb-save-hash-tables)
1069       (setq lsdb-hash-tables-are-dirty nil)
1070       (message "The LSDB was saved successfully."))))
1071
1072 (defun lsdb-mode-quit-window (&optional kill window)
1073   "Quit the current buffer.
1074 It partially emulates the GNU Emacs' of `quit-window'."
1075   (interactive "P")
1076   (unless window
1077     (setq window (selected-window)))
1078   (let ((buffer (window-buffer window)))
1079     (unless (save-selected-window
1080               (select-window window)
1081               (one-window-p))
1082       (delete-window window))
1083     (if kill
1084         (kill-buffer buffer)
1085       (bury-buffer buffer))))
1086
1087 (defun lsdb-hide-buffer ()
1088   "Hide the LSDB window."
1089   (let ((window (get-buffer-window lsdb-buffer-name)))
1090     (if window
1091         (lsdb-mode-quit-window nil window))))
1092
1093 (defun lsdb-show-buffer ()
1094   "Show the LSDB window."
1095   (if (get-buffer lsdb-buffer-name)
1096       (if lsdb-temp-buffer-show-function
1097           (let ((lsdb-pop-up-windows t))
1098             (funcall lsdb-temp-buffer-show-function lsdb-buffer-name))
1099         (pop-to-buffer lsdb-buffer-name))))
1100
1101 (defun lsdb-toggle-buffer (&optional arg)
1102   "Toggle hiding of the LSDB window.
1103 If given a negative prefix, always show; if given a positive prefix,
1104 always hide."
1105   (interactive
1106    (list (if current-prefix-arg
1107              (prefix-numeric-value current-prefix-arg)
1108            0)))
1109   (unless arg                           ;called noninteractively?
1110     (setq arg 0))
1111   (cond
1112    ((or (< arg 0)
1113         (and (zerop arg)
1114              (not (get-buffer-window lsdb-buffer-name))))
1115     (lsdb-show-buffer))
1116    ((or (> arg 0)
1117         (and (zerop arg)
1118              (get-buffer-window lsdb-buffer-name)))
1119     (lsdb-hide-buffer))))
1120
1121 (defun lsdb-lookup-records (regexp &optional entry-name)
1122   "Return the all records in the LSDB matching the REGEXP.
1123 If the optional 2nd argument ENTRY-NAME is given, matching only
1124 performed against the entry field."
1125   (let (records)
1126     (lsdb-maphash
1127      (if entry-name
1128          (progn
1129            (unless (symbolp entry-name)
1130              (setq entry-name (intern (downcase entry-name))))
1131            (lambda (key value)
1132              (let ((entry (cdr (assq entry-name value)))
1133                    found)
1134                (unless (listp entry)
1135                  (setq entry (list entry)))
1136                (while (and (not found) entry)
1137                  (if (string-match regexp (pop entry))
1138                      (setq found t)))
1139                (if found
1140                    (push (cons key value) records)))))
1141        (lambda (key value)
1142          (if (string-match regexp key)
1143              (push (cons key value) records))))
1144      lsdb-hash-table)
1145     records))
1146
1147 (defvar lsdb-mode-lookup-history nil)
1148
1149 (defun lsdb-mode-lookup (regexp &optional entry-name)
1150   "Display the all records in the LSDB matching the REGEXP.
1151 If the optional 2nd argument ENTRY-NAME is given, matching only
1152 performed against the entry field."
1153   (interactive
1154    (let* ((completion-ignore-case t)
1155           (entry-name
1156            (if current-prefix-arg
1157                (completing-read "Entry name: "
1158                                 lsdb-known-entry-names))))
1159      (list
1160       (read-from-minibuffer
1161        (if entry-name
1162            (format "Search records `%s' regexp: " entry-name)
1163          "Search records regexp: ")
1164        nil nil nil 'lsdb-mode-lookup-history)
1165       entry-name)))
1166   (lsdb-maybe-load-hash-tables)
1167   (let ((records (lsdb-lookup-records regexp entry-name)))
1168     (if records
1169         (lsdb-display-records records))))
1170
1171 ;;;###autoload
1172 (defalias 'lsdb 'lsdb-mode-lookup)
1173
1174 (defun lsdb-mode-next-record (&optional arg)
1175   "Go to the next record."
1176   (interactive "p")
1177   (unless arg                           ;called noninteractively?
1178     (setq arg 1))
1179   (if (< arg 0)
1180       (lsdb-mode-previous-record (- arg))
1181     (while (> arg 0)
1182       (goto-char (next-single-property-change
1183                   (point) 'lsdb-record nil (point-max)))
1184       (setq arg (1- arg)))))
1185
1186 (defun lsdb-mode-previous-record (&optional arg)
1187   "Go to the previous record."
1188   (interactive "p")
1189   (unless arg                           ;called noninteractively?
1190     (setq arg 1))
1191   (if (< arg 0)
1192       (lsdb-mode-next-record (- arg))
1193     (while (> arg 0)
1194       (goto-char (previous-single-property-change
1195                   (point) 'lsdb-record nil (point-min)))
1196       (setq arg (1- arg)))))
1197
1198 ;;;_ : Edit Forms -- stolen (and renamed) from gnus-eform.el
1199 (defvar lsdb-edit-form-buffer "*LSDB edit form*")
1200 (defvar lsdb-edit-form-done-function nil)
1201 (defvar lsdb-previous-window-configuration nil)
1202
1203 (defvar lsdb-edit-form-mode-map
1204   (let ((keymap (make-sparse-keymap)))
1205     (set-keymap-parent keymap emacs-lisp-mode-map)
1206     (define-key keymap "\C-c\C-c" 'lsdb-edit-form-done)
1207     (define-key keymap "\C-c\C-k" 'lsdb-edit-form-exit)
1208     keymap)
1209   "Edit form's keymap.")
1210
1211 (defun lsdb-edit-form-mode ()
1212   "Major mode for editing forms.
1213 It is a slightly enhanced emacs-lisp-mode.
1214
1215 \\{lsdb-edit-form-mode-map}"
1216   (interactive)
1217   (kill-all-local-variables)
1218   (setq major-mode 'lsdb-edit-form-mode
1219         mode-name "LSDB Edit Form")
1220   (use-local-map lsdb-edit-form-mode-map)
1221   (make-local-variable 'lsdb-edit-form-done-function)
1222   (make-local-variable 'lsdb-previous-window-configuration)
1223   (run-hooks 'lsdb-edit-form-mode-hook))
1224
1225 (defun lsdb-edit-form (form documentation exit-func)
1226   "Edit FORM in a new buffer.
1227 Call EXIT-FUNC on exit.  Display DOCUMENTATION in the beginning
1228 of the buffer."
1229   (let ((window-configuration
1230          (current-window-configuration)))
1231     (switch-to-buffer (get-buffer-create lsdb-edit-form-buffer))
1232     (lsdb-edit-form-mode)
1233     (setq lsdb-previous-window-configuration window-configuration
1234           lsdb-edit-form-done-function exit-func)
1235     (erase-buffer)
1236     (insert documentation)
1237     (unless (bolp)
1238       (insert "\n"))
1239     (goto-char (point-min))
1240     (while (not (eobp))
1241       (insert ";;; ")
1242       (forward-line 1))
1243     (insert ";; Type `C-c C-c' after you've finished editing.\n")
1244     (insert "\n")
1245     (let ((p (point)))
1246       (pp form (current-buffer))
1247       (insert "\n")
1248       (goto-char p))))
1249
1250 (defun lsdb-edit-form-done ()
1251   "Update changes and kill the current buffer."
1252   (interactive)
1253   (goto-char (point-min))
1254   (let ((form (condition-case nil
1255                   (read (current-buffer))
1256                 (end-of-file nil)))
1257         (func lsdb-edit-form-done-function))
1258     (lsdb-edit-form-exit)
1259     (funcall func form)))
1260
1261 (defun lsdb-edit-form-exit ()
1262   "Kill the current buffer."
1263   (interactive)
1264   (let ((window-configuration lsdb-previous-window-configuration))
1265     (kill-buffer (current-buffer))
1266     (set-window-configuration window-configuration)))
1267
1268 ;;;_. Interface to Semi-gnus
1269 ;;;###autoload
1270 (defun lsdb-gnus-insinuate ()
1271   "Call this function to hook LSDB into Semi-gnus."
1272   (add-hook 'gnus-article-prepare-hook 'lsdb-gnus-update-record)
1273   (add-hook 'gnus-save-newsrc-hook 'lsdb-mode-save))
1274
1275 (defvar gnus-current-headers)
1276 (defun lsdb-gnus-update-record ()
1277   (let ((entity gnus-current-headers)
1278         records)
1279     (with-temp-buffer
1280       (set-buffer-multibyte nil)
1281       (buffer-disable-undo)
1282       (mime-insert-entity entity)
1283       (setq records (lsdb-update-records))
1284       (when records
1285         (lsdb-display-record (car records))))))
1286
1287 ;;;_. Interface to Wanderlust
1288 ;;;###autoload
1289 (defun lsdb-wl-insinuate ()
1290   "Call this function to hook LSDB into Wanderlust."
1291   (add-hook 'wl-message-redisplay-hook 'lsdb-wl-update-record)
1292   (add-hook 'wl-summary-exit-hook 'lsdb-hide-buffer)
1293   (add-hook 'wl-summary-toggle-disp-off-hook 'lsdb-hide-buffer)
1294   (add-hook 'wl-summary-toggle-disp-folder-on-hook 'lsdb-hide-buffer)
1295   (add-hook 'wl-summary-toggle-disp-folder-off-hook 'lsdb-hide-buffer)
1296   (add-hook 'wl-summary-toggle-disp-folder-message-resumed-hook
1297             'lsdb-wl-show-buffer)
1298   (add-hook 'wl-exit-hook 'lsdb-mode-save)
1299   (add-hook 'wl-save-hook 'lsdb-mode-save))
1300
1301 (eval-when-compile
1302   (autoload 'wl-message-get-original-buffer "wl-message"))
1303 (defun lsdb-wl-update-record ()
1304   (save-excursion
1305     (set-buffer (wl-message-get-original-buffer))
1306     (let ((records (lsdb-update-records)))
1307       (when records
1308         (let ((lsdb-temp-buffer-show-function
1309                #'lsdb-wl-temp-buffer-show-function))
1310           (lsdb-display-record (car records)))))))
1311
1312 (defun lsdb-wl-toggle-buffer (&optional arg)
1313   "Toggle hiding of the LSDB window for Wanderlust.
1314 If given a negative prefix, always show; if given a positive prefix,
1315 always hide."
1316   (interactive
1317    (list (if current-prefix-arg
1318              (prefix-numeric-value current-prefix-arg)
1319            0)))
1320   (let ((lsdb-temp-buffer-show-function
1321          #'lsdb-wl-temp-buffer-show-function))
1322     (lsdb-toggle-buffer arg)))
1323
1324 (defun lsdb-wl-show-buffer ()
1325   (when lsdb-pop-up-windows
1326     (let ((lsdb-temp-buffer-show-function
1327            #'lsdb-wl-temp-buffer-show-function))
1328       (lsdb-show-buffer))))
1329
1330 (defvar wl-current-summary-buffer)
1331 (defvar wl-message-buffer)
1332 (defun lsdb-wl-temp-buffer-show-function (buffer)
1333   (when lsdb-pop-up-windows
1334     (save-selected-window
1335       (let ((window (or (get-buffer-window lsdb-buffer-name)
1336                         (progn
1337                           (select-window
1338                            (or (save-excursion
1339                                  (if (buffer-live-p wl-current-summary-buffer)
1340                                      (set-buffer wl-current-summary-buffer))
1341                                  (get-buffer-window wl-message-buffer))
1342                                (get-largest-window)))
1343                           (split-window-vertically)))))
1344         (set-window-buffer window buffer)
1345         (lsdb-fit-window-to-buffer window)))))
1346
1347 ;;;_. Interface to Mew written by Hideyuki SHIRAI <shirai@rdmg.mgcs.mei.co.jp>
1348 (eval-when-compile
1349   (autoload 'mew-sinfo-get-disp-msg "mew")
1350   (autoload 'mew-current-get-fld "mew")
1351   (autoload 'mew-current-get-msg "mew")
1352   (autoload 'mew-frame-id "mew")
1353   (autoload 'mew-cache-hit "mew"))
1354
1355 ;;;###autoload
1356 (defun lsdb-mew-insinuate ()
1357   "Call this function to hook LSDB into Mew."
1358   (add-hook 'mew-message-hook 'lsdb-mew-update-record)
1359   (add-hook 'mew-summary-toggle-disp-msg-hook
1360             (lambda ()
1361               (unless (mew-sinfo-get-disp-msg)
1362                 (lsdb-hide-buffer))))
1363   (add-hook 'mew-suspend-hook 'lsdb-hide-buffer)
1364   (add-hook 'mew-quit-hook 'lsdb-mode-save)
1365   (add-hook 'kill-emacs-hook 'lsdb-mode-save))
1366
1367 (defun lsdb-mew-update-record ()
1368   (let* ((fld (mew-current-get-fld (mew-frame-id)))
1369          (msg (mew-current-get-msg (mew-frame-id)))
1370          (cache (mew-cache-hit fld msg 'must-hit))
1371          records)
1372     (save-excursion
1373       (set-buffer cache)
1374       (make-local-variable 'lsdb-decode-field-body-function)
1375       (setq lsdb-decode-field-body-function
1376             (lambda (body name)
1377               (set-text-properties 0 (length body) nil body)
1378               body))
1379       (when (setq records (lsdb-update-records))
1380         (lsdb-display-record (car records))))))
1381
1382 ;;;_. Interface to MU-CITE
1383 (eval-when-compile
1384   (autoload 'mu-cite-get-value "mu-cite"))
1385
1386 (defun lsdb-mu-attribution (address)
1387   "Extract attribute information from LSDB."
1388   (let ((records
1389          (lsdb-lookup-records (concat "\\<" address "\\>") 'net)))
1390     (if records
1391         (cdr (assq 'attribution (cdr (car records)))))))
1392
1393 (defun lsdb-mu-set-attribution (attribution address)
1394   "Add attribute information to LSDB."
1395   (let ((records
1396          (lsdb-lookup-records (concat "\\<" address "\\>") 'net))
1397         entry)
1398     (when records
1399       (setq entry (assq 'attribution (cdr (car records))))
1400       (if entry
1401           (setcdr entry attribution)
1402         (setcdr (car records) (cons (cons 'attribution attribution)
1403                                     (cdr (car records))))
1404         (lsdb-puthash (car (car records)) (cdr (car records))
1405                       lsdb-hash-table)
1406         (run-hook-with-args 'lsdb-update-record-functions (car records))
1407         (setq lsdb-hash-tables-are-dirty t)))))
1408
1409 (defun lsdb-mu-get-prefix-method ()
1410   "A mu-cite method to return a prefix from LSDB or \">\".
1411 If an `attribution' value is found in LSDB, the value is returned.
1412 Otherwise \">\" is returned."
1413   (or (lsdb-mu-attribution (mu-cite-get-value 'address))
1414       ">"))
1415
1416 (defvar minibuffer-allow-text-properties)
1417
1418 (defvar lsdb-mu-history nil)
1419
1420 (defun lsdb-mu-get-prefix-register-method ()
1421   "A mu-cite method to return a prefix from LSDB or register it.
1422 If an `attribution' value is found in LSDB, the value is returned.
1423 Otherwise the function requests a prefix from a user.  The prefix will
1424 be registered to LSDB if the user wants it."
1425   (let ((address (mu-cite-get-value 'address)))
1426     (or (lsdb-mu-attribution address)
1427         (let* (minibuffer-allow-text-properties
1428                (result (read-string "Citation name? "
1429                                     (or (mu-cite-get-value 'x-attribution)
1430                                         (mu-cite-get-value 'full-name))
1431                                     'lsdb-mu-history)))
1432           (if (and (not (string-equal result ""))
1433                    (y-or-n-p (format "Register \"%s\"? " result)))
1434               (lsdb-mu-set-attribution result address))
1435           result))))
1436
1437 (defun lsdb-mu-get-prefix-register-verbose-method ()
1438   "A mu-cite method to return a prefix using LSDB.
1439
1440 In this method, a user must specify a prefix unconditionally.  If an
1441 `attribution' value is found in LSDB, the value is used as a initial
1442 value to input the prefix.  The prefix will be registered to LSDB if
1443 the user wants it."
1444   (let* ((address (mu-cite-get-value 'address))
1445          (attribution (lsdb-mu-attribution address))
1446          minibuffer-allow-text-properties
1447          (result (read-string "Citation name? "
1448                               (or attribution
1449                                   (mu-cite-get-value 'x-attribution)
1450                                   (mu-cite-get-value 'full-name))
1451                               'lsdb-mu-history)))
1452     (if (and (not (string-equal result ""))
1453              (not (string-equal result attribution))
1454              (y-or-n-p (format "Register \"%s\"? " result)))
1455         (lsdb-mu-set-attribution result address))
1456     result))
1457
1458 (defvar mu-cite-methods-alist)
1459 ;;;###autoload
1460 (defun lsdb-mu-insinuate ()
1461   (add-hook 'mu-cite-instantiation-hook
1462             (lambda ()
1463               (setq mu-cite-methods-alist
1464                     (nconc
1465                      mu-cite-methods-alist
1466                      (list
1467                       (cons 'lsdb-prefix
1468                             #'lsdb-mu-get-prefix-method)
1469                       (cons 'lsdb-prefix-register
1470                             #'lsdb-mu-get-prefix-register-method)
1471                       (cons 'lsdb-prefix-register-verbose
1472                             #'lsdb-mu-get-prefix-register-verbose-method)))))))
1473
1474 ;;;_. X-Face Rendering
1475 (defvar lsdb-x-face-cache
1476   (lsdb-make-hash-table :test 'equal))
1477
1478 (defun lsdb-x-face-available-image-type ()
1479   (static-if (featurep 'xemacs)
1480       (if (featurep 'xpm)
1481           'xpm)
1482     (and (>= emacs-major-version 21)
1483          (fboundp 'image-type-available-p)
1484          (if (image-type-available-p 'pbm)
1485              'pbm
1486            (if (image-type-available-p 'xpm)
1487                'xpm)))))
1488
1489 (defun lsdb-expose-x-face ()
1490   (let* ((record (get-text-property (point-min) 'lsdb-record))
1491          (x-face (cdr (assq 'x-face (cdr record))))
1492          (delimiter "\r "))
1493     (when (and lsdb-insert-x-face-function
1494                x-face)
1495       (goto-char (point-min))
1496       (end-of-line)
1497       (put-text-property 0 1 'invisible t delimiter) ;hide "\r"
1498       (put-text-property
1499        (point)
1500        (progn
1501          (insert delimiter)
1502          (while x-face
1503            (funcall lsdb-insert-x-face-function (pop x-face)))
1504          (point))
1505        'lsdb-record record))))
1506
1507 (defun lsdb-insert-x-face-image (data type marker)
1508   (static-if (featurep 'xemacs)
1509       (save-excursion
1510         (set-buffer (marker-buffer marker))
1511         (goto-char marker)
1512         (let* ((inhibit-read-only t)
1513                buffer-read-only
1514                (glyph (make-glyph (vector type :data data))))
1515           (set-extent-begin-glyph
1516            (make-extent (point) (point))
1517            glyph)))
1518     (save-excursion
1519       (set-buffer (marker-buffer marker))
1520       (goto-char marker)
1521       (let* ((inhibit-read-only t)
1522              buffer-read-only
1523              (image (create-image data type t :ascent 'center))
1524              (record (get-text-property (point) 'lsdb-record)))
1525         (put-text-property (point) (progn
1526                                      (insert-image image)
1527                                      (point))
1528                            'lsdb-record record)))))
1529
1530 (defun lsdb-insert-x-face-asynchronously (x-face)
1531   (let* ((type (lsdb-x-face-available-image-type))
1532          (shell-file-name lsdb-shell-file-name)
1533          (shell-command-switch lsdb-shell-command-switch)
1534          (process-connection-type nil)
1535          (cached (cdr (assq type (lsdb-gethash x-face lsdb-x-face-cache))))
1536          (marker (point-marker))
1537          process)
1538     (if cached
1539         (lsdb-insert-x-face-image cached type marker)
1540       (setq process
1541             (start-process-shell-command
1542              "lsdb-x-face-command" (generate-new-buffer " *lsdb work*")
1543              (concat "{ "
1544                      (nth 1 (assq type lsdb-x-face-command-alist))
1545                      "; } 2> /dev/null")))
1546       (process-send-string process (concat x-face "\n"))
1547       (process-send-eof process)
1548       (set-process-sentinel
1549        process
1550        `(lambda (process string)
1551           (unwind-protect
1552               (when (and (buffer-live-p (marker-buffer ,marker))
1553                          (equal string "finished\n"))
1554                 (let ((data
1555                        (with-current-buffer (process-buffer process)
1556                          (set-buffer-multibyte nil)
1557                          (buffer-string))))
1558                   (lsdb-insert-x-face-image data ',type ,marker)
1559                   (lsdb-puthash ,x-face (list (cons ',type data))
1560                                 lsdb-x-face-cache)))
1561             (kill-buffer (process-buffer process))))))))
1562
1563 (require 'product)
1564 (provide 'lsdb)
1565
1566 (product-provide 'lsdb
1567   (product-define "LSDB" nil '(0 5)))
1568
1569 ;;;_* Local emacs vars.
1570 ;;; The following `outline-layout' local variable setting:
1571 ;;;  - closes all topics from the first topic to just before the third-to-last,
1572 ;;;  - shows the children of the third to last (config vars)
1573 ;;;  - and the second to last (code section),
1574 ;;;  - and closes the last topic (this local-variables section).
1575 ;;;Local variables:
1576 ;;;outline-layout: (0 : -1 -1 0)
1577 ;;;End:
1578
1579 ;;; lsdb.el ends here