sb-mixi.el

   1 ;;; sb-mixi.el --- shimbun backend for mixi
   2
   3 ;; Copyright (C) 2006 OHASHI Akira
   4
   5 ;; Author: OHASHI Akira <bg66@koka-in.org>
   6 ;; Keywords: news
   7
   8 ;; This file is *NOT* a part of shimbun.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program; if not, you can either send email to this
  22 ;; program's maintainer or write to: The Free Software Foundation,
  23 ;; Inc.; 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; If you have bug reports and/or suggestions for improvement, please
  28 ;; send them via <URL:http://mixi.jp/view_community.pl?id=1596390>.
  29
  30 ;;; Code:
  31
  32 (require 'mixi)
  33 (require 'shimbun)
  34
  35 (eval-and-compile
  36   (luna-define-class shimbun-mixi (shimbun) (comment-cache))
  37   (luna-define-internal-accessors 'shimbun-mixi))
  38
  39 (defcustom shimbun-mixi-group-alist
  40   '(("new-diaries" . mixi-get-new-diaries)
  41     ("new-comments" . mixi-get-new-comments)
  42     ("new-bbses" . mixi-get-new-bbses)
  43     ("messages" . mixi-get-messages)
  44     ("messages.sent" .
  45      (lambda (range)
  46        (mixi-get-messages 'outbox range)))
  47     ("my-diaries" . "/home.pl")
  48     ("mixi-el" . "/view_community.pl?id=1596390")
  49     ("news.newest.domestic" .
  50      (lambda (range)
  51        (mixi-get-news 'domestic 'newest range)))
  52     ("news.newest.politics" .
  53      (lambda (range)
  54        (mixi-get-news 'politics 'newest range)))
  55     ("news.newest.economy" .
  56      (lambda (range)
  57        (mixi-get-news 'economy 'newest range)))
  58     ("news.newest.area" .
  59      (lambda (range)
  60        (mixi-get-news 'area 'newest range)))
  61     ("news.newest.abroad" .
  62      (lambda (range)
  63        (mixi-get-news 'abroad 'newest range)))
  64     ("news.newest.sports" .
  65      (lambda (range)
  66        (mixi-get-news 'sports 'newest range)))
  67     ("news.newest.entertainment" .
  68      (lambda (range)
  69        (mixi-get-news 'entertainment 'newest range)))
  70     ("news.newest.it" .
  71      (lambda (range)
  72        (mixi-get-news 'IT 'newest range)))
  73     ("news.pickup.domestic" .
  74      (lambda (range)
  75        (mixi-get-news 'domestic 'pickup range)))
  76     ("news.pickup.politics" .
  77      (lambda (range)
  78        (mixi-get-news 'politics 'pickup range)))
  79     ("news.pickup.economy" .
  80      (lambda (range)
  81        (mixi-get-news 'economy 'pickup range)))
  82     ("news.pickup.area" .
  83      (lambda (range)
  84        (mixi-get-news 'area 'pickup range)))
  85     ("news.pickup.abroad" .
  86      (lambda (range)
  87        (mixi-get-news 'abroad 'pickup range)))
  88     ("news.pickup.sports" .
  89      (lambda (range)
  90        (mixi-get-news 'sports 'pickup range)))
  91     ("news.pickup.entertainment" .
  92      (lambda (range)
  93        (mixi-get-news 'entertainment 'pickup range)))
  94     ("news.pickup.it" .
  95      (lambda (range)
  96        (mixi-get-news 'IT 'pickup range))))
  97   "*An alist of mixi shimbun group definition.
  98 Each element looks like (NAME . URL) or (NAME . FUNCTION).
  99 NAME is a shimbun group name.
 100 URL is the URL for mixi access point of the group.  If URL is friend's, get
 101 his/her diaries as article.  If community's, get its BBSes.  If diary's or
 102 BBS's, get its comments.
 103 FUNCTION is the function which has one `range' argument and returns the list
 104 of mixi object."
 105   :group 'shimbun
 106   :type '(repeat (cons :fromat "%v"
 107                        (string :tag "Group name")
 108                        (radio (string :tag "URL")
 109                               (const :tag "New diaries" mixi-get-new-diaries)
 110                               (const :tag "New comments" mixi-get-new-comments)
 111                               (const :tag "New BBSes" mixi-get-new-bbses)
 112                               (const :tag "Messages" mixi-get-messages)
 113                               (function :tag "Other function")))))
 114
 115 ;; FIXME: Don't use this user option.
 116 (defcustom shimbun-mixi-page-articles 10
 117   "*How many articles are there in one page."
 118   :group 'shimbun
 119   :type 'integer)
 120
 121 (defvar shimbun-mixi-x-face-alist
 122   '(("default" . "X-Face: CY;j#FoBnpK^37`-IoJvN!J^u;GciiPmMQ@T)~RP1]t8iv?v)/bVI:I\"F!JfWJvhM5{zY!=
 123  h.d+'g\\I{D>Ocy?Rc4uYUyOZj2%2Kl>,x-!MCSsyi3!L}psrrC1jlF,O?Ui>qf)X;sBz`/}\\066X%$
 124  siG'|4K!2?==|oB&#E'5GGH\\#z[muyQ")))
 125
 126 (defvar shimbun-mixi-reply-to nil)
 127
 128 (luna-define-method initialize-instance :after ((shimbun shimbun-mixi)
 129                                                 &rest init-args)
 130   (shimbun-mixi-set-comment-cache-internal shimbun
 131                                            (make-hash-table :test 'equal))
 132   shimbun)
 133
 134 (luna-define-method shimbun-close :after ((shimbun shimbun-mixi))
 135   (shimbun-mixi-set-comment-cache-internal shimbun nil)
 136   (mixi-logout))
 137
 138 (luna-define-method shimbun-groups ((shimbun shimbun-mixi))
 139   (mapcar 'car shimbun-mixi-group-alist))
 140
 141 (luna-define-method shimbun-reply-to ((shimbun shimbun-mixi))
 142   shimbun-mixi-reply-to)
 143
 144 (defun shimbun-mixi-make-subject (shimbun object)
 145   (let ((class (mixi-object-class object)))
 146     (if (eq class 'mixi-comment)
 147         (concat "Re: " (shimbun-mixi-make-subject
 148                         shimbun (mixi-comment-parent object)))
 149       (let ((prefix (when (eq class 'mixi-event) "[¥¤¥Ù¥ó¥È]"))
 150             (subject (mixi-object-title object))
 151             (suffix (when (string-match
 152                            "^new-" (shimbun-current-group-internal shimbun))
 153                       (concat " ("
 154                               (if (eq class 'mixi-diary)
 155                                   (mixi-friend-nick
 156                                    (mixi-diary-owner object))
 157                                 (mixi-community-name
 158                                  (mixi-bbs-community object)))
 159                               ")"))))
 160         (concat prefix subject suffix)))))
 161
 162 (defun shimbun-mixi-make-from (object)
 163   (let ((class (mixi-object-class object)))
 164     (if (eq class 'mixi-news)
 165         (mixi-news-media object)
 166       (let ((owner (mixi-object-owner object)))
 167         (mixi-friend-nick owner)))))
 168
 169 (defun shimbun-mixi-make-date (object)
 170   (let* ((time (mixi-object-time object))
 171          (cts (current-time-string time))
 172          (day-of-week (substring cts 0 3))
 173          (month (substring cts 4 7)))
 174     (concat day-of-week ", "
 175             (format-time-string "%d" time) " "
 176             month " "
 177             (format-time-string "%Y %H:%M:%S %z" time))))
 178
 179 (defun shimbun-mixi-make-message-id (object)
 180   (let ((class (mixi-object-class object)))
 181     (concat "<"
 182             (format-time-string "%Y%m%d%H%M" (mixi-object-time object)) "."
 183             (if (eq class 'mixi-comment)
 184                 (concat (mixi-friend-id (mixi-comment-owner object)) "@"
 185                         (mixi-object-id (mixi-comment-parent object)) "."
 186                         (mixi-friend-id (mixi-object-owner
 187                                          (mixi-comment-parent object))) ".")
 188               (concat (mixi-object-id object) "@"
 189                       (if (eq class 'mixi-news)
 190                           (mixi-news-media-id object)
 191                         (mixi-object-id (mixi-object-owner object))) "."))
 192             (mixi-object-name object) ".mixi.jp"
 193             ">")))
 194
 195 (defun shimbun-mixi-make-xref (object)
 196   (let ((class (mixi-object-class object)))
 197     (cond ((eq class 'mixi-diary)
 198            (mixi-expand-url (mixi-diary-page object)))
 199           ((eq class 'mixi-topic)
 200            (mixi-expand-url (mixi-topic-page object)))
 201           ((eq class 'mixi-event)
 202            (mixi-expand-url (mixi-event-page object)))
 203           ((eq class 'mixi-comment)
 204            (concat (shimbun-mixi-make-xref (mixi-comment-parent object))
 205                    "#comment"))
 206           ((eq class 'mixi-message)
 207            (mixi-expand-url (mixi-message-page object)))
 208           ((eq class 'mixi-news)
 209            (mixi-news-page object)))))
 210
 211 (defun shimbun-mixi-make-body (object)
 212   (let ((class (mixi-object-class object)))
 213     (cond ((eq class 'mixi-event)
 214            (let ((limit (mixi-event-limit object)))
 215              (setq limit (if limit
 216                              (format-time-string "%YÇ¯%m·î%dÆü" limit)
 217                            "»ØÄê¤Ê¤·"))
 218              (concat "<dl><dt>³«ºÅÆü»þ¡§</dt>"
 219                      "<dd>" (mixi-event-date object) "</dd>"
 220                      "<dt>³«ºÅ¾ì½ê¡§</dt>"
 221                      "<dd>" (mixi-event-place object) "</dd>"
 222                      "<dt>¾ÜºÙ¡§</dt>"
 223                      "<dd>" (mixi-event-detail object) "</dd>"
 224                      "<dt>Êç½¸´ü¸Â¡§</dt>"
 225                      "<dd>" limit "</dd>"
 226                      "<dt>»²²Ã¼Ô¡§</dt>"
 227                      "<dd>" (mixi-event-members object) "</dd></dl>")))
 228           (t (mixi-object-content object)))))
 229
 230 (defun shimbun-mixi-make-reply-to (object)
 231   (setq shimbun-mixi-reply-to "mixi;")
 232   (let ((class (mixi-object-class object)))
 233     (setq shimbun-mixi-reply-to
 234           (concat
 235            (cond ((eq class 'mixi-diary)
 236                   (concat shimbun-mixi-reply-to "comment;diary;"
 237                           (mixi-friend-id (mixi-diary-owner object)) ";"
 238                           (mixi-diary-id object)))
 239                  ((mixi-bbs-p object)
 240                   (concat shimbun-mixi-reply-to "comment;"
 241                           (mixi-object-name object) ";"
 242                           (mixi-community-id (mixi-bbs-community object)) ";"
 243                           (mixi-bbs-id object)))
 244                  ((eq class 'mixi-community)
 245                   (concat shimbun-mixi-reply-to "topic;"
 246                           (mixi-community-id object)))
 247                  ((or (eq class 'mixi-news) (eq object (mixi-make-me)))
 248                   (concat shimbun-mixi-reply-to "diary"))
 249                  ((eq class 'mixi-message)
 250                   (concat shimbun-mixi-reply-to "message;"
 251                           (mixi-friend-id (mixi-message-owner object))))
 252                  ((or (eq class 'mixi-friend) (eq class 'mixi-log))
 253                   (concat shimbun-mixi-reply-to "message;"
 254                           (mixi-friend-id object))))))))
 255
 256 (defun shimbun-mixi-get-headers (shimbun objects &optional range)
 257   (when objects
 258     (let (headers)
 259       (catch 'stop
 260         (mapc (lambda (object)
 261                 (when (mixi-object-p object)
 262                   (let ((class (mixi-object-class object)))
 263                     (when (mixi-parent-p object)
 264                       (let ((comments (mixi-get-comments object range)))
 265                         (mapc (lambda (header)
 266                                 (push header headers))
 267                               (shimbun-mixi-get-headers shimbun
 268                                                         comments))))
 269                     (let ((id (shimbun-mixi-make-message-id object)))
 270                       (when (and (eq class 'mixi-comment)
 271                                  (shimbun-search-id shimbun id))
 272                         (throw 'stop nil))
 273                       (push
 274                        (shimbun-create-header
 275                         0
 276                         (shimbun-mixi-make-subject shimbun object)
 277                         (shimbun-mixi-make-from object)
 278                         (shimbun-mixi-make-date object)
 279                         id
 280                         (if (eq class 'mixi-comment)
 281                             (shimbun-mixi-make-message-id
 282                              (mixi-comment-parent object))
 283                           "")
 284                         0 0
 285                         (shimbun-mixi-make-xref object))
 286                        headers)
 287                       (when (eq class 'mixi-comment)
 288                         (puthash id (mixi-comment-content object)
 289                                  (shimbun-mixi-comment-cache-internal
 290                                   shimbun)))))))
 291               objects))
 292       headers)))
 293
 294 (luna-define-method shimbun-get-headers ((shimbun shimbun-mixi)
 295                                          &optional range)
 296   (let ((url-or-function (cdr (assoc (shimbun-current-group-internal shimbun)
 297                                      shimbun-mixi-group-alist)))
 298         (range (when (integerp range) (* range shimbun-mixi-page-articles)))
 299         objects)
 300     (if (stringp url-or-function)
 301         (let* ((object (mixi-make-object-from-url url-or-function))
 302                (class (mixi-object-class object)))
 303           (cond ((eq class 'mixi-friend)
 304                  (setq objects (mixi-get-diaries object range)))
 305                 ((eq class 'mixi-community)
 306                  (setq objects (mixi-get-bbses object range)))
 307                 ((mixi-parent-p object)
 308                  (setq objects (mixi-get-comments object range)))
 309                 (t (error (concat (symbol-name class)
 310                                   " is not supported yet.")))))
 311       (setq objects (funcall url-or-function range)))
 312     (shimbun-sort-headers (shimbun-mixi-get-headers shimbun objects range))))
 313
 314 (defun shimbun-mixi-comment-article (url shimbun header)
 315   (let* ((message-id (shimbun-header-id header))
 316          (cache (shimbun-mixi-comment-cache-internal shimbun))
 317          (article (gethash message-id cache)))
 318     (unless (stringp article)
 319       (let ((parent (mixi-make-object-from-url url)))
 320         (mapc (lambda (comment)
 321                 (let ((id (shimbun-mixi-make-message-id comment))
 322                       (content (mixi-comment-content comment)))
 323                   (puthash id content cache)
 324                   (when (string= id message-id)
 325                     (setq article content))))
 326               (mixi-get-comments parent))))
 327     article))
 328
 329 (luna-define-method shimbun-article ((shimbun shimbun-mixi)
 330                                      header &optional outbuf)
 331   (when (shimbun-current-group-internal shimbun)
 332     (with-current-buffer (or outbuf (current-buffer))
 333       (w3m-insert-string
 334        (or (with-temp-buffer
 335              (let* ((url (shimbun-article-url shimbun header))
 336                     (object (mixi-make-object-from-url url))
 337                     (article (if (string-match "#comment$" url)
 338                                  (shimbun-mixi-comment-article
 339                                   url shimbun header)
 340                                (shimbun-mixi-make-body object))))
 341                (shimbun-mixi-make-reply-to object)
 342                (when (stringp article)
 343                  (insert article)))
 344              (shimbun-message shimbun "shimbun: Make contents...")
 345              (goto-char (point-min))
 346              (prog1 (shimbun-make-contents shimbun header)
 347                (shimbun-message shimbun "shimbun: Make contents...done")))
 348            "")))))
 349
 350 (defconst shimbun-mixi-to-regexp
 351   "^mixi;\\([a-z]+\\);?\\([a-z0-9]+\\)?;?\\([0-9]+\\)?;?\\([0-9]+\\)?")
 352
 353 (defun shimbun-mixi-send-mail (to title content)
 354   (when (string-match shimbun-mixi-to-regexp to)
 355     (let ((method (match-string 1 to)))
 356       (cond ((string= method "comment")
 357              (let ((parent (match-string 2 to))
 358                    (owner-id (match-string 3 to))
 359                    (id (match-string 4 to)))
 360                (if (string= parent "diary")
 361                    (mixi-post-comment
 362                     (mixi-make-diary (mixi-make-friend owner-id) id) content)
 363                  (let ((func (intern
 364                               (concat mixi-object-prefix "make-" parent))))
 365                    (mixi-post-comment
 366                     (funcall func (mixi-make-community owner-id) id)
 367                     content)))))
 368             ((string= method "topic")
 369              (mixi-post-topic (mixi-make-community (match-string 2 to))
 370                               title content))
 371             ((string= method "diary")
 372              (mixi-post-diary title content))
 373             ((string= method "message")
 374              (mixi-post-message (mixi-make-friend (match-string 2 to))
 375                                 title content))))))
 376
 377 (provide 'sb-mixi)
 378
 379 ;;; sb-mixi.el ends here