pgg-pgp5.el

   1 ;;; pgg-pgp5.el --- PGP 5.* support for PGG.
   2
   3 ;; Copyright (C) 1999 Daiki Ueno
   4
   5 ;; Author: Daiki Ueno <ueno@ueda.info.waseda.ac.jp>
   6 ;; Created: 1999/11/02
   7 ;; Keywords: PGP, OpenPGP
   8
   9 ;; This file is part of SEMI (Secure Emacs MIME Interface).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'pgg))
  29
  30 (defgroup pgg-pgp5 ()
  31   "PGP 5.* interface"
  32   :group 'pgg)
  33
  34 (defcustom pgg-pgp5-pgpe-program "pgpe"
  35   "PGP 5.* 'pgpe' executable."
  36   :group 'pgg-pgp5
  37   :type 'string)
  38
  39 (defcustom pgg-pgp5-pgps-program "pgps"
  40   "PGP 5.* 'pgps' executable."
  41   :group 'pgg-pgp5
  42   :type 'string)
  43
  44 (defcustom pgg-pgp5-pgpk-program "pgpk"
  45   "PGP 5.* 'pgpk' executable."
  46   :group 'pgg-pgp5
  47   :type 'string)
  48
  49 (defcustom pgg-pgp5-pgpv-program "pgpv"
  50   "PGP 5.* 'pgpv' executable."
  51   :group 'pgg-pgp5
  52   :type 'string)
  53
  54 (defcustom pgg-pgp5-shell-file-name "/bin/sh"
  55   "File name to load inferior shells from.  Bourne shell or its equivalent
  56 \(not tcsh) is needed for \"2>\"."
  57   :group 'pgg-pgp5
  58   :type 'string)
  59
  60 (defcustom pgg-pgp5-shell-command-switch "-c"
  61   "Switch used to have the shell execute its command line argument."
  62   :group 'pgg-pgp5
  63   :type 'string)
  64
  65 (defcustom pgg-pgp5-extra-args nil
  66   "Extra arguments for every PGP invocation."
  67   :group 'pgg-pgp5
  68   :type 'string)
  69
  70 (eval-and-compile
  71   (luna-define-class pgg-scheme-pgp5 (pgg-scheme))
  72   )
  73
  74 (defvar pgg-pgp5-user-id nil
  75   "GnuPG ID of your default identity.")
  76
  77 (defvar pgg-scheme-pgp5-instance nil)
  78
  79 ;;;###autoload
  80 (defun pgg-make-scheme-pgp5 ()
  81   (or pgg-scheme-pgp5-instance
  82       (setq pgg-scheme-pgp5-instance
  83             (luna-make-entity 'pgg-scheme-pgp5))))
  84
  85 (defun pgg-pgp5-process-region (start end passphrase program args)
  86   (let* ((errors-file-name
  87           (concat temporary-file-directory
  88                   (make-temp-name "pgg-errors")))
  89          (args
  90           (append args
  91                   pgg-pgp5-extra-args
  92                   (list (concat "2>" errors-file-name))))
  93          (shell-file-name pgg-pgp5-shell-file-name)
  94          (shell-command-switch pgg-pgp5-shell-command-switch)
  95          (output-buffer pgg-output-buffer)
  96          (errors-buffer pgg-errors-buffer)
  97          (process-connection-type nil)
  98          process status exit-status)
  99     (with-current-buffer (get-buffer-create output-buffer)
 100       (buffer-disable-undo)
 101       (erase-buffer))
 102     (when passphrase
 103       (setenv "PGPPASSFD" "0"))
 104     (as-binary-process
 105      (setq process
 106            (apply #'start-process-shell-command "*PGP*" output-buffer
 107                   program args)))
 108     (set-process-sentinel process 'ignore)
 109     (when passphrase
 110       (process-send-string process (concat passphrase "\n")))
 111     (process-send-region process start end)
 112     (process-send-eof process)
 113     (while (eq 'run (process-status process))
 114       (accept-process-output process 5))
 115     (setq status (process-status process)
 116           exit-status (process-exit-status process))
 117     (delete-process process)
 118     (with-current-buffer output-buffer
 119       (pgg-convert-lbt-region (point-min)(point-max) 'LF)
 120
 121       (if (memq status '(stop signal))
 122           (error "%s exited abnormally: '%s'" program exit-status))
 123       (if (= 127 exit-status)
 124           (error "%s could not be found" program))
 125
 126       (set-buffer (get-buffer-create errors-buffer))
 127       (buffer-disable-undo)
 128       (erase-buffer)
 129       (insert-file-contents errors-file-name)
 130       (delete-file errors-file-name)
 131
 132       (if (and process (eq 'run (process-status process)))
 133           (interrupt-process process))
 134       )
 135     ))
 136
 137 (luna-define-method lookup-key-string ((scheme pgg-scheme-pgp5)
 138                                        string &optional type)
 139   (let ((args (list "+language=en" "-l" string)))
 140     (with-current-buffer (get-buffer-create pgg-output-buffer)
 141       (buffer-disable-undo)
 142       (erase-buffer)
 143       (apply #'call-process pgg-pgp5-pgpk-program  nil t args)
 144       (goto-char (point-min))
 145       (when (re-search-forward "^sec" nil t)
 146         (substring
 147          (nth 2 (split-string
 148                  (buffer-substring (match-end 0)
 149                                    (progn (end-of-line)(point)))
 150                  ))
 151          2)))
 152     ))
 153
 154 (luna-define-method encrypt-region ((scheme pgg-scheme-pgp5)
 155                                     start end recipients)
 156   (let* ((pgg-pgp5-user-id pgg-default-user-id)
 157          (args
 158           `("+NoBatchInvalidKeys=off" "-fat" "+batchmode=1"
 159             ,@(if recipients
 160                   (apply #'append
 161                          (mapcar (lambda (rcpt)
 162                                    (list "-r"
 163                                          (concat "\"" rcpt "\"")))
 164                                  (append recipients
 165                                          (if pgg-encrypt-for-me
 166                                              (list pgg-pgp5-user-id)))))))
 167           ))
 168     (pgg-pgp5-process-region start end nil
 169                              pgg-pgp5-pgpe-program args)
 170     (pgg-process-when-success nil)
 171     ))
 172
 173 (luna-define-method decrypt-region ((scheme pgg-scheme-pgp5)
 174                                     start end)
 175   (let* ((pgg-pgp5-user-id pgg-default-user-id)
 176          (passphrase
 177           (pgg-read-passphrase
 178            (format "PGP passphrase for %s: " pgg-pgp5-user-id)
 179            (luna-send scheme 'lookup-key-string
 180                       scheme pgg-pgp5-user-id 'encrypt)))
 181          (args
 182           '("+verbose=1" "+batchmode=1" "+language=us" "-f")))
 183     (pgg-pgp5-process-region start end passphrase
 184                              pgg-pgp5-pgpv-program args)
 185     (pgg-process-when-success nil)
 186     ))
 187
 188 (luna-define-method sign-region ((scheme pgg-scheme-pgp5)
 189                                  start end &optional clearsign)
 190   (let* ((pgg-pgp5-user-id pgg-default-user-id)
 191          (passphrase
 192           (pgg-read-passphrase
 193            (format "PGP passphrase for %s: " pgg-pgp5-user-id)
 194            (luna-send scheme 'lookup-key-string
 195                       scheme pgg-pgp5-user-id 'sign)))
 196          (args
 197           (list (if clearsign "-fat" "-fbat")
 198                 "+verbose=1" "+language=us" "+batchmode=1"
 199                 "-u" pgg-pgp5-user-id)))
 200     (pgg-pgp5-process-region start end passphrase
 201                              pgg-pgp5-pgps-program args)
 202     (pgg-process-when-success
 203       (when (re-search-forward "^-+BEGIN PGP SIGNATURE" nil t);XXX
 204         (let ((packet
 205                (cdr (assq 2 (pgg-parse-armor-region
 206                              (progn (beginning-of-line 2)
 207                                     (point))
 208                              (point-max))))))
 209           (pgg-add-passphrase-cache
 210            (cdr (assq 'key-identifier packet))
 211            passphrase))))
 212     ))
 213
 214 (luna-define-method verify-region ((scheme pgg-scheme-pgp5)
 215                                    start end &optional signature)
 216   (let* ((basename (expand-file-name "pgg" temporary-file-directory))
 217          (orig-file (make-temp-name basename))
 218          (args '("+verbose=1" "+batchmode=1" "+language=us")))
 219     (write-region-as-binary start end orig-file)
 220     (when (stringp signature)
 221       (copy-file signature (setq signature (concat orig-file ".asc")))
 222       (setq args (append args (list signature)))
 223       )
 224     (pgg-pgp5-process-region (point-min)(point-max) nil
 225                              pgg-pgp5-pgpv-program args)
 226     (delete-file orig-file)
 227     (if signature (delete-file signature))
 228     (pgg-process-when-success nil)
 229     ))
 230
 231 (luna-define-method insert-key ((scheme pgg-scheme-pgp5))
 232   (let* ((pgg-pgp5-user-id pgg-default-user-id)
 233          (args
 234           (list "+verbose=1" "+batchmode=1" "+language=us" "-x"
 235                 (concat "\"" pgg-pgp5-user-id "\""))))
 236     (pgg-pgp5-process-region (point)(point) nil
 237                              pgg-pgp5-pgpk-program args)
 238     (insert-buffer-substring pgg-output-buffer)
 239     ))
 240
 241 (luna-define-method snarf-keys-region ((scheme pgg-scheme-pgp5)
 242                                        start end)
 243   (let* ((pgg-pgp5-user-id pgg-default-user-id)
 244          (basename (expand-file-name "pgg" temporary-file-directory))
 245          (key-file (make-temp-name basename))
 246          (args
 247           (list "+verbose=1" "+batchmode=1" "+language=us" "-a"
 248                 key-file)))
 249     (write-region-as-raw-text-CRLF start end key-file)
 250     (pgg-pgp5-process-region start end nil
 251                              pgg-pgp5-pgpk-program args)
 252     (delete-file key-file)
 253     (pgg-process-when-success nil)
 254     ))
 255
 256 (provide 'pgg-pgp5)
 257
 258 ;;; pgg-pgp5.el ends here