elmo/elmo-imap4.el

   1 ;;; elmo-imap4.el --- IMAP4 Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   5 ;; Copyright (C) 2000           OKAZAKI Tetsurou <okazaki@be.to>
   6 ;; Copyright (C) 2000           Daiki Ueno <ueno@unixuser.org>
   7
   8 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;;      OKAZAKI Tetsurou <okazaki@be.to>
  11 ;;      Daiki Ueno <ueno@unixuser.org>
  12 ;; Keywords: mail, net news
  13
  14 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  15
  16 ;; This program is free software; you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation; either version 2, or (at your option)
  19 ;; any later version.
  20 ;;
  21 ;; This program is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25 ;;
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  28 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  29 ;; Boston, MA 02111-1307, USA.
  30 ;;
  31
  32 ;;; Commentary:
  33 ;;
  34 ;; Origin of IMAP parser part is imap.el, included in Gnus.
  35 ;;
  36 ;;    Copyright (C) 1998, 1999, 2000
  37 ;;    Free Software Foundation, Inc.
  38 ;;    Author: Simon Josefsson <jas@pdc.kth.se>
  39 ;;
  40
  41 ;;; Code:
  42 (require 'elmo-vars)
  43 (require 'elmo-util)
  44 (require 'elmo-date)
  45 (require 'elmo-msgdb)
  46 (require 'elmo-cache)
  47 (require 'elmo)
  48 (require 'elmo-net)
  49 (require 'utf7)
  50 (require 'elmo-mime)
  51 (require 'time-stamp)
  52
  53 (eval-when-compile (require 'cl))
  54
  55 (defvar elmo-imap4-disuse-server-flag-mailbox-regexp "^#mh" ; UW imapd
  56   "Regexp to match IMAP4 mailbox names whose message flags on server should be ignored (For STATUS command).")
  57
  58 (defvar elmo-imap4-overview-fetch-chop-length 200
  59   "*Number of overviews to fetch in one request.")
  60
  61 ;; c.f. rfc2683 3.2.1.5 Long Command Lines
  62 ;;
  63 ;; "A client should limit the length of the command lines it generates
  64 ;;  to approximately 1000 octets (including all quoted strings but not
  65 ;;  including literals). If the client is unable to group things into
  66 ;;  ranges so that the command line is within that length, it should
  67 ;;  split the request into multiple commands. The client should use
  68 ;;  literals instead of long quoted strings, in order to keep the command
  69 ;;  length down.
  70 ;;  For its part, a server should allow for a command line of at least
  71 ;;  8000 octets. This provides plenty of leeway for accepting reasonable
  72 ;;  length commands from clients. The server should send a BAD response
  73 ;;  to a command that does not end within the server's maximum accepted
  74 ;;  command length. "
  75
  76 ;; To limit command line length, chop number set.
  77 (defvar elmo-imap4-number-set-chop-length 1000
  78   "*Number of messages to specify as a number-set argument for one request.")
  79
  80 (defvar elmo-imap4-force-login nil
  81   "*Non-nil forces to try 'login' if there is no 'auth' capability in imapd.")
  82
  83 (defvar elmo-imap4-use-select-to-update-status nil
  84   "*Some imapd have to send select command to update status.
  85 \(ex. UW imapd 4.5-BETA?\).  For these imapd, you must set this variable t.")
  86
  87 (defvar elmo-imap4-use-modified-utf7 nil
  88   "*Use mofidied UTF-7 (rfc2060) encoding for IMAP4 folder name.")
  89
  90 (defvar elmo-imap4-use-cache t
  91   "Use cache in imap4 folder.")
  92
  93 (defvar elmo-imap4-extra-namespace-alist
  94   '(("^\\({.*/nntp}\\).*$" . ".")) ; Default is for UW's remote nntp mailbox...
  95   "Extra namespace alist.
  96 A list of cons cell like: (REGEXP . DELIMITER).
  97 REGEXP should have a grouping for namespace prefix.")
  98
  99 (defvar elmo-imap4-disabled-extensions nil
 100   "List of server extensions that are disabled on the client side.")
 101
 102 ;;
 103 ;;; internal variables
 104 ;;
 105 (defvar elmo-imap4-seq-prefix "elmo-imap4")
 106 (defvar elmo-imap4-seqno 0)
 107 (defvar elmo-imap4-use-uid t
 108   "Use UID as message number.")
 109
 110 (defvar elmo-imap4-current-response nil)
 111 (defvar elmo-imap4-status nil)
 112 (defvar elmo-imap4-reached-tag "elmo-imap40")
 113
 114 ;;; buffer local variables
 115 (defvar elmo-imap4-default-hierarchy-delimiter "/")
 116
 117 (defvar elmo-imap4-server-capability nil)
 118 (defvar elmo-imap4-server-namespace nil)
 119
 120 (defvar elmo-imap4-parsing nil) ; indicates parsing.
 121
 122 (defvar elmo-imap4-fetch-callback nil)
 123 (defvar elmo-imap4-fetch-callback-data nil)
 124 (defvar elmo-imap4-status-callback nil)
 125 (defvar elmo-imap4-status-callback-data nil)
 126
 127 (defvar elmo-imap4-server-diff-async-callback nil)
 128 (defvar elmo-imap4-server-diff-async-callback-data nil)
 129
 130 ;;; progress...(no use?)
 131 (defvar elmo-imap4-count-progress nil)
 132 (defvar elmo-imap4-count-progress-message nil)
 133 (defvar elmo-imap4-progress-count nil)
 134
 135 ;;; XXX Temporal implementation
 136 (defvar elmo-imap4-current-msgdb nil)
 137 (defvar elmo-imap4-seen-messages nil)
 138
 139 (defvar elmo-imap4-local-variables
 140   '(elmo-imap4-status
 141     elmo-imap4-current-response
 142     elmo-imap4-seqno
 143     elmo-imap4-parsing
 144     elmo-imap4-reached-tag
 145     elmo-imap4-count-progress
 146     elmo-imap4-count-progress-message
 147     elmo-imap4-progress-count
 148     elmo-imap4-fetch-callback
 149     elmo-imap4-fetch-callback-data
 150     elmo-imap4-status-callback
 151     elmo-imap4-status-callback-data
 152     elmo-imap4-current-msgdb
 153     elmo-imap4-seen-messages))
 154
 155 ;;;;
 156
 157 (defconst elmo-imap4-quoted-specials-list '(?\\ ?\"))
 158
 159 (defconst elmo-imap4-non-atom-char-regex
 160   (eval-when-compile
 161     (concat "[^" "]!#$&'+,./0-9:;<=>?@A-Z[^_`a-z|}~-" "]")))
 162
 163 (defconst elmo-imap4-non-text-char-regex
 164   (eval-when-compile
 165     (concat "[^"
 166             "]\x01-\x09\x0b\x0c\x0e-\x1f\x7f !\"#$%&'()*+,./0-9:;<=>?@A-Z[\\^_`a-z{|}~-"
 167             "]")))
 168
 169 (defconst elmo-imap4-literal-threshold 1024
 170  "Limitation of characters that can be used in a quoted string.")
 171
 172 (defconst elmo-imap4-flag-specs '((important "\\Flagged")
 173                                   (read "\\Seen")
 174                                   (unread "\\Seen" 'remove)
 175                                   (answered "\\Answered")
 176                                   ;; draft-melnikov-imap-keywords-03.txt
 177                                   (forwarded "$Forwarded")
 178                                   (work "$Work")
 179                                   (personal "$Personal")
 180                                   (shouldreply "$ShouldReply")))
 181
 182 (defconst elmo-imap4-folder-name-syntax
 183   `(mailbox
 184     (?: [user "^[A-Za-z0-9]"] (?/ [auth ".+"]))
 185     ,@elmo-net-folder-name-syntax))
 186
 187 ;; For debugging.
 188 (defvar elmo-imap4-debug nil
 189   "Non-nil forces IMAP4 folder as debug mode.
 190 Debug information is inserted in the buffer \"*IMAP4 DEBUG*\"")
 191
 192 (defvar elmo-imap4-debug-inhibit-logging nil)
 193
 194 ;;; ELMO IMAP4 folder
 195 (eval-and-compile
 196   (luna-define-class elmo-imap4-folder (elmo-net-folder)
 197                      (mailbox))
 198   (luna-define-internal-accessors 'elmo-imap4-folder))
 199
 200 ;;; Session
 201 (eval-and-compile
 202   (luna-define-class elmo-imap4-session (elmo-network-session)
 203                      (capability current-mailbox read-only flags))
 204   (luna-define-internal-accessors 'elmo-imap4-session))
 205
 206 (defmacro elmo-imap4-session-capable-p (session capability)
 207   `(and (memq ,capability (elmo-imap4-session-capability-internal ,session))
 208         (not (memq ,capability elmo-imap4-disabled-extensions))))
 209
 210 ;;; MIME-ELMO-IMAP Location
 211 (eval-and-compile
 212   (luna-define-class mime-elmo-imap-location
 213                      (mime-imap-location)
 214                      (folder number rawbuf strategy))
 215   (luna-define-internal-accessors 'mime-elmo-imap-location))
 216
 217 ;;; Debug
 218 (defmacro elmo-imap4-debug (message &rest args)
 219   `(if elmo-imap4-debug
 220        (elmo-imap4-debug-1 ,message ,@args)))
 221
 222 (defun elmo-imap4-debug-1 (message &rest args)
 223   (with-current-buffer (get-buffer-create "*IMAP4 DEBUG*")
 224     (goto-char (point-max))
 225     (if elmo-imap4-debug-inhibit-logging
 226         (insert "NO LOGGING\n")
 227       (insert (apply 'format message args) "\n"))))
 228
 229 (defsubst elmo-imap4-decode-folder-string (string)
 230   (if elmo-imap4-use-modified-utf7
 231       (utf7-decode string 'imap)
 232     string))
 233
 234 (defsubst elmo-imap4-encode-folder-string (string)
 235   (if elmo-imap4-use-modified-utf7
 236       (utf7-encode string 'imap)
 237     string))
 238
 239 ;;; Response
 240
 241 (defmacro elmo-imap4-response-continue-req-p (response)
 242   "Returns non-nil if RESPONSE is '+' response."
 243   `(assq 'continue-req ,response))
 244
 245 (defmacro elmo-imap4-response-ok-p (response)
 246   "Returns non-nil if RESPONSE is an 'OK' response."
 247   `(assq 'ok ,response))
 248
 249 (defmacro elmo-imap4-response-bye-p (response)
 250   "Returns non-nil if RESPONSE is an 'BYE' response."
 251   `(assq 'bye ,response))
 252
 253 (defmacro elmo-imap4-response-garbage-p (response)
 254   "Returns non-nil if RESPONSE is an 'garbage' response."
 255   `(assq 'garbage ,response))
 256
 257 (defmacro elmo-imap4-response-value (response symbol)
 258   "Get value of the SYMBOL from RESPONSE."
 259   `(nth 1 (assq ,symbol ,response)))
 260
 261 (defsubst elmo-imap4-response-value-all (response symbol)
 262   "Get all value of the SYMBOL from RESPONSE."
 263   (let (matched)
 264     (while response
 265       (if (eq (car (car response)) symbol)
 266           (setq matched (nconc matched (nth 1 (car response)))))
 267       (setq response (cdr response)))
 268     matched))
 269
 270 (defmacro elmo-imap4-response-error-text (response)
 271   "Returns text of NO, BAD, BYE response."
 272   `(nth 1 (or (elmo-imap4-response-value ,response 'no)
 273               (elmo-imap4-response-value ,response 'bad)
 274               (elmo-imap4-response-value ,response 'bye))))
 275
 276 (defmacro elmo-imap4-response-bodydetail-text (response)
 277   "Returns text of BODY[section]<partial>."
 278   `(nth 3 (assq 'bodydetail ,response)))
 279
 280 ;;; Session commands.
 281
 282 ;;;(defun elmo-imap4-send-command-wait (session command)
 283 ;;;  "Send COMMAND to the SESSION and wait for response.
 284 ;;;Returns RESPONSE (parsed lisp object) of IMAP session."
 285 ;;;  (elmo-imap4-read-response session
 286 ;;;                         (elmo-imap4-send-command
 287 ;;;                          session
 288 ;;;                          command)))
 289
 290 (defun elmo-imap4-send-command-wait (session command)
 291   "Send COMMAND to the SESSION.
 292 Returns RESPONSE (parsed lisp object) of IMAP session.
 293 If response is not `OK', causes error with IMAP response text."
 294   (elmo-imap4-accept-ok session
 295                         (elmo-imap4-send-command
 296                          session
 297                          command)))
 298
 299 (defun elmo-imap4-send-command (session command)
 300   "Send COMMAND to the SESSION.
 301 Returns a TAG string which is assigned to the COMMAND."
 302   (let* ((command-args (if (listp command)
 303                            command
 304                          (list command)))
 305          (process (elmo-network-session-process-internal session))
 306          cmdstr tag token kind)
 307     (with-current-buffer (process-buffer process)
 308       (setq tag (concat elmo-imap4-seq-prefix
 309                         (number-to-string
 310                          (setq elmo-imap4-seqno (+ 1 elmo-imap4-seqno)))))
 311       (setq cmdstr (concat tag " "))
 312 ;;; No need.
 313 ;;;      (erase-buffer)
 314       (goto-char (point-min))
 315       (when (elmo-imap4-response-bye-p elmo-imap4-current-response)
 316         (elmo-imap4-process-bye session))
 317       (setq elmo-imap4-current-response nil)
 318       (when elmo-imap4-parsing
 319         (message "Waiting for IMAP response...")
 320         (accept-process-output (elmo-network-session-process-internal
 321                                 session))
 322         (message "Waiting for IMAP response...done"))
 323       (setq elmo-imap4-parsing t)
 324       (while (setq token (car command-args))
 325         (cond ((stringp token)   ; formatted
 326                (setq cmdstr (concat cmdstr token)))
 327               ((listp token)     ; unformatted
 328                (setq kind (car token))
 329                (cond ((eq kind 'atom)
 330                       (setq cmdstr (concat cmdstr (nth 1 token))))
 331                      ((eq kind 'quoted)
 332                       (setq cmdstr (concat
 333                                     cmdstr
 334                                     (elmo-imap4-format-quoted (nth 1 token)))))
 335                      ((eq kind 'literal)
 336                       (if (elmo-imap4-session-capable-p session 'literal+)
 337                           ;; rfc2088
 338                           (progn
 339                             (setq cmdstr (concat cmdstr
 340                                                  (format "{%d+}" (nth 2 token))
 341                                                  "\r\n"))
 342                             (process-send-string process cmdstr)
 343                             (setq cmdstr nil))
 344                         (setq cmdstr (concat cmdstr
 345                                              (format "{%d}" (nth 2 token))
 346                                              "\r\n"))
 347                         (process-send-string process cmdstr)
 348                         (setq cmdstr nil)
 349                         (elmo-imap4-accept-continue-req session))
 350                       (cond ((stringp (nth 1 token))
 351                              (setq cmdstr (nth 1 token)))
 352                             ((bufferp (nth 1 token))
 353                              (with-current-buffer (nth 1 token)
 354                                (process-send-region
 355                                 process
 356                                 (point-min)
 357                                 (+ (point-min) (nth 2 token)))))
 358                             (t
 359                              (error "Wrong argument for literal"))))
 360                      (t
 361                       (error "Unknown token kind %s" kind))))
 362               (t
 363                (error "Invalid argument")))
 364         (setq command-args (cdr command-args)))
 365       (elmo-imap4-debug "[%s] <- %s" (format-time-string "%T") cmdstr)
 366       (process-send-string process (concat cmdstr "\r\n"))
 367       tag)))
 368
 369 (defun elmo-imap4-send-string (session string)
 370   "Send STRING to the SESSION."
 371   (with-current-buffer (process-buffer
 372                         (elmo-network-session-process-internal session))
 373     (setq elmo-imap4-current-response nil)
 374     (goto-char (point-min))
 375     (elmo-imap4-debug "[%s] <-- %s" (format-time-string "%T") string)
 376     (process-send-string (elmo-network-session-process-internal session)
 377                          string)
 378     (process-send-string (elmo-network-session-process-internal session)
 379                          "\r\n")))
 380
 381 (defun elmo-imap4-read-response (session tag)
 382   "Read parsed response from SESSION.
 383 TAG is the tag of the command"
 384   (with-current-buffer (process-buffer
 385                         (elmo-network-session-process-internal session))
 386     (while (not (or (string= tag elmo-imap4-reached-tag)
 387                     (elmo-imap4-response-bye-p elmo-imap4-current-response)
 388                     (when (elmo-imap4-response-garbage-p
 389                            elmo-imap4-current-response)
 390                       (message "Garbage response: %s"
 391                                (elmo-imap4-response-value
 392                                 elmo-imap4-current-response
 393                                 'garbage))
 394                       t)))
 395       (when (memq (process-status
 396                    (elmo-network-session-process-internal session))
 397                   '(open run))
 398         (accept-process-output (elmo-network-session-process-internal session)
 399                                1)))
 400     (elmo-imap4-debug "[%s] => %s" (format-time-string "%T") (prin1-to-string elmo-imap4-current-response))
 401     (setq elmo-imap4-parsing nil)
 402     elmo-imap4-current-response))
 403
 404 (defsubst elmo-imap4-read-untagged (process)
 405   (with-current-buffer (process-buffer process)
 406     (while (not elmo-imap4-current-response)
 407       (accept-process-output process 1))
 408     (elmo-imap4-debug "[%s] =>%s" (format-time-string "%T") (prin1-to-string elmo-imap4-current-response))
 409     elmo-imap4-current-response))
 410
 411 (defun elmo-imap4-read-continue-req (session)
 412   "Returns a text following to continue-req in SESSION.
 413 If response is not `+' response, returns nil."
 414   (elmo-imap4-response-value
 415    (elmo-imap4-read-untagged
 416     (elmo-network-session-process-internal session))
 417    'continue-req))
 418
 419 (defun elmo-imap4-process-bye (session)
 420   (with-current-buffer (elmo-network-session-buffer session)
 421     (let ((r elmo-imap4-current-response))
 422       (setq elmo-imap4-current-response nil)
 423       (elmo-network-close-session session)
 424       (signal 'elmo-imap4-bye-error
 425               (list (concat (elmo-imap4-response-error-text r))
 426                     "Try Again")))))
 427
 428 (defun elmo-imap4-accept-continue-req (session)
 429   "Returns non-nil if `+' (continue-req) response is arrived in SESSION.
 430 If response is not `+' response, cause an error."
 431   (let (response)
 432     (setq response
 433           (elmo-imap4-read-untagged
 434            (elmo-network-session-process-internal session)))
 435     (or (elmo-imap4-response-continue-req-p response)
 436         (error "IMAP error: %s"
 437                (or (elmo-imap4-response-error-text response)
 438                    "No continut-req from server.")))))
 439
 440 (defun elmo-imap4-read-ok (session tag)
 441   "Returns non-nil if `OK' response of the command with TAG is arrived
 442 in SESSION. If response is not `OK' response, returns nil."
 443   (elmo-imap4-response-ok-p
 444    (elmo-imap4-read-response session tag)))
 445
 446 (defun elmo-imap4-accept-ok (session tag)
 447   "Accept only `OK' response from SESSION.
 448 If response is not `OK' response, causes error with IMAP response text."
 449   (let ((response (elmo-imap4-read-response session tag)))
 450     (if (elmo-imap4-response-ok-p response)
 451         response
 452       (if (elmo-imap4-response-bye-p response)
 453           (elmo-imap4-process-bye session)
 454         (error "IMAP error: %s"
 455                (or (elmo-imap4-response-error-text response)
 456                    "No `OK' response from server."))))))
 457
 458 ;;; MIME-ELMO-IMAP Location
 459 (luna-define-method mime-imap-location-section-body ((location
 460                                                       mime-elmo-imap-location)
 461                                                      section)
 462   (if (and (stringp section)
 463            (string= section "HEADER"))
 464       ;; Even in the section mode, header fields should be saved to the
 465       ;; raw buffer .
 466       (with-current-buffer (mime-elmo-imap-location-rawbuf-internal location)
 467         (erase-buffer)
 468         (elmo-message-fetch
 469          (mime-elmo-imap-location-folder-internal location)
 470          (mime-elmo-imap-location-number-internal location)
 471          (mime-elmo-imap-location-strategy-internal location)
 472          'unseen
 473          section)
 474         (buffer-string))
 475     (elmo-message-fetch-string
 476      (mime-elmo-imap-location-folder-internal location)
 477      (mime-elmo-imap-location-number-internal location)
 478      (mime-elmo-imap-location-strategy-internal location)
 479      'unseen
 480      section)))
 481
 482
 483 (luna-define-method mime-imap-location-bodystructure
 484   ((location mime-elmo-imap-location))
 485   (elmo-message-fetch-bodystructure
 486    (mime-elmo-imap-location-folder-internal location)
 487    (mime-elmo-imap-location-number-internal location)
 488    (mime-elmo-imap-location-strategy-internal location)))
 489
 490 (luna-define-method mime-imap-location-fetch-entity-p
 491   ((location mime-elmo-imap-location) entity)
 492   (or (not elmo-message-displaying) ; Fetching entity to save or force display.
 493       ;; cache exists
 494       (file-exists-p
 495        (expand-file-name
 496         (mmimap-entity-section (mime-entity-node-id-internal entity))
 497         (elmo-fetch-strategy-cache-path
 498          (mime-elmo-imap-location-strategy-internal location))))
 499       ;; not too large to fetch.
 500       (> elmo-message-fetch-threshold
 501          (or (mime-imap-entity-size-internal entity) 0))))
 502
 503 ;;;
 504
 505 (defun elmo-imap4-session-check (session)
 506   (with-current-buffer (elmo-network-session-buffer session)
 507     (setq elmo-imap4-fetch-callback nil)
 508     (setq elmo-imap4-fetch-callback-data nil))
 509   (elmo-imap4-send-command session "check"))
 510
 511 (defun elmo-imap4-atom-p (string)
 512   "Return t if STRING is an atom defined in rfc2060."
 513   (if (string= string "")
 514       nil
 515     (save-match-data
 516       (not (string-match elmo-imap4-non-atom-char-regex string)))))
 517
 518 (defun elmo-imap4-quotable-p (string)
 519   "Return t if STRING can be formatted as a quoted defined in rfc2060."
 520   (save-match-data
 521     (not (string-match elmo-imap4-non-text-char-regex string))))
 522
 523 (defun elmo-imap4-nil (string)
 524   "Return a list represents the special atom \"NIL\" defined in rfc2060, \
 525 if STRING is nil.
 526 Otherwise return nil."
 527   (if (eq string nil)
 528       (list 'atom "NIL")))
 529
 530 (defun elmo-imap4-atom (string)
 531   "Return a list represents STRING as an atom defined in rfc2060.
 532 Return nil if STRING is not an atom.  See `elmo-imap4-atom-p'."
 533   (if (elmo-imap4-atom-p string)
 534       (list 'atom string)))
 535
 536 (defun elmo-imap4-quoted (string)
 537   "Return a list represents STRING as a quoted defined in rfc2060.
 538 Return nil if STRING can not be formatted as a quoted.  See `elmo-imap4-quotable-p'."
 539   (if (elmo-imap4-quotable-p string)
 540       (list 'quoted string)))
 541
 542 (defun elmo-imap4-literal-1 (string-or-buffer length)
 543   "Internal function for `elmo-imap4-literal' and `elmo-imap4-buffer-literal'.
 544 Return a list represents STRING-OR-BUFFER as a literal defined in rfc2060.
 545 STRING-OR-BUFFER must be an encoded string or a single-byte string or a single-byte buffer.
 546 LENGTH must be the number of octets for STRING-OR-BUFFER."
 547   (list 'literal string-or-buffer length))
 548
 549 (defun elmo-imap4-literal (string)
 550   "Return a list represents STRING as a literal defined in rfc2060.
 551 STRING must be an encoded or a single-byte string."
 552   (elmo-imap4-literal-1 string (length string)))
 553
 554 (defun elmo-imap4-buffer-literal (buffer)
 555   "Return a list represents BUFFER as a literal defined in rfc2060.
 556 BUFFER must be a single-byte buffer."
 557   (elmo-imap4-literal-1 buffer (with-current-buffer buffer
 558                                  (buffer-size))))
 559
 560 (defun elmo-imap4-string-1 (string length)
 561   "Internal function for `elmo-imap4-string' and `elmo-imap4-buffer-string'.
 562 Return a list represents STRING as a string defined in rfc2060.
 563 STRING must be an encoded or a single-byte string.
 564 LENGTH must be the number of octets for STRING."
 565   (or (elmo-imap4-quoted string)
 566       (elmo-imap4-literal-1 string length)))
 567
 568 (defun elmo-imap4-string (string)
 569   "Return a list represents STRING as a string defined in rfc2060.
 570 STRING must be an encoded or a single-byte string."
 571   (let ((length (length string)))
 572     (if (< elmo-imap4-literal-threshold length)
 573         (elmo-imap4-literal-1 string length)
 574       (elmo-imap4-string-1 string length))))
 575
 576 (defun elmo-imap4-buffer-string (buffer)
 577   "Return a list represents BUFFER as a string defined in rfc2060.
 578 BUFFER must be a single-byte buffer."
 579   (let ((length (with-current-buffer buffer
 580                   (buffer-size))))
 581     (if (< elmo-imap4-literal-threshold length)
 582         (elmo-imap4-literal-1 buffer length)
 583       (elmo-imap4-string-1 (with-current-buffer buffer
 584                              (buffer-string))
 585                            length))))
 586
 587 (defun elmo-imap4-astring-1 (string length)
 588   "Internal function for `elmo-imap4-astring' and `elmo-imap4-buffer-astring'.
 589 Return a list represents STRING as an astring defined in rfc2060.
 590 STRING must be an encoded or a single-byte string.
 591 LENGTH must be the number of octets for STRING."
 592   (or (elmo-imap4-atom string)
 593       (elmo-imap4-string-1 string length)))
 594
 595 (defun elmo-imap4-astring (string)
 596   "Return a list represents STRING as an astring defined in rfc2060.
 597 STRING must be an encoded or a single-byte string."
 598   (let ((length (length string)))
 599     (if (< elmo-imap4-literal-threshold length)
 600         (elmo-imap4-literal-1 string length)
 601       (elmo-imap4-astring-1 string length))))
 602
 603 (defun elmo-imap4-buffer-astring (buffer)
 604   "Return a list represents BUFFER as an astring defined in rfc2060.
 605 BUFFER must be a single-byte buffer."
 606   (let ((length (with-current-buffer buffer
 607                   (buffer-size))))
 608     (if (< elmo-imap4-literal-threshold length)
 609         (elmo-imap4-literal-1 buffer length)
 610       (elmo-imap4-astring-1 (with-current-buffer buffer
 611                               (buffer-string))
 612                             length))))
 613
 614 (defun elmo-imap4-nstring (string)
 615   "Return a list represents STRING as a nstring defined in rfc2060.
 616 STRING must be an encoded or a single-byte string."
 617    (or (elmo-imap4-nil string)
 618        (elmo-imap4-string string)))
 619
 620 (defun elmo-imap4-buffer-nstring (buffer)
 621   "Return a list represents BUFFER as a nstring defined in rfc2060.
 622 BUFFER must be a single-byte buffer."
 623    (or (elmo-imap4-nil buffer)
 624        (elmo-imap4-buffer-string buffer)))
 625
 626 (defalias 'elmo-imap4-mailbox 'elmo-imap4-astring)
 627 (defalias 'elmo-imap4-field-body 'elmo-imap4-astring)
 628 (defalias 'elmo-imap4-userid 'elmo-imap4-astring)
 629 (defalias 'elmo-imap4-password 'elmo-imap4-astring)
 630
 631 (defun elmo-imap4-format-quoted (string)
 632   "Return STRING in a form of the quoted-string defined in rfc2060."
 633   (concat "\""
 634           (std11-wrap-as-quoted-pairs string elmo-imap4-quoted-specials-list)
 635           "\""))
 636
 637 (defsubst elmo-imap4-response-get-selectable-mailbox-list (response)
 638   (delq nil
 639         (mapcar
 640          (lambda (entry)
 641            (if (and (eq 'list (car entry))
 642                     (not (elmo-string-member-ignore-case "\\Noselect" (nth 1 (nth 1 entry)))))
 643                (car (nth 1 entry))))
 644          response)))
 645
 646 (luna-define-method elmo-message-fetch-bodystructure ((folder
 647                                                        elmo-imap4-folder)
 648                                                       number strategy)
 649   (if (elmo-fetch-strategy-use-cache strategy)
 650       (elmo-object-load
 651        (elmo-file-cache-expand-path
 652         (elmo-fetch-strategy-cache-path strategy)
 653         "bodystructure"))
 654     (let ((session (elmo-imap4-get-session folder))
 655           bodystructure)
 656       (elmo-imap4-session-select-mailbox
 657        session
 658        (elmo-imap4-folder-mailbox-internal folder))
 659       (with-current-buffer (elmo-network-session-buffer session)
 660         (setq elmo-imap4-fetch-callback nil)
 661         (setq elmo-imap4-fetch-callback-data nil))
 662       (prog1 (setq bodystructure
 663                    (elmo-imap4-response-value
 664                     (elmo-imap4-response-value
 665                      (elmo-imap4-send-command-wait
 666                       session
 667                       (format
 668                        (if elmo-imap4-use-uid
 669                            "uid fetch %s bodystructure"
 670                          "fetch %s bodystructure")
 671                        number))
 672                      'fetch)
 673                     'bodystructure))
 674         (when (elmo-fetch-strategy-save-cache strategy)
 675           (elmo-file-cache-delete
 676            (elmo-fetch-strategy-cache-path strategy))
 677           (elmo-object-save
 678            (elmo-file-cache-expand-path
 679             (elmo-fetch-strategy-cache-path strategy)
 680             "bodystructure")
 681            bodystructure))))))
 682
 683 ;;; Backend methods.
 684 (luna-define-method elmo-create-folder-plugged ((folder elmo-imap4-folder))
 685   (elmo-imap4-send-command-wait
 686    (elmo-imap4-get-session folder)
 687    (list "create " (elmo-imap4-mailbox
 688                     (elmo-imap4-folder-mailbox-internal folder)))))
 689
 690 (defun elmo-imap4-get-session (folder &optional if-exists)
 691   (elmo-network-get-session 'elmo-imap4-session
 692                             (concat
 693                              (if (elmo-folder-biff-internal folder)
 694                                  "BIFF-")
 695                              "IMAP")
 696                             folder if-exists))
 697
 698 (defun elmo-imap4-session-select-mailbox (session mailbox
 699                                                   &optional force no-error)
 700   "Select MAILBOX in SESSION.
 701 If optional argument FORCE is non-nil, select mailbox even if current mailbox
 702 is same as MAILBOX.
 703 If second optional argument NO-ERROR is non-nil, don't cause an error when
 704 selecting folder was failed.
 705 If NO-ERROR is 'notify-bye, only BYE response is reported as error.
 706 Returns response value if selecting folder succeed. "
 707   (when (or force
 708             (not (string=
 709                   (elmo-imap4-session-current-mailbox-internal session)
 710                   mailbox)))
 711     (let (response result)
 712       (unwind-protect
 713           (setq response
 714                 (elmo-imap4-read-response
 715                  session
 716                  (elmo-imap4-send-command
 717                   session
 718                   (list
 719                    "select "
 720                    (elmo-imap4-mailbox mailbox)))))
 721         (if (setq result (elmo-imap4-response-ok-p response))
 722             (progn
 723               (elmo-imap4-session-set-current-mailbox-internal session mailbox)
 724               (elmo-imap4-session-set-read-only-internal
 725                session
 726                (nth 1 (assq 'read-only (assq 'ok response))))
 727               (elmo-imap4-session-set-flags-internal
 728                session
 729                (nth 1 (or (assq 'permanentflags response)
 730                           (assq 'flags response)))))
 731           (elmo-imap4-session-set-current-mailbox-internal session nil)
 732           (if (and (eq no-error 'notify-bye)
 733                    (elmo-imap4-response-bye-p response))
 734               (elmo-imap4-process-bye session)
 735             (unless no-error
 736               (error "%s"
 737                      (or (elmo-imap4-response-error-text response)
 738                          (format "Select %s failed" mailbox)))))))
 739       (and result response))))
 740
 741 (defun elmo-imap4-session-unselect-mailbox (session mailbox)
 742   "Unselect MAILBOX in SESSION.
 743 Deselecting will exit selected state without causing silent
 744 EXPUNGE for deleted messages."
 745   (if (elmo-imap4-session-capable-p session 'unselect)
 746       (elmo-imap4-send-command-wait session "unselect")
 747     (elmo-imap4-send-command-wait
 748      session
 749      (list "examine " (elmo-imap4-mailbox mailbox)))
 750     (elmo-imap4-send-command-wait session "close")))
 751
 752 (defun elmo-imap4-check-validity (spec validity-file)
 753 ;;; Not used.
 754 ;;;(elmo-imap4-send-command-wait
 755 ;;;(elmo-imap4-get-session spec)
 756 ;;;(list "status "
 757 ;;;      (elmo-imap4-mailbox
 758 ;;;       (elmo-imap4-spec-mailbox spec))
 759 ;;;      " (uidvalidity)")))
 760   )
 761
 762 (defun elmo-imap4-sync-validity  (spec validity-file)
 763   ;; Not used.
 764   )
 765
 766 (defun elmo-imap4-elist (folder query tags)
 767   (let ((session (elmo-imap4-get-session folder)))
 768     (elmo-imap4-session-select-mailbox
 769      session
 770      (elmo-imap4-folder-mailbox-internal folder))
 771     (let ((answer (elmo-imap4-response-value
 772                    (elmo-imap4-send-command-wait
 773                     session query) 'esearch))
 774           tag result)
 775       (while answer
 776         (setq tag (intern (downcase (car answer))))
 777         (cond ((eq tag 'uid)
 778                nil)
 779               ((memq tag tags)
 780                (setq result
 781                      (append result
 782                              (if (eq tag 'all)
 783                                  (sort
 784                                   (elmo-number-set-to-number-list
 785                                    (mapcar #'(lambda (x)
 786                                                (let ((y (split-string x ":")))
 787                                                  (if (null (cdr y))
 788                                                      (string-to-number (car y))
 789                                                    (cons (string-to-number (car y))
 790                                                          (string-to-number (cadr y))))))
 791                                            (split-string (cadr answer) "\,"))) '<)
 792                                (string-to-number (cadr answer))))))
 793               (t nil))
 794         (setq answer (cdr answer)))
 795       result)))
 796
 797 (defun elmo-imap4-list (folder flag)
 798   (let ((session (elmo-imap4-get-session folder)))
 799     (elmo-imap4-session-select-mailbox
 800      session
 801      (elmo-imap4-folder-mailbox-internal folder))
 802     (if (elmo-imap4-session-capable-p session 'esearch)
 803         (elmo-imap4-elist folder
 804                           (concat (if elmo-imap4-use-uid "uid " "")
 805                                   "search return (all) " flag) '(all))
 806       (elmo-imap4-response-value
 807        (elmo-imap4-send-command-wait
 808         session
 809         (format (if elmo-imap4-use-uid "uid search %s"
 810                   "search %s") flag))
 811        'search))))
 812
 813 (defun elmo-imap4-session-flag-available-p (session flag)
 814   (case flag
 815     ((read unread) (elmo-string-member-ignore-case
 816                     "\\seen" (elmo-imap4-session-flags-internal session)))
 817     (important
 818      (elmo-string-member-ignore-case
 819       "\\flagged" (elmo-imap4-session-flags-internal session)))
 820     (digest
 821      (or (elmo-string-member-ignore-case
 822           "\\seen" (elmo-imap4-session-flags-internal session))
 823          (elmo-string-member-ignore-case
 824           "\\flagged" (elmo-imap4-session-flags-internal session))))
 825     (answered
 826      (elmo-string-member-ignore-case
 827       (concat "\\" (symbol-name flag))
 828       (elmo-imap4-session-flags-internal session)))
 829     (t
 830      (member "\\*" (elmo-imap4-session-flags-internal session)))))
 831
 832 (defun elmo-imap4-flag-to-imap-search-key (flag)
 833   (case flag
 834     (read "seen")
 835     (unread "unseen")
 836     (important "flagged")
 837     (answered "answered")
 838     (new "new")
 839     (t (concat
 840         "keyword "
 841         (or (car (cdr (assq flag elmo-imap4-flag-specs)))
 842             (symbol-name flag))))))
 843
 844 (defun elmo-imap4-flag-to-imap-criteria (flag)
 845   (case flag
 846     ((any digest)
 847      (let ((criteria "flagged")
 848            (global-flags (delq 'important (elmo-get-global-flags t t))))
 849        (dolist (flag (delete 'new
 850                              (delete 'cached
 851                                      (copy-sequence
 852                                       (case flag
 853                                         (any
 854                                          elmo-preserved-flags)
 855                                         (digest
 856                                          elmo-digest-flags))))))
 857          (setq criteria (concat "or "
 858                                 (elmo-imap4-flag-to-imap-search-key flag)
 859                                 " "
 860                                 criteria)))
 861        (while global-flags
 862          (setq criteria (concat "or keyword "
 863                                 (symbol-name (car global-flags))
 864                                 " "
 865                                 criteria))
 866          (setq global-flags (cdr global-flags)))
 867        criteria))
 868     (t
 869      (elmo-imap4-flag-to-imap-search-key flag))))
 870
 871 (defun elmo-imap4-folder-list-flagged (folder flag &optional type)
 872   "List flagged message numbers in the FOLDER.
 873 FLAG is one of the `unread', `read', `important', `answered',
 874 `any'.
 875 When optional argument TYPE is symbol 'unmatch, negate search
 876 condition."
 877   (let ((session (elmo-imap4-get-session folder))
 878         (criteria (concat (if (eq type 'unmatch) "not " "")
 879                           (elmo-imap4-flag-to-imap-criteria flag))))
 880     (if (elmo-imap4-session-flag-available-p session flag)
 881         (elmo-imap4-list folder criteria)
 882       ;; List flagged messages in the msgdb.
 883       (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))))
 884
 885 (defvar elmo-imap4-rfc822-size "RFC822\.SIZE")
 886 (defvar elmo-imap4-rfc822-text "RFC822\.TEXT")
 887 (defvar elmo-imap4-rfc822-header "RFC822\.HEADER")
 888 (defvar elmo-imap4-header-fields "HEADER\.FIELDS")
 889
 890 (defun elmo-imap4-make-number-set-list (msg-list &optional chop-length)
 891   "Make RFC2060's message set specifier from MSG-LIST.
 892 Returns a list of (NUMBER . SET-STRING).
 893 SET-STRING is the message set specifier described in RFC2060.
 894 NUMBER is contained message number in SET-STRING.
 895 Every SET-STRING does not contain number of messages longer than CHOP-LENGTH.
 896 If CHOP-LENGTH is not specified, message set is not chopped."
 897   (let (count cont-list set-list)
 898     (setq msg-list (sort (copy-sequence msg-list) '<))
 899     (while msg-list
 900       (setq cont-list nil)
 901       (setq count 0)
 902       (unless chop-length
 903         (setq chop-length (length msg-list)))
 904       (while (and (not (null msg-list))
 905                   (< count chop-length))
 906         (setq cont-list
 907               (elmo-number-set-append
 908                cont-list (car msg-list)))
 909         (incf count)
 910         (setq msg-list (cdr msg-list)))
 911       (setq set-list
 912             (cons
 913              (cons
 914               count
 915               (mapconcat
 916                (lambda (x)
 917                  (cond ((consp x)
 918                         (format "%s:%s" (car x) (cdr x)))
 919                        ((integerp x)
 920                         (number-to-string x))))
 921                cont-list
 922                ","))
 923              set-list)))
 924     (nreverse set-list)))
 925
 926 ;;
 927 ;; app-data:
 928 ;; cons of flag-table and folder structure
 929 (defsubst elmo-imap4-fetch-callback-1-subr (entity flags app-data)
 930   "A msgdb entity callback function."
 931   (let ((use-flag (elmo-folder-use-flag-p (cdr app-data)))
 932         (flag-table (car app-data))
 933         (msg-id (elmo-message-entity-field entity 'message-id))
 934         saved-flags flag-list)
 935 ;;;    (when (elmo-string-member-ignore-case "\\Flagged" flags)
 936 ;;;      (elmo-msgdb-global-mark-set msg-id elmo-msgdb-important-mark))
 937     (setq saved-flags (elmo-flag-table-get flag-table msg-id)
 938           flag-list
 939           (if use-flag
 940               (append
 941                (and (memq 'new saved-flags)
 942                     (not (elmo-string-member-ignore-case "\\Seen" flags))
 943                     '(new))
 944                (and (elmo-string-member-ignore-case "\\Flagged" flags)
 945                     '(important))
 946                (and (not (elmo-string-member-ignore-case "\\Seen" flags))
 947                     '(unread))
 948                (and (elmo-string-member-ignore-case "\\Answered" flags)
 949                     '(answered))
 950                (and (elmo-file-cache-exists-p msg-id)
 951                     '(cached)))
 952             saved-flags))
 953     (elmo-msgdb-append-entity elmo-imap4-current-msgdb
 954                               entity
 955                               flag-list)))
 956
 957 ;; Current buffer is process buffer.
 958 (defun elmo-imap4-fetch-callback-1 (element app-data)
 959   (let ((handler (elmo-msgdb-message-entity-handler elmo-imap4-current-msgdb)))
 960     (elmo-imap4-fetch-callback-1-subr
 961      (with-temp-buffer
 962        (insert (or (elmo-imap4-response-bodydetail-text element)
 963                    ""))
 964        ;; Replace all CRLF with LF.
 965        (elmo-delete-cr-buffer)
 966        (elmo-msgdb-create-message-entity-from-buffer
 967         handler
 968         (elmo-imap4-response-value element 'uid)
 969         :size (elmo-imap4-response-value element 'rfc822size)))
 970      (elmo-imap4-response-value element 'flags)
 971      app-data)
 972     (elmo-progress-notify 'elmo-folder-msgdb-create)))
 973
 974 (defun elmo-imap4-parse-capability (string)
 975   (if (string-match "^\\*\\(.*\\)$" string)
 976       (read
 977        (concat "(" (downcase (elmo-match-string 1 string)) ")"))))
 978
 979 (defun elmo-imap4-clear-login (session)
 980   (when (elmo-imap4-session-capable-p session 'logindisabled)
 981     (signal 'elmo-authenticate-error '(elmo-imap4-clear-login)))
 982   (let ((elmo-imap4-debug-inhibit-logging t))
 983     (or
 984      (elmo-imap4-read-ok
 985       session
 986       (elmo-imap4-send-command
 987        session
 988        (list "login "
 989              (elmo-imap4-userid (elmo-network-session-user-internal session))
 990              " "
 991              (elmo-imap4-password
 992               (elmo-get-passwd (elmo-network-session-password-key session))))))
 993      (signal 'elmo-authenticate-error '(elmo-imap4-clear-login)))))
 994
 995 (defun elmo-imap4-auth-login (session)
 996   (let ((tag (elmo-imap4-send-command session "authenticate login"))
 997         (elmo-imap4-debug-inhibit-logging t))
 998     (or (elmo-imap4-read-continue-req session)
 999         (signal 'elmo-authenticate-error '(elmo-imap4-auth-login)))
1000     (elmo-imap4-send-string session
1001                             (elmo-base64-encode-string
1002                              (elmo-network-session-user-internal session)))
1003     (or (elmo-imap4-read-continue-req session)
1004         (signal 'elmo-authenticate-error '(elmo-imap4-auth-login)))
1005     (elmo-imap4-send-string session
1006                             (elmo-base64-encode-string
1007                              (elmo-get-passwd
1008                               (elmo-network-session-password-key session))))
1009     (or (elmo-imap4-read-ok session tag)
1010         (signal 'elmo-authenticate-error '(elmo-imap4-auth-login)))
1011     (setq elmo-imap4-status 'auth)))
1012
1013 (luna-define-method
1014   elmo-network-initialize-session-buffer :after ((session
1015                                                   elmo-imap4-session) buffer)
1016   (with-current-buffer buffer
1017     (mapc 'make-variable-buffer-local elmo-imap4-local-variables)
1018     (setq elmo-imap4-seqno 0)
1019     (setq elmo-imap4-status 'initial)))
1020
1021 (luna-define-method elmo-network-initialize-session ((session
1022                                                       elmo-imap4-session))
1023   (let ((process (elmo-network-session-process-internal session)))
1024     (with-current-buffer (process-buffer process)
1025       ;; Skip garbage output from process before greeting.
1026       (while (and (memq (process-status process) '(open run))
1027                   (goto-char (point-max))
1028                   (or (/= (forward-line -1) 0)
1029                       (not (elmo-imap4-parse-greeting))))
1030         (accept-process-output process 1))
1031       (erase-buffer)
1032       (set-process-filter process 'elmo-imap4-arrival-filter)
1033       (set-process-sentinel process 'elmo-imap4-sentinel)
1034 ;;;      (while (and (memq (process-status process) '(open run))
1035 ;;;               (eq elmo-imap4-status 'initial))
1036 ;;;     (message "Waiting for server response...")
1037 ;;;     (accept-process-output process 1))
1038 ;;;      (message "")
1039       (unless (memq elmo-imap4-status '(nonauth auth))
1040         (signal 'elmo-open-error
1041                 (list 'elmo-network-initialize-session)))
1042       (elmo-imap4-session-set-capability-internal
1043        session
1044        (elmo-imap4-response-value
1045         (elmo-imap4-send-command-wait session "capability")
1046         'capability))
1047       (when (eq (elmo-network-stream-type-symbol
1048                  (elmo-network-session-stream-type-internal session))
1049                 'starttls)
1050         (or (elmo-imap4-session-capable-p session 'starttls)
1051             (signal 'elmo-open-error
1052                     '(elmo-imap4-starttls-error)))
1053         (elmo-imap4-send-command-wait session "starttls")
1054         (starttls-negotiate process)
1055         (elmo-imap4-session-set-capability-internal
1056          session
1057          (elmo-imap4-response-value
1058           (elmo-imap4-send-command-wait session "capability")
1059           'capability))))))
1060
1061 (luna-define-method elmo-network-authenticate-session ((session
1062                                                         elmo-imap4-session))
1063   (with-current-buffer (process-buffer
1064                         (elmo-network-session-process-internal session))
1065     (let* ((auth (elmo-network-session-auth-internal session))
1066            (auth (if (listp auth) auth (list auth))))
1067       (unless (or (eq elmo-imap4-status 'auth)
1068                   (null auth))
1069         (cond
1070          ((eq 'clear (car auth))
1071           (elmo-imap4-clear-login session))
1072          ((eq 'login (car auth))
1073           (elmo-imap4-auth-login session))
1074          (t
1075           (let* ((elmo-imap4-debug-inhibit-logging t)
1076                  (sasl-mechanisms
1077                   (delq nil
1078                         (mapcar
1079                          (lambda (cap)
1080                            (if (string-match "^auth=\\(.*\\)$"
1081                                              (symbol-name cap))
1082                                (match-string 1 (upcase (symbol-name cap)))))
1083                          (elmo-imap4-session-capability-internal session))))
1084                  (mechanism
1085                   (sasl-find-mechanism
1086                    (delq nil
1087                          (mapcar (lambda (cap) (upcase (symbol-name cap)))
1088                                  (if (listp auth)
1089                                      auth
1090                                    (list auth)))))) ;)
1091                  client name step response tag
1092                  sasl-read-passphrase)
1093             (unless mechanism
1094               (if (or elmo-imap4-force-login
1095                       (y-or-n-p
1096                        (format
1097                         "There's no %s capability in server. continue?"
1098                         (elmo-list-to-string
1099                          (elmo-network-session-auth-internal session)))))
1100                   (setq mechanism (sasl-find-mechanism
1101                                    sasl-mechanisms))
1102                 (signal 'elmo-authenticate-error
1103                         '(elmo-imap4-auth-no-mechanisms))))
1104             (setq client
1105                   (sasl-make-client
1106                    mechanism
1107                    (elmo-network-session-user-internal session)
1108                    "imap"
1109                    (elmo-network-session-server-internal session)))
1110 ;;;         (if elmo-imap4-auth-user-realm
1111 ;;;             (sasl-client-set-property client 'realm elmo-imap4-auth-user-realm))
1112             (setq name (sasl-mechanism-name mechanism)
1113                   step (sasl-next-step client nil))
1114             (elmo-network-session-set-auth-internal
1115              session
1116              (intern (downcase name)))
1117             (setq sasl-read-passphrase
1118                   (lambda (prompt)
1119                     (elmo-get-passwd
1120                      (elmo-network-session-password-key session))))
1121             (setq tag
1122                   (elmo-imap4-send-command
1123                    session
1124                    (concat "AUTHENTICATE " name
1125                            (and (sasl-step-data step)
1126                                 (concat
1127                                  " "
1128                                  (elmo-base64-encode-string
1129                                   (sasl-step-data step)
1130                                   'no-lin-break))))))
1131             (catch 'done
1132               (while t
1133                 (setq response
1134                       (elmo-imap4-read-untagged
1135                        (elmo-network-session-process-internal session)))
1136                 (if (elmo-imap4-response-ok-p response)
1137                     (if (sasl-next-step client step)
1138                         ;; Bogus server?
1139                         (signal 'elmo-authenticate-error
1140                                 (list (intern
1141                                        (concat "elmo-imap4-auth-"
1142                                                (downcase name)))))
1143                       ;; The authentication process is finished.
1144                       (throw 'done nil)))
1145                 (unless (elmo-imap4-response-continue-req-p response)
1146                   ;; response is NO or BAD.
1147                   (signal 'elmo-authenticate-error
1148                           (list (intern
1149                                  (concat "elmo-imap4-auth-"
1150                                          (downcase name))))))
1151                 (sasl-step-set-data
1152                  step
1153                  (elmo-base64-decode-string
1154                   (elmo-imap4-response-value response 'continue-req)))
1155                 (setq step (sasl-next-step client step))
1156                 (setq tag
1157                       (elmo-imap4-send-string
1158                        session
1159                        (if (sasl-step-data step)
1160                            (elmo-base64-encode-string (sasl-step-data step)
1161                                                       'no-line-break)
1162                          ""))))))))
1163 ;; Some servers return reduced capabilities when client asks for them
1164 ;; before login. It might be a good idea to ask them again, otherwise
1165 ;; we can miss some useful feature.
1166         (elmo-imap4-session-set-capability-internal
1167          session
1168          (elmo-imap4-response-value
1169           (elmo-imap4-send-command-wait session "capability")
1170           'capability))))))
1171
1172 (luna-define-method elmo-network-setup-session ((session
1173                                                  elmo-imap4-session))
1174   (with-current-buffer (elmo-network-session-buffer session)
1175     (when (elmo-imap4-session-capable-p session 'namespace)
1176       (setq elmo-imap4-server-namespace
1177             (elmo-imap4-response-value
1178              (elmo-imap4-send-command-wait session "namespace")
1179              'namespace)))))
1180
1181 (defun elmo-imap4-setup-send-buffer (&optional string)
1182   (let ((send-buf (get-buffer-create " *elmo-imap4-setup-send-buffer*"))
1183         (source-buf (unless string (current-buffer))))
1184     (save-excursion
1185       (save-match-data
1186         (set-buffer send-buf)
1187         (erase-buffer)
1188         (set-buffer-multibyte nil)
1189         (if string
1190             (insert string)
1191           (with-current-buffer source-buf
1192             (copy-to-buffer send-buf (point-min) (point-max))))
1193         (goto-char (point-min))
1194         (if (eq (re-search-forward "^$" nil t)
1195                 (point-max))
1196             (insert "\n"))
1197         (goto-char (point-min))
1198         (while (search-forward "\n" nil t)
1199           (replace-match "\r\n"))))
1200     send-buf))
1201
1202 (defun elmo-imap4-setup-send-buffer-from-file (file)
1203   (let ((tmp-buf (get-buffer-create
1204                   " *elmo-imap4-setup-send-buffer-from-file*")))
1205     (save-excursion
1206       (save-match-data
1207         (set-buffer tmp-buf)
1208         (erase-buffer)
1209         (as-binary-input-file
1210          (insert-file-contents file))
1211         (goto-char (point-min))
1212         (if (eq (re-search-forward "^$" nil t)
1213                 (point-max))
1214             (insert "\n"))
1215         (goto-char (point-min))
1216         (while (search-forward "\n" nil t)
1217           (replace-match "\r\n"))))
1218     tmp-buf))
1219
1220 (luna-define-method elmo-delete-message-safe ((folder elmo-imap4-folder)
1221                                               number msgid)
1222   (let ((session (elmo-imap4-get-session folder))
1223         candidates)
1224     (elmo-imap4-session-select-mailbox
1225      session
1226      (elmo-imap4-folder-mailbox-internal folder))
1227     (setq candidates
1228           (elmo-imap4-response-value
1229            (elmo-imap4-send-command-wait session
1230                                          (list
1231                                           (if elmo-imap4-use-uid
1232                                               "uid search header message-id "
1233                                             "search header message-id ")
1234                                           (elmo-imap4-field-body msgid)))
1235            'search))
1236     (if (memq number candidates)
1237         (elmo-folder-delete-messages folder (list number)))))
1238
1239 (defun elmo-imap4-server-diff-async-callback-1 (status data)
1240   (funcall elmo-imap4-server-diff-async-callback
1241            (list (elmo-imap4-response-value status 'recent)
1242                  (elmo-imap4-response-value status 'unseen)
1243                  (elmo-imap4-response-value status 'messages))
1244            data))
1245
1246 (defun elmo-imap4-server-diff-async (folder)
1247   (let ((session (elmo-imap4-get-session folder)))
1248     ;; We should `check' folder to obtain newest information here.
1249     ;; But since there's no asynchronous check mechanism in elmo yet,
1250     ;; checking is not done here.
1251     (with-current-buffer (elmo-network-session-buffer session)
1252       (setq elmo-imap4-status-callback
1253             'elmo-imap4-server-diff-async-callback-1)
1254       (setq elmo-imap4-status-callback-data
1255             elmo-imap4-server-diff-async-callback-data))
1256     (elmo-imap4-send-command session
1257                              (list
1258                               "status "
1259                               (elmo-imap4-mailbox
1260                                (elmo-imap4-folder-mailbox-internal folder))
1261                               " (recent unseen messages)"))))
1262
1263 (luna-define-method elmo-server-diff-async ((folder elmo-imap4-folder))
1264   (let ((session (elmo-imap4-get-session folder)))
1265 ;;;    ;; commit.
1266 ;;;    (elmo-imap4-commit spec)
1267     (with-current-buffer (elmo-network-session-buffer session)
1268       (setq elmo-imap4-status-callback
1269             'elmo-imap4-server-diff-async-callback-1)
1270       (setq elmo-imap4-status-callback-data
1271             elmo-imap4-server-diff-async-callback-data))
1272     (elmo-imap4-send-command session
1273                              (list
1274                               "status "
1275                               (elmo-imap4-mailbox
1276                                (elmo-imap4-folder-mailbox-internal folder))
1277                               " (recent unseen messages)"))))
1278
1279 ;;; IMAP parser.
1280
1281 (defvar elmo-imap4-server-eol "\r\n"
1282   "The EOL string sent from the server.")
1283
1284 (defvar elmo-imap4-client-eol "\r\n"
1285   "The EOL string we send to the server.")
1286
1287 (defvar elmo-imap4-literal-progress-reporter nil)
1288
1289 (defun elmo-imap4-find-next-line ()
1290   "Return point at end of current line, taking into account literals.
1291 Return nil if no complete line has arrived."
1292   (when (re-search-forward (concat elmo-imap4-server-eol "\\|{\\([0-9]+\\)}"
1293                                    elmo-imap4-server-eol)
1294                            nil t)
1295     (if (match-string 1)
1296         (if (< (point-max) (+ (point) (string-to-number (match-string 1))))
1297             (progn
1298               (when elmo-imap4-literal-progress-reporter
1299                 (elmo-progress-notify
1300                  'elmo-retrieve-message
1301                  :set (- (point-max) (point))
1302                  :total (string-to-number (match-string 1))))
1303               nil)
1304           (goto-char (+ (point) (string-to-number (match-string 1))))
1305           (elmo-imap4-find-next-line))
1306       (point))))
1307
1308 (defun elmo-imap4-sentinel (process string)
1309   (delete-process process))
1310
1311 (defun elmo-imap4-arrival-filter (proc string)
1312   "IMAP process filter."
1313   (when (buffer-live-p (process-buffer proc))
1314   (with-current-buffer (process-buffer proc)
1315     (goto-char (point-max))
1316     (insert string)
1317     (let (end)
1318       (goto-char (point-min))
1319       (while (setq end (elmo-imap4-find-next-line))
1320         (save-restriction
1321           (narrow-to-region (point-min) end)
1322           (delete-char (- (length elmo-imap4-server-eol)))
1323           (goto-char (point-min))
1324           (unwind-protect
1325               (case elmo-imap4-status
1326                 (initial
1327                  (setq elmo-imap4-current-response
1328                        (list
1329                         (list 'greeting (elmo-imap4-parse-greeting)))))
1330                 ((auth nonauth selected examine)
1331                  (setq elmo-imap4-current-response
1332                        (cons (elmo-imap4-parse-response)
1333                              elmo-imap4-current-response)))
1334                 (t
1335                  (message "Unknown state %s in arrival filter"
1336                           elmo-imap4-status)))
1337             (delete-region (point-min) (point-max)))))))))
1338
1339 ;; IMAP parser.
1340
1341 (defsubst elmo-imap4-forward ()
1342   (or (eobp) (forward-char 1)))
1343
1344 (defsubst elmo-imap4-parse-number ()
1345   (when (looking-at "[0-9]+")
1346     (prog1
1347         (string-to-number (match-string 0))
1348       (goto-char (match-end 0)))))
1349
1350 (defsubst elmo-imap4-parse-literal ()
1351   (when (looking-at "{\\([0-9]+\\)}\r\n")
1352     (let ((pos (match-end 0))
1353           (len (string-to-number (match-string 1))))
1354       (if (< (point-max) (+ pos len))
1355           nil
1356         (goto-char (+ pos len))
1357         (buffer-substring pos (+ pos len))))))
1358 ;;;     (list ' pos (+ pos len))))))
1359
1360 (defsubst elmo-imap4-parse-string ()
1361   (cond ((eq (char-after (point)) ?\")
1362          (forward-char 1)
1363          (let ((p (point)) (name ""))
1364            (skip-chars-forward "^\"\\\\")
1365            (setq name (buffer-substring p (point)))
1366            (while (eq (char-after (point)) ?\\)
1367              (setq p (1+ (point)))
1368              (forward-char 2)
1369              (skip-chars-forward "^\"\\\\")
1370              (setq name (concat name (buffer-substring p (point)))))
1371            (forward-char 1)
1372            name))
1373         ((eq (char-after (point)) ?{)
1374          (elmo-imap4-parse-literal))))
1375
1376 (defsubst elmo-imap4-parse-nil ()
1377   (if (looking-at "NIL")
1378       (goto-char (match-end 0))))
1379
1380 (defsubst elmo-imap4-parse-nstring ()
1381   (or (elmo-imap4-parse-string)
1382       (and (elmo-imap4-parse-nil)
1383            nil)))
1384
1385 (defsubst elmo-imap4-parse-astring ()
1386   (or (elmo-imap4-parse-string)
1387       (buffer-substring (point)
1388                         (if (re-search-forward "[(){ \r\n%*\"\\]" nil t)
1389                             (goto-char (1- (match-end 0)))
1390                           (end-of-line)
1391                           (point)))))
1392
1393 (defsubst elmo-imap4-parse-address ()
1394   (let (address)
1395     (when (eq (char-after (point)) ?\()
1396       (elmo-imap4-forward)
1397       (setq address (vector (prog1 (elmo-imap4-parse-nstring)
1398                               (elmo-imap4-forward))
1399                             (prog1 (elmo-imap4-parse-nstring)
1400                               (elmo-imap4-forward))
1401                             (prog1 (elmo-imap4-parse-nstring)
1402                               (elmo-imap4-forward))
1403                             (elmo-imap4-parse-nstring)))
1404       (when (eq (char-after (point)) ?\))
1405         (elmo-imap4-forward)
1406         address))))
1407
1408 (defsubst elmo-imap4-parse-address-list ()
1409   (if (eq (char-after (point)) ?\()
1410       (let (address addresses)
1411         (elmo-imap4-forward)
1412         (while (and (not (eq (char-after (point)) ?\)))
1413                     ;; next line for MS Exchange bug
1414                     (progn (and (eq (char-after (point)) (string-to-char " "))
1415                                 (elmo-imap4-forward)) t)
1416                     (setq address (elmo-imap4-parse-address)))
1417           (setq addresses (cons address addresses)))
1418         (when (eq (char-after (point)) ?\))
1419           (elmo-imap4-forward)
1420           (nreverse addresses)))
1421     (assert (elmo-imap4-parse-nil))))
1422
1423 (defsubst elmo-imap4-parse-mailbox ()
1424   (let ((mailbox (elmo-imap4-parse-astring)))
1425     (if (string-equal "INBOX" (upcase mailbox))
1426         "INBOX"
1427       mailbox)))
1428
1429 (defun elmo-imap4-parse-greeting ()
1430   "Parse a IMAP greeting."
1431   (cond ((looking-at "\\* OK ")
1432          (setq elmo-imap4-status 'nonauth))
1433         ((looking-at "\\* PREAUTH ")
1434          (setq elmo-imap4-status 'auth))
1435         ((looking-at "\\* BYE ")
1436          (setq elmo-imap4-status 'closed))))
1437
1438 (defun elmo-imap4-parse-response ()
1439   "Parse a IMAP command response."
1440   (elmo-imap4-debug "[%s] -> %s" (format-time-string "%T") (buffer-substring (point) (point-max)))
1441   (let (token)
1442     (case (setq token (read (current-buffer)))
1443       (+ (progn
1444            (skip-chars-forward " ")
1445            (list 'continue-req (buffer-substring (point) (point-max)))))
1446       (* (case (prog1 (setq token (read (current-buffer)))
1447                  (elmo-imap4-forward))
1448            (OK         (elmo-imap4-parse-resp-text-code))
1449            (NO         (elmo-imap4-parse-resp-text-code))
1450            (BAD        (elmo-imap4-parse-resp-text-code))
1451            (BYE        (elmo-imap4-parse-bye))
1452            (FLAGS      (list 'flags
1453                              (elmo-imap4-parse-flag-list)))
1454            (LIST       (list 'list (elmo-imap4-parse-data-list)))
1455            (LSUB       (list 'lsub (elmo-imap4-parse-data-list)))
1456            (SEARCH     (list
1457                         'search
1458                         (read (concat "("
1459                                       (buffer-substring (point) (point-max))
1460                                       ")"))))
1461            (ESEARCH     (list
1462                          'esearch
1463                          (cddr (split-string (buffer-substring (point) (point-max)) " "))))
1464            (STATUS     (elmo-imap4-parse-status))
1465            ;; Added
1466            (NAMESPACE  (elmo-imap4-parse-namespace))
1467            (CAPABILITY (list 'capability
1468                              (read
1469                               (concat "(" (downcase (buffer-substring
1470                                                      (point) (point-max)))
1471                                       ")"))))
1472            (ACL (elmo-imap4-parse-acl))
1473            (t       (case (prog1 (read (current-buffer))
1474                             (elmo-imap4-forward))
1475                       (EXISTS  (list 'exists token))
1476                       (RECENT  (list 'recent token))
1477                       (EXPUNGE (list 'expunge token))
1478                       (FETCH   (elmo-imap4-parse-fetch token))
1479                       (t       (list 'garbage (buffer-string)))))))
1480       (t (if (not (string-match elmo-imap4-seq-prefix (symbol-name token)))
1481              (list 'garbage (buffer-string))
1482            (case (prog1 (read (current-buffer))
1483                    (elmo-imap4-forward))
1484              (OK  (progn
1485                     (setq elmo-imap4-parsing nil)
1486                     (setq token (symbol-name token))
1487                     (elmo-unintern token)
1488                     (elmo-imap4-debug "*%s* OK arrived" token)
1489                     (setq elmo-imap4-reached-tag token)
1490                     (list 'ok (elmo-imap4-parse-resp-text-code))))
1491              (NO  (progn
1492                     (setq elmo-imap4-parsing nil)
1493                     (setq token (symbol-name token))
1494                     (elmo-unintern token)
1495                     (elmo-imap4-debug "*%s* NO arrived" token)
1496                     (setq elmo-imap4-reached-tag token)
1497                     (let (code text)
1498                       (when (eq (char-after (point)) ?\[)
1499                         (setq code (buffer-substring (point)
1500                                                      (search-forward "]")))
1501                         (elmo-imap4-forward))
1502                       (setq text (buffer-substring (point) (point-max)))
1503                       (list 'no (list code text)))))
1504              (BAD (progn
1505                     (setq elmo-imap4-parsing nil)
1506                     (elmo-imap4-debug "*%s* BAD arrived" token)
1507                     (setq token (symbol-name token))
1508                     (elmo-unintern token)
1509                     (setq elmo-imap4-reached-tag token)
1510                     (let (code text)
1511                       (when (eq (char-after (point)) ?\[)
1512                         (setq code (buffer-substring (point)
1513                                                      (search-forward "]")))
1514                         (elmo-imap4-forward))
1515                       (setq text (buffer-substring (point) (point-max)))
1516                       (list 'bad (list code text)))))
1517              (t   (list 'garbage (buffer-string)))))))))
1518
1519 (defun elmo-imap4-parse-bye ()
1520   (let (code text)
1521     (when (eq (char-after (point)) ?\[)
1522       (setq code (buffer-substring (point)
1523                                    (search-forward "]")))
1524       (elmo-imap4-forward))
1525     (setq text (buffer-substring (point) (point-max)))
1526     (list 'bye (list code text))))
1527
1528 (defun elmo-imap4-parse-text ()
1529   (goto-char (point-min))
1530   (when (search-forward "[" nil t)
1531     (search-forward "]")
1532     (elmo-imap4-forward))
1533   (list 'text (buffer-substring (point) (point-max))))
1534
1535 (defun elmo-imap4-parse-resp-text-code ()
1536   (when (eq (char-after (point)) ?\[)
1537     (elmo-imap4-forward)
1538     (cond ((search-forward "PERMANENTFLAGS " nil t)
1539            (list 'permanentflags (elmo-imap4-parse-flag-list)))
1540           ((search-forward "UIDNEXT " nil t)
1541            (list 'uidnext (read (current-buffer))))
1542           ((search-forward "UNSEEN " nil t)
1543            (list 'unseen (read (current-buffer))))
1544           ((looking-at "UIDVALIDITY \\([0-9]+\\)")
1545            (list 'uidvalidity (match-string 1)))
1546           ((search-forward "READ-ONLY" nil t)
1547            (list 'read-only t))
1548           ((search-forward "READ-WRITE" nil t)
1549            (list 'read-write t))
1550           ((search-forward "NEWNAME " nil t)
1551            (let (oldname newname)
1552              (setq oldname (elmo-imap4-parse-string))
1553              (elmo-imap4-forward)
1554              (setq newname (elmo-imap4-parse-string))
1555              (list 'newname newname oldname)))
1556           ((search-forward "TRYCREATE" nil t)
1557            (list 'trycreate t))
1558           ((looking-at "APPENDUID \\([0-9]+\\) \\([0-9]+\\)")
1559            (list 'appenduid
1560                  (list (match-string 1)
1561                        (string-to-number (match-string 2)))))
1562           ((looking-at "COPYUID \\([0-9]+\\) \\([0-9,:]+\\) \\([0-9,:]+\\)")
1563            (list 'copyuid (list (match-string 1)
1564                                 (match-string 2)
1565                                 (match-string 3))))
1566           ((search-forward "ALERT] " nil t)
1567            (message "IMAP server information: %s"
1568                     (buffer-substring (point) (point-max))))
1569           (t (list 'unknown)))))
1570
1571 (defun elmo-imap4-parse-data-list ()
1572   (let (flags delimiter mailbox)
1573     (setq flags (elmo-imap4-parse-flag-list))
1574     (when (looking-at " NIL\\| \"\\\\?\\(.\\)\"")
1575       (setq delimiter (match-string 1))
1576       (goto-char (1+ (match-end 0)))
1577       (when (setq mailbox (elmo-imap4-parse-mailbox))
1578         (list mailbox flags delimiter)))))
1579
1580 (defsubst elmo-imap4-parse-header-list ()
1581   (when (eq (char-after (point)) ?\()
1582     (let (strlist)
1583       (while (not (eq (char-after (point)) ?\)))
1584         (elmo-imap4-forward)
1585         (push (elmo-imap4-parse-astring) strlist))
1586       (elmo-imap4-forward)
1587       (nreverse strlist))))
1588
1589 (defsubst elmo-imap4-parse-fetch-body-section ()
1590   (let ((section
1591          (buffer-substring (point)
1592                            (1-
1593                             (progn (re-search-forward "[] ]" nil t)
1594                                    (point))))))
1595     (if (eq (char-before) (string-to-char " "))
1596         (prog1
1597             (mapconcat 'identity
1598                        (cons section (elmo-imap4-parse-header-list)) " ")
1599           (search-forward "]" nil t))
1600       section)))
1601
1602 (defun elmo-imap4-parse-fetch (response)
1603   (when (eq (char-after (point)) ?\()
1604     (let (element list)
1605       (while (not (eq (char-after (point)) ?\)))
1606         (elmo-imap4-forward)
1607         (let ((token (read (current-buffer))))
1608           (elmo-imap4-forward)
1609           (setq element
1610                 (cond ((eq token 'UID)
1611                        (list 'uid (condition-case nil
1612                                       (read (current-buffer))
1613                                     (error nil))))
1614                       ((eq token 'FLAGS)
1615                        (list 'flags (elmo-imap4-parse-flag-list)))
1616                       ((eq token 'ENVELOPE)
1617                        (list 'envelope (elmo-imap4-parse-envelope)))
1618                       ((eq token 'INTERNALDATE)
1619                        (list 'internaldate (elmo-imap4-parse-string)))
1620                       ((eq token 'RFC822)
1621                        (list 'rfc822 (elmo-imap4-parse-nstring)))
1622                       ((eq token (intern elmo-imap4-rfc822-header))
1623                        (list 'rfc822header (elmo-imap4-parse-nstring)))
1624                       ((eq token (intern elmo-imap4-rfc822-text))
1625                        (list 'rfc822text (elmo-imap4-parse-nstring)))
1626                       ((eq token (intern elmo-imap4-rfc822-size))
1627                        (list 'rfc822size (read (current-buffer))))
1628                       ((eq token 'BODY)
1629                        (if (eq (char-before) ?\[)
1630                            (list
1631                             'bodydetail
1632                             (upcase (elmo-imap4-parse-fetch-body-section))
1633                             (and
1634                              (eq (char-after (point)) ?<)
1635                              (buffer-substring (1+ (point))
1636                                                (progn
1637                                                  (search-forward ">" nil t)
1638                                                  (point))))
1639                             (progn (elmo-imap4-forward)
1640                                    (elmo-imap4-parse-nstring)))
1641                          (list 'body (elmo-imap4-parse-body))))
1642                       ((eq token 'BODYSTRUCTURE)
1643                        (list 'bodystructure (elmo-imap4-parse-body)))))
1644           (setq list (cons element list))))
1645       (and elmo-imap4-fetch-callback
1646            (funcall elmo-imap4-fetch-callback
1647                     list elmo-imap4-fetch-callback-data))
1648       (list 'fetch list))))
1649
1650 (defun elmo-imap4-parse-status ()
1651   (let ((mailbox (elmo-imap4-parse-mailbox))
1652         status)
1653     (when (and mailbox (search-forward "(" nil t))
1654       (while (not (eq (char-after (point)) ?\)))
1655         (setq status
1656               (cons
1657                (let ((token (read (current-buffer))))
1658                  (case (intern (upcase (symbol-name token)))
1659                    (MESSAGES
1660                     (list 'messages (read (current-buffer))))
1661                    (RECENT
1662                     (list 'recent (read (current-buffer))))
1663                    (UIDNEXT
1664                     (list 'uidnext (read (current-buffer))))
1665                    (UIDVALIDITY
1666                     (and (looking-at " \\([0-9]+\\)")
1667                          (prog1 (list 'uidvalidity (match-string 1))
1668                            (goto-char (match-end 1)))))
1669                    (UNSEEN
1670                     (list 'unseen (read (current-buffer))))
1671                    (t
1672                     (message
1673                      "Unknown status data %s in mailbox %s ignored"
1674                      token mailbox))))
1675                status))
1676         (skip-chars-forward " ")))
1677     (and elmo-imap4-status-callback
1678          (funcall elmo-imap4-status-callback
1679                   status
1680                   elmo-imap4-status-callback-data))
1681     (list 'status status)))
1682
1683
1684 (defmacro elmo-imap4-value (value)
1685   `(if (eq ,value 'NIL)
1686        nil
1687      ,value))
1688
1689 (defmacro elmo-imap4-nth (pos list)
1690   `(let ((value (nth ,pos ,list)))
1691      (elmo-imap4-value value)))
1692
1693 (defun elmo-imap4-parse-namespace ()
1694   (list 'namespace
1695         (nconc
1696          (copy-sequence elmo-imap4-extra-namespace-alist)
1697          (elmo-imap4-parse-namespace-subr
1698           (read (concat "(" (buffer-substring
1699                              (point) (point-max))
1700                         ")"))))))
1701
1702 (defun elmo-imap4-parse-namespace-subr (ns)
1703   (let (prefix delim namespace-alist default-delim)
1704     ;; 0: personal, 1: other, 2: shared
1705     (dotimes (i 3)
1706       (setq namespace-alist
1707             (nconc namespace-alist
1708                    (delq nil
1709                          (mapcar
1710                           (lambda (namespace)
1711                             (setq prefix (elmo-imap4-nth 0 namespace)
1712                                   delim (elmo-imap4-nth 1 namespace))
1713                             (if (and prefix delim
1714                                      (string-match
1715                                       (concat (regexp-quote delim) "\\'")
1716                                       prefix))
1717                                 (setq prefix (substring prefix 0
1718                                                         (match-beginning 0))))
1719                             (if (eq (length prefix) 0)
1720                                 (progn (setq default-delim delim) nil)
1721                               (cons
1722                                (concat "^\\("
1723                                        (if (string= (downcase prefix) "inbox")
1724                                            "[Ii][Nn][Bb][Oo][Xx]"
1725                                          (regexp-quote prefix))
1726                                        "\\).*$")
1727                                delim)))
1728                           (elmo-imap4-nth i ns))))))
1729     (if default-delim
1730         (setq namespace-alist
1731               (nconc namespace-alist
1732                      (list (cons "^.*$" default-delim)))))
1733     namespace-alist))
1734
1735 (defun elmo-imap4-parse-acl ()
1736   (let ((mailbox (elmo-imap4-parse-mailbox))
1737         identifier rights acl)
1738     (while (eq (char-after (point)) (string-to-char " "))
1739       (elmo-imap4-forward)
1740       (setq identifier (elmo-imap4-parse-astring))
1741       (elmo-imap4-forward)
1742       (setq rights (elmo-imap4-parse-astring))
1743       (setq acl (append acl (list (cons identifier rights)))))
1744     (list 'acl acl mailbox)))
1745
1746 (defun elmo-imap4-parse-flag-list ()
1747   (let ((str (buffer-substring (+ (point) 1)
1748                                (progn (search-forward ")" nil t)
1749                                       (- (point) 1)))))
1750     (unless (eq (length str) 0)
1751       (split-string str))))
1752
1753 (defun elmo-imap4-parse-envelope ()
1754   (when (eq (char-after (point)) ?\()
1755     (elmo-imap4-forward)
1756     (vector (prog1 (elmo-imap4-parse-nstring);; date
1757               (elmo-imap4-forward))
1758             (prog1 (elmo-imap4-parse-nstring);; subject
1759               (elmo-imap4-forward))
1760             (prog1 (elmo-imap4-parse-address-list);; from
1761               (elmo-imap4-forward))
1762             (prog1 (elmo-imap4-parse-address-list);; sender
1763               (elmo-imap4-forward))
1764             (prog1 (elmo-imap4-parse-address-list);; reply-to
1765               (elmo-imap4-forward))
1766             (prog1 (elmo-imap4-parse-address-list);; to
1767               (elmo-imap4-forward))
1768             (prog1 (elmo-imap4-parse-address-list);; cc
1769               (elmo-imap4-forward))
1770             (prog1 (elmo-imap4-parse-address-list);; bcc
1771               (elmo-imap4-forward))
1772             (prog1 (elmo-imap4-parse-nstring);; in-reply-to
1773               (elmo-imap4-forward))
1774             (prog1 (elmo-imap4-parse-nstring);; message-id
1775               (elmo-imap4-forward)))))
1776
1777 (defsubst elmo-imap4-parse-string-list ()
1778   (cond ((eq (char-after (point)) ?\();; body-fld-param
1779          (let (strlist str)
1780            (elmo-imap4-forward)
1781            (while (setq str (elmo-imap4-parse-string))
1782              (push str strlist)
1783              (elmo-imap4-forward))
1784            (nreverse strlist)))
1785         ((elmo-imap4-parse-nil)
1786          nil)))
1787
1788 (defun elmo-imap4-parse-body-extension ()
1789   (if (eq (char-after (point)) ?\()
1790       (let (b-e)
1791         (elmo-imap4-forward)
1792         (push (elmo-imap4-parse-body-extension) b-e)
1793         (while (eq (char-after (point)) (string-to-char " "))
1794           (elmo-imap4-forward)
1795           (push (elmo-imap4-parse-body-extension) b-e))
1796         (assert (eq (char-after (point)) ?\)))
1797         (elmo-imap4-forward)
1798         (nreverse b-e))
1799     (or (elmo-imap4-parse-number)
1800         (elmo-imap4-parse-nstring))))
1801
1802 (defsubst elmo-imap4-parse-body-ext ()
1803   (let (ext)
1804     (when (eq (char-after (point)) (string-to-char " ")) ; body-fld-dsp
1805       (elmo-imap4-forward)
1806       (let (dsp)
1807         (if (eq (char-after (point)) ?\()
1808             (progn
1809               (elmo-imap4-forward)
1810               (push (elmo-imap4-parse-string) dsp)
1811               (elmo-imap4-forward)
1812               (push (elmo-imap4-parse-string-list) dsp)
1813               (elmo-imap4-forward))
1814           (assert (elmo-imap4-parse-nil)))
1815         (push (nreverse dsp) ext))
1816       (when (eq (char-after (point)) (string-to-char " ")) ; body-fld-lang
1817         (elmo-imap4-forward)
1818         (if (eq (char-after (point)) ?\()
1819             (push (elmo-imap4-parse-string-list) ext)
1820           (push (elmo-imap4-parse-nstring) ext))
1821         (while (eq (char-after (point)) (string-to-char " "));; body-extension
1822           (elmo-imap4-forward)
1823           (setq ext (append (elmo-imap4-parse-body-extension) ext)))))
1824     ext))
1825
1826 (defun elmo-imap4-parse-body ()
1827   (let (body)
1828     (when (eq (char-after (point)) ?\()
1829       (elmo-imap4-forward)
1830       (if (eq (char-after (point)) ?\()
1831           (let (subbody)
1832             (while (and (eq (char-after (point)) ?\()
1833                         (setq subbody (elmo-imap4-parse-body)))
1834               (push subbody body))
1835             (elmo-imap4-forward)
1836             (push (elmo-imap4-parse-string) body);; media-subtype
1837             (when (eq (char-after (point)) (string-to-char " ")) ; body-ext-mpart:
1838               (elmo-imap4-forward)
1839               (if (eq (char-after (point)) ?\();; body-fld-param
1840                   (push (elmo-imap4-parse-string-list) body)
1841                 (push (and (elmo-imap4-parse-nil) nil) body))
1842               (setq body
1843                     (append (elmo-imap4-parse-body-ext) body)));; body-ext-...
1844             (assert (eq (char-after (point)) ?\)))
1845             (elmo-imap4-forward)
1846             (nreverse body))
1847
1848         (push (elmo-imap4-parse-string) body);; media-type
1849         (elmo-imap4-forward)
1850         (push (elmo-imap4-parse-string) body);; media-subtype
1851         (elmo-imap4-forward)
1852         ;; next line for Sun SIMS bug
1853         (and (eq (char-after (point)) (string-to-char " "))
1854              (elmo-imap4-forward))
1855         (if (eq (char-after (point)) ?\();; body-fld-param
1856             (push (elmo-imap4-parse-string-list) body)
1857           (push (and (elmo-imap4-parse-nil) nil) body))
1858         (elmo-imap4-forward)
1859         (push (elmo-imap4-parse-nstring) body);; body-fld-id
1860         (elmo-imap4-forward)
1861         (push (elmo-imap4-parse-nstring) body);; body-fld-desc
1862         (elmo-imap4-forward)
1863         (push (elmo-imap4-parse-string) body);; body-fld-enc
1864         (elmo-imap4-forward)
1865         (push (elmo-imap4-parse-number) body);; body-fld-octets
1866
1867         ;; ok, we're done parsing the required parts, what comes now is one
1868         ;; of three things:
1869         ;;
1870         ;; envelope       (then we're parsing body-type-msg)
1871         ;; body-fld-lines (then we're parsing body-type-text)
1872         ;; body-ext-1part (then we're parsing body-type-basic)
1873         ;;
1874         ;; the problem is that the two first are in turn optionally followed
1875         ;; by the third.  So we parse the first two here (if there are any)...
1876
1877         (when (eq (char-after (point)) (string-to-char " "))
1878           (elmo-imap4-forward)
1879           (let (lines)
1880             (cond ((eq (char-after (point)) ?\();; body-type-msg:
1881                    (push (elmo-imap4-parse-envelope) body);; envelope
1882                    (elmo-imap4-forward)
1883                    (push (elmo-imap4-parse-body) body);; body
1884                    (elmo-imap4-forward)
1885                    (push (elmo-imap4-parse-number) body));; body-fld-lines
1886                   ((setq lines (elmo-imap4-parse-number));; body-type-text:
1887                    (push lines body));; body-fld-lines
1888                   (t
1889                    (backward-char)))));; no match...
1890
1891         ;; ...and then parse the third one here...
1892
1893         (when (eq (char-after (point)) (string-to-char " ")) ; body-ext-1part:
1894           (elmo-imap4-forward)
1895           (push (elmo-imap4-parse-nstring) body);; body-fld-md5
1896           (setq body
1897                 (append (elmo-imap4-parse-body-ext) body)));; body-ext-1part..
1898
1899         (assert (eq (char-after (point)) ?\)))
1900         (elmo-imap4-forward)
1901         (nreverse body)))))
1902
1903 (luna-define-method elmo-folder-initialize ((folder elmo-imap4-folder) name)
1904   (let ((default-user   elmo-imap4-default-user)
1905         (default-server elmo-imap4-default-server)
1906         (default-port   elmo-imap4-default-port)
1907         (elmo-network-stream-type-alist
1908          (if elmo-imap4-stream-type-alist
1909              (append elmo-imap4-stream-type-alist
1910                      elmo-network-stream-type-alist)
1911            elmo-network-stream-type-alist))
1912         tokens)
1913     (when (string-match "\\(.*\\)@\\(.*\\)" default-server)
1914       ;; case: imap4-default-server is specified like
1915       ;; "hoge%imap.server@gateway".
1916       (setq default-user (elmo-match-string 1 default-server))
1917       (setq default-server (elmo-match-string 2 default-server)))
1918     (setq tokens (car (elmo-parse-separated-tokens
1919                        name
1920                        elmo-imap4-folder-name-syntax)))
1921     ;; mailbox
1922     (elmo-imap4-folder-set-mailbox-internal folder
1923                                             (elmo-imap4-encode-folder-string
1924                                              (cdr (assq 'mailbox tokens))))
1925     ;; user
1926     (elmo-net-folder-set-user-internal folder
1927                                        (or (cdr (assq 'user tokens))
1928                                            default-user))
1929     ;; auth
1930     (elmo-net-folder-set-auth-internal
1931      folder
1932      (let ((auth (cdr (assq 'auth tokens))))
1933        (or (and auth (intern auth))
1934            elmo-imap4-default-authenticate-type
1935            'clear)))
1936     ;; network
1937     (elmo-net-folder-set-parameters
1938      folder
1939      tokens
1940      (list :server      default-server
1941            :port        default-port
1942            :stream-type
1943            (elmo-get-network-stream-type elmo-imap4-default-stream-type)))
1944     folder))
1945
1946 ;;; ELMO IMAP4 folder
1947 (luna-define-method elmo-folder-expand-msgdb-path ((folder
1948                                                     elmo-imap4-folder))
1949   (convert-standard-filename
1950    (let ((mailbox (elmo-imap4-folder-mailbox-internal folder)))
1951      (if (string= "inbox" (downcase mailbox))
1952          (setq mailbox "inbox"))
1953      (if (eq (string-to-char mailbox) ?/)
1954          (setq mailbox (substring mailbox 1 (length mailbox))))
1955      ;; don't use expand-file-name (e.g. %~/something)
1956      (concat
1957       (expand-file-name
1958        (or (elmo-net-folder-user-internal folder) "nobody")
1959        (expand-file-name (or (elmo-net-folder-server-internal folder)
1960                              "nowhere")
1961                          (expand-file-name
1962                           "imap"
1963                           elmo-msgdb-directory)))
1964       "/" mailbox))))
1965
1966 (luna-define-method elmo-folder-status-plugged ((folder
1967                                                  elmo-imap4-folder))
1968   (elmo-imap4-folder-status-plugged folder))
1969
1970 (defun elmo-imap4-folder-status-plugged (folder)
1971   (let ((session (elmo-imap4-get-session folder))
1972         (killed (elmo-msgdb-killed-list-load
1973                  (elmo-folder-msgdb-path folder)))
1974         status)
1975     (with-current-buffer (elmo-network-session-buffer session)
1976       (setq elmo-imap4-status-callback nil)
1977       (setq elmo-imap4-status-callback-data nil))
1978     (setq status (elmo-imap4-response-value
1979                   (elmo-imap4-send-command-wait
1980                    session
1981                    (list "status "
1982                          (elmo-imap4-mailbox
1983                           (elmo-imap4-folder-mailbox-internal folder))
1984                          " (uidnext messages)"))
1985                   'status))
1986     (cons
1987      (- (elmo-imap4-response-value status 'uidnext) 1)
1988      (if killed
1989          (-
1990           (elmo-imap4-response-value status 'messages)
1991           (elmo-msgdb-killed-list-length killed))
1992        (elmo-imap4-response-value status 'messages)))))
1993
1994 (defun elmo-imap4-folder-list-range (folder min max)
1995   (elmo-imap4-list
1996    folder
1997    (concat
1998     (let ((killed (elmo-folder-killed-list-internal folder)))
1999       (if (and killed
2000                (eq (length killed) 1)
2001                (consp (car killed))
2002                (eq (car (car killed)) 1))
2003           ;; What about elmo-imap4-use-uid?
2004           (format "uid %d:%s" (cdr (car killed)) max)
2005         (format "uid %s:%s" min max)))
2006     " undeleted")))
2007
2008 (luna-define-method elmo-folder-list-messages-plugged
2009   ((folder elmo-imap4-folder) &optional enable-killed)
2010   (let* ((old (elmo-msgdb-list-messages (elmo-folder-msgdb folder)))
2011          (new (elmo-imap4-folder-list-range
2012                folder (1+ (or (elmo-folder-get-info-max folder) 0)) "*"))
2013          (united-old-new (elmo-union old new)))
2014     (if (= (length united-old-new) (or (elmo-folder-get-info-length folder) 0))
2015         united-old-new
2016       (elmo-union new
2017                   (elmo-imap4-folder-list-range
2018                    folder
2019                    1 (1+ (or (elmo-folder-get-info-max folder) 0)))))))
2020
2021 (luna-define-method elmo-folder-list-flagged-plugged
2022   ((folder elmo-imap4-folder) flag)
2023   (elmo-imap4-folder-list-flagged folder flag))
2024
2025 (luna-define-method elmo-folder-use-flag-p ((folder elmo-imap4-folder))
2026   (not (string-match elmo-imap4-disuse-server-flag-mailbox-regexp
2027                      (elmo-imap4-folder-mailbox-internal folder))))
2028
2029 (luna-define-method elmo-folder-list-subfolders ((folder elmo-imap4-folder)
2030                                                  &optional one-level)
2031   (let* ((root (elmo-imap4-folder-mailbox-internal folder))
2032          (session (elmo-imap4-get-session folder))
2033          (prefix (elmo-folder-prefix-internal folder))
2034          (namespace-assoc
2035                   (elmo-string-matched-assoc
2036                    root
2037                    (with-current-buffer (elmo-network-session-buffer session)
2038                      elmo-imap4-server-namespace)))
2039          (delim (or (cdr namespace-assoc)
2040                  elmo-imap4-default-hierarchy-delimiter))
2041          ;; Append delimiter when root with namespace.
2042          (root-nodelim root)
2043          (root (if (and namespace-assoc
2044                         (match-end 1)
2045                         (string= (substring root (match-end 1))
2046                                  ""))
2047                    (concat root delim)
2048                  root))
2049          result append-serv type)
2050     (setq result (elmo-imap4-response-get-selectable-mailbox-list
2051                   (elmo-imap4-send-command-wait
2052                    session
2053                    (list "list " (elmo-imap4-mailbox root) " *"))))
2054     ;; The response of Courier-imap doesn't contain a specified folder itself.
2055     (unless (member root result)
2056       (setq result
2057             (append result
2058                     (elmo-imap4-response-get-selectable-mailbox-list
2059                      (elmo-imap4-send-command-wait
2060                       session
2061                       (list "list \"\" " (elmo-imap4-mailbox
2062                                           root-nodelim)))))))
2063     (when (or (not (string= (elmo-net-folder-user-internal folder)
2064                             elmo-imap4-default-user))
2065               (not (eq (elmo-net-folder-auth-internal folder)
2066                        (or elmo-imap4-default-authenticate-type 'clear))))
2067       (setq append-serv (concat ":"
2068                                 (elmo-quote-syntactical-element
2069                                  (elmo-net-folder-user-internal folder)
2070                                  'user elmo-imap4-folder-name-syntax))))
2071     (unless (eq (elmo-net-folder-auth-internal folder)
2072                 (or elmo-imap4-default-authenticate-type 'clear))
2073       (setq append-serv
2074             (concat append-serv "/"
2075                     (symbol-name (elmo-net-folder-auth-internal folder)))))
2076     (unless (string= (elmo-net-folder-server-internal folder)
2077                      elmo-imap4-default-server)
2078       (setq append-serv (concat append-serv "@"
2079                                 (elmo-net-folder-server-internal folder))))
2080     (unless (eq (elmo-net-folder-port-internal folder) elmo-imap4-default-port)
2081       (setq append-serv (concat append-serv ":"
2082                                 (number-to-string
2083                                  (elmo-net-folder-port-internal folder)))))
2084     (setq type (elmo-net-folder-stream-type-internal folder))
2085     (unless (eq (elmo-network-stream-type-symbol type)
2086                 elmo-imap4-default-stream-type)
2087       (if type
2088           (setq append-serv (concat append-serv
2089                                     (elmo-network-stream-type-spec-string
2090                                      type)))))
2091     (if one-level
2092         (let ((re-delim (regexp-quote delim))
2093               (case-fold-search nil)
2094               folder ret has-child-p)
2095           ;; Append delimiter
2096           (when (and root
2097                      (not (string= root ""))
2098                      (not (string-match
2099                            (concat "\\(.*\\)" re-delim "\\'")
2100                            root)))
2101             (setq root (concat root delim)))
2102           (while (setq folder (car result))
2103             (setq has-child-p
2104                   (when (string-match
2105                          (concat "^\\(" (regexp-quote root) "[^" re-delim "]" "+\\)"
2106                                  re-delim)
2107                          folder)
2108                     (setq folder (match-string 1 folder))))
2109             (setq result (delq
2110                           nil
2111                           (mapcar (lambda (fld)
2112                                     (if (string-match
2113                                          (concat "^" (regexp-quote folder)
2114                                                  "\\(" re-delim "\\|\\'\\)")
2115                                          fld)
2116                                         (progn (setq has-child-p t) nil)
2117                                       fld))
2118                                   (cdr result)))
2119                   folder (concat prefix
2120                                  (elmo-quote-syntactical-element
2121                                   (elmo-imap4-decode-folder-string folder)
2122                                   'mailbox elmo-imap4-folder-name-syntax)
2123                                  (and append-serv
2124                                       (eval append-serv)))
2125                   ret (append ret (if has-child-p
2126                                       (list (list folder))
2127                                     (list folder)))))
2128           ret)
2129       (mapcar (lambda (fld)
2130                 (concat prefix
2131                         (elmo-quote-syntactical-element
2132                          (elmo-imap4-decode-folder-string fld)
2133                          'mailbox elmo-imap4-folder-name-syntax)
2134                         (and append-serv
2135                              (eval append-serv))))
2136               result))))
2137
2138 (luna-define-method elmo-folder-exists-p-plugged ((folder elmo-imap4-folder))
2139   (let ((session (elmo-imap4-get-session folder)))
2140     (if (string=
2141          (elmo-imap4-session-current-mailbox-internal session)
2142          (elmo-imap4-folder-mailbox-internal folder))
2143         t
2144       (elmo-imap4-session-select-mailbox
2145        session
2146        (elmo-imap4-folder-mailbox-internal folder)
2147        'force 'notify-bye))))
2148
2149 (luna-define-method elmo-folder-creatable-p ((folder elmo-imap4-folder))
2150   t)
2151
2152 (luna-define-method elmo-folder-writable-p ((folder elmo-imap4-folder))
2153   t)
2154
2155 (luna-define-method elmo-folder-delete ((folder elmo-imap4-folder))
2156   (let* ((exists (elmo-folder-exists-p folder))
2157          (msgs (and exists
2158                     (elmo-folder-list-messages folder))))
2159     (when (yes-or-no-p (format "%sDelete msgdb and substance of \"%s\"? "
2160                                (if (> (length msgs) 0)
2161                                    (format "%d msg(s) exists. " (length msgs))
2162                                  "")
2163                                (elmo-folder-name-internal folder)))
2164       (let ((session (elmo-imap4-get-session folder)))
2165         (when (elmo-imap4-folder-mailbox-internal folder)
2166           (when msgs (elmo-folder-delete-messages-internal folder msgs))
2167           ;; close selected mailbox except one with \Noselect attribute
2168           (when exists
2169             (elmo-imap4-send-command-wait session "close"))
2170           (elmo-imap4-send-command-wait
2171            session
2172            (list "delete "
2173                  (elmo-imap4-mailbox
2174                   (elmo-imap4-folder-mailbox-internal folder)))))
2175         (elmo-imap4-session-set-current-mailbox-internal session nil))
2176       (elmo-msgdb-delete-path folder)
2177       t)))
2178
2179 (luna-define-method elmo-folder-rename-internal ((folder elmo-imap4-folder)
2180                                                  new-folder)
2181   (let ((session (elmo-imap4-get-session folder)))
2182     ;; make sure the folder is selected.
2183     (elmo-imap4-session-select-mailbox session
2184                                        (elmo-imap4-folder-mailbox-internal
2185                                         folder))
2186     (elmo-imap4-session-unselect-mailbox session
2187                                          (elmo-imap4-folder-mailbox-internal
2188                                           folder))
2189     (elmo-imap4-send-command-wait session "close")
2190     (elmo-imap4-send-command-wait
2191      session
2192      (list "rename "
2193            (elmo-imap4-mailbox
2194             (elmo-imap4-folder-mailbox-internal folder))
2195            " "
2196            (elmo-imap4-mailbox
2197             (elmo-imap4-folder-mailbox-internal new-folder))))
2198     (elmo-imap4-session-set-current-mailbox-internal
2199      session (elmo-imap4-folder-mailbox-internal new-folder))))
2200
2201 (defun elmo-imap4-copy-messages (src-folder dst-folder numbers)
2202   (let ((session (elmo-imap4-get-session src-folder))
2203         (set-list (elmo-imap4-make-number-set-list
2204                    numbers
2205                    elmo-imap4-number-set-chop-length))
2206         succeeds)
2207     (elmo-imap4-session-select-mailbox session
2208                                        (elmo-imap4-folder-mailbox-internal
2209                                         src-folder))
2210     (while set-list
2211       (if (elmo-imap4-send-command-wait session
2212                                         (list
2213                                          (format
2214                                           (if elmo-imap4-use-uid
2215                                               "uid copy %s "
2216                                             "copy %s ")
2217                                           (cdr (car set-list)))
2218                                          (elmo-imap4-mailbox
2219                                           (elmo-imap4-folder-mailbox-internal
2220                                            dst-folder))))
2221           (setq succeeds (append succeeds numbers)))
2222       (setq set-list (cdr set-list)))
2223     succeeds))
2224
2225 (defun elmo-imap4-set-flag (folder numbers flag &optional remove)
2226   "Set flag on messages.
2227 FOLDER is the ELMO folder structure.
2228 NUMBERS is the message numbers to be flagged.
2229 FLAG is the flag name.
2230 If optional argument REMOVE is non-nil, remove FLAG."
2231   (let ((session (elmo-imap4-get-session folder))
2232         response set-list)
2233     (elmo-imap4-session-select-mailbox session
2234                                        (elmo-imap4-folder-mailbox-internal
2235                                         folder))
2236     (when (or (elmo-string-member-ignore-case
2237                flag
2238                (elmo-imap4-session-flags-internal session))
2239               (member "\\*" (elmo-imap4-session-flags-internal session))
2240               (string= flag "\\Deleted")) ; XXX Humm..
2241       (setq set-list (elmo-imap4-make-number-set-list
2242                       numbers
2243                       elmo-imap4-number-set-chop-length))
2244       (while set-list
2245         (with-current-buffer (elmo-network-session-buffer session)
2246           (setq elmo-imap4-fetch-callback nil)
2247           (setq elmo-imap4-fetch-callback-data nil))
2248         (unless (elmo-imap4-response-ok-p
2249                  (elmo-imap4-send-command-wait
2250                   session
2251                   (format
2252                    (if elmo-imap4-use-uid
2253                        "uid store %s %sflags.silent (%s)"
2254                      "store %s %sflags.silent (%s)")
2255                    (cdr (car set-list))
2256                    (if remove "-" "+")
2257                    flag)))
2258           (setq response 'fail))
2259         (setq set-list (cdr set-list)))
2260       (not (eq response 'fail)))))
2261
2262 (luna-define-method elmo-folder-delete-messages-plugged
2263   ((folder elmo-imap4-folder) numbers)
2264   (let ((session (elmo-imap4-get-session folder))
2265         (expunge
2266          (or (null (elmo-imap4-list folder "deleted"))
2267              (y-or-n-p
2268               "There's hidden deleted messages, expunge anyway?"))))
2269     (elmo-imap4-session-select-mailbox
2270      session
2271      (elmo-imap4-folder-mailbox-internal folder))
2272     (unless (elmo-imap4-set-flag folder numbers "\\Deleted")
2273       (error "Failed to set deleted flag"))
2274     (when expunge
2275       (elmo-imap4-send-command session "expunge"))
2276     t))
2277
2278 (defun elmo-imap4-detect-search-charset (string)
2279   (with-temp-buffer
2280     (insert string)
2281     (detect-mime-charset-region (point-min) (point-max))))
2282
2283 (defun elmo-imap4-search-internal-primitive (folder session filter from-msgs)
2284   (let ((search-key (elmo-filter-key filter))
2285         (imap-search-keys '("bcc" "body" "cc" "from" "subject" "to"
2286                             "larger" "smaller" "flag"))
2287         (total 0)
2288         (length (length from-msgs))
2289         charset set-list end results)
2290     (cond
2291      ((string= "last" search-key)
2292       (let ((numbers (or from-msgs (elmo-folder-list-messages folder))))
2293         (nthcdr (max (- (length numbers)
2294                         (string-to-number (elmo-filter-value filter)))
2295                      0)
2296                 numbers)))
2297      ((string= "first" search-key)
2298       (let* ((numbers (or from-msgs (elmo-folder-list-messages folder)))
2299              (rest (nthcdr (string-to-number (elmo-filter-value filter) )
2300                            numbers)))
2301         (mapc (lambda (x) (delete x numbers)) rest)
2302         numbers))
2303      ((string= "flag" search-key)
2304       (elmo-imap4-folder-list-flagged
2305        folder (intern (elmo-filter-value filter)) (elmo-filter-type filter)))
2306      ((or (string= "since" search-key)
2307           (string= "before" search-key))
2308       (setq search-key (concat "sent" search-key)
2309             set-list (elmo-imap4-make-number-set-list
2310                       from-msgs
2311                       elmo-imap4-number-set-chop-length)
2312             end nil)
2313       (while (not end)
2314         (setq results
2315               (append
2316                results
2317                (elmo-imap4-response-value
2318                 (elmo-imap4-send-command-wait
2319                  session
2320                  (format
2321                   (if elmo-imap4-use-uid
2322                       "uid search %s%s%s %s"
2323                     "search %s%s%s %s")
2324                   (if from-msgs
2325                       (concat
2326                        (if elmo-imap4-use-uid "uid ")
2327                        (cdr (car set-list))
2328                        " ")
2329                     "")
2330                   (if (eq (elmo-filter-type filter)
2331                           'unmatch)
2332                       "not " "")
2333                   search-key
2334                   (elmo-date-get-description
2335                    (elmo-date-get-datevec
2336                     (elmo-filter-value filter)))))
2337                 'search)))
2338         (setq set-list (cdr set-list)
2339               end (null set-list)))
2340       results)
2341      (t
2342       (setq charset
2343             (if (eq (length (elmo-filter-value filter)) 0)
2344                 (setq charset 'us-ascii)
2345               (elmo-imap4-detect-search-charset
2346                (elmo-filter-value filter)))
2347             set-list (elmo-imap4-make-number-set-list
2348                       from-msgs
2349                       elmo-imap4-number-set-chop-length)
2350             end nil)
2351       (while (not end)
2352         (setq results
2353               (append
2354                results
2355                (elmo-imap4-response-value
2356                 (elmo-imap4-send-command-wait
2357                  session
2358                  (list
2359                   (if elmo-imap4-use-uid "uid ")
2360                   "search "
2361                   "CHARSET "
2362                   (elmo-imap4-astring
2363                    (symbol-name charset))
2364                   " "
2365                   (if from-msgs
2366                       (concat
2367                        (if elmo-imap4-use-uid "uid ")
2368                        (cdr (car set-list))
2369                        " ")
2370                     "")
2371                   (if (eq (elmo-filter-type filter)
2372                           'unmatch)
2373                       "not " "")
2374                   (format "%s%s "
2375                           (if (member
2376                                (elmo-filter-key filter)
2377                                imap-search-keys)
2378                               ""
2379                             "header ")
2380                           (elmo-filter-key filter))
2381                   (elmo-imap4-astring
2382                    (encode-mime-charset-string
2383                     (elmo-filter-value filter) charset))))
2384                 'search)))
2385         (setq set-list (cdr set-list)
2386               end (null set-list)))
2387       results))))
2388
2389 (defun elmo-imap4-search-internal (folder session condition from-msgs)
2390   (let (result)
2391     (cond
2392      ((vectorp condition)
2393       (setq result (elmo-imap4-search-internal-primitive
2394                     folder session condition from-msgs)))
2395      ((eq (car condition) 'and)
2396       (setq result (elmo-imap4-search-internal folder session (nth 1 condition)
2397                                                from-msgs)
2398             result (elmo-list-filter result
2399                                      (elmo-imap4-search-internal
2400                                       folder session (nth 2 condition)
2401                                       from-msgs))))
2402      ((eq (car condition) 'or)
2403       (setq result (elmo-imap4-search-internal
2404                     folder session (nth 1 condition) from-msgs)
2405             result (elmo-uniq-list
2406                     (nconc result
2407                            (elmo-imap4-search-internal
2408                             folder session (nth 2 condition) from-msgs)))
2409             result (sort result '<))))))
2410
2411 (luna-define-method elmo-folder-search :around ((folder elmo-imap4-folder)
2412                                                 condition &optional numbers)
2413   (if (elmo-folder-plugged-p folder)
2414       (save-excursion
2415         (let ((session (elmo-imap4-get-session folder))
2416               ret)
2417           (message "Searching...")
2418           (elmo-imap4-session-select-mailbox
2419            session
2420            (elmo-imap4-folder-mailbox-internal folder))
2421           (setq ret (elmo-imap4-search-internal folder session condition numbers))
2422           (message "Searching...done")
2423           ret))
2424     (luna-call-next-method)))
2425
2426 (luna-define-method elmo-folder-msgdb-create-plugged
2427   ((folder elmo-imap4-folder) numbers flag-table)
2428   (when numbers
2429     (let ((session (elmo-imap4-get-session folder))
2430           (headers
2431            (elmo-uniq-list
2432             (append
2433              '("Subject" "From" "To" "Cc" "Date"
2434                "Message-Id" "References" "In-Reply-To")
2435              (mapcar #'capitalize (elmo-msgdb-extra-fields 'non-virtual)))))
2436           (total 0)
2437           print-length print-depth
2438           rfc2060 set-list)
2439       (setq rfc2060 (elmo-imap4-session-capable-p session 'imap4rev1))
2440       (elmo-with-progress-display (elmo-folder-msgdb-create (length numbers))
2441           "Creating msgdb"
2442         (elmo-imap4-session-select-mailbox
2443          session (elmo-imap4-folder-mailbox-internal folder))
2444         (setq set-list (elmo-imap4-make-number-set-list
2445                         numbers
2446                         elmo-imap4-overview-fetch-chop-length))
2447         ;; Setup callback.
2448         (with-current-buffer (elmo-network-session-buffer session)
2449           (setq elmo-imap4-current-msgdb (elmo-make-msgdb)
2450                 elmo-imap4-seen-messages nil
2451                 elmo-imap4-fetch-callback 'elmo-imap4-fetch-callback-1
2452                 elmo-imap4-fetch-callback-data (cons flag-table folder))
2453           (while set-list
2454             (elmo-imap4-send-command-wait
2455              session
2456              ;; get overview entity from IMAP4
2457              (format "%sfetch %s (%s rfc822.size flags)"
2458                      (if elmo-imap4-use-uid "uid " "")
2459                      (cdr (car set-list))
2460                      (if rfc2060
2461                          (format "body.peek[header.fields %s]" headers)
2462                        (format "%s" headers))))
2463             (setq set-list (cdr set-list)))
2464           (when elmo-imap4-seen-messages
2465             (elmo-imap4-set-flag folder elmo-imap4-seen-messages "\\Seen"))
2466           ;; cannot setup the global flag while retrieval.
2467           (dolist (number (elmo-msgdb-list-messages elmo-imap4-current-msgdb))
2468             (elmo-global-flags-set (elmo-msgdb-flags elmo-imap4-current-msgdb
2469                                                      number)
2470                                    folder number
2471                                    (elmo-message-entity-field
2472                                     (elmo-msgdb-message-entity
2473                                      elmo-imap4-current-msgdb number)
2474                                     'message-id)))
2475           elmo-imap4-current-msgdb)))))
2476
2477 (luna-define-method elmo-folder-set-flag-plugged ((folder elmo-imap4-folder)
2478                                                   numbers flag)
2479   (let ((spec (cdr (assq flag elmo-imap4-flag-specs))))
2480     (elmo-imap4-set-flag folder numbers (or (car spec)
2481                                             (capitalize (symbol-name flag)))
2482                          (nth 1 spec))))
2483
2484 (luna-define-method elmo-folder-unset-flag-plugged ((folder elmo-imap4-folder)
2485                                                     numbers flag)
2486   (let ((spec (cdr (assq flag elmo-imap4-flag-specs))))
2487     (elmo-imap4-set-flag folder numbers (or (car spec)
2488                                             (capitalize (symbol-name flag)))
2489                          (not (nth 1 spec)))))
2490
2491 (luna-define-method elmo-message-use-cache-p ((folder elmo-imap4-folder)
2492                                               number)
2493   elmo-imap4-use-cache)
2494
2495 (luna-define-method elmo-folder-message-appendable-p ((folder elmo-imap4-folder))
2496   (if (elmo-folder-plugged-p folder)
2497       (not (elmo-imap4-session-read-only-internal
2498             (elmo-imap4-get-session folder)))
2499     elmo-enable-disconnected-operation)) ; offline refile.
2500
2501 (luna-define-method elmo-folder-check-plugged ((folder elmo-imap4-folder))
2502   (let ((session (elmo-imap4-get-session folder 'if-exists)))
2503     (when session
2504       (if (string=
2505            (elmo-imap4-session-current-mailbox-internal session)
2506            (elmo-imap4-folder-mailbox-internal folder))
2507           (if elmo-imap4-use-select-to-update-status
2508               (elmo-imap4-session-select-mailbox
2509                session
2510                (elmo-imap4-folder-mailbox-internal folder)
2511                'force)
2512             (elmo-imap4-session-check session))))))
2513
2514 (defsubst elmo-imap4-folder-diff-plugged (folder)
2515   (let ((session (elmo-imap4-get-session folder))
2516         messages new unread response killed uidnext)
2517 ;;;    (elmo-imap4-commit spec)
2518     (with-current-buffer (elmo-network-session-buffer session)
2519       (setq elmo-imap4-status-callback nil)
2520       (setq elmo-imap4-status-callback-data nil))
2521     (if elmo-imap4-use-select-to-update-status
2522         (elmo-imap4-session-select-mailbox
2523          session
2524          (elmo-imap4-folder-mailbox-internal folder)))
2525     (setq response
2526           (elmo-imap4-send-command-wait session
2527                                         (list
2528                                          "status "
2529                                          (elmo-imap4-mailbox
2530                                           (elmo-imap4-folder-mailbox-internal
2531                                            folder))
2532                                          " (recent unseen messages uidnext)")))
2533     (setq response (elmo-imap4-response-value response 'status))
2534     (setq messages (elmo-imap4-response-value response 'messages))
2535     (setq uidnext (elmo-imap4-response-value response 'uidnext))
2536     (setq killed (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder)))
2537     ;;
2538     (when killed
2539       (when (and (consp (car killed))
2540                  (eq (car (car killed)) 1))
2541         (setq messages (- uidnext (cdr (car killed)) 1)))
2542       (setq messages (- messages
2543                         (elmo-msgdb-killed-list-length (cdr killed)))))
2544     (setq new (elmo-imap4-response-value response 'recent)
2545           unread (elmo-imap4-response-value response 'unseen))
2546     (if (< unread new) (setq new unread))
2547     (list new unread messages)))
2548
2549 (luna-define-method elmo-folder-diff-plugged ((folder elmo-imap4-folder))
2550   (elmo-imap4-folder-diff-plugged folder))
2551
2552 (luna-define-method elmo-folder-diff-async ((folder elmo-imap4-folder))
2553   (setq elmo-imap4-server-diff-async-callback
2554         elmo-folder-diff-async-callback)
2555   (setq elmo-imap4-server-diff-async-callback-data
2556         elmo-folder-diff-async-callback-data)
2557   (elmo-imap4-server-diff-async folder))
2558
2559 (luna-define-method elmo-folder-open :around ((folder elmo-imap4-folder)
2560                                               &optional load-msgdb)
2561   (if (elmo-folder-plugged-p folder)
2562       (let (session mailbox msgdb result response tag)
2563         (condition-case err
2564             (progn
2565               (setq session (elmo-imap4-get-session folder)
2566                     mailbox (elmo-imap4-folder-mailbox-internal folder)
2567                     tag (elmo-imap4-send-command session
2568                                                  (list "select "
2569                                                        (elmo-imap4-mailbox
2570                                                         mailbox))))
2571               (message "Selecting %s..."
2572                        (elmo-folder-name-internal folder))
2573               (if load-msgdb
2574                   (setq msgdb (elmo-folder-msgdb-load folder 'silent)))
2575               (elmo-folder-set-killed-list-internal
2576                folder
2577                (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder)))
2578               (if (setq result (elmo-imap4-response-ok-p
2579                                 (setq response
2580                                       (elmo-imap4-read-response session tag))))
2581                   (progn
2582                     (let ((exists (assq 'exists response))) ; update message count,
2583                       (when exists                          ; so merge update can go
2584                         (elmo-folder-set-info-hashtb folder nil (cadr exists))))
2585                     (elmo-imap4-session-set-current-mailbox-internal
2586                      session mailbox)
2587                     (elmo-imap4-session-set-read-only-internal
2588                      session
2589                      (nth 1 (assq 'read-only (assq 'ok response))))
2590                     (elmo-imap4-session-set-flags-internal
2591                      session
2592                      (nth 1 (or (assq 'permanentflags response)
2593                                 (assq 'flags response)))))
2594                 (elmo-imap4-session-set-current-mailbox-internal session nil)
2595                 (if (elmo-imap4-response-bye-p response)
2596                     (elmo-imap4-process-bye session)
2597                   (error "%s"
2598                          (or (elmo-imap4-response-error-text response)
2599                              (format "Select %s failed" mailbox)))))
2600               (message "Selecting %s...done"
2601                        (elmo-folder-name-internal folder))
2602               (elmo-folder-set-msgdb-internal
2603                folder msgdb))
2604           (quit
2605            (if (elmo-imap4-response-ok-p response)
2606                (elmo-imap4-session-set-current-mailbox-internal
2607                 session mailbox)
2608              (and session
2609                   (elmo-imap4-session-set-current-mailbox-internal
2610                    session nil))))
2611           (error
2612            (if (elmo-imap4-response-ok-p response)
2613                (elmo-imap4-session-set-current-mailbox-internal
2614                 session mailbox)
2615              (and session
2616                   (elmo-imap4-session-set-current-mailbox-internal
2617                    session nil))))))
2618     (luna-call-next-method)))
2619
2620 ;; elmo-folder-open-internal: do nothing.
2621
2622 (luna-define-method elmo-find-fetch-strategy ((folder elmo-imap4-folder) number
2623                                               &optional
2624                                               ignore-cache
2625                                               require-entireness)
2626   (let ((entity (elmo-message-entity folder number)))
2627     (if (null entity)
2628         (elmo-make-fetch-strategy 'entire)
2629       (let* ((size (elmo-message-entity-field entity 'size))
2630              (message-id (elmo-message-entity-field entity 'message-id))
2631              (cache-file (elmo-file-cache-get message-id))
2632              (use-cache (and (not ignore-cache)
2633                              (elmo-message-use-cache-p folder number)
2634                              (if require-entireness
2635                                  (eq (elmo-file-cache-status cache-file)
2636                                      'entire)
2637                                (elmo-file-cache-status cache-file)))))
2638         (elmo-make-fetch-strategy
2639          (if use-cache
2640              (elmo-file-cache-status cache-file)
2641            (if (and (not require-entireness)
2642                     elmo-message-fetch-threshold
2643                     (integerp size)
2644                     (>= size elmo-message-fetch-threshold)
2645                     (or (not elmo-message-fetch-confirm)
2646                         (not (prog1
2647                                  (y-or-n-p
2648                                   (format
2649                                    "Fetch entire message at once? (%dbytes)"
2650                                    size))
2651                                (message "")))))
2652                'section
2653              'entire))
2654          use-cache
2655          (elmo-message-use-cache-p folder number)
2656          (elmo-file-cache-path cache-file))))))
2657
2658 (luna-define-method elmo-folder-create-plugged ((folder elmo-imap4-folder))
2659   (elmo-imap4-send-command-wait
2660    (elmo-imap4-get-session folder)
2661    (list "create "
2662          (elmo-imap4-mailbox
2663           (elmo-imap4-folder-mailbox-internal folder)))))
2664
2665 (defun elmo-imap4-flags-to-imap (flags)
2666   "Convert FLAGS to the IMAP flag string."
2667   (let ((imap-flag (if (not (memq 'unread flags)) "\\Seen")))
2668     (dolist (flag flags)
2669       (unless (memq flag '(new read unread cached))
2670         (setq imap-flag
2671               (concat imap-flag
2672                       (if imap-flag " ")
2673                       (or (car (cdr (assq flag elmo-imap4-flag-specs)))
2674                           (capitalize (symbol-name flag)))))))
2675     imap-flag))
2676
2677 (luna-define-method elmo-folder-append-buffer
2678   ((folder elmo-imap4-folder) &optional flags number)
2679   (if (elmo-folder-plugged-p folder)
2680       (let ((session (elmo-imap4-get-session folder))
2681             send-buffer result)
2682         (elmo-imap4-session-select-mailbox session
2683                                            (elmo-imap4-folder-mailbox-internal
2684                                             folder))
2685         (setq send-buffer (elmo-imap4-setup-send-buffer))
2686         (unwind-protect
2687             (setq result
2688                   (elmo-imap4-send-command-wait
2689                    session
2690                    (list
2691                     "append "
2692                     (elmo-imap4-mailbox (elmo-imap4-folder-mailbox-internal
2693                                          folder))
2694                     (if (and flags (elmo-folder-use-flag-p folder))
2695                         (concat " (" (elmo-imap4-flags-to-imap flags) ") ")
2696                       " () ")
2697                     (elmo-imap4-buffer-literal send-buffer))))
2698           (kill-buffer send-buffer))
2699         (when result
2700           (elmo-folder-preserve-flags
2701            folder (elmo-msgdb-get-message-id-from-buffer) flags))
2702         result)
2703     ;; Unplugged
2704     (if elmo-enable-disconnected-operation
2705         (elmo-folder-append-buffer-dop folder flags number)
2706       (error "Unplugged"))))
2707
2708 (eval-when-compile
2709   (defmacro elmo-imap4-identical-system-p (folder1 folder2)
2710     "Return t if FOLDER1 and FOLDER2 are in the same IMAP4 system."
2711     `(and (string= (elmo-net-folder-server-internal ,folder1)
2712                    (elmo-net-folder-server-internal ,folder2))
2713           (eq (elmo-net-folder-port-internal ,folder1)
2714               (elmo-net-folder-port-internal ,folder2))
2715           (string= (elmo-net-folder-user-internal ,folder1)
2716                    (elmo-net-folder-user-internal ,folder2)))))
2717
2718 (luna-define-method elmo-folder-next-message-number-plugged
2719   ((folder elmo-imap4-folder))
2720   (let ((session (elmo-imap4-get-session folder))
2721         messages new unread response killed uidnext)
2722     (with-current-buffer (elmo-network-session-buffer session)
2723       (setq elmo-imap4-status-callback nil)
2724       (setq elmo-imap4-status-callback-data nil))
2725     (if elmo-imap4-use-select-to-update-status
2726         (elmo-imap4-session-select-mailbox
2727          session
2728          (elmo-imap4-folder-mailbox-internal folder)))
2729     (setq response
2730           (elmo-imap4-send-command-wait session
2731                                         (list
2732                                          "status "
2733                                          (elmo-imap4-mailbox
2734                                           (elmo-imap4-folder-mailbox-internal
2735                                            folder))
2736                                          " (uidnext)"))
2737           response (elmo-imap4-response-value response 'status))
2738     (elmo-imap4-response-value response 'uidnext)))
2739
2740 (defun elmo-folder-append-messages-imap4-imap4 (dst-folder
2741                                                 src-folder
2742                                                 numbers
2743                                                 same-number)
2744   (if (and (elmo-imap4-identical-system-p dst-folder src-folder)
2745            (elmo-folder-plugged-p dst-folder))
2746       ;; Plugged
2747       (prog1
2748           (elmo-imap4-copy-messages src-folder dst-folder numbers)
2749         (elmo-progress-notify 'elmo-folder-move-messages (length numbers)))
2750     (elmo-folder-append-messages dst-folder src-folder numbers same-number
2751                                  'elmo-folder-append-messages-imap4-imap4)))
2752
2753 (luna-define-method elmo-message-deletable-p ((folder elmo-imap4-folder)
2754                                               number)
2755   (if (elmo-folder-plugged-p folder)
2756       (not (elmo-imap4-session-read-only-internal
2757             (elmo-imap4-get-session folder)))
2758     elmo-enable-disconnected-operation)) ; offline refile.
2759
2760 ;;;(luna-define-method elmo-message-fetch-unplugged
2761 ;;;  ((folder elmo-imap4-folder)
2762 ;;;   number strategy  &optional section outbuf unseen)
2763 ;;;  (error "%d%s is not cached." number (if section
2764 ;;;                                       (format "(%s)" section)
2765 ;;;                                     "")))
2766
2767 (defsubst elmo-imap4-message-fetch (folder number strategy
2768                                            section outbuf unseen)
2769   (let ((session (elmo-imap4-get-session folder))
2770         response)
2771     (elmo-imap4-session-select-mailbox session
2772                                        (elmo-imap4-folder-mailbox-internal
2773                                         folder))
2774     (with-current-buffer (elmo-network-session-buffer session)
2775       (setq elmo-imap4-fetch-callback nil)
2776       (setq elmo-imap4-fetch-callback-data nil))
2777     (elmo-with-progress-display (elmo-retrieve-message
2778                                  (elmo-message-field folder number :size)
2779                                  elmo-imap4-literal-progress-reporter)
2780         "Retrieving"
2781       (setq response
2782             (elmo-imap4-send-command-wait session
2783                                           (format
2784                                            (if elmo-imap4-use-uid
2785                                                "uid fetch %s body%s[%s]"
2786                                              "fetch %s body%s[%s]")
2787                                            number
2788                                            (if unseen ".peek" "")
2789                                            (or section "")))))
2790     (if (setq response (elmo-imap4-response-bodydetail-text
2791                         (elmo-imap4-response-value-all
2792                          response 'fetch)))
2793         (with-current-buffer outbuf
2794           (erase-buffer)
2795           (insert response)
2796           (elmo-delete-cr-buffer)
2797           t))))
2798
2799 (luna-define-method elmo-message-fetch-plugged ((folder elmo-imap4-folder)
2800                                                 number strategy
2801                                                 &optional section
2802                                                 outbuf unseen)
2803   (when elmo-imap4-set-seen-flag-explicitly
2804     (elmo-imap4-set-flag folder (list number) "\\Seen"))
2805   (elmo-imap4-message-fetch folder number strategy section outbuf unseen))
2806
2807 (luna-define-method elmo-message-fetch-field ((folder elmo-imap4-folder)
2808                                               number field)
2809   (let ((session (elmo-imap4-get-session folder)))
2810     (elmo-imap4-session-select-mailbox session
2811                                        (elmo-imap4-folder-mailbox-internal
2812                                         folder))
2813     (with-current-buffer (elmo-network-session-buffer session)
2814       (setq elmo-imap4-fetch-callback nil)
2815       (setq elmo-imap4-fetch-callback-data nil))
2816     (with-temp-buffer
2817       (insert
2818        (elmo-imap4-response-bodydetail-text
2819         (elmo-imap4-response-value
2820          (elmo-imap4-send-command-wait session
2821                                        (concat
2822                                         (if elmo-imap4-use-uid
2823                                             "uid ")
2824                                         (format
2825                                          "fetch %s (body.peek[header.fields (%s)])"
2826                                          number field)))
2827          'fetch)))
2828       (elmo-delete-cr-buffer)
2829       (goto-char (point-min))
2830       (std11-field-body (symbol-name field)))))
2831
2832 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder
2833                                                           elmo-imap4-folder)
2834                                                          condition)
2835   nil)
2836
2837 (autoload 'elmo-global-flags-set "elmo-flag")
2838 (autoload 'elmo-get-global-flags "elmo-flag")
2839
2840 (require 'product)
2841 (product-provide (provide 'elmo-imap4) (require 'elmo-version))
2842
2843 ;;; elmo-imap4.el ends here