pgg-gpg.el

   1 ;;; pgg-gpg.el --- GnuPG support for PGG.
   2
   3 ;; Copyright (C) 1999,2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Daiki Ueno <ueno@unixuser.org>
   6 ;; Created: 1999/10/28
   7 ;; Keywords: PGP, OpenPGP, GnuPG
   8
   9 ;; This file is part of SEMI (Secure Emacs MIME Interface).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'pgg))
  29
  30 (defgroup pgg-gpg ()
  31   "GnuPG interface"
  32   :group 'pgg)
  33
  34 (defcustom pgg-gpg-program "gpg"
  35   "The GnuPG executable."
  36   :group 'pgg-gpg
  37   :type 'string)
  38
  39 (defcustom pgg-gpg-extra-args nil
  40   "Extra arguments for every GnuPG invocation."
  41   :group 'pgg-gpg
  42   :type 'string)
  43
  44 (eval-and-compile
  45   (luna-define-class pgg-scheme-gpg (pgg-scheme)))
  46
  47 (defvar pgg-gpg-user-id nil
  48   "GnuPG ID of your default identity.")
  49
  50 (defvar pgg-scheme-gpg-instance nil)
  51
  52 ;;;###autoload
  53 (defun pgg-make-scheme-gpg ()
  54   (or pgg-scheme-gpg-instance
  55       (setq pgg-scheme-gpg-instance
  56             (luna-make-entity 'pgg-scheme-gpg))))
  57
  58 (defun pgg-gpg-process-region (start end passphrase program args)
  59   (let* ((output-file-name
  60           (concat temporary-file-directory (make-temp-name "pgg-output")))
  61          (args
  62           `("--status-fd" "2"
  63             ,@(if passphrase '("--passphrase-fd" "0"))
  64             "--output" ,output-file-name
  65             ,@pgg-gpg-extra-args ,@args))
  66          (output-buffer pgg-output-buffer)
  67          (errors-buffer pgg-errors-buffer)
  68          (orig-mode (default-file-modes))
  69          (process-connection-type nil)
  70          process status exit-status)
  71     (with-current-buffer (get-buffer-create errors-buffer)
  72       (buffer-disable-undo)
  73       (erase-buffer))
  74     (unwind-protect
  75         (progn
  76           (set-default-file-modes 448)
  77           (let ((coding-system-for-write 'binary))
  78             (setq process
  79                   (apply #'start-process "*GnuPG*" errors-buffer
  80                          program args)))
  81           (set-process-sentinel process #'ignore)
  82           (when passphrase
  83             (process-send-string process (concat passphrase "\n")))
  84           (process-send-region process start end)
  85           (process-send-eof process)
  86           (while (eq 'run (process-status process))
  87             (accept-process-output process 5))
  88           (setq status (process-status process)
  89                 exit-status (process-exit-status process))
  90           (delete-process process)
  91           (with-current-buffer (get-buffer-create output-buffer)
  92             (buffer-disable-undo)
  93             (erase-buffer)
  94             (if (file-exists-p output-file-name)
  95                 (let ((coding-system-for-read 'raw-text-dos))
  96                   (insert-file-contents output-file-name)))
  97             (set-buffer errors-buffer)
  98             (if (memq status '(stop signal))
  99                 (error "%s exited abnormally: '%s'" program exit-status))
 100             (if (= 127 exit-status)
 101                 (error "%s could not be found" program))))
 102       (if (and process (eq 'run (process-status process)))
 103           (interrupt-process process))
 104       (if (file-exists-p output-file-name)
 105           (delete-file output-file-name))
 106       (set-default-file-modes orig-mode))))
 107
 108 (defun pgg-gpg-possibly-cache-passphrase (passphrase)
 109   (if (and pgg-cache-passphrase
 110            (progn
 111              (goto-char (point-min))
 112              (re-search-forward "^\\[GNUPG:] GOOD_PASSPHRASE\\>" nil t)))
 113       (pgg-add-passphrase-cache
 114        (progn
 115          (goto-char (point-min))
 116          (if (re-search-forward
 117               "^\\[GNUPG:] NEED_PASSPHRASE \\w+ ?\\w*" nil t)
 118              (substring (match-string 0) -8)))
 119        passphrase)))
 120
 121 (luna-define-method pgg-scheme-lookup-key ((scheme pgg-scheme-gpg)
 122                                            string &optional type)
 123   (let ((args (list "--with-colons" "--no-greeting" "--batch"
 124                     (if type "--list-secret-keys" "--list-keys")
 125                     string)))
 126     (with-temp-buffer
 127       (apply #'call-process pgg-gpg-program nil t nil args)
 128       (goto-char (point-min))
 129       (if (re-search-forward "^\\(sec\\|pub\\):"  nil t)
 130           (substring
 131            (nth 3 (split-string
 132                    (buffer-substring (match-end 0)
 133                                      (progn (end-of-line)(point)))
 134                    ":")) 8)))))
 135
 136 (luna-define-method pgg-scheme-encrypt-region ((scheme pgg-scheme-gpg)
 137                                                start end recipients)
 138   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 139          (args
 140           `("--batch" "--armor" "--always-trust" "--encrypt"
 141             ,@(if recipients
 142                   (apply #'nconc
 143                          (mapcar (lambda (rcpt)
 144                                    (list "--remote-user" rcpt))
 145                                  (append recipients
 146                                          (if pgg-encrypt-for-me
 147                                              (list pgg-gpg-user-id)))))))))
 148     (pgg-as-lbt start end 'CRLF
 149       (pgg-gpg-process-region start end nil pgg-gpg-program args))
 150     (pgg-process-when-success)))
 151
 152 (luna-define-method pgg-scheme-decrypt-region ((scheme pgg-scheme-gpg)
 153                                                start end)
 154   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 155          (passphrase
 156           (pgg-read-passphrase
 157            (format "GnuPG passphrase for %s: " pgg-gpg-user-id)
 158            (pgg-scheme-lookup-key scheme pgg-gpg-user-id 'encrypt)))
 159          (args '("--batch" "--decrypt")))
 160     (pgg-gpg-process-region start end passphrase pgg-gpg-program args)
 161     (with-current-buffer pgg-errors-buffer
 162       (pgg-gpg-possibly-cache-passphrase passphrase)
 163       (goto-char (point-min))
 164       (re-search-forward "^\\[GNUPG:] DECRYPTION_OKAY\\>" nil t))))
 165
 166 (luna-define-method pgg-scheme-sign-region ((scheme pgg-scheme-gpg)
 167                                             start end &optional cleartext)
 168   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 169          (passphrase
 170           (pgg-read-passphrase
 171            (format "GnuPG passphrase for %s: " pgg-gpg-user-id)
 172            (pgg-scheme-lookup-key scheme pgg-gpg-user-id 'sign)))
 173          (args
 174           (list (if cleartext "--clearsign" "--detach-sign")
 175                 "--armor" "--batch" "--verbose"
 176                 "--local-user" pgg-gpg-user-id))
 177          (inhibit-read-only t)
 178          buffer-read-only)
 179     (pgg-as-lbt start end 'CRLF
 180       (pgg-gpg-process-region start end passphrase pgg-gpg-program args))
 181     (with-current-buffer pgg-errors-buffer
 182       (pgg-gpg-possibly-cache-passphrase passphrase))
 183     (pgg-process-when-success)))
 184
 185 (luna-define-method pgg-scheme-verify-region ((scheme pgg-scheme-gpg)
 186                                               start end &optional signature)
 187   (let ((args '("--batch" "--verify")))
 188     (when (stringp signature)
 189       (setq args (append args (list signature))))
 190     (setq args (append args '("-")))
 191     (pgg-gpg-process-region start end nil pgg-gpg-program args)
 192     (with-current-buffer pgg-errors-buffer
 193       (goto-char (point-min))
 194       (while (re-search-forward "^gpg: " nil t)
 195         (replace-match ""))
 196       (goto-char (point-min))
 197       (prog1 (re-search-forward "^\\[GNUPG:] GOODSIG\\>" nil t)
 198         (goto-char (point-min))
 199         (delete-matching-lines "^warning\\|\\[GNUPG:]")
 200         (set-buffer pgg-output-buffer)
 201         (insert-buffer-substring pgg-errors-buffer)))))
 202
 203 (luna-define-method pgg-scheme-insert-key ((scheme pgg-scheme-gpg))
 204   (let* ((pgg-gpg-user-id (or pgg-gpg-user-id pgg-default-user-id))
 205          (args (list "--batch" "--export" "--armor"
 206                      pgg-gpg-user-id)))
 207     (pgg-gpg-process-region (point)(point) nil pgg-gpg-program args)
 208     (insert-buffer-substring pgg-output-buffer)))
 209
 210 (luna-define-method pgg-scheme-snarf-keys-region ((scheme pgg-scheme-gpg)
 211                                                   start end)
 212   (let ((args '("--import" "--batch" "-")) status)
 213     (pgg-gpg-process-region start end nil pgg-gpg-program args)
 214     (set-buffer pgg-errors-buffer)
 215     (goto-char (point-min))
 216     (when (re-search-forward "^\\[GNUPG:] IMPORT_RES\\>" nil t)
 217       (setq status (buffer-substring (match-end 0)
 218                                      (progn (end-of-line)(point)))
 219             status (vconcat (mapcar #'string-to-int (split-string status))))
 220       (erase-buffer)
 221       (insert (format "Imported %d key(s).
 222 \tArmor contains %d key(s) [%d bad, %d old].\n"
 223                       (+ (aref status 2)
 224                          (aref status 10))
 225                       (aref status 0)
 226                       (aref status 1)
 227                       (+ (aref status 4)
 228                          (aref status 11)))
 229               (if (zerop (aref status 9))
 230                   ""
 231                 "\tSecret keys are imported.\n")))
 232     (append-to-buffer pgg-output-buffer (point-min)(point-max))
 233     (pgg-process-when-success)))
 234
 235 (provide 'pgg-gpg)
 236
 237 ;;; pgg-gpg.el ends here