lisp/riece-commands.el

   1 ;;; riece-commands.el --- commands available in command buffer
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Created: 1998-09-28
   6 ;; Keywords: IRC, riece
   7
   8 ;; This file is part of Riece.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Code:
  26
  27 (require 'riece-channel)
  28 (require 'riece-complete)
  29 (require 'riece-layout)
  30 (require 'riece-display)
  31 (require 'riece-server)
  32 (require 'riece-misc)
  33 (require 'riece-identity)
  34 (require 'riece-message)
  35 (require 'riece-mcat)
  36
  37 (autoload 'derived-mode-class "derived")
  38
  39 ;;; Channel movement:
  40 (defun riece-command-switch-to-channel (channel)
  41   (interactive (list (riece-completing-read-identity
  42                       (riece-mcat "Switch to channel/user: ")
  43                       riece-current-channels nil t)))
  44   (unless (equal channel riece-current-channel)
  45     (riece-switch-to-channel channel)))
  46
  47 (defun riece-command-switch-to-channel-by-number (number)
  48   (interactive
  49    (let ((command-name (symbol-name this-command)))
  50      (if (string-match "[0-9]+$" command-name)
  51          (list (string-to-number (match-string 0 command-name)))
  52        (list (string-to-number (read-string (riece-mcat "Switch to number: ")))))))
  53   (let ((channel (nth (1- number) riece-current-channels)))
  54     (if channel
  55         (riece-command-switch-to-channel channel)
  56       (error "No such number!"))))
  57
  58 (eval-and-compile
  59   (let ((number 1))
  60     (while (<= number 20)
  61       (defalias (intern (concat "riece-command-switch-to-channel-by-number-"
  62                                 (number-to-string number)))
  63         'riece-command-switch-to-channel-by-number)
  64       (setq number (1+ number)))))
  65
  66 (defun riece-command-next-channel ()
  67   "Select the next channel."
  68   (interactive)
  69   (when (> (length riece-current-channels) 1)
  70     (let ((pointer (cdr (riece-identity-member
  71                          riece-current-channel
  72                          riece-current-channels))))
  73       (while (and pointer
  74                   (null (car pointer)))
  75         (setq pointer (cdr pointer)))
  76       (when (null pointer)
  77         (setq pointer riece-current-channels)
  78         (while (and pointer
  79                     (null (car pointer)))
  80           (setq pointer (cdr pointer))))
  81       (if (car pointer)
  82           (riece-command-switch-to-channel (car pointer))
  83         (error "No such channel!")))))
  84
  85 (defun riece-command-previous-channel ()
  86   "Select the previous channel."
  87   (interactive)
  88   (when (> (length riece-current-channels) 1)
  89     (let ((pointer (riece-identity-member
  90                     riece-current-channel
  91                     riece-current-channels))
  92           (start riece-current-channels)
  93           channel)
  94       (while (and start (not (eq start pointer)))
  95         (if (car start)
  96             (setq channel (car start)))
  97         (setq start (cdr start)))
  98       (when (null channel)
  99         (setq start (copy-sequence riece-current-channels))
 100         (setq start (delq nil start))
 101         (and (> (length start) 1)
 102              (setq channel (nth (1- (length start)) start))))
 103       (if channel
 104           (riece-command-switch-to-channel channel)
 105         (error "No such channel!")))))
 106
 107 (defun riece-command-select-command-buffer ()
 108   "Select the command buffer."
 109   (interactive)
 110   (let ((window (get-buffer-window riece-command-buffer)))
 111     (if window
 112         (select-window window))))
 113
 114 (defun riece-command-configure-windows ()
 115   (interactive)
 116   "Reconfigure windows with the current layout."
 117   (riece-redisplay-buffers t))
 118
 119 (defun riece-command-suspend-resume ()
 120   (interactive)
 121   "Save or restore the current window configuration."
 122   (let ((entry (assq 'riece-window-configuration (frame-parameters))))
 123     (modify-frame-parameters (selected-frame)
 124                              (list (cons 'riece-window-configuration
 125                                          (current-window-configuration))))
 126     (if (cdr entry)
 127         (set-window-configuration (cdr entry))
 128       (delete-other-windows))
 129     (message
 130      (substitute-command-keys
 131       "\\[riece-command-suspend-resume] to get back the last windows"))))
 132
 133 (defun riece-command-change-layout (name)
 134   "Select a layout-name from all current available layouts and change
 135 the layout to the selected layout-name."
 136   (interactive (list (completing-read (riece-mcat "Change layout: ")
 137                                       riece-layout-alist)))
 138   (setq riece-layout name
 139         riece-save-variables-are-dirty t)
 140   (riece-command-configure-windows))
 141
 142 (defun riece-command-toggle-channel-buffer-mode ()
 143   (interactive)
 144   (setq riece-channel-buffer-mode
 145         (not riece-channel-buffer-mode)
 146         riece-save-variables-are-dirty t)
 147   (riece-command-configure-windows))
 148
 149 (defun riece-command-toggle-others-buffer-mode ()
 150   (interactive)
 151   (setq riece-others-buffer-mode
 152         (not riece-others-buffer-mode)
 153         riece-save-variables-are-dirty t)
 154   (riece-command-configure-windows))
 155
 156 (defun riece-command-toggle-user-list-buffer-mode ()
 157   (interactive)
 158   (setq riece-user-list-buffer-mode
 159         (not riece-user-list-buffer-mode)
 160         riece-save-variables-are-dirty t)
 161   (riece-command-configure-windows))
 162
 163 (defun riece-command-toggle-channel-list-buffer-mode ()
 164   (interactive)
 165   (setq riece-channel-list-buffer-mode
 166         (not riece-channel-list-buffer-mode)
 167         riece-save-variables-are-dirty t)
 168   (riece-command-configure-windows))
 169
 170 (defun riece-command-finger (user &optional recurse)
 171   (interactive
 172    (let* ((completion-ignore-case t)
 173           (user (riece-completing-read-identity
 174                  (riece-mcat "Finger user: ")
 175                  (riece-get-users-on-server (riece-current-server-name))
 176                  nil nil nil nil nil t)))
 177      (list user current-prefix-arg)))
 178   (if recurse
 179       (riece-send-string (format "WHOIS %s %s\r\n"
 180                                  (riece-identity-prefix user)
 181                                  (riece-identity-prefix user)))
 182     (riece-send-string (format "WHOIS %s\r\n" (riece-identity-prefix user)))))
 183
 184 (defun riece-command-topic (topic)
 185   (interactive
 186    (progn
 187      (riece-check-channel-commands-are-usable t)
 188      (list (read-from-minibuffer
 189             (riece-mcat "Set topic: ")
 190             (cons (or (riece-with-server-buffer
 191                           (riece-identity-server
 192                            riece-current-channel)
 193                         (riece-channel-get-topic
 194                          (riece-identity-prefix
 195                           riece-current-channel)))
 196                       "")
 197                   0)))))
 198   (riece-send-string (format "TOPIC %s :%s\r\n"
 199                              (riece-identity-prefix riece-current-channel)
 200                              topic)
 201                      riece-current-channel))
 202
 203 (defun riece-command-invite (user)
 204   (interactive
 205    (let ((completion-ignore-case t))
 206      (riece-check-channel-commands-are-usable t)
 207      (list (riece-completing-read-identity
 208             (riece-mcat "Invite user: ")
 209             (riece-get-users-on-server (riece-current-server-name))
 210             nil nil nil nil nil t))))
 211   (riece-send-string (format "INVITE %s :%s\r\n"
 212                              (riece-identity-prefix user)
 213                              (riece-identity-prefix riece-current-channel))))
 214
 215 (defun riece-command-kick (user &optional message)
 216   (interactive
 217    (let ((completion-ignore-case t))
 218      (riece-check-channel-commands-are-usable t)
 219      (list (completing-read
 220             (riece-mcat "Kick user: ")
 221             (riece-with-server-buffer
 222                 (riece-identity-server riece-current-channel)
 223               (riece-channel-get-users (riece-identity-prefix
 224                                         riece-current-channel))))
 225            (if current-prefix-arg
 226                (read-string "Message: ")))))
 227   (riece-send-string
 228    (if message
 229        (format "KICK %s %s :%s\r\n"
 230                (riece-identity-prefix riece-current-channel)
 231                user message)
 232      (format "KICK %s %s\r\n"
 233              (riece-identity-prefix riece-current-channel)
 234              user))
 235    riece-current-channel))
 236
 237 (defun riece-command-kick-with-ban (user pattern &optional message)
 238   (interactive
 239    (let ((completion-ignore-case t))
 240      (riece-check-channel-commands-are-usable t)
 241      (riece-with-server-buffer (riece-identity-server riece-current-channel)
 242        (list
 243         (completing-read (riece-mcat "Kick user: ")
 244                          (riece-channel-get-users (riece-identity-prefix
 245                                                    riece-current-channel)))
 246         (completing-read (riece-mcat "Ban pattern: ")
 247                          (mapcar
 248                           (lambda (user)
 249                             (list (concat (car user) "!"
 250                                           (riece-user-get-user-at-host
 251                                            (car user)))))
 252                           users))
 253         (if current-prefix-arg
 254             (read-string "Message: "))))))
 255   (riece-send-string (format "MODE %s :+b %s\r\n"
 256                              (riece-identity-prefix riece-current-channel)
 257                              pattern)
 258                      riece-current-channel)
 259   (riece-send-string
 260    (if message
 261        (format "KICK %s %s :%s\r\n"
 262                (riece-identity-prefix riece-current-channel)
 263                user message)
 264      (format "KICK %s %s\r\n"
 265              (riece-identity-prefix riece-current-channel)
 266              user))
 267    riece-current-channel))
 268
 269 (defun riece-command-names (pattern)
 270   (interactive
 271    (let ((completion-ignore-case t))
 272      (list (read-from-minibuffer
 273             (riece-mcat "NAMES pattern: ")
 274             (if (and riece-current-channel
 275                      (riece-channel-p (riece-identity-prefix
 276                                        riece-current-channel)))
 277                 (cons (riece-identity-prefix riece-current-channel)
 278                       0))))))
 279   (if (or (not (equal pattern ""))
 280           (yes-or-no-p (riece-mcat
 281                         "Really want to query NAMES without argument? ")))
 282       (riece-send-string (format "NAMES %s\r\n" pattern))))
 283
 284 (defun riece-command-who (pattern)
 285   (interactive
 286    (let ((completion-ignore-case t))
 287      (list (read-from-minibuffer
 288             (riece-mcat "WHO pattern: ")
 289             (if (and riece-current-channel
 290                      (riece-channel-p (riece-identity-prefix
 291                                        riece-current-channel)))
 292                 (cons (riece-identity-prefix riece-current-channel)
 293                       0))))))
 294   (if (or (not (equal pattern ""))
 295           (yes-or-no-p (riece-mcat
 296                         "Really want to query WHO without argument? ")))
 297       (riece-send-string (format "WHO %s\r\n" pattern))))
 298
 299 (defun riece-command-list (pattern)
 300   (interactive
 301    (let ((completion-ignore-case t))
 302      (list (read-from-minibuffer
 303             (riece-mcat "LIST pattern: ")
 304             (if (and riece-current-channel
 305                      (riece-channel-p (riece-identity-prefix
 306                                        riece-current-channel)))
 307                 (cons (riece-identity-prefix riece-current-channel)
 308                       0))))))
 309   (if (or (not (equal pattern ""))
 310           (yes-or-no-p (riece-mcat
 311                         "Really want to query LIST without argument? ")))
 312       (riece-send-string (format "LIST %s\r\n" pattern))))
 313
 314 (defun riece-command-change-mode (channel change)
 315   (interactive
 316    (let* ((completion-ignore-case t)
 317           (channel
 318            (if current-prefix-arg
 319                (riece-completing-read-identity
 320                 (riece-mcat "Change mode for channel/user: ")
 321                 (riece-get-identities-on-server (riece-current-server-name))
 322                 nil nil nil nil nil t)
 323              (riece-check-channel-commands-are-usable t)
 324              riece-current-channel))
 325           (riece-overriding-server-name (riece-identity-server channel))
 326           (riece-temp-minibuffer-message
 327            (concat (riece-mcat "[Available modes: ")
 328                    (riece-with-server-buffer (riece-identity-server channel)
 329                      (if (riece-channel-p (riece-identity-prefix channel))
 330                          (if riece-supported-channel-modes
 331                              (apply #'string riece-supported-channel-modes))
 332                        (if riece-supported-user-modes
 333                            (apply #'string riece-supported-user-modes))))
 334                    "]")))
 335      (list channel
 336            (read-from-minibuffer
 337             (concat (riece-concat-channel-modes
 338                      channel (riece-mcat "Mode (? for help)")) ": ")
 339             nil riece-minibuffer-map))))
 340   (if (equal change "")
 341       (riece-send-string (format "MODE %s\r\n"
 342                                  (riece-identity-prefix channel)))
 343     (riece-send-string (format "MODE %s %s\r\n"
 344                                (riece-identity-prefix channel)
 345                                change))))
 346
 347 (defun riece-command-set-operators (users &optional arg)
 348   (interactive
 349    (progn
 350      (riece-check-channel-commands-are-usable t)
 351      (let ((completion-ignore-case t))
 352        (list (riece-completing-read-multiple
 353               (if current-prefix-arg
 354                   (riece-mcat "Unset +o for users")
 355                 (riece-mcat "Set +o for users"))
 356               (riece-with-server-buffer
 357                   (riece-identity-server riece-current-channel)
 358                 (riece-channel-get-users (riece-identity-prefix
 359                                          riece-current-channel)))
 360               (if current-prefix-arg
 361                   (lambda (user)
 362                     (memq ?o (cdr user)))
 363                 (lambda (user)
 364                   (not (memq ?o (cdr user))))))
 365              current-prefix-arg))))
 366   (let (group)
 367     (while users
 368       (setq group (cons (car users) group)
 369             users (cdr users))
 370       (when (or (= (length group) 3)
 371                 (null users))
 372         (riece-send-string
 373          (format "MODE %s %c%s %s\r\n"
 374                  (riece-identity-prefix riece-current-channel)
 375                  (if current-prefix-arg
 376                      ?-
 377                    ?+)
 378                  (make-string (length group) ?o)
 379                  (mapconcat #'identity (nreverse group) " ")))
 380         (setq group nil)))))
 381
 382 (defun riece-command-set-speakers (users &optional arg)
 383   (interactive
 384    (progn
 385      (riece-check-channel-commands-are-usable t)
 386      (let ((completion-ignore-case t))
 387        (list (riece-completing-read-multiple
 388               (if current-prefix-arg
 389                   (riece-mcat "Unset +v for users")
 390                 (riece-mcat "Set +v for users"))
 391               (riece-with-server-buffer
 392                   (riece-identity-server riece-current-channel)
 393                 (riece-channel-get-users (riece-identity-prefix
 394                                           riece-current-channel)))
 395               (if current-prefix-arg
 396                   (lambda (user)
 397                     (memq ?v (cdr user)))
 398                 (lambda (user)
 399                   (not (memq ?v (cdr user))))))
 400              current-prefix-arg))))
 401   (let (group)
 402     (while users
 403       (setq group (cons (car users) group)
 404             users (cdr users))
 405       (when (or (= (length group) 3)
 406                 (null users))
 407         (riece-send-string
 408          (format "MODE %s %c%s %s\r\n"
 409                  (riece-identity-prefix riece-current-channel)
 410                  (if current-prefix-arg
 411                      ?-
 412                    ?+)
 413                  (make-string (length group) ?v)
 414                  (mapconcat #'identity (nreverse group) " ")))
 415         (setq group nil)))))
 416
 417 (defun riece-command-send-message (message notice)
 418   "Send MESSAGE to the current channel."
 419   (run-hooks 'riece-command-send-message-hook)
 420   (if (equal message "")
 421       (error (riece-mcat "No text to send")))
 422   (riece-check-channel-commands-are-usable)
 423   (if notice
 424       (progn
 425         (riece-send-string
 426          (format "NOTICE %s :%s\r\n"
 427                  (riece-identity-prefix riece-current-channel)
 428                  message)
 429          riece-current-channel)
 430         (riece-display-message
 431          (riece-make-message (riece-current-nickname) riece-current-channel
 432                              message 'notice t)))
 433     (riece-send-string
 434      (format "PRIVMSG %s :%s\r\n"
 435              (riece-identity-prefix riece-current-channel)
 436              message)
 437      riece-current-channel)
 438     (riece-display-message
 439      (riece-make-message (riece-current-nickname) riece-current-channel
 440                          message nil t))))
 441
 442 (defun riece-command-enter-message ()
 443   "Send the current line to the current channel."
 444   (interactive)
 445   (riece-command-send-message (buffer-substring
 446                                (riece-line-beginning-position)
 447                                (riece-line-end-position))
 448                               nil)
 449   (let ((next-line-add-newlines t))
 450     (next-line 1)))
 451
 452 (defun riece-command-enter-message-as-notice ()
 453   "Send the current line to the current channel as NOTICE."
 454   (interactive)
 455   (riece-command-send-message (buffer-substring
 456                                (riece-line-beginning-position)
 457                                (riece-line-end-position))
 458                               t)
 459   (let ((next-line-add-newlines t))
 460     (next-line 1)))
 461
 462 (defun riece-command-enter-message-to-user (user)
 463   "Send the current line to USER."
 464   (interactive
 465    (if (and (bolp) (eolp))
 466        (error "No text to send")
 467      (let ((completion-ignore-case t))
 468        (list (riece-completing-read-identity
 469               (riece-mcat "Message to user: ")
 470               (riece-get-users-on-server (riece-current-server-name))
 471               nil nil nil nil nil t)))))
 472   (let ((text (buffer-substring
 473                (riece-line-beginning-position)
 474                (riece-line-end-position))))
 475     (riece-send-string
 476      (format "PRIVMSG %s :%s\r\n" (riece-identity-prefix user) text)
 477      user)
 478     (riece-display-message
 479      (riece-make-message (riece-current-nickname) user text nil t)))
 480   (let ((next-line-add-newlines t))
 481     (next-line 1)))
 482
 483 (defun riece-command-join-channel (target key)
 484   (unless (riece-server-opened (riece-identity-server target))
 485     (error "%s" (substitute-command-keys
 486                  "Type \\[riece-command-open-server] to open server.")))
 487   (riece-send-string (if key
 488                          (format "JOIN %s :%s\r\n"
 489                                  (riece-identity-prefix target)
 490                                  key)
 491                        (format "JOIN %s\r\n"
 492                                (riece-identity-prefix target)))
 493                      target))
 494
 495 (defun riece-command-join-partner (target)
 496   (let ((pointer (riece-identity-member target riece-current-channels)))
 497     (if pointer
 498         (riece-command-switch-to-channel (car pointer))
 499       (riece-join-channel target)
 500       (riece-switch-to-channel target))))
 501
 502 (defun riece-command-join (target)
 503   (interactive
 504    (let ((completion-ignore-case t))
 505      (list
 506       (if riece-join-channel-candidate
 507           (let ((default (riece-format-identity
 508                           riece-join-channel-candidate)))
 509             (riece-completing-read-identity
 510              (format (riece-mcat "Join channel/user (default %s): ") default)
 511              (riece-get-identities-on-server (riece-current-server-name))
 512              nil nil nil nil default))
 513         (riece-completing-read-identity
 514          (riece-mcat "Join channel/user: ")
 515          (riece-get-identities-on-server (riece-current-server-name)))))))
 516   (let ((pointer (riece-identity-member target riece-current-channels)))
 517     (if pointer
 518         (riece-command-switch-to-channel (car pointer))
 519       (if (riece-channel-p (riece-identity-prefix target))
 520           (riece-command-join-channel target nil)
 521         (riece-command-join-partner target)))))
 522
 523 (defun riece-command-part-channel (target message)
 524   (unless (riece-server-opened (riece-identity-server target))
 525     (error "%s" (substitute-command-keys
 526                  "Type \\[riece-command-open-server] to open server.")))
 527   (riece-send-string (if message
 528                          (format "PART %s :%s\r\n"
 529                                  (riece-identity-prefix target)
 530                                  message)
 531                        (format "PART %s\r\n"
 532                                (riece-identity-prefix target)))
 533                      target))
 534
 535 (defun riece-command-part (target &optional message)
 536   (interactive
 537    (progn
 538      (riece-check-channel-commands-are-usable)
 539      (let* ((completion-ignore-case t)
 540             (target
 541              (riece-completing-read-identity
 542               (format (riece-mcat "Part from channel/user (default %s): ")
 543                       (riece-format-identity riece-current-channel))
 544               riece-current-channels nil nil nil nil
 545               (riece-format-identity riece-current-channel)))
 546             (message
 547              (if current-prefix-arg
 548                  (read-string (riece-mcat "Message: "))
 549                riece-part-message)))
 550        (list target message))))
 551   (if (riece-identity-member target riece-current-channels)
 552       (if (riece-channel-p (riece-identity-prefix target))
 553           (riece-command-part-channel target message)
 554         (riece-part-channel target))
 555     (error "You are not talking with %s" target)))
 556
 557 (defun riece-command-change-nickname (nickname)
 558   "Change your nickname to NICK."
 559   (interactive "sEnter your nickname: ")
 560   (riece-send-string (format "NICK %s\r\n" nickname)))
 561
 562 (defun riece-command-scroll-down (lines)
 563   "Scroll LINES down dialogue buffer from command buffer."
 564   (interactive "P")
 565   (let ((buffer (if (and riece-channel-buffer-mode
 566                          riece-current-channel)
 567                     riece-channel-buffer
 568                   riece-dialogue-buffer)))
 569     (if (get-buffer-window buffer)
 570         (condition-case nil
 571             (let ((other-window-scroll-buffer buffer))
 572               (scroll-other-window-down lines))
 573           (beginning-of-buffer
 574            (message (riece-mcat "Beginning of buffer")))))))
 575
 576 (defun riece-command-scroll-up (lines)
 577   "Scroll LINES up dialogue buffer from command buffer."
 578   (interactive "P")
 579   (let ((buffer (if (and riece-channel-buffer-mode
 580                          riece-current-channel)
 581                     riece-channel-buffer
 582                   riece-dialogue-buffer)))
 583     (if (get-buffer-window buffer)
 584         (condition-case nil
 585             (let ((other-window-scroll-buffer buffer))
 586               (scroll-other-window lines))
 587           (end-of-buffer
 588            (message (riece-mcat "End of buffer")))))))
 589
 590 (defun riece-command-user-list-scroll-down (lines)
 591   "Scroll LINES down user list buffer from command buffer."
 592   (interactive "P")
 593   (if (get-buffer-window riece-user-list-buffer)
 594       (condition-case nil
 595           (let ((other-window-scroll-buffer riece-user-list-buffer))
 596             (scroll-other-window-down lines))
 597         (beginning-of-buffer
 598          (message (riece-mcat "Beginning of buffer"))))))
 599
 600 (defun riece-command-user-list-scroll-up (lines)
 601   "Scroll LINES up user list buffer from command buffer."
 602   (interactive "P")
 603   (if (get-buffer-window riece-user-list-buffer)
 604       (condition-case nil
 605           (let ((other-window-scroll-buffer riece-user-list-buffer))
 606             (scroll-other-window lines))
 607         (end-of-buffer
 608          (message (riece-mcat "End of buffer"))))))
 609
 610 (defun riece-command-toggle-away (&optional message)
 611   "Mark yourself as being away."
 612   (interactive
 613    (if (and (not (riece-with-server-buffer (riece-identity-server
 614                                             (riece-current-nickname))
 615                    (riece-user-get-away (riece-identity-prefix
 616                                          (riece-current-nickname)))))
 617             current-prefix-arg)
 618        (list (read-from-minibuffer
 619               (riece-mcat "Away message: ") (cons (or riece-away-message "")
 620                                                   0)))))
 621   (if (riece-with-server-buffer (riece-identity-server
 622                                  (riece-current-nickname))
 623         (riece-user-get-away (riece-identity-prefix
 624                               (riece-current-nickname))))
 625       (riece-send-string "AWAY\r\n")
 626     (riece-send-string (format "AWAY :%s\r\n" (or message
 627                                                   riece-away-message)))))
 628
 629 (defun riece-command-toggle-freeze (&optional arg)
 630   "Prevent automatic scrolling of the dialogue window.
 631 If prefix argument ARG is non-nil, toggle frozen status."
 632   (interactive "P")
 633   (with-current-buffer (if (eq (derived-mode-class major-mode)
 634                                'riece-dialogue-mode)
 635                            (current-buffer)
 636                          (if (and riece-channel-buffer-mode
 637                                   riece-channel-buffer)
 638                              riece-channel-buffer
 639                            riece-dialogue-buffer))
 640     (setq riece-freeze (if arg
 641                            (< 0 (prefix-numeric-value arg))
 642                          (not riece-freeze)))
 643     (riece-emit-signal 'buffer-freeze-changed
 644                        (current-buffer) riece-freeze)))
 645
 646 (defun riece-command-toggle-own-freeze (&optional arg)
 647   "Prevent automatic scrolling of the dialogue window.
 648 The difference from `riece-command-freeze' is that your messages are hidden.
 649 If prefix argument ARG is non-nil, toggle frozen status."
 650   (interactive "P")
 651   (with-current-buffer (if (eq (derived-mode-class major-mode)
 652                                'riece-dialogue-mode)
 653                            (current-buffer)
 654                          (if (and riece-channel-buffer-mode
 655                                   riece-channel-buffer)
 656                              riece-channel-buffer
 657                            riece-dialogue-buffer))
 658     (if (if arg
 659             (< 0 (prefix-numeric-value arg))
 660           (not (eq riece-freeze 'own)))
 661         (setq riece-freeze 'own)
 662       (setq riece-freeze nil))
 663     (riece-emit-signal 'buffer-freeze-changed
 664                        (current-buffer) riece-freeze)))
 665
 666 (eval-when-compile
 667   (autoload 'riece-exit "riece"))
 668 (defun riece-command-quit (&optional arg)
 669   "Quit IRC."
 670   (interactive "P")
 671   (if (null riece-server-process-alist)
 672       (progn
 673         (message (riece-mcat "No server process"))
 674         (ding))
 675     (if (y-or-n-p (riece-mcat "Really quit IRC? "))
 676         (let ((message
 677                (if arg
 678                    (read-string (riece-mcat "Message: "))
 679                  riece-quit-message))
 680               (alist riece-server-process-alist))
 681           (while alist
 682             (riece-quit-server-process (cdr (car alist)) message)
 683             (setq alist (cdr alist)))))))
 684
 685 (defun riece-command-raw (command)
 686   "Enter raw IRC command, which is sent to the server."
 687   (interactive "sIRC command: ")
 688   (riece-send-string (concat command "\r\n")))
 689
 690 (defun riece-command-beginning-of-buffer ()
 691   "Scroll channel buffer to the beginning."
 692   (interactive)
 693   (let (buffer window)
 694     (setq buffer (if riece-channel-buffer-mode
 695                      riece-channel-buffer
 696                    riece-dialogue-buffer))
 697     (or (setq window (get-buffer-window buffer))
 698         (setq window (get-buffer-window riece-dialogue-buffer)
 699               buffer riece-dialogue-buffer))
 700     (when window
 701       (save-selected-window
 702         (select-window window)
 703         (goto-char (point-min))))))
 704
 705 (defun riece-command-end-of-buffer ()
 706   "Scroll channel buffer to the end."
 707   (interactive)
 708   (let (buffer window)
 709     (setq buffer (if riece-channel-buffer-mode
 710                      riece-channel-buffer
 711                    riece-dialogue-buffer))
 712     (or (setq window (get-buffer-window buffer))
 713         (setq window (get-buffer-window riece-dialogue-buffer)
 714               buffer riece-dialogue-buffer))
 715     (when window
 716       (save-selected-window
 717         (select-window window)
 718         (goto-char (point-max))))))
 719
 720 (defun riece-command-copy-region (start end)
 721   "Move current region between START and END to `kill-ring'."
 722   (interactive "r")
 723   (kill-new (buffer-substring-no-properties start end)))
 724
 725 (defun riece-command-complete-user ()
 726   "Complete a user name in the current buffer."
 727   (interactive)
 728   (let* ((completion-ignore-case t)
 729          (table (mapcar (lambda (user)
 730                           (list (riece-format-identity user t)))
 731                         (riece-get-users-on-server
 732                          (riece-current-server-name))))
 733          (current (or (current-word) ""))
 734          (completion (try-completion current table))
 735          (all (all-completions current table)))
 736     (if (eq completion t)
 737         nil
 738       (if (null completion)
 739           (message (riece-mcat "Can't find completion for \"%s\"") current)
 740         (if (equal current completion)
 741             (with-output-to-temp-buffer "*Help*"
 742               (display-completion-list all))
 743           (re-search-forward "\\>" nil t)
 744           (delete-region (point) (- (point) (length current)))
 745           (insert completion))))))
 746
 747 (defun riece-command-open-server (server-name)
 748   (interactive
 749    (list (completing-read (riece-mcat "Open server: ") riece-server-alist)))
 750   (if (riece-server-process server-name)
 751       (error "%s is already opened" server-name))
 752   (riece-open-server
 753    (riece-server-name-to-server server-name)
 754    server-name))
 755
 756 (defun riece-command-close-server (server-name &optional message)
 757   (interactive
 758    (list (completing-read (riece-mcat "Close server: ")
 759                           riece-server-process-alist)
 760          (if current-prefix-arg
 761              (read-string (riece-mcat "Message: "))
 762            riece-quit-message)))
 763   (let ((process (riece-server-process server-name)))
 764     (unless process
 765       (error "%s is not opened" server-name))
 766     (riece-quit-server-process process message)))
 767
 768 (defun riece-command-universal-server-name-argument ()
 769   (interactive)
 770   (let* ((riece-overriding-server-name
 771           (completing-read (riece-mcat "Server: ") riece-server-process-alist))
 772          (command
 773           (key-binding (read-key-sequence
 774                         (format (riece-mcat "Command to execute on \"%s\":")
 775                                 riece-overriding-server-name)))))
 776     (message "")
 777     (call-interactively command)))
 778
 779 (eval-when-compile
 780   (autoload 'riece-save-variables-files "riece"))
 781 (defun riece-command-save-variables ()
 782   "Save `riece-variables-file'."
 783   (interactive)
 784   (if (or riece-save-variables-are-dirty
 785           (y-or-n-p (riece-mcat "No changes made.  Save anyway? ")))
 786       (riece-save-variables-files)))
 787
 788 (provide 'riece-commands)
 789
 790 ;;; riece-commands.el ends here