pgg-gpg.el

   1 ;;; pgg-gpg.el --- GnuPG support for PGG.
   2
   3 ;; Copyright (C) 1999,2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Daiki Ueno <ueno@unixuser.org>
   6 ;; Created: 1999/10/28
   7 ;; Keywords: PGP, OpenPGP, GnuPG
   8
   9 ;; This file is part of SEMI (Secure Emacs MIME Interface).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (require 'mel) ; binary-to-text-funcall
  29 (eval-when-compile (require 'pgg))
  30
  31 (defgroup pgg-gpg ()
  32   "GnuPG interface"
  33   :group 'pgg)
  34
  35 (defcustom pgg-gpg-program "gpg"
  36   "The GnuPG executable."
  37   :group 'pgg-gpg
  38   :type 'string)
  39
  40 (defcustom pgg-gpg-extra-args nil
  41   "Extra arguments for every GnuPG invocation."
  42   :group 'pgg-gpg
  43   :type 'string)
  44
  45 (eval-and-compile
  46   (luna-define-class pgg-scheme-gpg (pgg-scheme)))
  47
  48 (defvar pgg-gpg-user-id nil
  49   "GnuPG ID of your default identity.")
  50
  51 (defvar pgg-scheme-gpg-instance nil)
  52
  53 ;;;###autoload
  54 (defun pgg-make-scheme-gpg ()
  55   (or pgg-scheme-gpg-instance
  56       (setq pgg-scheme-gpg-instance
  57             (luna-make-entity 'pgg-scheme-gpg))))
  58
  59 (defun pgg-gpg-process-region (start end passphrase program args)
  60   (let* ((output-file-name
  61           (concat temporary-file-directory (make-temp-name "pgg-output")))
  62          (args
  63           `("--status-fd" "2"
  64             ,@(if passphrase '("--passphrase-fd" "0"))
  65             "--output" ,output-file-name
  66             ,@pgg-gpg-extra-args ,@args))
  67          (output-buffer pgg-output-buffer)
  68          (errors-buffer pgg-errors-buffer)
  69          (orig-mode (default-file-modes))
  70          (process-connection-type nil)
  71          process status exit-status)
  72     (with-current-buffer (get-buffer-create errors-buffer)
  73       (buffer-disable-undo)
  74       (erase-buffer))
  75     (unwind-protect
  76         (progn
  77           (set-default-file-modes 448)
  78           (let ((coding-system-for-write 'binary))
  79             (setq process
  80                   (apply #'start-process "*GnuPG*" errors-buffer
  81                          program args)))
  82           (set-process-sentinel process #'ignore)
  83           (when passphrase
  84             (process-send-string process (concat passphrase "\n")))
  85           (process-send-region process start end)
  86           (process-send-eof process)
  87           (while (eq 'run (process-status process))
  88             (accept-process-output process 5))
  89           (setq status (process-status process)
  90                 exit-status (process-exit-status process))
  91           (delete-process process)
  92           (with-current-buffer (get-buffer-create output-buffer)
  93             (buffer-disable-undo)
  94             (erase-buffer)
  95             (if (file-exists-p output-file-name)
  96                 (let ((coding-system-for-read 'raw-text-dos))
  97                   (insert-file-contents output-file-name)))
  98             (set-buffer errors-buffer)
  99             (if (memq status '(stop signal))
 100                 (error "%s exited abnormally: '%s'" program exit-status))
 101             (if (= 127 exit-status)
 102                 (error "%s could not be found" program))))
 103       (if (and process (eq 'run (process-status process)))
 104           (interrupt-process process))
 105       (if (file-exists-p output-file-name)
 106           (delete-file output-file-name))
 107       (set-default-file-modes orig-mode))))
 108
 109 (defun pgg-gpg-possibly-cache-passphrase (passphrase)
 110   (if (and pgg-cache-passphrase
 111            (progn
 112              (goto-char (point-min))
 113              (re-search-forward "^\\[GNUPG:] GOOD_PASSPHRASE\\>" nil t)))
 114       (pgg-add-passphrase-cache
 115        (progn
 116          (goto-char (point-min))
 117          (if (re-search-forward
 118               "^\\[GNUPG:] NEED_PASSPHRASE \\w+ ?\\w*" nil t)
 119              (substring (match-string 0) -8)))
 120        passphrase)))
 121
 122 (luna-define-method pgg-scheme-lookup-key ((scheme pgg-scheme-gpg)
 123                                            string &optional type)
 124   (let ((args (list "--with-colons" "--no-greeting" "--batch"
 125                     (if type "--list-secret-keys" "--list-keys")
 126                     string)))
 127     (with-temp-buffer
 128       (apply #'call-process pgg-gpg-program nil t nil args)
 129       (goto-char (point-min))
 130       (if (re-search-forward "^\\(sec\\|pub\\):"  nil t)
 131           (substring
 132            (nth 3 (split-string
 133                    (buffer-substring (match-end 0)
 134                                      (progn (end-of-line)(point)))
 135                    ":")) 8)))))
 136
 137 (luna-define-method pgg-scheme-encrypt-region ((scheme pgg-scheme-gpg)
 138                                                start end recipients)
 139   (let* ((user-id (or pgg-overriding-user-id pgg-gpg-user-id
 140                       pgg-default-user-id))
 141          (args
 142           `("--batch" "--armor" "--always-trust" "--encrypt"
 143             ,@(if recipients
 144                   (apply #'nconc
 145                          (mapcar (lambda (rcpt)
 146                                    (list "--remote-user" rcpt))
 147                                  (append recipients
 148                                          (if pgg-encrypt-for-me
 149                                              (list user-id)))))))))
 150     (pgg-as-lbt start end 'CRLF
 151       (pgg-gpg-process-region start end nil pgg-gpg-program args))
 152     (pgg-process-when-success)))
 153
 154 (luna-define-method pgg-scheme-decrypt-region ((scheme pgg-scheme-gpg)
 155                                                start end)
 156   (let* ((user-id (or pgg-overriding-user-id pgg-gpg-user-id
 157                       pgg-default-user-id))
 158          (passphrase
 159           (pgg-read-passphrase
 160            (format "GnuPG passphrase for %s: " pgg-gpg-user-id)
 161            (pgg-scheme-lookup-key scheme user-id 'encrypt)))
 162          (args '("--batch" "--decrypt")))
 163     (pgg-gpg-process-region start end passphrase pgg-gpg-program args)
 164     (with-current-buffer pgg-errors-buffer
 165       (pgg-gpg-possibly-cache-passphrase passphrase)
 166       (goto-char (point-min))
 167       (re-search-forward "^\\[GNUPG:] DECRYPTION_OKAY\\>" nil t))))
 168
 169 (luna-define-method pgg-scheme-sign-region ((scheme pgg-scheme-gpg)
 170                                             start end &optional cleartext)
 171   (let* ((user-id (or pgg-overriding-user-id pgg-gpg-user-id
 172                       pgg-default-user-id))
 173          (passphrase
 174           (pgg-read-passphrase
 175            (format "GnuPG passphrase for %s: " user-id)
 176            (pgg-scheme-lookup-key scheme user-id 'sign)))
 177          (args
 178           (list (if cleartext "--clearsign" "--detach-sign")
 179                 "--armor" "--batch" "--verbose"
 180                 "--local-user" user-id))
 181          (inhibit-read-only t)
 182          buffer-read-only)
 183     (pgg-as-lbt start end 'CRLF
 184       (pgg-gpg-process-region start end passphrase pgg-gpg-program args))
 185     (with-current-buffer pgg-errors-buffer
 186       (pgg-gpg-possibly-cache-passphrase passphrase))
 187     (pgg-process-when-success)))
 188
 189 (luna-define-method pgg-scheme-verify-region ((scheme pgg-scheme-gpg)
 190                                               start end &optional signature)
 191   (let ((args '("--batch" "--verify")))
 192     (when (stringp signature)
 193       (setq args (append args (list signature))))
 194     (setq args (append args '("-")))
 195     (pgg-gpg-process-region start end nil pgg-gpg-program args)
 196     (with-current-buffer pgg-errors-buffer
 197       (goto-char (point-min))
 198       (while (re-search-forward "^gpg: " nil t)
 199         (replace-match ""))
 200       (goto-char (point-min))
 201       (prog1 (re-search-forward "^\\[GNUPG:] GOODSIG\\>" nil t)
 202         (goto-char (point-min))
 203         (delete-matching-lines "^warning\\|\\[GNUPG:]")
 204         (set-buffer pgg-output-buffer)
 205         (insert-buffer-substring pgg-errors-buffer)))))
 206
 207 (luna-define-method pgg-scheme-insert-key ((scheme pgg-scheme-gpg))
 208   (let* ((user-id (or pgg-overriding-user-id pgg-gpg-user-id
 209                       pgg-default-user-id))
 210          (args (list "--batch" "--export" "--armor" user-id)))
 211     (pgg-gpg-process-region (point)(point) nil pgg-gpg-program args)
 212     (insert-buffer-substring pgg-output-buffer)))
 213
 214 (luna-define-method pgg-scheme-snarf-keys-region ((scheme pgg-scheme-gpg)
 215                                                   start end)
 216   (let ((args '("--import" "--batch" "-")) status)
 217     (pgg-gpg-process-region start end nil pgg-gpg-program args)
 218     (set-buffer pgg-errors-buffer)
 219     (goto-char (point-min))
 220     (when (re-search-forward "^\\[GNUPG:] IMPORT_RES\\>" nil t)
 221       (setq status (buffer-substring (match-end 0)
 222                                      (progn (end-of-line)(point)))
 223             status (vconcat (mapcar #'string-to-int (split-string status))))
 224       (erase-buffer)
 225       (insert (format "Imported %d key(s).
 226 \tArmor contains %d key(s) [%d bad, %d old].\n"
 227                       (+ (aref status 2)
 228                          (aref status 10))
 229                       (aref status 0)
 230                       (aref status 1)
 231                       (+ (aref status 4)
 232                          (aref status 11)))
 233               (if (zerop (aref status 9))
 234                   ""
 235                 "\tSecret keys are imported.\n")))
 236     (append-to-buffer pgg-output-buffer (point-min)(point-max))
 237     (pgg-process-when-success)))
 238
 239 (provide 'pgg-gpg)
 240
 241 ;;; pgg-gpg.el ends here