lisp/riece-commands.el

   1 ;;; riece-commands.el --- commands available in command buffer
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-channel)
  28 (require 'riece-complete)
  29 (require 'riece-layout)
  30 (require 'riece-display)
  31 (require 'riece-server)
  32 (require 'riece-misc)
  33 (require 'riece-identity)
  34 (require 'riece-message)
  35 (require 'riece-mcat)
  36
  37 (autoload 'derived-mode-class "derived")
  38
  39 ;;; Channel movement:
  40 (defun riece-command-switch-to-channel (channel)
  41   (interactive (list (riece-completing-read-identity
  42                       (riece-mcat "Switch to channel/user: ")
  43                       riece-current-channels nil t)))
  44   (unless (equal channel riece-current-channel)
  45     (riece-switch-to-channel channel)))
  46
  47 (defun riece-command-switch-to-channel-by-number (number)
  48   (interactive
  49    (let ((command-name (symbol-name this-command)))
  50      (if (string-match "[0-9]+$" command-name)
  51          (list (string-to-number (match-string 0 command-name)))
  52        (list (string-to-number (read-string (riece-mcat "Switch to number: ")))))))
  53   (let ((channel (nth (1- number) riece-current-channels)))
  54     (if channel
  55         (riece-command-switch-to-channel channel)
  56       (error "No such number!"))))
  57
  58 (eval-and-compile
  59   (let ((number 1))
  60     (while (<= number 20)
  61       (defalias (intern (concat "riece-command-switch-to-channel-by-number-"
  62                                 (number-to-string number)))
  63         'riece-command-switch-to-channel-by-number)
  64       (setq number (1+ number)))))
  65
  66 (defun riece-command-next-channel ()
  67   "Select the next channel."
  68   (interactive)
  69   (when (> (length riece-current-channels) 1)
  70     (let ((pointer (cdr (riece-identity-member
  71                          riece-current-channel
  72                          riece-current-channels))))
  73       (while (and pointer
  74                   (null (car pointer)))
  75         (setq pointer (cdr pointer)))
  76       (when (null pointer)
  77         (setq pointer riece-current-channels)
  78         (while (and pointer
  79                     (null (car pointer)))
  80           (setq pointer (cdr pointer))))
  81       (if (car pointer)
  82           (riece-command-switch-to-channel (car pointer))
  83         (error "No such channel!")))))
  84
  85 (defun riece-command-previous-channel ()
  86   "Select the previous channel."
  87   (interactive)
  88   (when (> (length riece-current-channels) 1)
  89     (let ((pointer (riece-identity-member
  90                     riece-current-channel
  91                     riece-current-channels))
  92           (start riece-current-channels)
  93           channel)
  94       (while (and start (not (eq start pointer)))
  95         (if (car start)
  96             (setq channel (car start)))
  97         (setq start (cdr start)))
  98       (when (null channel)
  99         (setq start (copy-sequence riece-current-channels))
 100         (setq start (delq nil start))
 101         (and (> (length start) 1)
 102              (setq channel (nth (1- (length start)) start))))
 103       (if channel
 104           (riece-command-switch-to-channel channel)
 105         (error "No such channel!")))))
 106
 107 (defun riece-command-select-command-buffer ()
 108   "Select the command buffer."
 109   (interactive)
 110   (let ((window (get-buffer-window riece-command-buffer)))
 111     (if window
 112         (select-window window))))
 113
 114 (defun riece-command-configure-windows ()
 115   (interactive)
 116   "Reconfigure windows with the current layout."
 117   (riece-redisplay-buffers t))
 118
 119 (defun riece-command-suspend-resume ()
 120   (interactive)
 121   "Save or restore the current window configuration."
 122   (let ((entry (assq 'riece-window-configuration (frame-parameters))))
 123     (modify-frame-parameters (selected-frame)
 124                              (list (cons 'riece-window-configuration
 125                                          (current-window-configuration))))
 126     (if (cdr entry)
 127         (set-window-configuration (cdr entry))
 128       (delete-other-windows))
 129     (message
 130      (substitute-command-keys
 131       "\\[riece-command-suspend-resume] to get back the last windows"))))
 132
 133 (defun riece-command-change-layout (name)
 134   "Select a layout-name from all current available layouts and change
 135 the layout to the selected layout-name."
 136   (interactive (list (completing-read (riece-mcat "Change layout: ")
 137                                       riece-layout-alist)))
 138   (setq riece-layout name
 139         riece-save-variables-are-dirty t)
 140   (riece-command-configure-windows))
 141
 142 (defun riece-command-toggle-channel-buffer-mode ()
 143   (interactive)
 144   (setq riece-channel-buffer-mode
 145         (not riece-channel-buffer-mode)
 146         riece-save-variables-are-dirty t)
 147   (riece-command-configure-windows))
 148
 149 (defun riece-command-toggle-others-buffer-mode ()
 150   (interactive)
 151   (setq riece-others-buffer-mode
 152         (not riece-others-buffer-mode)
 153         riece-save-variables-are-dirty t)
 154   (riece-command-configure-windows))
 155
 156 (defun riece-command-toggle-user-list-buffer-mode ()
 157   (interactive)
 158   (setq riece-user-list-buffer-mode
 159         (not riece-user-list-buffer-mode)
 160         riece-save-variables-are-dirty t)
 161   (riece-command-configure-windows))
 162
 163 (defun riece-command-toggle-channel-list-buffer-mode ()
 164   (interactive)
 165   (setq riece-channel-list-buffer-mode
 166         (not riece-channel-list-buffer-mode)
 167         riece-save-variables-are-dirty t)
 168   (riece-command-configure-windows))
 169
 170 (defun riece-command-finger (user &optional recurse)
 171   (interactive
 172    (let* ((completion-ignore-case t)
 173           (user (riece-completing-read-identity
 174                  (riece-mcat "Finger user: ")
 175                  (riece-get-users-on-server (riece-current-server-name))
 176                  nil nil nil nil nil t)))
 177      (list user current-prefix-arg)))
 178   (if recurse
 179       (riece-send-string (format "WHOIS %s %s\r\n"
 180                                  (riece-identity-prefix user)
 181                                  (riece-identity-prefix user)))
 182     (riece-send-string (format "WHOIS %s\r\n" (riece-identity-prefix user)))))
 183
 184 (defun riece-command-topic (topic)
 185   (interactive
 186    (progn
 187      (riece-check-channel-commands-are-usable t)
 188      (list (read-from-minibuffer
 189             (riece-mcat "Set topic: ")
 190             (cons (or (riece-with-server-buffer
 191                           (riece-identity-server
 192                            riece-current-channel)
 193                         (riece-channel-get-topic
 194                          (riece-identity-prefix
 195                           riece-current-channel)))
 196                       "")
 197                   0)))))
 198   (riece-send-string (format "TOPIC %s :%s\r\n"
 199                              (riece-identity-prefix riece-current-channel)
 200                              topic)
 201                      riece-current-channel))
 202
 203 (defun riece-command-invite (user)
 204   (interactive
 205    (let ((completion-ignore-case t))
 206      (riece-check-channel-commands-are-usable t)
 207      (list (riece-completing-read-identity
 208             (riece-mcat "Invite user: ")
 209             (riece-get-users-on-server (riece-current-server-name))
 210             nil nil nil nil nil t))))
 211   (riece-send-string (format "INVITE %s :%s\r\n"
 212                              (riece-identity-prefix user)
 213                              (riece-identity-prefix riece-current-channel))))
 214
 215 (defun riece-command-kick (user &optional message)
 216   (interactive
 217    (let ((completion-ignore-case t))
 218      (riece-check-channel-commands-are-usable t)
 219      (list (completing-read
 220             (riece-mcat "Kick user: ")
 221             (riece-with-server-buffer
 222                 (riece-identity-server riece-current-channel)
 223               (riece-channel-get-users (riece-identity-prefix
 224                                         riece-current-channel))))
 225            (if current-prefix-arg
 226                (read-string "Message: ")))))
 227   (riece-send-string
 228    (if message
 229        (format "KICK %s %s :%s\r\n"
 230                (riece-identity-prefix riece-current-channel)
 231                user message)
 232      (format "KICK %s %s\r\n"
 233              (riece-identity-prefix riece-current-channel)
 234              user))
 235    riece-current-channel))
 236
 237 (defun riece-command-kick-with-ban (user pattern &optional message)
 238   (interactive
 239    (let ((completion-ignore-case t)
 240          users patterns)
 241      (riece-check-channel-commands-are-usable t)
 242      (riece-with-server-buffer (riece-identity-server riece-current-channel)
 243        (setq users (riece-channel-get-users (riece-identity-prefix
 244                                              riece-current-channel))
 245              patterns (mapcar
 246                        (lambda (user)
 247                          (list (concat (car user) "!"
 248                                        (riece-user-get-user-at-host
 249                                         (car user)))))
 250                        users)))
 251      (list
 252       (completing-read (riece-mcat "Kick user: ") users)
 253       (completing-read (riece-mcat "Ban pattern: ") patterns)
 254       (if current-prefix-arg
 255           (read-string "Message: ")))))
 256   (riece-send-string (format "MODE %s :+b %s\r\n"
 257                              (riece-identity-prefix riece-current-channel)
 258                              pattern)
 259                      riece-current-channel)
 260   (riece-send-string
 261    (if message
 262        (format "KICK %s %s :%s\r\n"
 263                (riece-identity-prefix riece-current-channel)
 264                user message)
 265      (format "KICK %s %s\r\n"
 266              (riece-identity-prefix riece-current-channel)
 267              user))
 268    riece-current-channel))
 269
 270 (defun riece-command-names (pattern)
 271   (interactive
 272    (let ((completion-ignore-case t))
 273      (list (read-from-minibuffer
 274             (riece-mcat "NAMES pattern: ")
 275             (if (and riece-current-channel
 276                      (riece-channel-p (riece-identity-prefix
 277                                        riece-current-channel)))
 278                 (cons (riece-identity-prefix riece-current-channel)
 279                       0))))))
 280   (if (or (not (equal pattern ""))
 281           (yes-or-no-p (riece-mcat
 282                         "Really want to query NAMES without argument? ")))
 283       (riece-send-string (format "NAMES %s\r\n" pattern))))
 284
 285 (defun riece-command-who (pattern)
 286   (interactive
 287    (let ((completion-ignore-case t))
 288      (list (read-from-minibuffer
 289             (riece-mcat "WHO pattern: ")
 290             (if (and riece-current-channel
 291                      (riece-channel-p (riece-identity-prefix
 292                                        riece-current-channel)))
 293                 (cons (riece-identity-prefix riece-current-channel)
 294                       0))))))
 295   (if (or (not (equal pattern ""))
 296           (yes-or-no-p (riece-mcat
 297                         "Really want to query WHO without argument? ")))
 298       (riece-send-string (format "WHO %s\r\n" pattern))))
 299
 300 (defun riece-command-list (pattern)
 301   (interactive
 302    (let ((completion-ignore-case t))
 303      (list (read-from-minibuffer
 304             (riece-mcat "LIST pattern: ")
 305             (if (and riece-current-channel
 306                      (riece-channel-p (riece-identity-prefix
 307                                        riece-current-channel)))
 308                 (cons (riece-identity-prefix riece-current-channel)
 309                       0))))))
 310   (if (or (not (equal pattern ""))
 311           (yes-or-no-p (riece-mcat
 312                         "Really want to query LIST without argument? ")))
 313       (riece-send-string (format "LIST %s\r\n" pattern))))
 314
 315 (defun riece-command-change-mode (channel change)
 316   (interactive
 317    (let* ((completion-ignore-case t)
 318           (channel
 319            (if current-prefix-arg
 320                (riece-completing-read-identity
 321                 (riece-mcat "Change mode for channel/user: ")
 322                 (riece-get-identities-on-server (riece-current-server-name))
 323                 nil nil nil nil nil t)
 324              (riece-check-channel-commands-are-usable t)
 325              riece-current-channel))
 326           (riece-overriding-server-name (riece-identity-server channel))
 327           (riece-temp-minibuffer-message
 328            (concat (riece-mcat "[Available modes: ")
 329                    (riece-with-server-buffer (riece-identity-server channel)
 330                      (if (riece-channel-p (riece-identity-prefix channel))
 331                          (if riece-supported-channel-modes
 332                              (apply #'string riece-supported-channel-modes))
 333                        (if riece-supported-user-modes
 334                            (apply #'string riece-supported-user-modes))))
 335                    "]")))
 336      (list channel
 337            (read-from-minibuffer
 338             (concat (riece-concat-channel-modes
 339                      channel (riece-mcat "Mode (? for help)")) ": ")
 340             nil riece-minibuffer-map))))
 341   (if (equal change "")
 342       (riece-send-string (format "MODE %s\r\n"
 343                                  (riece-identity-prefix channel)))
 344     (riece-send-string (format "MODE %s %s\r\n"
 345                                (riece-identity-prefix channel)
 346                                change))))
 347
 348 (defun riece-command-set-operators (users &optional arg)
 349   (interactive
 350    (progn
 351      (riece-check-channel-commands-are-usable t)
 352      (let ((completion-ignore-case t))
 353        (list (riece-completing-read-multiple
 354               (if current-prefix-arg
 355                   (riece-mcat "Unset +o for users")
 356                 (riece-mcat "Set +o for users"))
 357               (riece-with-server-buffer
 358                   (riece-identity-server riece-current-channel)
 359                 (riece-channel-get-users (riece-identity-prefix
 360                                          riece-current-channel)))
 361               (if current-prefix-arg
 362                   (lambda (user)
 363                     (memq ?o (cdr user)))
 364                 (lambda (user)
 365                   (not (memq ?o (cdr user))))))
 366              current-prefix-arg))))
 367   (let (group)
 368     (while users
 369       (setq group (cons (car users) group)
 370             users (cdr users))
 371       (when (or (= (length group) 3)
 372                 (null users))
 373         (riece-send-string
 374          (format "MODE %s %c%s %s\r\n"
 375                  (riece-identity-prefix riece-current-channel)
 376                  (if current-prefix-arg
 377                      ?-
 378                    ?+)
 379                  (make-string (length group) ?o)
 380                  (mapconcat #'identity (nreverse group) " ")))
 381         (setq group nil)))))
 382
 383 (defun riece-command-set-speakers (users &optional arg)
 384   (interactive
 385    (progn
 386      (riece-check-channel-commands-are-usable t)
 387      (let ((completion-ignore-case t))
 388        (list (riece-completing-read-multiple
 389               (if current-prefix-arg
 390                   (riece-mcat "Unset +v for users")
 391                 (riece-mcat "Set +v for users"))
 392               (riece-with-server-buffer
 393                   (riece-identity-server riece-current-channel)
 394                 (riece-channel-get-users (riece-identity-prefix
 395                                           riece-current-channel)))
 396               (if current-prefix-arg
 397                   (lambda (user)
 398                     (memq ?v (cdr user)))
 399                 (lambda (user)
 400                   (not (memq ?v (cdr user))))))
 401              current-prefix-arg))))
 402   (let (group)
 403     (while users
 404       (setq group (cons (car users) group)
 405             users (cdr users))
 406       (when (or (= (length group) 3)
 407                 (null users))
 408         (riece-send-string
 409          (format "MODE %s %c%s %s\r\n"
 410                  (riece-identity-prefix riece-current-channel)
 411                  (if current-prefix-arg
 412                      ?-
 413                    ?+)
 414                  (make-string (length group) ?v)
 415                  (mapconcat #'identity (nreverse group) " ")))
 416         (setq group nil)))))
 417
 418 (defun riece-command-send-message (message notice)
 419   "Send MESSAGE to the current channel."
 420   (run-hooks 'riece-command-send-message-hook)
 421   (if (equal message "")
 422       (error (riece-mcat "No text to send")))
 423   (riece-check-channel-commands-are-usable)
 424   (if notice
 425       (progn
 426         (riece-send-string
 427          (format "NOTICE %s :%s\r\n"
 428                  (riece-identity-prefix riece-current-channel)
 429                  message)
 430          riece-current-channel)
 431         (riece-display-message
 432          (riece-make-message (riece-current-nickname) riece-current-channel
 433                              message 'notice t)))
 434     (riece-send-string
 435      (format "PRIVMSG %s :%s\r\n"
 436              (riece-identity-prefix riece-current-channel)
 437              message)
 438      riece-current-channel)
 439     (riece-display-message
 440      (riece-make-message (riece-current-nickname) riece-current-channel
 441                          message nil t))))
 442
 443 (defun riece-command-enter-message ()
 444   "Send the current line to the current channel."
 445   (interactive)
 446   (riece-command-send-message (buffer-substring
 447                                (riece-line-beginning-position)
 448                                (riece-line-end-position))
 449                               nil)
 450   (let ((next-line-add-newlines t))
 451     (next-line 1)))
 452
 453 (defun riece-command-enter-message-as-notice ()
 454   "Send the current line to the current channel as NOTICE."
 455   (interactive)
 456   (riece-command-send-message (buffer-substring
 457                                (riece-line-beginning-position)
 458                                (riece-line-end-position))
 459                               t)
 460   (let ((next-line-add-newlines t))
 461     (next-line 1)))
 462
 463 (defun riece-command-enter-message-to-user (user)
 464   "Send the current line to USER."
 465   (interactive
 466    (if (and (bolp) (eolp))
 467        (error "No text to send")
 468      (let ((completion-ignore-case t))
 469        (list (riece-completing-read-identity
 470               (riece-mcat "Message to user: ")
 471               (riece-get-users-on-server (riece-current-server-name))
 472               nil nil nil nil nil t)))))
 473   (let ((text (buffer-substring
 474                (riece-line-beginning-position)
 475                (riece-line-end-position))))
 476     (riece-send-string
 477      (format "PRIVMSG %s :%s\r\n" (riece-identity-prefix user) text)
 478      user)
 479     (riece-display-message
 480      (riece-make-message (riece-current-nickname) user text nil t)))
 481   (let ((next-line-add-newlines t))
 482     (next-line 1)))
 483
 484 (defun riece-command-join-channel (target key)
 485   (unless (riece-server-opened (riece-identity-server target))
 486     (error "%s" (substitute-command-keys
 487                  "Type \\[riece-command-open-server] to open server.")))
 488   (riece-send-string (if key
 489                          (format "JOIN %s :%s\r\n"
 490                                  (riece-identity-prefix target)
 491                                  key)
 492                        (format "JOIN %s\r\n"
 493                                (riece-identity-prefix target)))
 494                      target))
 495
 496 (defun riece-command-join-partner (target)
 497   (let ((pointer (riece-identity-member target riece-current-channels)))
 498     (if pointer
 499         (riece-command-switch-to-channel (car pointer))
 500       (riece-join-channel target)
 501       (riece-switch-to-channel target))))
 502
 503 (defun riece-command-join (target)
 504   (interactive
 505    (let ((completion-ignore-case t))
 506      (list
 507       (if riece-join-channel-candidate
 508           (let ((default (riece-format-identity
 509                           riece-join-channel-candidate)))
 510             (riece-completing-read-identity
 511              (format (riece-mcat "Join channel/user (default %s): ") default)
 512              (riece-get-identities-on-server (riece-current-server-name))
 513              nil nil nil nil default))
 514         (riece-completing-read-identity
 515          (riece-mcat "Join channel/user: ")
 516          (riece-get-identities-on-server (riece-current-server-name)))))))
 517   (let ((pointer (riece-identity-member target riece-current-channels)))
 518     (if pointer
 519         (riece-command-switch-to-channel (car pointer))
 520       (if (riece-channel-p (riece-identity-prefix target))
 521           (riece-command-join-channel target nil)
 522         (riece-command-join-partner target)))))
 523
 524 (defun riece-command-part-channel (target message)
 525   (unless (riece-server-opened (riece-identity-server target))
 526     (error "%s" (substitute-command-keys
 527                  "Type \\[riece-command-open-server] to open server.")))
 528   (riece-send-string (if message
 529                          (format "PART %s :%s\r\n"
 530                                  (riece-identity-prefix target)
 531                                  message)
 532                        (format "PART %s\r\n"
 533                                (riece-identity-prefix target)))
 534                      target))
 535
 536 (defun riece-command-part (target &optional message)
 537   (interactive
 538    (progn
 539      (riece-check-channel-commands-are-usable)
 540      (let* ((completion-ignore-case t)
 541             (target
 542              (riece-completing-read-identity
 543               (format (riece-mcat "Part from channel/user (default %s): ")
 544                       (riece-format-identity riece-current-channel))
 545               riece-current-channels nil nil nil nil
 546               (riece-format-identity riece-current-channel)))
 547             (message
 548              (if current-prefix-arg
 549                  (read-string (riece-mcat "Message: "))
 550                riece-part-message)))
 551        (list target message))))
 552   (if (riece-identity-member target riece-current-channels)
 553       (if (riece-channel-p (riece-identity-prefix target))
 554           (riece-command-part-channel target message)
 555         (riece-part-channel target))
 556     (error "You are not talking with %s" target)))
 557
 558 (defun riece-command-change-nickname (nickname)
 559   "Change your nickname to NICK."
 560   (interactive "sEnter your nickname: ")
 561   (riece-send-string (format "NICK %s\r\n" nickname)))
 562
 563 (defun riece-command-scroll-down (lines)
 564   "Scroll LINES down dialogue buffer from command buffer."
 565   (interactive "P")
 566   (let ((buffer (if (and riece-channel-buffer-mode
 567                          riece-current-channel)
 568                     riece-channel-buffer
 569                   riece-dialogue-buffer)))
 570     (if (get-buffer-window buffer)
 571         (condition-case nil
 572             (let ((other-window-scroll-buffer buffer))
 573               (scroll-other-window-down lines))
 574           (beginning-of-buffer
 575            (message (riece-mcat "Beginning of buffer")))))))
 576
 577 (defun riece-command-scroll-up (lines)
 578   "Scroll LINES up dialogue buffer from command buffer."
 579   (interactive "P")
 580   (let ((buffer (if (and riece-channel-buffer-mode
 581                          riece-current-channel)
 582                     riece-channel-buffer
 583                   riece-dialogue-buffer)))
 584     (if (get-buffer-window buffer)
 585         (condition-case nil
 586             (let ((other-window-scroll-buffer buffer))
 587               (scroll-other-window lines))
 588           (end-of-buffer
 589            (message (riece-mcat "End of buffer")))))))
 590
 591 (defun riece-command-user-list-scroll-down (lines)
 592   "Scroll LINES down user list buffer from command buffer."
 593   (interactive "P")
 594   (if (get-buffer-window riece-user-list-buffer)
 595       (condition-case nil
 596           (let ((other-window-scroll-buffer riece-user-list-buffer))
 597             (scroll-other-window-down lines))
 598         (beginning-of-buffer
 599          (message (riece-mcat "Beginning of buffer"))))))
 600
 601 (defun riece-command-user-list-scroll-up (lines)
 602   "Scroll LINES up user list buffer from command buffer."
 603   (interactive "P")
 604   (if (get-buffer-window riece-user-list-buffer)
 605       (condition-case nil
 606           (let ((other-window-scroll-buffer riece-user-list-buffer))
 607             (scroll-other-window lines))
 608         (end-of-buffer
 609          (message (riece-mcat "End of buffer"))))))
 610
 611 (defun riece-command-toggle-away (&optional message)
 612   "Mark yourself as being away."
 613   (interactive
 614    (if (and (not (riece-with-server-buffer (riece-identity-server
 615                                             (riece-current-nickname))
 616                    (riece-user-get-away (riece-identity-prefix
 617                                          (riece-current-nickname)))))
 618             current-prefix-arg)
 619        (list (read-from-minibuffer
 620               (riece-mcat "Away message: ") (cons (or riece-away-message "")
 621                                                   0)))))
 622   (if (riece-with-server-buffer (riece-identity-server
 623                                  (riece-current-nickname))
 624         (riece-user-get-away (riece-identity-prefix
 625                               (riece-current-nickname))))
 626       (riece-send-string "AWAY\r\n")
 627     (riece-send-string (format "AWAY :%s\r\n" (or message
 628                                                   riece-away-message)))))
 629
 630 (defun riece-command-toggle-freeze (&optional arg)
 631   "Prevent automatic scrolling of the dialogue window.
 632 If prefix argument ARG is non-nil, toggle frozen status."
 633   (interactive "P")
 634   (with-current-buffer (if (eq (derived-mode-class major-mode)
 635                                'riece-dialogue-mode)
 636                            (current-buffer)
 637                          (if (and riece-channel-buffer-mode
 638                                   riece-channel-buffer)
 639                              riece-channel-buffer
 640                            riece-dialogue-buffer))
 641     (setq riece-freeze (if arg
 642                            (< 0 (prefix-numeric-value arg))
 643                          (not riece-freeze)))
 644     (riece-emit-signal 'buffer-freeze-changed
 645                        (current-buffer) riece-freeze)))
 646
 647 (defun riece-command-toggle-own-freeze (&optional arg)
 648   "Prevent automatic scrolling of the dialogue window.
 649 The difference from `riece-command-freeze' is that your messages are hidden.
 650 If prefix argument ARG is non-nil, toggle frozen status."
 651   (interactive "P")
 652   (with-current-buffer (if (eq (derived-mode-class major-mode)
 653                                'riece-dialogue-mode)
 654                            (current-buffer)
 655                          (if (and riece-channel-buffer-mode
 656                                   riece-channel-buffer)
 657                              riece-channel-buffer
 658                            riece-dialogue-buffer))
 659     (if (if arg
 660             (< 0 (prefix-numeric-value arg))
 661           (not (eq riece-freeze 'own)))
 662         (setq riece-freeze 'own)
 663       (setq riece-freeze nil))
 664     (riece-emit-signal 'buffer-freeze-changed
 665                        (current-buffer) riece-freeze)))
 666
 667 (eval-when-compile
 668   (autoload 'riece-exit "riece"))
 669 (defun riece-command-quit (&optional arg)
 670   "Quit IRC."
 671   (interactive "P")
 672   (if (null riece-server-process-alist)
 673       (progn
 674         (message (riece-mcat "No server process"))
 675         (ding))
 676     (if (y-or-n-p (riece-mcat "Really quit IRC? "))
 677         (let ((message
 678                (if arg
 679                    (read-string (riece-mcat "Message: "))
 680                  riece-quit-message))
 681               (alist riece-server-process-alist))
 682           (while alist
 683             (riece-quit-server-process (cdr (car alist)) message)
 684             (setq alist (cdr alist)))))))
 685
 686 (defun riece-command-raw (command)
 687   "Enter raw IRC command, which is sent to the server."
 688   (interactive "sIRC command: ")
 689   (riece-send-string (concat command "\r\n")))
 690
 691 (defun riece-command-beginning-of-buffer ()
 692   "Scroll channel buffer to the beginning."
 693   (interactive)
 694   (let (buffer window)
 695     (setq buffer (if riece-channel-buffer-mode
 696                      riece-channel-buffer
 697                    riece-dialogue-buffer))
 698     (or (setq window (get-buffer-window buffer))
 699         (setq window (get-buffer-window riece-dialogue-buffer)
 700               buffer riece-dialogue-buffer))
 701     (when window
 702       (save-selected-window
 703         (select-window window)
 704         (goto-char (point-min))))))
 705
 706 (defun riece-command-end-of-buffer ()
 707   "Scroll channel buffer to the end."
 708   (interactive)
 709   (let (buffer window)
 710     (setq buffer (if riece-channel-buffer-mode
 711                      riece-channel-buffer
 712                    riece-dialogue-buffer))
 713     (or (setq window (get-buffer-window buffer))
 714         (setq window (get-buffer-window riece-dialogue-buffer)
 715               buffer riece-dialogue-buffer))
 716     (when window
 717       (save-selected-window
 718         (select-window window)
 719         (goto-char (point-max))))))
 720
 721 (defun riece-command-copy-region (start end)
 722   "Move current region between START and END to `kill-ring'."
 723   (interactive "r")
 724   (kill-new (buffer-substring-no-properties start end)))
 725
 726 (defun riece-command-complete-user ()
 727   "Complete a user name in the current buffer."
 728   (interactive)
 729   (let* ((completion-ignore-case t)
 730          (table (mapcar (lambda (user)
 731                           (list (riece-format-identity user t)))
 732                         (riece-get-users-on-server
 733                          (riece-current-server-name))))
 734          (current (or (current-word) ""))
 735          (completion (try-completion current table))
 736          (all (all-completions current table)))
 737     (if (eq completion t)
 738         nil
 739       (if (null completion)
 740           (message (riece-mcat "Can't find completion for \"%s\"") current)
 741         (if (equal current completion)
 742             (with-output-to-temp-buffer "*Help*"
 743               (display-completion-list all))
 744           (re-search-forward "\\>" nil t)
 745           (delete-region (point) (- (point) (length current)))
 746           (insert completion))))))
 747
 748 (defun riece-command-open-server (server-name)
 749   (interactive
 750    (list (completing-read (riece-mcat "Open server: ") riece-server-alist)))
 751   (if (riece-server-process server-name)
 752       (error "%s is already opened" server-name))
 753   (riece-open-server
 754    (riece-server-name-to-server server-name)
 755    server-name))
 756
 757 (defun riece-command-close-server (server-name &optional message)
 758   (interactive
 759    (list (completing-read (riece-mcat "Close server: ")
 760                           riece-server-process-alist)
 761          (if current-prefix-arg
 762              (read-string (riece-mcat "Message: "))
 763            riece-quit-message)))
 764   (let ((process (riece-server-process server-name)))
 765     (unless process
 766       (error "%s is not opened" server-name))
 767     (riece-quit-server-process process message)))
 768
 769 (defun riece-command-universal-server-name-argument ()
 770   (interactive)
 771   (let* ((riece-overriding-server-name
 772           (completing-read (riece-mcat "Server: ") riece-server-process-alist))
 773          (command
 774           (key-binding (read-key-sequence
 775                         (format (riece-mcat "Command to execute on \"%s\":")
 776                                 riece-overriding-server-name)))))
 777     (message "")
 778     (call-interactively command)))
 779
 780 (eval-when-compile
 781   (autoload 'riece-save-variables-files "riece"))
 782 (defun riece-command-save-variables ()
 783   "Save `riece-variables-file'."
 784   (interactive)
 785   (if (or riece-save-variables-are-dirty
 786           (y-or-n-p (riece-mcat "No changes made.  Save anyway? ")))
 787       (riece-save-variables-files)))
 788
 789 (provide 'riece-commands)
 790
 791 ;;; riece-commands.el ends here