elmo/elmo-dop.el

   1 ;;; elmo-dop.el -- Modules for Disconnected Operations on ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'elmo)
  33 (require 'elmo-vars)
  34 (require 'elmo-msgdb)
  35 (require 'elmo-util)
  36 (require 'elmo-localdir)
  37
  38 ;; global variable.
  39 (defvar elmo-dop-queue nil
  40   "A list of (folder-name function-to-be-called argument-list).
  41 Automatically loaded/saved.")
  42
  43 (defmacro elmo-make-dop-queue (fname method arguments)
  44   "Make a dop queue."
  45   (` (vector (, fname) (, method) (, arguments))))
  46
  47 (defmacro elmo-dop-queue-fname (queue)
  48   "Return the folder name string of the QUEUE."
  49   (` (aref (, queue) 0)))
  50
  51 (defmacro elmo-dop-queue-method (queue)
  52   "Return the method symbol of the QUEUE."
  53   (` (aref (, queue) 1)))
  54
  55 (defmacro elmo-dop-queue-arguments (queue)
  56   "Return the arguments of the QUEUE."
  57   (` (aref (, queue) 2)))
  58
  59 (defun elmo-dop-queue-append (folder method arguments)
  60   "Append to disconnected operation queue."
  61   (let ((queue (elmo-make-dop-queue (elmo-folder-name-internal folder)
  62                                     method arguments)))
  63     (setq elmo-dop-queue (nconc elmo-dop-queue (list queue)))))
  64
  65 (defun elmo-dop-queue-flush (&optional force)
  66   "Flush disconnected operations.
  67 If optional argument FORCE is non-nil, try flushing all operation queues
  68 even an operation concerns the unplugged folder."
  69   (elmo-dop-queue-merge)
  70   (let ((queue elmo-dop-queue)
  71         (count 0)
  72         folder
  73         len)
  74     ;; obsolete
  75     (unless (or (null queue)
  76                 (vectorp (car queue)))
  77       (when (y-or-n-p "Saved queue is old version(2.4). Clear all pending operations? ")
  78         (setq elmo-dop-queue nil)
  79         (message "All pending operations are cleared.")
  80         (elmo-dop-queue-save)))
  81     (setq count (length queue))
  82     (when (> count 0)
  83       (if (elmo-y-or-n-p
  84            (format "%d pending operation(s) exists.  Perform now? " count)
  85            (not elmo-dop-flush-confirm) t)
  86           (progn
  87             (message "")
  88             (sit-for 0)
  89             (let ((queue elmo-dop-queue)
  90                   (performed 0)
  91                   (i 0)
  92                   (num (length elmo-dop-queue))
  93                   folder func failure)
  94               (while queue
  95                 ;; now perform pending processes.
  96                 (setq failure nil)
  97                 (setq i (+ 1 i))
  98                 (message "Flushing queue....%d/%d." i num)
  99                 (condition-case err
 100                     (progn
 101                       (apply (elmo-dop-queue-method (car queue))
 102                              (prog1
 103                                  (setq folder
 104                                        (elmo-make-folder
 105                                         (elmo-dop-queue-fname (car queue))))
 106                                (elmo-folder-open folder))
 107                              (elmo-dop-queue-arguments (car queue)))
 108                       (elmo-folder-close folder))
 109                   (quit  (setq failure t))
 110                   (error (setq failure err)))
 111                 (if failure
 112                     ();
 113                   (setq elmo-dop-queue (delq (car queue) elmo-dop-queue))
 114                   (setq performed (+ 1 performed)))
 115                 (setq queue (cdr queue)))
 116               (message "%d/%d operation(s) are performed successfully."
 117                        performed num)
 118               (sit-for 0) ;
 119               (elmo-dop-queue-save)))
 120         (if (elmo-y-or-n-p "Clear all pending operations? "
 121                            (not elmo-dop-flush-confirm) t)
 122             (progn
 123               (setq elmo-dop-queue nil)
 124               (message "All pending operations are cleared.")
 125               (elmo-dop-queue-save))
 126           (message "")))
 127       count)))
 128
 129 (defvar elmo-dop-merge-funcs nil)
 130 (defun elmo-dop-queue-merge ()
 131   ;; XXXX Not implemented yet.
 132   )
 133
 134 ;;; dop spool folder
 135 (defmacro elmo-dop-spool-folder (folder)
 136   "Return a spool folder for disconnected operations
 137 which is corresponded to the FOLDER."
 138   (` (elmo-make-folder
 139       (concat "+" (expand-file-name "spool" (elmo-folder-msgdb-path
 140                                              (, folder)))))))
 141
 142 (defun elmo-dop-spool-folder-append-buffer (folder)
 143   "Append current buffer content to the dop spool folder.
 144 FOLDER is the folder structure.
 145 Return a message number."
 146   (setq folder (elmo-dop-spool-folder folder))
 147   (let ((new-number (1+ (car (elmo-folder-status folder)))))
 148     (unless (elmo-folder-exists-p folder)
 149       (elmo-folder-create folder))
 150     ;; dop folder is a localdir folder.
 151     (write-region-as-binary (point-min) (point-max)
 152                           (expand-file-name
 153                            (int-to-string new-number)
 154                            (elmo-localdir-folder-directory-internal folder))
 155                           nil 'no-msg)
 156     new-number))
 157
 158
 159 (defun elmo-dop-spool-folder-list-messages (folder)
 160   "List messages in the dop spool folder.
 161 FOLDER is the folder structure."
 162   (setq folder (elmo-dop-spool-folder folder))
 163   (if (elmo-folder-exists-p folder)
 164       (elmo-folder-list-messages folder)))
 165
 166 (defun elmo-dop-list-deleting-messages (folder)
 167   "List messages which are on the deleting queue for the folder.
 168 FOLDER is the folder structure."
 169   (let (messages)
 170     (dolist (queue elmo-dop-queue)
 171       (if (and (string= (elmo-dop-queue-fname queue)
 172                         (elmo-folder-name-internal folder))
 173                (eq (elmo-dop-queue-method queue)
 174                    'elmo-folder-delete-messages-dop-delayed))
 175           (setq messages (nconc messages
 176                                 (mapcar
 177                                  'car
 178                                  (car (elmo-dop-queue-arguments queue)))))))))
 179
 180 ;;; DOP operations.
 181 (defsubst elmo-folder-append-buffer-dop (folder unread &optional number)
 182   (elmo-dop-queue-append
 183    folder 'elmo-folder-append-buffer-dop-delayed
 184    (list unread
 185          (elmo-dop-spool-folder-append-buffer
 186           folder)
 187          number)))
 188
 189 (defsubst elmo-folder-delete-messages-dop (folder numbers)
 190   (elmo-dop-queue-append folder 'elmo-folder-delete-messages-dop-delayed
 191                          (list
 192                           (mapcar
 193                            (lambda (number)
 194                              (cons number (elmo-message-field
 195                                            folder number 'message-id)))
 196                            numbers)))
 197   t)
 198
 199 (defsubst elmo-message-encache-dop (folder number)
 200   (elmo-dop-queue-append folder 'elmo-message-encache (list number)))
 201
 202 (defsubst elmo-create-folder-dop (folder)
 203   (elmo-dop-queue-append folder 'elmo-folder-create nil))
 204
 205 (defsubst elmo-folder-mark-as-read-dop (folder numbers)
 206   (elmo-dop-queue-append folder 'elmo-folder-mark-as-read (list numbers)))
 207
 208 (defsubst elmo-folder-unmark-read-dop (folder numbers)
 209   (elmo-dop-queue-append folder 'elmo-folder-unmark-read (list numbers)))
 210
 211 (defsubst elmo-folder-mark-as-important-dop (folder numbers)
 212   (elmo-dop-queue-append folder 'elmo-folder-mark-as-important (list numbers)))
 213
 214 (defsubst elmo-folder-unmark-important-dop (folder numbers)
 215   (elmo-dop-queue-append folder 'elmo-folder-unmark-important (list numbers)))
 216
 217 ;;; Execute as subsutitute for plugged operation.
 218 (defun elmo-folder-status-dop (folder)
 219   (let* ((number-alist (elmo-msgdb-number-load
 220                         (elmo-folder-msgdb-path folder)))
 221          (number-list (mapcar 'car number-alist))
 222          (spool-folder (elmo-dop-spool-folder folder))
 223          spool-length
 224          (i 0)
 225          max-num)
 226     (setq spool-length (length (car (if (elmo-folder-exists-p spool-folder)
 227                                         (elmo-folder-status spool-folder)))))
 228     (setq max-num
 229           (or (nth (max (- (length number-list) 1) 0) number-list)
 230               0))
 231     (cons (+ max-num spool-length) (+ (length number-list) spool-length))))
 232
 233 ;;; Delayed operation (executed at online status).
 234 (defun elmo-folder-append-buffer-dop-delayed (folder unread number set-number)
 235   (let ((spool-folder (elmo-dop-spool-folder folder)))
 236     (with-temp-buffer
 237       (elmo-message-fetch spool-folder number
 238                           (elmo-make-fetch-strategy 'entire)
 239                           nil (current-buffer) 'unread)
 240       (condition-case nil
 241           (elmo-folder-append-buffer folder unread set-number)
 242         (error
 243          ;; Append failed...
 244          (elmo-folder-append-buffer (elmo-make-folder elmo-lost+found-folder)
 245                                     unread set-number)))
 246       (elmo-folder-delete-messages spool-folder (list number))
 247       t)))
 248
 249 (defun elmo-folder-delete-messages-dop-delayed (folder number-alist)
 250   (elmo-folder-delete-messages
 251    folder
 252    ;; messages are deleted only if message-id is not changed.
 253    (mapcar 'car
 254            (elmo-delete-if
 255             (lambda (pair)
 256               (not (string=
 257                     (cdr pair)
 258                     (elmo-message-fetch-field folder (car pair)
 259                                               'message-id))))
 260             number-alist))))
 261
 262 ;;; Util
 263 (defun elmo-dop-msgdb (msgdb)
 264   (list (mapcar (function
 265                  (lambda (x)
 266                    (elmo-msgdb-overview-entity-set-number
 267                     x
 268                     (* -1
 269                        (elmo-msgdb-overview-entity-get-number x)))))
 270                 (nth 0 msgdb))
 271         (mapcar (function
 272                  (lambda (x) (cons
 273                               (* -1 (car x))
 274                               (cdr x))))
 275                 (nth 1 msgdb))
 276         (mapcar (function
 277                  (lambda (x) (cons
 278                               (* -1 (car x))
 279                               (cdr x)))) (nth 2 msgdb))))
 280
 281 (require 'product)
 282 (product-provide (provide 'elmo-dop) (require 'elmo-version))
 283
 284 ;;; elmo-dop.el ends here