mime-play.el

   1 ;;; mime-play.el --- Playback processing module for mime-view.el
   2
   3 ;; Copyright (C) 1994,95,96,97,98,99,2000 Free Software Foundation, Inc.
   4
   5 ;; Author: MORIOKA Tomohiko <tomo@m17n.org>
   6 ;; Created: 1995/9/26 (separated from tm-view.el)
   7 ;;      Renamed: 1997/2/21 from tm-play.el
   8 ;; Keywords: MIME, multimedia, mail, news
   9
  10 ;; This file is part of SEMI (Secretariat of Emacs MIME Interfaces).
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'mime-view)
  30 (require 'alist)
  31 (require 'filename)
  32
  33 (eval-when-compile
  34   (condition-case nil
  35       (require 'bbdb)
  36     (error (defvar bbdb-buffer-name nil)))
  37   )
  38
  39 (defcustom mime-save-directory "~/"
  40   "*Name of the directory where MIME entity will be saved in.
  41 If t, it means current directory."
  42   :group 'mime-view
  43   :type '(choice (const :tag "Current directory" t)
  44                  (directory)))
  45
  46 (defvar mime-play-find-every-situations t
  47   "*Find every available situations if non-nil.")
  48
  49
  50 ;;; @ content decoder
  51 ;;;
  52
  53 ;;;###autoload
  54 (defun mime-preview-play-current-entity (&optional ignore-examples mode)
  55   "Play current entity.
  56 It decodes current entity to call internal or external method.  The
  57 method is selected from variable `mime-acting-condition'.
  58 If IGNORE-EXAMPLES (C-u prefix) is specified, this function ignores
  59 `mime-acting-situation-example-list'.
  60 If MODE is specified, play as it.  Default MODE is \"play\"."
  61   (interactive "P")
  62   (let ((entity (get-text-property (point) 'mime-view-entity)))
  63     (if entity
  64         (let ((situation
  65                (get-text-property (point) 'mime-view-situation)))
  66           (or mode
  67               (setq mode "play"))
  68           (setq situation
  69                 (if (assq 'mode situation)
  70                     (put-alist 'mode mode (copy-alist situation))
  71                   (cons (cons 'mode mode)
  72                         situation)))
  73           (if ignore-examples
  74               (setq situation
  75                     (cons (cons 'ignore-examples ignore-examples)
  76                           situation)))
  77           (mime-play-entity entity situation)
  78           ))))
  79
  80 ;;;###autoload
  81 (defun mime-play-entity (entity &optional situation ignored-method)
  82   "Play entity specified by ENTITY.
  83 It decodes the entity to call internal or external method.  The method
  84 is selected from variable `mime-acting-condition'.  If MODE is
  85 specified, play as it.  Default MODE is \"play\"."
  86   (let ((ret
  87          (mime-unify-situations (mime-entity-situation entity situation)
  88                                 mime-acting-condition
  89                                 mime-acting-situation-example-list
  90                                 'method ignored-method
  91                                 mime-play-find-every-situations))
  92         method)
  93     (setq mime-acting-situation-example-list (cdr ret)
  94           ret (car ret))
  95     (cond ((cdr ret)
  96            (setq ret (select-menu-alist
  97                       "Methods"
  98                       (mapcar (function
  99                                (lambda (situation)
 100                                  (cons
 101                                   (format "%s"
 102                                           (cdr (assq 'method situation)))
 103                                   situation)))
 104                               ret)))
 105            (setq ret (mime-sort-situation ret))
 106            (add-to-list 'mime-acting-situation-example-list (cons ret 0))
 107            )
 108           (t
 109            (setq ret (car ret))
 110            ))
 111     (setq method (cdr (assq 'method ret)))
 112     (cond ((and (symbolp method)
 113                 (fboundp method))
 114            (funcall method entity ret)
 115            )
 116           ((stringp method)
 117            (mime-activate-mailcap-method entity ret)
 118            )
 119           ;; ((and (listp method)(stringp (car method)))
 120           ;;  (mime-activate-external-method entity ret)
 121           ;;  )
 122           (t
 123            (mime-show-echo-buffer "No method are specified for %s\n"
 124                                   (mime-type/subtype-string
 125                                    (cdr (assq 'type situation))
 126                                    (cdr (assq 'subtype situation))))
 127            (if (y-or-n-p "Do you want to save current entity to disk?")
 128                (mime-save-content entity situation))
 129            ))
 130     ))
 131
 132
 133 ;;; @ external decoder
 134 ;;;
 135
 136 (defvar mime-mailcap-method-filename-alist nil)
 137
 138 (defvar mime-mailcap-method-messages-coding-system 'undecided
 139   "Coding system for an external mailcap method.")
 140
 141 (defun mime-activate-mailcap-method (entity situation)
 142   (let ((method (cdr (assoc 'method situation)))
 143         (name (mime-entity-safe-filename entity)))
 144     (setq name
 145           (if (and name (not (string= name "")))
 146               (expand-file-name name temporary-file-directory)
 147             (make-temp-name
 148              (expand-file-name "EMI" temporary-file-directory))
 149             ))
 150     (mime-write-entity-content entity name)
 151     (message "External method is starting...")
 152     (let ((process
 153            (let ((command
 154                   (mime-format-mailcap-command
 155                    method
 156                    (cons (cons 'filename name) situation))))
 157              (binary-to-text-funcall
 158               mime-mailcap-method-messages-coding-system
 159               #'start-process command mime-echo-buffer-name
 160               shell-file-name shell-command-switch command))))
 161       (set-alist 'mime-mailcap-method-filename-alist process name)
 162       (set-process-sentinel process 'mime-mailcap-method-sentinel))))
 163
 164 (defun mime-mailcap-method-sentinel (process event)
 165   (let ((file (cdr (assq process mime-mailcap-method-filename-alist))))
 166     (if (file-exists-p file)
 167         (delete-file file)
 168       ))
 169   (remove-alist 'mime-mailcap-method-filename-alist process)
 170   (message (format "%s %s" process event)))
 171
 172 (defvar mime-echo-window-is-shared-with-bbdb
 173   (module-installed-p 'bbdb)
 174   "*If non-nil, mime-echo window is shared with BBDB window.")
 175
 176 (defvar mime-echo-window-height
 177   (function
 178    (lambda ()
 179      (/ (window-height) 5)
 180      ))
 181   "*Size of mime-echo window.
 182 It allows function or integer.  If it is function,
 183 `mime-show-echo-buffer' calls it to get height of mime-echo window.
 184 Otherwise `mime-show-echo-buffer' uses it as height of mime-echo
 185 window.")
 186
 187 (defun mime-show-echo-buffer (&rest forms)
 188   "Show mime-echo buffer to display MIME-playing information."
 189   (get-buffer-create mime-echo-buffer-name)
 190   (let ((the-win (selected-window))
 191         (win (get-buffer-window mime-echo-buffer-name)))
 192     (unless win
 193       (unless (and mime-echo-window-is-shared-with-bbdb
 194                    (condition-case nil
 195                        (setq win (get-buffer-window bbdb-buffer-name))
 196                      (error nil)))
 197         (select-window (get-buffer-window (or mime-preview-buffer
 198                                               (current-buffer))))
 199         (setq win (split-window-vertically
 200                    (- (window-height)
 201                       (if (functionp mime-echo-window-height)
 202                           (funcall mime-echo-window-height)
 203                         mime-echo-window-height)
 204                       )))
 205         )
 206       (set-window-buffer win mime-echo-buffer-name)
 207       )
 208     (select-window win)
 209     (goto-char (point-max))
 210     (if forms
 211         (let ((buffer-read-only nil))
 212           (insert (apply (function format) forms))
 213           ))
 214     (select-window the-win)
 215     ))
 216
 217
 218 ;;; @ file name
 219 ;;;
 220
 221 (defvar mime-view-file-name-char-regexp "[A-Za-z0-9+_-]")
 222
 223 (defvar mime-view-file-name-regexp-1
 224   (concat mime-view-file-name-char-regexp "+\\."
 225           mime-view-file-name-char-regexp "+"))
 226
 227 (defvar mime-view-file-name-regexp-2
 228   (concat (regexp-* mime-view-file-name-char-regexp)
 229           "\\(\\." mime-view-file-name-char-regexp "+\\)*"))
 230
 231 (defun mime-entity-safe-filename (entity)
 232   (let ((filename
 233          (or (mime-entity-filename entity)
 234              (let ((subj
 235                     (or (mime-entity-read-field entity 'Content-Description)
 236                         (mime-entity-read-field entity 'Subject))))
 237                (if (and subj
 238                         (or (string-match mime-view-file-name-regexp-1 subj)
 239                             (string-match mime-view-file-name-regexp-2 subj)))
 240                    (substring subj (match-beginning 0)(match-end 0))
 241                  )))))
 242     (if filename
 243         (replace-as-filename filename)
 244       )))
 245
 246
 247 ;;; @ file extraction
 248 ;;;
 249
 250 (defun mime-save-content (entity situation)
 251   (let ((name (or (mime-entity-safe-filename entity)
 252                   (format "%s" (mime-entity-media-type entity))))
 253         (dir (if (eq t mime-save-directory)
 254                  default-directory
 255                mime-save-directory))
 256         filename)
 257     (setq filename (read-file-name
 258                     (concat "File name: (default "
 259                             (file-name-nondirectory name) ") ")
 260                     dir
 261                     (concat (file-name-as-directory dir)
 262                             (file-name-nondirectory name))))
 263     (if (file-directory-p filename)
 264         (setq filename (concat (file-name-as-directory filename)
 265                                (file-name-nondirectory name))))
 266     (if (file-exists-p filename)
 267         (or (yes-or-no-p (format "File %s exists. Save anyway? " filename))
 268             (error "")))
 269     (mime-write-entity-content entity (expand-file-name filename))
 270     ))
 271
 272
 273 ;;; @ file detection
 274 ;;;
 275
 276 (defvar mime-magic-type-alist
 277   '(("^\377\330\377[\340\356]..JFIF"    image jpeg)
 278     ("^\211PNG"                         image png)
 279     ("^GIF8[79]"                        image gif)
 280     ("^II\\*\000"                       image tiff)
 281     ("^MM\000\\*"                       image tiff)
 282     ("^MThd"                            audio midi)
 283     ("^\000\000\001\263"                video mpeg)
 284     )
 285   "*Alist of regexp about magic-number vs. corresponding media-types.
 286 Each element looks like (REGEXP TYPE SUBTYPE).
 287 REGEXP is a regular expression to match against the beginning of the
 288 content of entity.
 289 TYPE is symbol to indicate primary type of media-type.
 290 SUBTYPE is symbol to indicate subtype of media-type.")
 291
 292 (defun mime-detect-content (entity situation)
 293   (let (type subtype)
 294     (let ((mdata (mime-entity-content entity))
 295           (rest mime-magic-type-alist))
 296       (while (not (let ((cell (car rest)))
 297                     (if cell
 298                         (if (string-match (car cell) mdata)
 299                             (setq type (nth 1 cell)
 300                                   subtype (nth 2 cell))
 301                           )
 302                       t)))
 303         (setq rest (cdr rest))))
 304     (setq situation (del-alist 'method (copy-alist situation)))
 305     (mime-play-entity entity
 306                       (if type
 307                           (put-alist 'type type
 308                                      (put-alist 'subtype subtype
 309                                                 situation))
 310                         situation)
 311                       'mime-detect-content)))
 312
 313
 314 ;;; @ mail/news message
 315 ;;;
 316
 317 (defun mime-preview-quitting-method-for-mime-show-message-mode ()
 318   "Quitting method for mime-view.
 319 It is registered to variable `mime-preview-quitting-method-alist'."
 320   (let ((mother mime-mother-buffer)
 321         (win-conf mime-preview-original-window-configuration))
 322     (if (and (boundp 'mime-view-temp-message-buffer)
 323              (buffer-live-p mime-view-temp-message-buffer))
 324         (kill-buffer mime-view-temp-message-buffer))
 325     (mime-preview-kill-buffer)
 326     (set-window-configuration win-conf)
 327     (pop-to-buffer mother)))
 328
 329 (defun mime-view-message/rfc822 (entity situation)
 330   (let* ((new-name
 331           (format "%s-%s" (buffer-name) (mime-entity-number entity)))
 332          (mother (current-buffer))
 333          (children (car (mime-entity-children entity)))
 334          (preview-buffer
 335           (mime-display-message
 336            children new-name mother nil
 337            (cdr (assq 'major-mode
 338                       (get-text-property (point) 'mime-view-situation))))))
 339     (or (get-buffer-window preview-buffer)
 340         (let ((m-win (get-buffer-window mother)))
 341           (if m-win
 342               (set-window-buffer m-win preview-buffer)
 343             (switch-to-buffer preview-buffer)
 344             )))))
 345
 346
 347 ;;; @ message/partial
 348 ;;;
 349
 350 (defun mime-store-message/partial-piece (entity cal)
 351   (let* ((root-dir
 352           (expand-file-name
 353            (concat "m-prts-" (user-login-name)) temporary-file-directory))
 354          (id (cdr (assoc "id" cal)))
 355          (number (cdr (assoc "number" cal)))
 356          (total (cdr (assoc "total" cal)))
 357          file
 358          (mother (current-buffer)))
 359     (or (file-exists-p root-dir)
 360         (make-directory root-dir))
 361     (setq id (replace-as-filename id))
 362     (setq root-dir (concat root-dir "/" id))
 363     (or (file-exists-p root-dir)
 364         (make-directory root-dir))
 365     (setq file (concat root-dir "/FULL"))
 366     (if (file-exists-p file)
 367         (let ((full-buf (get-buffer-create "FULL"))
 368               (pwin (or (get-buffer-window mother)
 369                         (get-largest-window)))
 370               pbuf)
 371           (save-window-excursion
 372             (set-buffer full-buf)
 373             (erase-buffer)
 374             (binary-insert-encoded-file file)
 375             (setq major-mode 'mime-show-message-mode)
 376             (mime-view-buffer (current-buffer) nil mother)
 377             (setq pbuf (current-buffer))
 378             (make-local-variable 'mime-view-temp-message-buffer)
 379             (setq mime-view-temp-message-buffer full-buf))
 380           (set-window-buffer pwin pbuf)
 381           (select-window pwin))
 382       (setq file (concat root-dir "/" number))
 383       (mime-write-entity-body entity file)
 384       (let ((total-file (concat root-dir "/CT")))
 385         (setq total
 386               (if total
 387                   (progn
 388                     (or (file-exists-p total-file)
 389                         (save-excursion
 390                           (set-buffer
 391                            (get-buffer-create mime-temp-buffer-name))
 392                           (erase-buffer)
 393                           (insert total)
 394                           (write-region (point-min)(point-max) total-file)
 395                           (kill-buffer (current-buffer))
 396                           ))
 397                     (string-to-number total)
 398                     )
 399                 (and (file-exists-p total-file)
 400                      (save-excursion
 401                        (set-buffer (find-file-noselect total-file))
 402                        (prog1
 403                            (and (re-search-forward "[0-9]+" nil t)
 404                                 (string-to-number
 405                                  (buffer-substring (match-beginning 0)
 406                                                    (match-end 0)))
 407                                 )
 408                          (kill-buffer (current-buffer))
 409                          )))
 410                 )))
 411       (if (and total (> total 0)
 412                (>= (length (directory-files root-dir nil "^[0-9]+$" t))
 413                    total))
 414           (catch 'tag
 415             (save-excursion
 416               (set-buffer (get-buffer-create mime-temp-buffer-name))
 417               (let ((full-buf (current-buffer)))
 418                 (erase-buffer)
 419                 (let ((i 1))
 420                   (while (<= i total)
 421                     (setq file (concat root-dir "/" (int-to-string i)))
 422                     (or (file-exists-p file)
 423                         (throw 'tag nil)
 424                         )
 425                     (binary-insert-encoded-file file)
 426                     (goto-char (point-max))
 427                     (setq i (1+ i))))
 428                 (binary-write-decoded-region
 429                  (point-min)(point-max)
 430                  (expand-file-name "FULL" root-dir))
 431                 (let ((i 1))
 432                   (while (<= i total)
 433                     (let ((file (format "%s/%d" root-dir i)))
 434                       (and (file-exists-p file)
 435                            (delete-file file)))
 436                     (setq i (1+ i))))
 437                 (let ((file (expand-file-name "CT" root-dir)))
 438                   (and (file-exists-p file)
 439                        (delete-file file)))
 440                 (let ((buf (current-buffer))
 441                       (pwin (or (get-buffer-window mother)
 442                                 (get-largest-window)))
 443                       (pbuf (mime-display-message
 444                              (mime-open-entity 'buffer (current-buffer))
 445                              nil mother nil 'mime-show-message-mode)))
 446                   (with-current-buffer pbuf
 447                     (make-local-variable 'mime-view-temp-message-buffer)
 448                     (setq mime-view-temp-message-buffer buf))
 449                   (set-window-buffer pwin pbuf)
 450                   (select-window pwin)
 451                   )))))
 452       )))
 453
 454
 455 ;;; @ message/external-body
 456 ;;;
 457
 458 (defvar mime-raw-dired-function
 459   (if (and (>= emacs-major-version 19) window-system)
 460       (function dired-other-frame)
 461     (function mime-raw-dired-function-for-one-frame)
 462     ))
 463
 464 (defun mime-raw-dired-function-for-one-frame (dir)
 465   (let ((win (or (get-buffer-window mime-preview-buffer)
 466                  (get-largest-window))))
 467     (select-window win)
 468     (dired dir)
 469     ))
 470
 471 (defun mime-view-message/external-anon-ftp (entity cal)
 472   (let* ((site (cdr (assoc "site" cal)))
 473          (directory (cdr (assoc "directory" cal)))
 474          (name (cdr (assoc "name" cal)))
 475          (pathname (concat "/anonymous@" site ":" directory)))
 476     (message (concat "Accessing " (expand-file-name name pathname) " ..."))
 477     (funcall mime-raw-dired-function pathname)
 478     (goto-char (point-min))
 479     (search-forward name)
 480     ))
 481
 482 (defvar mime-raw-browse-url-function mime-browse-url-function)
 483
 484 (defun mime-view-message/external-url (entity cal)
 485   (let ((url (cdr (assoc "url" cal))))
 486     (message (concat "Accessing " url " ..."))
 487     (funcall mime-raw-browse-url-function url)))
 488
 489
 490 ;;; @ rot13-47
 491 ;;;
 492
 493 (defun mime-view-caesar (entity situation)
 494   "Internal method for mime-view to display ROT13-47-48 message."
 495   (let ((buf (get-buffer-create
 496               (format "%s-%s" (buffer-name) (mime-entity-number entity)))))
 497     (with-current-buffer buf
 498       (setq buffer-read-only nil)
 499       (erase-buffer)
 500       (mime-insert-text-content entity)
 501       (mule-caesar-region (point-min) (point-max))
 502       (set-buffer-modified-p nil)
 503       )
 504     (let ((win (get-buffer-window (current-buffer))))
 505       (or (eq (selected-window) win)
 506           (select-window (or win (get-largest-window)))
 507           ))
 508     (view-buffer buf)
 509     (goto-char (point-min))
 510     ))
 511
 512
 513 ;;; @ end
 514 ;;;
 515
 516 (provide 'mime-play)
 517
 518 ;;; mime-play.el ends here