pgg-pgp.el

   1 ;;; pgg-pgp.el --- PGP 2.* and 6.* support for PGG.
   2
   3 ;; Copyright (C) 1999 Daiki Ueno
   4
   5 ;; Author: Daiki Ueno <ueno@ueda.info.waseda.ac.jp>
   6 ;; Created: 1999/11/02
   7 ;; Keywords: PGP, OpenPGP
   8
   9 ;; This file is part of SEMI (Secure Emacs MIME Interface).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'pgg))
  29
  30 (defgroup pgg-pgp ()
  31   "PGP 2.* and 6.* interface"
  32   :group 'pgg)
  33
  34 (defcustom pgg-pgp-program "pgp"
  35   "PGP 2.* and 6.* executable."
  36   :group 'pgg-pgp
  37   :type 'string)
  38
  39 (defcustom pgg-pgp-shell-file-name "/bin/sh"
  40   "File name to load inferior shells from.  Bourne shell or its equivalent
  41 \(not tcsh) is needed for \"2>\"."
  42   :group 'pgg-pgp
  43   :type 'string)
  44
  45 (defcustom pgg-pgp-shell-command-switch "-c"
  46   "Switch used to have the shell execute its command line argument."
  47   :group 'pgg-pgp
  48   :type 'string)
  49
  50 (defcustom pgg-pgp-extra-args nil
  51   "Extra arguments for every PGP invocation."
  52   :group 'pgg-pgp
  53   :type 'string)
  54
  55 (eval-and-compile
  56   (luna-define-class pgg-scheme-pgp (pgg-scheme))
  57   )
  58
  59 (defvar pgg-pgp-user-id nil
  60   "GnuPG ID of your default identity.")
  61
  62 (defvar pgg-scheme-pgp-instance nil)
  63
  64 ;;;###autoload
  65 (defun pgg-make-scheme-pgp ()
  66   (or pgg-scheme-pgp-instance
  67       (setq pgg-scheme-pgp-instance
  68             (luna-make-entity 'pgg-scheme-pgp))))
  69
  70 (defun pgg-pgp-process-region (start end passphrase program args)
  71   (let* ((errors-file-name
  72           (concat temporary-file-directory
  73                   (make-temp-name "pgg-errors")))
  74          (args
  75           (append args
  76                   pgg-pgp-extra-args
  77                   (list (concat "2>" errors-file-name))))
  78          (shell-file-name pgg-pgp-shell-file-name)
  79          (shell-command-switch pgg-pgp-shell-command-switch)
  80          (output-buffer pgg-output-buffer)
  81          (errors-buffer pgg-errors-buffer)
  82          (process-connection-type nil)
  83          process status exit-status)
  84     (with-current-buffer (get-buffer-create output-buffer)
  85       (buffer-disable-undo)
  86       (erase-buffer))
  87     (when passphrase
  88       (setenv "PGPPASSFD" "0"))
  89     (as-binary-process
  90      (setq process
  91            (apply #'start-process-shell-command "*PGP*" output-buffer
  92                   program args)))
  93     (set-process-sentinel process 'ignore)
  94     (when passphrase
  95       (process-send-string process (concat passphrase "\n")))
  96     (process-send-region process start end)
  97     (process-send-eof process)
  98     (while (eq 'run (process-status process))
  99       (accept-process-output process 5))
 100     (setq status (process-status process)
 101           exit-status (process-exit-status process))
 102     (delete-process process)
 103     (with-current-buffer output-buffer
 104       (pgg-convert-lbt-region (point-min)(point-max) 'LF)
 105
 106       (if (memq status '(stop signal))
 107           (error "%s exited abnormally: '%s'" program exit-status))
 108       (if (= 127 exit-status)
 109           (error "%s could not be found" program))
 110
 111       (set-buffer (get-buffer-create errors-buffer))
 112       (buffer-disable-undo)
 113       (erase-buffer)
 114       (insert-file-contents errors-file-name)
 115       (delete-file errors-file-name)
 116
 117       (if (and process (eq 'run (process-status process)))
 118           (interrupt-process process))
 119       )
 120     ))
 121
 122 (luna-define-method lookup-key-string ((scheme pgg-scheme-pgp)
 123                                        string &optional type)
 124   (let ((args (list "+batchmode" "+language=en" "-kv" string)))
 125     (with-current-buffer (get-buffer-create pgg-output-buffer)
 126       (buffer-disable-undo)
 127       (erase-buffer)
 128       (apply #'call-process pgg-pgp-program nil t args)
 129       (goto-char (point-min))
 130       (cond
 131        ((re-search-forward "^pub\\s +[0-9]+/" nil t);PGP 2.*
 132         (buffer-substring (point)(+ 8 (point))))
 133        ((re-search-forward "^Type" nil t);PGP 6.*
 134         (beginning-of-line 2)
 135         (substring
 136          (nth 2 (split-string
 137                  (buffer-substring (point)
 138                                    (progn (end-of-line) (point)))
 139                  ))
 140          2))))
 141     ))
 142
 143 (luna-define-method encrypt-region ((scheme pgg-scheme-pgp)
 144                                     start end recipients)
 145   (let* ((pgg-pgp-user-id pgg-default-user-id)
 146          (args
 147           `("+encrypttoself=off +verbose=1" "+batchmode"
 148             "+language=us" "-fate"
 149             ,@(if recipients
 150                   (mapcar (lambda (rcpt) (concat "\"" rcpt "\""))
 151                           (append recipients
 152                                   (if pgg-encrypt-for-me
 153                                       (list pgg-pgp-user-id))))))
 154           ))
 155     (pgg-pgp-process-region start end nil
 156                             pgg-pgp-program args)
 157     (pgg-process-when-success nil)
 158     ))
 159
 160 (luna-define-method decrypt-region ((scheme pgg-scheme-pgp)
 161                                     start end)
 162   (let* ((pgg-pgp-user-id pgg-default-user-id)
 163          (passphrase
 164           (pgg-read-passphrase
 165            (format "PGP passphrase for %s: " pgg-pgp-user-id)
 166            (luna-send scheme 'lookup-key-string
 167                       scheme pgg-pgp-user-id 'encrypt)))
 168          (args
 169           '("+verbose=1" "+batchmode" "+language=us" "-f")))
 170     (pgg-pgp-process-region start end passphrase
 171                             pgg-pgp-program args)
 172     (pgg-process-when-success nil)
 173     ))
 174
 175 (luna-define-method sign-region ((scheme pgg-scheme-pgp)
 176                                  start end &optional clearsign)
 177   (let* ((pgg-pgp-user-id pgg-default-user-id)
 178          (passphrase
 179           (pgg-read-passphrase
 180            (format "PGP passphrase for %s: " pgg-pgp-user-id)
 181            (luna-send scheme 'lookup-key-string
 182                       scheme pgg-pgp-user-id 'sign)))
 183          (args
 184           (list (if clearsign "-fast" "-fbast")
 185                 "+verbose=1" "+language=us" "+batchmode"
 186                 "-u" pgg-pgp-user-id)))
 187     (pgg-pgp-process-region start end passphrase
 188                             pgg-pgp-program args)
 189     (pgg-process-when-success
 190       (goto-char (point-min))
 191       (when (re-search-forward "^-+BEGIN PGP" nil t);XXX
 192         (let ((packet
 193                (cdr (assq 2 (pgg-parse-armor-region
 194                              (progn (beginning-of-line 2)
 195                                     (point))
 196                              (point-max))))))
 197           (pgg-add-passphrase-cache
 198            (cdr (assq 'key-identifier packet))
 199            passphrase))))
 200     ))
 201
 202 (luna-define-method verify-region ((scheme pgg-scheme-pgp)
 203                                    start end &optional signature)
 204   (let* ((basename (expand-file-name "pgg" temporary-file-directory))
 205          (orig-file (make-temp-name basename))
 206          (args '("+verbose=1" "+batchmode" "+language=us"))
 207          (orig-mode (default-file-modes)))
 208     (unwind-protect
 209         (progn
 210           (set-default-file-modes 448)
 211           (write-region-as-binary start end orig-file)
 212           )
 213       (set-default-file-modes orig-mode))
 214     (when (stringp signature)
 215       (copy-file signature (setq signature (concat orig-file ".asc")))
 216       (setq args (append args (list signature orig-file)))
 217       )
 218     (pgg-pgp-process-region (point-min)(point-max) nil
 219                             pgg-pgp-program args)
 220     (delete-file orig-file)
 221     (if signature (delete-file signature))
 222     (pgg-process-when-success
 223       (goto-char (point-min))
 224       (let ((case-fold-search t))
 225         (while (re-search-forward "^warning: " nil t)
 226           (delete-region (match-beginning 0)
 227                          (progn (beginning-of-line 2) (point)))))
 228       (goto-char (point-min))
 229       (when (re-search-forward "^\\.$" nil t)
 230         (delete-region (point-min)
 231                        (progn (beginning-of-line 2)
 232                               (point)))))
 233     ))
 234
 235 (luna-define-method insert-key ((scheme pgg-scheme-pgp))
 236   (let* ((pgg-pgp-user-id pgg-default-user-id)
 237          (args
 238           (list "+verbose=1" "+batchmode" "+language=us" "-kxaf"
 239                 (concat "\"" pgg-pgp-user-id "\""))))
 240     (pgg-pgp-process-region (point)(point) nil
 241                              pgg-pgp-program args)
 242     (insert-buffer-substring pgg-output-buffer)
 243     ))
 244
 245 (luna-define-method snarf-keys-region ((scheme pgg-scheme-pgp)
 246                                        start end)
 247   (let* ((pgg-pgp-user-id pgg-default-user-id)
 248          (basename (expand-file-name "pgg" temporary-file-directory))
 249          (key-file (make-temp-name basename))
 250          (args
 251           (list "+verbose=1" "+batchmode" "+language=us" "-kaf"
 252                 key-file)))
 253     (write-region-as-raw-text-CRLF start end key-file)
 254     (pgg-pgp-process-region start end nil
 255                             pgg-pgp-program args)
 256     (delete-file key-file)
 257     (pgg-process-when-success nil)
 258     ))
 259
 260 (provide 'pgg-pgp)
 261
 262 ;;; pgg-pgp.el ends here