mime-bbdb.el

   1 ;;; mime-bbdb.el --- SEMI shared module for BBDB
   2
   3 ;; Copyright (C) 1995,1996,1997 Shuhei KOBAYASHI
   4 ;; Copyright (C) 1997,1998 MORIOKA Tomohiko
   5
   6 ;; Author: Shuhei KOBAYASHI <shuhei-k@jaist.ac.jp>
   7 ;; Maintainer: Shuhei KOBAYASHI <shuhei-k@jaist.ac.jp>
   8 ;; Keywords: BBDB, MIME, multimedia, multilingual, mail, news
   9
  10 ;; This file is part of SEMI (Suite of Emacs MIME Interfaces).
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Code:
  28
  29 (require 'path-util)
  30 (require 'std11)
  31 (require 'mime-view)
  32
  33 (if (module-installed-p 'bbdb-com)
  34     (require 'bbdb-com)
  35   (eval-when-compile
  36     ;; imported from bbdb-1.51
  37     (defmacro bbdb-pop-up-elided-display ()
  38       '(if (boundp 'bbdb-pop-up-elided-display)
  39            bbdb-pop-up-elided-display
  40          bbdb-elided-display))
  41     (defmacro bbdb-user-mail-names ()
  42       "Returns a regexp matching the address of the logged-in user"
  43       '(or bbdb-user-mail-names
  44            (setq bbdb-user-mail-names
  45                  (concat "\\b" (regexp-quote (user-login-name)) "\\b"))))))
  46
  47
  48 ;;; @ User Variables
  49 ;;;
  50
  51 (defvar mime-bbdb/use-mail-extr t
  52   "*If non-nil, `mail-extract-address-components' is used.
  53 Otherwise `mime-bbdb/extract-address-components' overrides it.")
  54
  55 (defvar mime-bbdb/auto-create-p nil
  56   "*If t, create new BBDB records automatically.
  57 If function, then it is called with no arguments to decide whether an
  58 entry should be automatically creaded.
  59
  60 mime-bbdb uses this variable instead of `bbdb/mail-auto-create-p' or
  61 `bbdb/news-auto-create-p' unless other tm-MUA overrides it.")
  62
  63 (defvar mime-bbdb/delete-empty-window nil
  64   "*If non-nil, delete empty BBDB window.
  65 All bbdb-MUAs but bbdb-gnus display BBDB window even if it is empty.
  66 If you prefer behavior of bbdb-gnus, set this variable to t.
  67
  68 For framepop users: If empty, `framepop-banish' is used instead.")
  69
  70 ;;; @ mail-extr
  71 ;;;
  72
  73 (defun mime-bbdb/extract-address-components (str)
  74   (let* ((ret     (std11-extract-address-components str))
  75          (phrase  (car ret))
  76          (address (car (cdr ret)))
  77          (methods mime-bbdb/canonicalize-full-name-methods))
  78     (while (and phrase methods)
  79       (setq phrase  (funcall (car methods) phrase)
  80             methods (cdr methods)))
  81     (if (string= address "") (setq address nil))
  82     (if (string= phrase "") (setq phrase nil))
  83     (list phrase address)))
  84
  85 (or mime-bbdb/use-mail-extr
  86     (progn
  87       (require 'mail-extr) ; for `what-domain'
  88       (or (fboundp 'tm:mail-extract-address-components)
  89           (fset 'tm:mail-extract-address-components
  90                 (symbol-function 'mail-extract-address-components)))
  91       (fset 'mail-extract-address-components
  92             (symbol-function 'mime-bbdb/extract-address-components))))
  93
  94
  95 ;;; @ bbdb-extract-field-value
  96 ;;;
  97
  98 (or (fboundp 'tm:bbdb-extract-field-value)
  99     (progn
 100       ;; (require 'bbdb-hooks) ; not provided.
 101       ;; (or (fboundp 'bbdb-extract-field-value) ; defined as autoload
 102
 103       ;; almost BBDB functions are autoloaded.
 104       ;; (or (fboundp 'bbdb-header-start)
 105       (or (and (fboundp 'bbdb-extract-field-value)
 106                (not (eq 'autoload (car-safe (symbol-function
 107                                              'bbdb-extract-field-value)))))
 108           (load "bbdb-hooks"))
 109       (fset 'tm:bbdb-extract-field-value
 110             (symbol-function 'bbdb-extract-field-value))
 111       (defun bbdb-extract-field-value (field)
 112         (let ((value (tm:bbdb-extract-field-value field)))
 113           (and value
 114                (eword-decode-string value))))))
 115
 116
 117 ;;; @ full-name canonicalization methods
 118 ;;;
 119
 120 (defun mime-bbdb/canonicalize-spaces (str)
 121   (let (dest)
 122     (while (string-match "\\s +" str)
 123       (setq dest (cons (substring str 0 (match-beginning 0)) dest))
 124       (setq str (substring str (match-end 0))))
 125     (or (string= str "")
 126         (setq dest (cons str dest)))
 127     (setq dest (nreverse dest))
 128     (mapconcat 'identity dest " ")))
 129
 130 (defun mime-bbdb/canonicalize-dots (str)
 131   (let (dest)
 132     (while (string-match "\\." str)
 133       (setq dest (cons (substring str 0 (match-end 0)) dest))
 134       (setq str (substring str (match-end 0))))
 135     (or (string= str "")
 136         (setq dest (cons str dest)))
 137     (setq dest (nreverse dest))
 138     (mapconcat 'identity dest " ")))
 139
 140 (defvar mime-bbdb/canonicalize-full-name-methods
 141   '(eword-decode-string
 142     mime-bbdb/canonicalize-dots
 143     mime-bbdb/canonicalize-spaces))
 144
 145
 146 ;;; @ BBDB functions for mime-view-mode
 147 ;;;
 148
 149 (defun mime-bbdb/update-record (&optional offer-to-create)
 150   "Return the record corresponding to the current MIME previewing message.
 151 Creating or modifying it as necessary. A record will be created if
 152 mime-bbdb/auto-create-p is non-nil, or if OFFER-TO-CREATE is non-nil and
 153 the user confirms the creation."
 154   (save-excursion
 155     (if (and mime-preview-buffer
 156              (get-buffer mime-preview-buffer))
 157         (set-buffer mime-preview-buffer))
 158     (if bbdb-use-pop-up
 159         (mime-bbdb/pop-up-bbdb-buffer offer-to-create)
 160       (let* ((message (get-text-property (point-min) 'mime-view-entity))
 161              (from (mime-entity-fetch-field message 'From))
 162              addr)
 163         (if (or (null from)
 164                 (null (setq addr (car (mime-entity-read-field message 'From))))
 165                 (string-match (bbdb-user-mail-names)
 166                               (std11-address-string addr)))
 167             (setq from (or (mime-entity-fetch-field message 'To)
 168                            from)))
 169         (if from
 170             (bbdb-annotate-message-sender
 171              (mime-decode-field-body from 'From) t
 172              (or (bbdb-invoke-hook-for-value mime-bbdb/auto-create-p)
 173                  offer-to-create)
 174              offer-to-create))))))
 175
 176 (defun mime-bbdb/annotate-sender (string)
 177   "Add a line to the end of the Notes field of the BBDB record
 178 corresponding to the sender of this message."
 179   (interactive
 180    (list (if bbdb-readonly-p
 181              (error "The Insidious Big Brother Database is read-only.")
 182            (read-string "Comments: "))))
 183   (bbdb-annotate-notes (mime-bbdb/update-record t) string))
 184
 185 (defun mime-bbdb/edit-notes (&optional arg)
 186   "Edit the notes field or (with a prefix arg) a user-defined field
 187 of the BBDB record corresponding to the sender of this message."
 188   (interactive "P")
 189   (let ((record (or (mime-bbdb/update-record t)
 190                     (error ""))))
 191     (bbdb-display-records (list record))
 192     (if arg
 193         (bbdb-record-edit-property record nil t)
 194       (bbdb-record-edit-notes record t))))
 195
 196 (defun mime-bbdb/show-sender ()
 197   "Display the contents of the BBDB for the sender of this message.
 198 This buffer will be in bbdb-mode, with associated keybindings."
 199   (interactive)
 200   (let ((record (mime-bbdb/update-record t)))
 201     (if record
 202         (bbdb-display-records (list record))
 203         (error "unperson"))))
 204
 205 (defun mime-bbdb/pop-up-bbdb-buffer (&optional offer-to-create)
 206   "Make the *BBDB* buffer be displayed along with the MIME preview window(s),
 207 displaying the record corresponding to the sender of the current message."
 208   (let ((framepop (eq temp-buffer-show-function 'framepop-display-buffer)))
 209     (or framepop
 210         (bbdb-pop-up-bbdb-buffer
 211          (function
 212           (lambda (w)
 213             (let ((b (current-buffer)))
 214               (set-buffer (window-buffer w))
 215               (prog1 (eq major-mode 'mime-view-mode)
 216                 (set-buffer b)))))))
 217     (let ((bbdb-gag-messages t)
 218           (bbdb-use-pop-up nil)
 219           (bbdb-electric-p nil))
 220       (let ((record (mime-bbdb/update-record offer-to-create))
 221             (bbdb-elided-display (bbdb-pop-up-elided-display))
 222             (b (current-buffer)))
 223         (if framepop
 224             (if record
 225                 (bbdb-display-records (list record))
 226               (framepop-banish))
 227           (bbdb-display-records (if record (list record) nil))
 228           (if (and (null record)
 229                    mime-bbdb/delete-empty-window)
 230               (delete-windows-on (get-buffer "*BBDB*"))))
 231         (set-buffer b)
 232         record))))
 233
 234 (defun mime-bbdb/define-keys ()
 235   (let ((mime-view-mode-map (current-local-map)))
 236     (define-key mime-view-mode-map ";" 'mime-bbdb/edit-notes)
 237     (define-key mime-view-mode-map ":" 'mime-bbdb/show-sender)))
 238
 239 (add-hook 'mime-view-mode-hook 'mime-bbdb/define-keys)
 240
 241
 242 ;;; @ for signature.el
 243 ;;;
 244
 245 (defun signature/get-bbdb-sigtype (addr)
 246   "Extract sigtype information from BBDB."
 247   (let ((record (bbdb-search-simple nil addr)))
 248     (and record
 249          (bbdb-record-getprop record 'sigtype))))
 250
 251 (defun signature/set-bbdb-sigtype (sigtype addr)
 252   "Add sigtype information to BBDB."
 253   (let* ((bbdb-notice-hook nil)
 254          (record (bbdb-annotate-message-sender
 255                   addr t
 256                   (bbdb-invoke-hook-for-value
 257                    bbdb/mail-auto-create-p)
 258                   t)))
 259     (if record
 260         (progn
 261           (bbdb-record-putprop record 'sigtype sigtype)
 262           (bbdb-change-record record nil)))))
 263
 264 (defun signature/get-sigtype-from-bbdb (&optional verbose)
 265   (let* ((to (std11-field-body "To"))
 266          (addr (and to
 267                     (car (cdr (mail-extract-address-components to)))))
 268          (sigtype (signature/get-bbdb-sigtype addr))
 269          return)
 270     (if addr
 271         (if verbose
 272             (progn
 273               (setq return (signature/get-sigtype-interactively sigtype))
 274               (if (and (not (string-equal return sigtype))
 275                        (y-or-n-p
 276                         (format "Register \"%s\" for <%s>? " return addr)))
 277                   (signature/set-bbdb-sigtype return addr))
 278               return)
 279           (or sigtype
 280               (signature/get-signature-file-name))))))
 281
 282
 283 ;;; @ end
 284 ;;;
 285
 286 (provide 'mime-bbdb)
 287
 288 (run-hooks 'mime-bbdb-load-hook)
 289
 290 ;;; end of mime-bbdb.el