pgg.el

   1 ;;; pgg.el --- glue for the various PGP implementations.
   2
   3 ;; Copyright (C) 1999 Daiki Ueno
   4
   5 ;; Author: Daiki Ueno <ueno@ueda.info.waseda.ac.jp>
   6 ;; Created: 1999/10/28
   7 ;; Keywords: PGP
   8
   9 ;; This file is part of SEMI (Secure Emacs MIME Interface).
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (require 'calist)
  29
  30 (eval-and-compile (require 'luna))
  31
  32 (require 'pgg-def)
  33 (require 'pgg-parse)
  34
  35 (eval-when-compile
  36   (ignore-errors
  37     (require 'w3)
  38     (require 'url)))
  39
  40 (in-calist-package 'pgg)
  41
  42 (defun pgg-field-match-method-with-containment
  43   (calist field-type field-value)
  44   (let ((s-field (assq field-type calist)))
  45     (cond ((null s-field)
  46            (cons (cons field-type field-value) calist)
  47            )
  48           ((memq (cdr s-field) field-value)
  49            calist))))
  50
  51 (define-calist-field-match-method 'signature-version
  52   #'pgg-field-match-method-with-containment)
  53
  54 (define-calist-field-match-method 'symmetric-key-algorithm
  55   #'pgg-field-match-method-with-containment)
  56
  57 (define-calist-field-match-method 'public-key-algorithm
  58   #'pgg-field-match-method-with-containment)
  59
  60 (define-calist-field-match-method 'hash-algorithm
  61   #'pgg-field-match-method-with-containment)
  62
  63 (defvar pgg-verify-condition nil
  64   "Condition-tree about which PGP implementation is used for verifying.")
  65
  66 (defvar pgg-decrypt-condition nil
  67   "Condition-tree about which PGP implementation is used for decrypting.")
  68
  69 (ctree-set-calist-strictly
  70  'pgg-verify-condition
  71  '((signature-version 3)(public-key-algorithm RSA)(hash-algorithm MD5)
  72    (scheme . pgp)))
  73
  74 (ctree-set-calist-strictly
  75  'pgg-decrypt-condition
  76  '((public-key-algorithm RSA)(symmetric-key-algorithm IDEA)
  77    (scheme . pgp)))
  78
  79 (ctree-set-calist-strictly
  80  'pgg-verify-condition
  81  '((signature-version 3 4)
  82    (public-key-algorithm RSA ELG DSA)
  83    (hash-algorithm MD5 SHA1 RIPEMD160)
  84    (scheme . pgp5)))
  85
  86 (ctree-set-calist-strictly
  87  'pgg-decrypt-condition
  88  '((public-key-algorithm RSA ELG DSA)
  89    (symmetric-key-algorithm 3DES CAST5 IDEA)
  90    (scheme . pgp5)))
  91
  92 (ctree-set-calist-strictly
  93  'pgg-verify-condition
  94  '((signature-version 3 4)
  95    (public-key-algorithm ELG-E DSA ELG)
  96    (hash-algorithm MD5 SHA1 RIPEMD160)
  97    (scheme . gpg)))
  98
  99 (ctree-set-calist-strictly
 100  'pgg-decrypt-condition
 101  '((public-key-algorithm ELG-E DSA ELG)
 102    (symmetric-key-algorithm 3DES CAST5 BLOWFISH TWOFISH)
 103    (scheme . gpg)))
 104
 105 ;;; @ definition of the implementation scheme
 106 ;;;
 107
 108 (eval-and-compile
 109   (luna-define-class pgg-scheme ())
 110
 111   (luna-define-internal-accessors 'pgg-scheme)
 112   )
 113
 114 (luna-define-generic lookup-key-string (scheme string &optional type)
 115   "Search keys associated with STRING")
 116
 117 (luna-define-generic encrypt-region (scheme start end recipients)
 118   "Encrypt the current region between START and END.")
 119
 120 (luna-define-generic decrypt-region (scheme start end)
 121   "Decrypt the current region between START and END.")
 122
 123 (luna-define-generic sign-region (scheme start end &optional cleartext)
 124   "Make detached signature from text between START and END.")
 125
 126 (luna-define-generic verify-region (scheme start end &optional signature)
 127   "Verify region between START and END
 128 as the detached signature SIGNATURE.")
 129
 130 (luna-define-generic insert-key (scheme)
 131   "Insert public key at point.")
 132
 133 (luna-define-generic snarf-keys-region (scheme start end)
 134   "Add all public keys in region between START
 135 and END to the keyring.")
 136
 137 ;;; @ interface functions
 138 ;;;
 139
 140 (defvar pgg-fetch-key-function (function pgg-fetch-key-with-w3))
 141
 142 (defmacro pgg-make-scheme (scheme)
 143   `(progn
 144      (require (intern (format "pgg-%s" ,scheme)))
 145      (funcall (intern (format "pgg-make-scheme-%s"
 146                               ,scheme)))))
 147
 148 ;;;###autoload
 149 (defun pgg-encrypt-region (start end rcpts)
 150   (interactive
 151    (list (region-beginning)(region-end)
 152          (split-string (read-string "Recipients: ") "[ \t,]+")))
 153   (let* ((entity (pgg-make-scheme pgg-default-scheme))
 154          (status (luna-send entity 'encrypt-region
 155                             entity start end rcpts)))
 156     (when (interactive-p)
 157       (if status
 158           (progn
 159             (delete-region start end)
 160             (insert-buffer-substring pgg-output-buffer))
 161         (with-output-to-temp-buffer pgg-echo-buffer
 162           (set-buffer standard-output)
 163           (insert-buffer-substring pgg-errors-buffer))))
 164     status))
 165
 166 ;;;###autoload
 167 (defun pgg-decrypt-region (start end)
 168   (interactive "r")
 169   (let* ((packet (cdr (assq 1 (pgg-parse-armor-region start end))))
 170          (scheme
 171           (or pgg-scheme
 172               (cdr (assq 'scheme
 173                          (progn
 174                            (in-calist-package 'pgg)
 175                            (ctree-match-calist pgg-decrypt-condition
 176                                                packet))))
 177               pgg-default-scheme))
 178          (entity (pgg-make-scheme scheme))
 179          (status (luna-send entity 'decrypt-region entity start end)))
 180     (when (interactive-p)
 181       (if status
 182           (progn
 183             (delete-region start end)
 184             (insert-buffer-substring pgg-output-buffer))
 185         (with-output-to-temp-buffer pgg-echo-buffer
 186           (set-buffer standard-output)
 187           (insert-buffer-substring pgg-errors-buffer))))
 188     status))
 189
 190 ;;;###autoload
 191 (defun pgg-sign-region (start end &optional cleartext)
 192   (interactive "r")
 193   (let* ((entity (pgg-make-scheme pgg-default-scheme))
 194          (status (luna-send entity 'sign-region
 195                             entity start end
 196                             (or (interactive-p) cleartext))))
 197     (when (interactive-p)
 198       (if status
 199           (progn
 200             (delete-region start end)
 201             (insert-buffer-substring pgg-output-buffer))
 202         (with-output-to-temp-buffer pgg-echo-buffer
 203           (set-buffer standard-output)
 204           (insert-buffer-substring pgg-errors-buffer))))
 205     status))
 206
 207 ;;;###autoload
 208 (defun pgg-verify-region (start end &optional signature fetch)
 209   (interactive "r")
 210   (let* ((packet
 211           (if (null signature) nil
 212             (with-temp-buffer
 213               (buffer-disable-undo)
 214               (set-buffer-multibyte nil)
 215               (insert-file-contents signature)
 216               (cdr (assq 2 (pgg-decode-armor-region (point-min)(point-max))))
 217               )))
 218          (scheme
 219           (or pgg-scheme
 220               (cdr (assq 'scheme
 221                          (progn
 222                            (in-calist-package 'pgg)
 223                            (ctree-match-calist pgg-verify-condition
 224                                                packet))))
 225               pgg-default-scheme))
 226          (entity (pgg-make-scheme scheme))
 227          (key (cdr (assq 'key-identifier packet)))
 228          keyserver
 229          status)
 230     (and (stringp key)
 231          (setq key (concat "0x" (pgg-truncate-key-identifier key)))
 232          (null (let ((pgg-scheme scheme))
 233                  (pgg-lookup-key-string key)))
 234          (or fetch (interactive-p))
 235          (y-or-n-p (format "Key %s not found; attempt to fetch? " key))
 236          (setq keyserver
 237                (or (cdr (assq 'preferred-key-server packet))
 238                    pgg-default-keyserver-address))
 239          (pgg-fetch-key keyserver key))
 240     (setq status (luna-send entity 'verify-region
 241                             entity start end signature))
 242     (when (interactive-p)
 243       (with-output-to-temp-buffer pgg-echo-buffer
 244         (set-buffer standard-output)
 245         (insert-buffer-substring
 246          (if status pgg-output-buffer pgg-errors-buffer))
 247         ))
 248     status))
 249
 250 ;;;###autoload
 251 (defun pgg-insert-key ()
 252   (interactive)
 253   (let ((entity (pgg-make-scheme (or pgg-scheme pgg-default-scheme))))
 254     (luna-send entity 'insert-key entity)))
 255
 256 ;;;###autoload
 257 (defun pgg-snarf-keys-region (start end)
 258   (interactive "r")
 259   (let* ((entity (pgg-make-scheme (or pgg-scheme pgg-default-scheme)))
 260          (status (luna-send entity 'snarf-keys-region entity start end)))
 261     (when (interactive-p)
 262       (with-output-to-temp-buffer pgg-echo-buffer
 263         (set-buffer standard-output)
 264         (insert-buffer-substring
 265          (if status pgg-output-buffer pgg-errors-buffer))
 266         ))
 267     status))
 268
 269 (defun pgg-lookup-key-string (string &optional type)
 270   (let ((entity (pgg-make-scheme (or pgg-scheme pgg-default-scheme))))
 271     (luna-send entity 'lookup-key-string entity string type)))
 272
 273 (defvar pgg-insert-url-function  (function pgg-insert-url-with-w3))
 274
 275 (defun pgg-insert-url-with-w3 (url)
 276   (require 'w3)
 277   (require 'url)
 278   (let (buffer-file-name)
 279     (url-insert-file-contents url)))
 280
 281 (defvar pgg-insert-url-extra-arguments nil)
 282 (defvar pgg-insert-url-program nil)
 283
 284 (defun pgg-insert-url-with-program (url)
 285   (let ((args (copy-sequence pgg-insert-url-extra-arguments))
 286         process)
 287     (insert
 288      (with-temp-buffer
 289        (setq process
 290              (apply #'start-process " *PGG url*" (current-buffer)
 291                     pgg-insert-url-program (nconc args (list url))))
 292        (set-process-sentinel process #'ignore)
 293        (while (eq 'run (process-status process))
 294          (accept-process-output process 5))
 295        (delete-process process)
 296        (if (and process (eq 'run (process-status process)))
 297            (interrupt-process process))
 298        (buffer-string)))
 299     ))
 300
 301 (defun pgg-fetch-key (keyserver key)
 302   "Attempt to fetch a key for addition to PGP or GnuPG keyring."
 303   (with-current-buffer (get-buffer-create pgg-output-buffer)
 304     (buffer-disable-undo)
 305     (erase-buffer)
 306     (let ((proto (if (string-match "^[a-zA-Z\\+\\.\\\\-]+:" keyserver)
 307                      (substring keyserver 0 (1- (match-end 0))))))
 308       (save-excursion
 309         (funcall pgg-insert-url-function
 310                  (if proto keyserver
 311                    (format "http://%s:11371/pks/lookup?op=get&search=%s"
 312                            keyserver key))))
 313       (when (re-search-forward "^-+BEGIN" nil 'last)
 314         (delete-region (point-min) (match-beginning 0))
 315         (when (re-search-forward "^-+END" nil t)
 316           (delete-region (progn (end-of-line) (point))
 317                          (point-max)))
 318         (insert "\n")
 319         (with-temp-buffer
 320           (insert-buffer-substring pgg-output-buffer)
 321           (pgg-snarf-keys-region (point-min)(point-max))))
 322       )))
 323
 324
 325 ;;; @ utility functions
 326 ;;;
 327
 328 (defvar pgg-passphrase-cache-expiry 16)
 329 (defvar pgg-passphrase-cache (make-vector 7 0))
 330
 331 (defvar pgg-read-passphrase nil)
 332 (defun pgg-read-passphrase (prompt &optional key)
 333   (if (not pgg-read-passphrase)
 334       (if (functionp 'read-passwd)
 335           (setq pgg-read-passphrase 'read-passwd)
 336         (if (load "passwd" t)
 337             (setq pgg-read-passphrase 'read-passwd)
 338           (autoload 'ange-ftp-read-passwd "ange-ftp")
 339           (setq pgg-read-passphrase 'ange-ftp-read-passwd))))
 340   (or (and key (setq key (pgg-truncate-key-identifier key))
 341            (symbol-value (intern-soft key pgg-passphrase-cache)))
 342       (funcall pgg-read-passphrase prompt)))
 343
 344 (defun pgg-add-passphrase-cache (key passphrase)
 345   (setq key (pgg-truncate-key-identifier key))
 346   (set (intern key pgg-passphrase-cache)
 347        passphrase)
 348   (run-at-time pgg-passphrase-cache-expiry nil
 349                #'pgg-remove-passphrase-cache
 350                key))
 351
 352 (defun pgg-remove-passphrase-cache (key)
 353   (unintern key pgg-passphrase-cache))
 354
 355 (defmacro pgg-convert-lbt-region (start end lbt)
 356   `(let ((pgg-conversion-end (set-marker (make-marker) ,end)))
 357      (goto-char ,start)
 358      (case ,lbt
 359        (CRLF
 360         (while (progn
 361                  (end-of-line)
 362                  (> (marker-position pgg-conversion-end) (point)))
 363           (insert "\r")
 364           (forward-line 1)))
 365        (LF
 366         (while (re-search-forward "\r$" pgg-conversion-end t)
 367           (replace-match ""))))
 368      ))
 369
 370 (put 'pgg-as-lbt 'lisp-indent-function 3)
 371
 372 (defmacro pgg-as-lbt (start end lbt &rest body)
 373   `(let ((inhibit-read-only t)
 374          buffer-read-only
 375          buffer-undo-list)
 376      (pgg-convert-lbt-region ,start ,end ,lbt)
 377      (let ((,end (point)))
 378        ,@body)
 379      (push nil buffer-undo-list)
 380      (undo)))
 381
 382
 383 ;;; @ postprocess macros
 384 ;;;
 385
 386 (put 'pgg-process-when-success 'lisp-indent-function 0)
 387
 388 (defmacro pgg-process-when-success (&rest body)
 389   `(with-current-buffer pgg-output-buffer
 390      (if (zerop (buffer-size)) nil ,@body t)))
 391
 392 (provide 'pgg)
 393
 394 ;;; pgg.el ends here