lisp/riece-message.el

   1 ;;; riece-message.el --- generate and display message line
   2 ;; Copyright (C) 1999-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: message
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (require 'riece-identity)
  27 (require 'riece-channel)
  28 (require 'riece-user)
  29 (require 'riece-display)
  30 (require 'riece-misc)
  31
  32 (defgroup riece-message nil
  33   "Messages"
  34   :tag "Message"
  35   :prefix "riece-"
  36   :group 'riece)
  37
  38 (defcustom riece-message-make-open-bracket-function
  39   #'riece-message-make-open-bracket
  40   "Function which makes `open-bracket' string for each message."
  41   :type 'function
  42   :group 'riece-message)
  43
  44 (defcustom riece-message-make-close-bracket-function
  45   #'riece-message-make-close-bracket
  46   "Function which makes `close-bracket' string for each message."
  47   :type 'function
  48   :group 'riece-message)
  49
  50 (defcustom riece-message-make-name-function
  51   #'riece-message-make-name
  52   "Function which makes local identity for each message."
  53   :type 'function
  54   :group 'riece-message)
  55
  56 (defcustom riece-message-make-global-name-function
  57   #'riece-message-make-global-name
  58   "Function which makes global identity for each message."
  59   :type 'function
  60   :group 'riece-message)
  61
  62 (defun riece-message-make-open-bracket (message)
  63   "Makes `open-bracket' string for MESSAGE."
  64   (if (riece-message-own-p message)
  65       ">"
  66     (if (eq (riece-message-type message) 'notice)
  67         "{"
  68       (if (riece-message-private-p message)
  69           "="
  70         (if (riece-message-external-p message)
  71             "("
  72           "<")))))
  73
  74 (defun riece-message-make-close-bracket (message)
  75   "Makes `close-bracket' string for MESSAGE."
  76   (if (riece-message-own-p message)
  77       "<"
  78     (if (eq (riece-message-type message) 'notice)
  79         "}"
  80       (if (riece-message-private-p message)
  81           "="
  82         (if (riece-message-external-p message)
  83             ")"
  84           ">")))))
  85
  86 (defun riece-message-make-name (message)
  87   "Makes local identity for MESSAGE."
  88   (if (and (riece-message-private-p message)
  89            (riece-message-own-p message))
  90       (riece-identity-prefix (riece-message-target message))
  91     (riece-identity-prefix (riece-message-speaker message))))
  92
  93 (defun riece-message-make-global-name (message)
  94   "Makes global identity for MESSAGE."
  95   (if (riece-message-private-p message)
  96       (if (riece-message-own-p message)
  97           (riece-identity-prefix (riece-message-target message))
  98         (riece-identity-prefix (riece-message-speaker message)))
  99     (concat (riece-decode-identity (riece-message-target message) t) ":"
 100             (riece-identity-prefix (riece-message-speaker message)))))
 101
 102 (defun riece-message-buffer (message)
 103   "Return the buffer where MESSAGE should appear."
 104   (let* ((target (if (riece-identity-equal
 105                       (riece-message-target message)
 106                       (riece-current-nickname))
 107                      (riece-message-speaker message)
 108                    (riece-message-target message)))
 109          (buffer (riece-channel-buffer-name target)))
 110     (unless (get-buffer buffer)
 111       (riece-join-channel target)
 112       ;; If you are not joined any channel,
 113       ;; switch to the target immediately.
 114       (unless riece-current-channel
 115         (riece-switch-to-channel target))
 116       (riece-redisplay-buffers))
 117     buffer))
 118
 119 (defun riece-message-parent-buffers (message buffer)
 120   "Return the parents of BUFFER where MESSAGE should appear.
 121 Normally they are *Dialogue* and/or *Others*."
 122   (if (or (and buffer (riece-frozen buffer))
 123           (and riece-current-channel
 124                (if (riece-message-private-p message)
 125                    (not (riece-identity-equal
 126                          (riece-message-speaker message)
 127                          riece-current-channel))
 128                  (not (riece-identity-equal
 129                        (riece-message-target message)
 130                        riece-current-channel)))))
 131       (list riece-dialogue-buffer riece-others-buffer)
 132     riece-dialogue-buffer))
 133
 134 (defun riece-display-message (message)
 135   "Display MESSAGE object."
 136   (let ((open-bracket
 137          (funcall riece-message-make-open-bracket-function message))
 138         (close-bracket
 139          (funcall riece-message-make-close-bracket-function message))
 140         (name
 141          (funcall riece-message-make-name-function message))
 142         (global-name
 143          (funcall riece-message-make-global-name-function message))
 144         (buffer (riece-message-buffer message))
 145         parent-buffers)
 146     (when (and buffer
 147                (riece-message-own-p message)
 148                (riece-own-frozen buffer))
 149       (with-current-buffer buffer
 150         (setq riece-freeze nil))
 151       (riece-update-status-indicators))
 152     (setq parent-buffers (riece-message-parent-buffers message buffer))
 153     (riece-insert buffer
 154                   (concat open-bracket name close-bracket
 155                           " " (riece-message-text message) "\n"))
 156     (riece-insert parent-buffers
 157                   (concat
 158                    (riece-concat-server-name
 159                     (concat open-bracket global-name close-bracket
 160                             " " (riece-message-text message)))
 161                    "\n"))
 162     (run-hook-with-args 'riece-after-display-message-functions message)))
 163
 164 (defun riece-make-message (speaker target text &optional type own-p)
 165   "Make an instance of message object.
 166 Arguments are appropriate to the sender, the receiver, and text
 167 content, respectively.
 168 Optional 4th argument TYPE specifies the type of the message.
 169 Currently possible values are `action' and `notice'.
 170 Optional 5th argument is the flag to indicate that this message is not
 171 from the network."
 172   (vector speaker target text type own-p))
 173
 174 (defun riece-message-speaker (message)
 175   "Return the sender of MESSAGE."
 176   (aref message 0))
 177
 178 (defun riece-message-target (message)
 179   "Return the receiver of MESSAGE."
 180   (aref message 1))
 181
 182 (defun riece-message-text (message)
 183   "Return the text part of MESSAGE."
 184   (aref message 2))
 185
 186 (defun riece-message-type (message)
 187   "Return the type of MESSAGE.
 188 Currently possible values are `action' and `notice'."
 189   (aref message 3))
 190
 191 (defun riece-message-own-p (message)
 192   "Return t if MESSAGE is not from the network."
 193   (aref message 4))
 194
 195 (defun riece-message-private-p (message)
 196   "Return t if MESSAGE is a private message."
 197   (if (riece-message-own-p message)
 198       (not (riece-channel-p (riece-identity-prefix
 199                              (riece-message-target message))))
 200     (riece-identity-equal
 201      (riece-message-target message)
 202      (riece-current-nickname))))
 203
 204 (defun riece-message-external-p (message)
 205   "Return t if MESSAGE is from outside the channel."
 206   (not (riece-identity-member
 207         (riece-message-speaker message)
 208         (let ((target (riece-message-target message)))
 209           (riece-with-identity-buffer target
 210             (mapcar
 211              (lambda (user)
 212                (riece-make-identity user (riece-identity-server target)))
 213              (riece-channel-get-users (riece-identity-prefix target))))))))
 214
 215 (defun riece-own-channel-message (message &optional channel type)
 216   "Display MESSAGE as you sent to CHNL."
 217   (riece-display-message
 218    (riece-make-message (riece-current-nickname)
 219                        (or channel riece-current-channel)
 220                        message type t)))
 221
 222 (provide 'riece-message)
 223
 224 ;;; riece-message.el ends here