lisp/riece-rdcc.el

   1 ;;; riece-rdcc.el --- DCC file sending protocol support (written in Ruby)
   2 ;; Copyright (C) 1998-2003 Daiki Ueno
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: IRC, riece
   6
   7 ;; This file is part of Riece.
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  22 ;; Boston, MA 02110-1301, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; NOTE: This is an add-on module for Riece.
  27
  28 ;;; Code:
  29
  30 (require 'riece-globals)
  31 (require 'riece-misc)
  32 (require 'riece-channel)
  33 (require 'riece-identity)
  34 (require 'riece-ctcp)                   ;for riece-ctcp-additional-clientinfo
  35 (require 'riece-ruby)
  36 (require 'riece-mcat)
  37
  38 (defgroup riece-rdcc nil
  39   "DCC written in Ruby."
  40   :prefix "riece-"
  41   :group 'riece)
  42
  43 (defcustom riece-rdcc-server-address nil
  44   "Local address of the DCC server.
  45 Only used for sending files."
  46   :type 'string
  47   :group 'riece-rdcc)
  48
  49 (defcustom riece-rdcc-send-program
  50   '("\
  51 require 'socket'
  52 address = " address "
  53 unless address
  54   sock = UDPSocket.new
  55   sock.connect('164.46.176.4', 7)               # www.unixuser.org/echo
  56   address = sock.getsockname[4 .. 7].unpack('CCCC').join('.')
  57 end
  58 server = TCPServer.new(address, 0)
  59 output(\"#{server.addr[3].split(/\\./).collect{|c| c.to_i}.pack('CCCC').unpack('N')[0]} #{server.addr[1]}\")
  60 session = server.accept
  61 if session
  62   total = 0
  63   File.open(" file ") {|file|
  64     while (bytes = file.read(" block-size "))
  65       total += bytes.length
  66       output(total)
  67       session.write(bytes)
  68       begin
  69         buf = session.read(4)
  70       end until buf.unpack('N')[0] == total
  71     end
  72   }
  73   session.close
  74 end
  75 ")
  76   "Ruby program to send file with DCC."
  77   :type 'list
  78   :group 'riece-rdcc)
  79
  80 (defcustom riece-rdcc-decode-address-program
  81   '("\"#{" address " >> 24 & 0xFF}.#{" address " >> 16 & 0xFF}.#{"
  82     address " >> 8 & 0xFF}.#{" address " & 0xFF}\"")
  83   "Ruby program to numeric IP address."
  84   :type 'list
  85   :group 'riece-rdcc)
  86
  87 (defcustom riece-rdcc-save-directory nil
  88   "Default directory where received files are saved in."
  89   :type 'directory
  90   :group 'riece-rdcc)
  91
  92 (defcustom riece-rdcc-block-size 1024
  93   "Number of bytes sent as a block."
  94   :type 'integer
  95   :group 'riece-rdcc)
  96
  97 (defvar riece-rdcc-requests nil)
  98
  99 (defvar riece-rdcc-request-user nil)
 100 (defvar riece-rdcc-request-file nil)
 101 (defvar riece-rdcc-request-size nil)
 102
 103 (defvar riece-rdcc-temp-file nil)
 104 (defvar riece-rdcc-received-size nil)
 105
 106 (defconst riece-rdcc-description
 107   "DCC file sending protocol support (written in Ruby.)")
 108
 109 (defvar temporary-file-directory)
 110 (defvar jka-compr-compression-info-list)
 111 (defvar jam-zcat-filename-list)
 112
 113 (defun riece-rdcc-output-handler (name output time)
 114   (if (string-match "\\([0-9]+\\) \\([0-9]+\\)" output)
 115       (let ((address (match-string 1 output))
 116             (port (match-string 2 output)))
 117         (riece-send-string
 118          (format "PRIVMSG %s :\1DCC SEND %s %s %s %d\1\r\n"
 119                  (riece-identity-prefix
 120                   (riece-ruby-property name 'riece-rdcc-request-user))
 121                  (file-name-nondirectory
 122                   (riece-ruby-property name 'riece-rdcc-request-file))
 123                  address port
 124                  (riece-ruby-property name 'riece-rdcc-request-size)))))
 125   (riece-ruby-set-output-handler name #'riece-rdcc-output-handler-2))
 126
 127 (defun riece-rdcc-output-handler-2 (name output time)
 128   (message (riece-mcat "Sending %s...(%s/%d)")
 129            (riece-ruby-property name 'riece-rdcc-request-file)
 130            (string-to-number output)
 131            (riece-ruby-property name 'riece-rdcc-request-size)))
 132
 133 (defun riece-rdcc-exit-handler (name)
 134   (message (riece-mcat "Sending %s...done")
 135            (riece-ruby-property name 'riece-rdcc-request-file)))
 136
 137 (defun riece-command-dcc-send (user file)
 138   (interactive
 139    (let ((completion-ignore-case t))
 140      (list (riece-completing-read-identity
 141             (riece-mcat "User: ")
 142             (riece-get-users-on-server (riece-current-server-name)))
 143            (expand-file-name (read-file-name (riece-mcat "File: "))))))
 144   (let ((name (riece-ruby-execute
 145                (riece-ruby-substitute-variables
 146                 riece-rdcc-send-program
 147                 (list (cons 'address
 148                             (if riece-rdcc-server-address
 149                                 (concat "'" riece-rdcc-server-address
 150                                         "'")
 151                               "nil"))
 152                       (cons 'file
 153                             (concat "'" file "'"))
 154                       (cons 'block-size
 155                             (number-to-string
 156                              riece-rdcc-block-size)))))))
 157     (riece-ruby-set-property name 'riece-rdcc-request-user user)
 158     (riece-ruby-set-property name 'riece-rdcc-request-file file)
 159     (riece-ruby-set-property name 'riece-rdcc-request-size
 160                              (nth 7 (file-attributes file)))
 161     (riece-ruby-set-output-handler name #'riece-rdcc-output-handler)
 162     (riece-ruby-set-exit-handler name #'riece-rdcc-exit-handler)))
 163
 164 (defun riece-rdcc-filter (process input)
 165   (save-excursion
 166     (set-buffer (process-buffer process))
 167     (erase-buffer)
 168     (insert input)
 169     (let ((coding-system-for-write 'binary)
 170           jka-compr-compression-info-list jam-zcat-filename-list)
 171       (write-region (point-min) (point-max) riece-rdcc-temp-file t 0))
 172     (setq riece-rdcc-received-size (+ (buffer-size) riece-rdcc-received-size))
 173     (process-send-string
 174      process
 175      (format "%c%c%c%c"
 176              (lsh riece-rdcc-received-size -24)
 177              (logand (lsh riece-rdcc-received-size -16) 255)
 178              (logand (lsh riece-rdcc-received-size -8) 255)
 179              (logand riece-rdcc-received-size 255)))
 180     (message (riece-mcat "Receiving %s from %s...(%s/%s)")
 181              (file-name-nondirectory riece-rdcc-request-file)
 182              riece-rdcc-request-user
 183              (riece-rdcc-format-size riece-rdcc-received-size)
 184              (riece-rdcc-format-size riece-rdcc-request-size))
 185     (if (= riece-rdcc-received-size riece-rdcc-request-size)
 186         (set-process-filter process nil))))
 187
 188 (defun riece-rdcc-sentinel (process status)
 189   (save-excursion
 190     (set-buffer (process-buffer process))
 191     (unless (= riece-rdcc-received-size riece-rdcc-request-size)
 192       (error "Premature end of file"))
 193     (message (riece-mcat "Receiving %s from %s...done")
 194              (file-name-nondirectory riece-rdcc-request-file)
 195              riece-rdcc-request-user)
 196     (condition-case nil
 197         (progn
 198           (rename-file riece-rdcc-temp-file riece-rdcc-request-file)
 199           (delete-directory (file-name-directory riece-rdcc-temp-file)))
 200       (file-already-exists
 201        (error "Can't save %s.  Temporarily saved in %s"
 202               riece-rdcc-request-file riece-rdcc-temp-file))))
 203   (kill-buffer (process-buffer process)))
 204
 205 (defun riece-rdcc-decode-address (address)
 206   (let ((name (riece-ruby-execute
 207                (riece-ruby-substitute-variables
 208                 riece-rdcc-decode-address-program
 209                 (list (cons 'address address)))))
 210         response)
 211     (while (equal (nth 2 (setq response (riece-ruby-inspect name))) "running")
 212       (accept-process-output riece-ruby-process))
 213     (riece-ruby-clear name)
 214     (nth 1 response)))
 215
 216 (defun riece-command-dcc-receive (request file)
 217   (interactive
 218    (progn
 219      (unless riece-rdcc-requests
 220        (error "No request"))
 221      (let* ((request
 222              (if (= (length riece-rdcc-requests) 1)
 223                  (car riece-rdcc-requests)
 224                (with-output-to-temp-buffer "*Help*"
 225                  (let ((requests riece-rdcc-requests)
 226                        (index 1))
 227                    (while requests
 228                      (princ (format (riece-mcat "%2d: %s %s (%d bytes)\n")
 229                                     index
 230                                     (car (car requests))
 231                                     (nth 1 (car requests))
 232                                     (nth 4 (car requests))))
 233                      (setq index (1+ index)
 234                            requests (cdr requests)))))
 235                (let ((number (read-string "Request#: ")))
 236                  (unless (string-match "^[0-9]+$" number)
 237                    (error "Not a number"))
 238                  (if (or (> (setq number (string-to-number number))
 239                             (length riece-rdcc-requests))
 240                          (< number 1))
 241                      (error "Invalid number"))
 242                  (nth (1- number) riece-rdcc-requests))))
 243             (default-name (expand-file-name
 244                            (convert-standard-filename (nth 1 request))
 245                            (or riece-rdcc-save-directory
 246                                default-directory))))
 247        (list request
 248              (expand-file-name
 249               (read-file-name
 250                (format (riece-mcat "Save as (default %s) ")
 251                        (file-name-nondirectory default-name))
 252                (file-name-directory default-name)
 253                default-name))))))
 254   (let* ((temp-file (expand-file-name
 255                      (file-name-nondirectory file)
 256                      (expand-file-name (make-temp-name "riece-rdcc")
 257                                        (if (featurep 'xemacs)
 258                                            (temp-directory)
 259                                          temporary-file-directory))))
 260          (orig-mode (default-file-modes))
 261          selective-display
 262          (coding-system-for-read 'binary)
 263          (coding-system-for-write 'binary)
 264          process)
 265     (unwind-protect
 266         (progn
 267           (set-default-file-modes 448)
 268           ;; This may throw an error.
 269           (make-directory (file-name-directory temp-file)))
 270       (set-default-file-modes orig-mode))
 271     (setq process (open-network-stream
 272                    "DCC" (generate-new-buffer " *DCC*")
 273                    (riece-rdcc-decode-address (nth 2 request))
 274                    (nth 3 request)))
 275     (setq riece-rdcc-requests (delq request riece-rdcc-requests))
 276     (with-current-buffer (process-buffer process)
 277       (if (fboundp 'set-buffer-multibyte)
 278           (set-buffer-multibyte nil))
 279       (buffer-disable-undo)
 280       (erase-buffer)
 281       (make-local-variable 'riece-rdcc-request-user)
 282       (setq riece-rdcc-request-user (car request))
 283       (make-local-variable 'riece-rdcc-request-file)
 284       (setq riece-rdcc-request-file file)
 285       (make-local-variable 'riece-rdcc-request-size)
 286       (setq riece-rdcc-request-size (nth 4 request))
 287       (make-local-variable 'riece-rdcc-temp-file)
 288       (setq riece-rdcc-temp-file temp-file)
 289       (make-local-variable 'riece-rdcc-received-size)
 290       (setq riece-rdcc-received-size 0))
 291     (set-process-filter process #'riece-rdcc-filter)
 292     (set-process-sentinel process #'riece-rdcc-sentinel)))
 293
 294 (defun riece-rdcc-format-size (size)
 295   (if (< size 1024)
 296       (format "%0.1f" size)
 297     (setq size (/ size 1024.0))
 298     (if (< size 1024)
 299         (format "%0.1fKB" size)
 300       (setq size (/ size 1024.0))
 301       (if (< size 1024)
 302           (format "%0.1fMB" size)
 303         (format "%0.1fGB" (/ size 1024.0))))))
 304
 305 (defun riece-handle-dcc-request (prefix target message)
 306   (let ((case-fold-search t))
 307     (when (and (get 'riece-rdcc 'riece-addon-enabled)
 308                (string-match
 309                 "SEND \\(\\([^ ]+\\)\\|\"\\(.+\\)\"\\) \\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)"
 310                 message))
 311       (let ((file (or (match-string 2 message)
 312                       (match-string 3 message)))
 313             (address (match-string 4 message))
 314             (port (string-to-number (match-string 5 message)))
 315             (size (string-to-number (match-string 6 message)))
 316             (buffer (if (riece-channel-p target)
 317                         (riece-channel-buffer (riece-make-identity
 318                                                target riece-server-name))))
 319             (user (riece-prefix-nickname prefix)))
 320         (setq riece-rdcc-requests
 321               (cons (list user file address port size)
 322                     riece-rdcc-requests))
 323         (message "%s"
 324                  (with-current-buffer (window-buffer (selected-window))
 325                    (substitute-command-keys
 326                     (format
 327                      (riece-mcat
 328                       "Type \\[riece-command-dcc-receive] to receive")
 329                      user))))
 330         (riece-insert-change buffer (format "DCC SEND from %s: %s (%s)\n"
 331                                             user file
 332                                             (riece-rdcc-format-size size)))
 333         (riece-insert-change
 334          (if (and riece-channel-buffer-mode
 335                   (not (eq buffer riece-channel-buffer)))
 336              (list riece-dialogue-buffer riece-others-buffer)
 337            riece-dialogue-buffer)
 338          (concat
 339           (riece-concat-server-name
 340            (format "DCC SEND from %s (%s) to %s: %s (%s)"
 341                    user
 342                    (riece-strip-user-at-host
 343                     (riece-prefix-user-at-host prefix))
 344                    (riece-decode-coding-string target)
 345                    file
 346                    (riece-rdcc-format-size size)))
 347           "\n")))
 348       t)))
 349
 350 (defun riece-rdcc-requires ()
 351   '(riece-ctcp))
 352
 353 (defvar riece-dialogue-mode-map)
 354 (defun riece-rdcc-insinuate ()
 355   (add-to-list 'riece-ctcp-additional-clientinfo "DCC")
 356   (add-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 357
 358 (defun riece-rdcc-uninstall ()
 359   (setq riece-ctcp-additional-clientinfo
 360         (delete "DCC" riece-ctcp-additional-clientinfo))
 361   (remove-hook 'riece-ctcp-dcc-request-hook 'riece-handle-dcc-request))
 362
 363 (defun riece-rdcc-enable ()
 364   (define-key riece-dialogue-mode-map "\C-ds" 'riece-command-dcc-send)
 365   (define-key riece-dialogue-mode-map "\C-dr" 'riece-command-dcc-receive))
 366
 367 (defun riece-rdcc-disable ()
 368   (define-key riece-dialogue-mode-map "\C-ds" nil)
 369   (define-key riece-dialogue-mode-map "\C-dr" nil))
 370
 371 (provide 'riece-rdcc)
 372
 373 ;;; riece-rdcc.el ends here