elmo/elmo-imap4.el

   1 ;;; elmo-imap4.el --- IMAP4 Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   5 ;; Copyright (C) 2000           OKAZAKI Tetsurou <okazaki@be.to>
   6 ;; Copyright (C) 2000           Daiki Ueno <ueno@unixuser.org>
   7
   8 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   9 ;;      Kenichi OKADA <okada@opaopa.org>
  10 ;;      OKAZAKI Tetsurou <okazaki@be.to>
  11 ;;      Daiki Ueno <ueno@unixuser.org>
  12 ;; Keywords: mail, net news
  13
  14 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  15
  16 ;; This program is free software; you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation; either version 2, or (at your option)
  19 ;; any later version.
  20 ;;
  21 ;; This program is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25 ;;
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  28 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  29 ;; Boston, MA 02111-1307, USA.
  30 ;;
  31
  32 ;;; Commentary:
  33 ;;
  34 ;; Origin of IMAP parser part is imap.el, included in Gnus.
  35 ;;
  36 ;;    Copyright (C) 1998, 1999, 2000
  37 ;;    Free Software Foundation, Inc.
  38 ;;    Author: Simon Josefsson <jas@pdc.kth.se>
  39 ;;
  40
  41 (require 'elmo-vars)
  42 (require 'elmo-util)
  43 (require 'elmo-date)
  44 (require 'elmo-msgdb)
  45 (require 'elmo-cache)
  46 (require 'elmo)
  47 (require 'elmo-net)
  48 (require 'utf7)
  49 (require 'elmo-mime)
  50
  51 ;;; Code:
  52 (eval-when-compile (require 'cl))
  53
  54 (defvar elmo-imap4-disuse-server-flag-mailbox-regexp "^#mh" ; UW imapd
  55   "Regexp to match IMAP4 mailbox names whose message flags on server should be ignored (For STATUS command).")
  56
  57 (defvar elmo-imap4-overview-fetch-chop-length 200
  58   "*Number of overviews to fetch in one request.")
  59
  60 ;; c.f. rfc2683 3.2.1.5 Long Command Lines
  61 ;;
  62 ;; "A client should limit the length of the command lines it generates
  63 ;;  to approximately 1000 octets (including all quoted strings but not
  64 ;;  including literals). If the client is unable to group things into
  65 ;;  ranges so that the command line is within that length, it should
  66 ;;  split the request into multiple commands. The client should use
  67 ;;  literals instead of long quoted strings, in order to keep the command
  68 ;;  length down.
  69 ;;  For its part, a server should allow for a command line of at least
  70 ;;  8000 octets. This provides plenty of leeway for accepting reasonable
  71 ;;  length commands from clients. The server should send a BAD response
  72 ;;  to a command that does not end within the server's maximum accepted
  73 ;;  command length. "
  74
  75 ;; To limit command line length, chop number set.
  76 (defvar elmo-imap4-number-set-chop-length 1000
  77   "*Number of messages to specify as a number-set argument for one request.")
  78
  79 (defvar elmo-imap4-force-login nil
  80   "*Non-nil forces to try 'login' if there is no 'auth' capability in imapd.")
  81
  82 (defvar elmo-imap4-use-select-to-update-status nil
  83   "*Some imapd have to send select command to update status.
  84 \(ex. UW imapd 4.5-BETA?\).  For these imapd, you must set this variable t.")
  85
  86 (defvar elmo-imap4-use-modified-utf7 nil
  87   "*Use mofidied UTF-7 (rfc2060) encoding for IMAP4 folder name.")
  88
  89 (defvar elmo-imap4-use-cache t
  90   "Use cache in imap4 folder.")
  91
  92 (defvar elmo-imap4-extra-namespace-alist
  93   '(("^\\({.*/nntp}\\).*$" . ".")) ; Default is for UW's remote nntp mailbox...
  94   "Extra namespace alist.
  95 A list of cons cell like: (REGEXP . DELIMITER).
  96 REGEXP should have a grouping for namespace prefix.")
  97 ;;
  98 ;;; internal variables
  99 ;;
 100 (defvar elmo-imap4-seq-prefix "elmo-imap4")
 101 (defvar elmo-imap4-seqno 0)
 102 (defvar elmo-imap4-use-uid t
 103   "Use UID as message number.")
 104
 105 (defvar elmo-imap4-current-response nil)
 106 (defvar elmo-imap4-status nil)
 107 (defvar elmo-imap4-reached-tag "elmo-imap40")
 108
 109 ;;; buffer local variables
 110 (defvar elmo-imap4-default-hierarchy-delimiter "/")
 111
 112 (defvar elmo-imap4-server-capability nil)
 113 (defvar elmo-imap4-server-namespace nil)
 114
 115 (defvar elmo-imap4-parsing nil) ; indicates parsing.
 116
 117 (defvar elmo-imap4-fetch-callback nil)
 118 (defvar elmo-imap4-fetch-callback-data nil)
 119 (defvar elmo-imap4-status-callback nil)
 120 (defvar elmo-imap4-status-callback-data nil)
 121
 122 (defvar elmo-imap4-server-diff-async-callback nil)
 123 (defvar elmo-imap4-server-diff-async-callback-data nil)
 124
 125 ;;; progress...(no use?)
 126 (defvar elmo-imap4-count-progress nil)
 127 (defvar elmo-imap4-count-progress-message nil)
 128 (defvar elmo-imap4-progress-count nil)
 129
 130 ;;; XXX Temporal implementation
 131 (defvar elmo-imap4-current-msgdb nil)
 132 (defvar elmo-imap4-seen-messages nil)
 133
 134 (defvar elmo-imap4-local-variables
 135   '(elmo-imap4-status
 136     elmo-imap4-current-response
 137     elmo-imap4-seqno
 138     elmo-imap4-parsing
 139     elmo-imap4-reached-tag
 140     elmo-imap4-count-progress
 141     elmo-imap4-count-progress-message
 142     elmo-imap4-progress-count
 143     elmo-imap4-fetch-callback
 144     elmo-imap4-fetch-callback-data
 145     elmo-imap4-status-callback
 146     elmo-imap4-status-callback-data
 147     elmo-imap4-current-msgdb
 148     elmo-imap4-seen-messages))
 149
 150 ;;;;
 151
 152 (defconst elmo-imap4-quoted-specials-list '(?\\ ?\"))
 153
 154 (defconst elmo-imap4-non-atom-char-regex
 155   (eval-when-compile
 156     (concat "[^" "]!#$&'+,./0-9:;<=>?@A-Z[^_`a-z|}~-" "]")))
 157
 158 (defconst elmo-imap4-non-text-char-regex
 159   (eval-when-compile
 160     (concat "[^"
 161             "]\x01-\x09\x0b\x0c\x0e-\x1f\x7f !\"#$%&'()*+,./0-9:;<=>?@A-Z[\\^_`a-z{|}~-"
 162             "]")))
 163
 164 (defconst elmo-imap4-literal-threshold 1024
 165  "Limitation of characters that can be used in a quoted string.")
 166
 167 (defconst elmo-imap4-flag-specs '((important "\\Flagged")
 168                                   (read "\\Seen")
 169                                   (unread "\\Seen" 'remove)
 170                                   (answered "\\Answered")
 171                                   ;; draft-melnikov-imap-keywords-03.txt
 172                                   (forwarded "$Forwarded")
 173                                   (work "$Work")
 174                                   (personal "$Personal")
 175                                   (shouldreply "$ShouldReply")))
 176
 177 (defconst elmo-imap4-folder-name-syntax
 178   `(mailbox
 179     (?: [user "^[A-Za-z]"] (?/ [auth ".+"]))
 180     ,@elmo-net-folder-name-syntax))
 181
 182 ;; For debugging.
 183 (defvar elmo-imap4-debug nil
 184   "Non-nil forces IMAP4 folder as debug mode.
 185 Debug information is inserted in the buffer \"*IMAP4 DEBUG*\"")
 186
 187 (defvar elmo-imap4-debug-inhibit-logging nil)
 188
 189 ;;; ELMO IMAP4 folder
 190 (eval-and-compile
 191   (luna-define-class elmo-imap4-folder (elmo-net-folder)
 192                      (mailbox))
 193   (luna-define-internal-accessors 'elmo-imap4-folder))
 194
 195 ;;; Session
 196 (eval-and-compile
 197   (luna-define-class elmo-imap4-session (elmo-network-session)
 198                      (capability current-mailbox read-only flags))
 199   (luna-define-internal-accessors 'elmo-imap4-session))
 200
 201 (defmacro elmo-imap4-session-capable-p (session capability)
 202   `(memq ,capability (elmo-imap4-session-capability-internal ,session)))
 203
 204 ;;; MIME-ELMO-IMAP Location
 205 (eval-and-compile
 206   (luna-define-class mime-elmo-imap-location
 207                      (mime-imap-location)
 208                      (folder number rawbuf strategy))
 209   (luna-define-internal-accessors 'mime-elmo-imap-location))
 210
 211 ;;; Debug
 212 (defmacro elmo-imap4-debug (message &rest args)
 213   (` (if elmo-imap4-debug
 214          (elmo-imap4-debug-1 (, message) (,@ args)))))
 215
 216 (defun elmo-imap4-debug-1 (message &rest args)
 217   (with-current-buffer (get-buffer-create "*IMAP4 DEBUG*")
 218     (goto-char (point-max))
 219     (if elmo-imap4-debug-inhibit-logging
 220         (insert "NO LOGGING\n")
 221       (insert (apply 'format message args) "\n"))))
 222
 223 (defsubst elmo-imap4-decode-folder-string (string)
 224   (if elmo-imap4-use-modified-utf7
 225       (utf7-decode string 'imap)
 226     string))
 227
 228 (defsubst elmo-imap4-encode-folder-string (string)
 229   (if elmo-imap4-use-modified-utf7
 230       (utf7-encode string 'imap)
 231     string))
 232
 233 ;;; Response
 234
 235 (defmacro elmo-imap4-response-continue-req-p (response)
 236   "Returns non-nil if RESPONSE is '+' response."
 237   (` (assq 'continue-req (, response))))
 238
 239 (defmacro elmo-imap4-response-ok-p (response)
 240   "Returns non-nil if RESPONSE is an 'OK' response."
 241   (` (assq 'ok (, response))))
 242
 243 (defmacro elmo-imap4-response-bye-p (response)
 244   "Returns non-nil if RESPONSE is an 'BYE' response."
 245   (` (assq 'bye (, response))))
 246
 247 (defmacro elmo-imap4-response-garbage-p (response)
 248   "Returns non-nil if RESPONSE is an 'garbage' response."
 249   (` (assq 'garbage (, response))))
 250
 251 (defmacro elmo-imap4-response-value (response symbol)
 252   "Get value of the SYMBOL from RESPONSE."
 253   (` (nth 1 (assq (, symbol) (, response)))))
 254
 255 (defsubst elmo-imap4-response-value-all (response symbol)
 256   "Get all value of the SYMBOL from RESPONSE."
 257   (let (matched)
 258     (while response
 259       (if (eq (car (car response)) symbol)
 260           (setq matched (nconc matched (nth 1 (car response)))))
 261       (setq response (cdr response)))
 262     matched))
 263
 264 (defmacro elmo-imap4-response-error-text (response)
 265   "Returns text of NO, BAD, BYE response."
 266   (` (nth 1 (or (elmo-imap4-response-value (, response) 'no)
 267                 (elmo-imap4-response-value (, response) 'bad)
 268                 (elmo-imap4-response-value (, response) 'bye)))))
 269
 270 (defmacro elmo-imap4-response-bodydetail-text (response)
 271   "Returns text of BODY[section]<partial>."
 272   (` (nth 3 (assq 'bodydetail (, response)))))
 273
 274 ;;; Session commands.
 275
 276 ; (defun elmo-imap4-send-command-wait (session command)
 277 ;   "Send COMMAND to the SESSION and wait for response.
 278 ; Returns RESPONSE (parsed lisp object) of IMAP session."
 279 ;   (elmo-imap4-read-response session
 280 ;                           (elmo-imap4-send-command
 281 ;                            session
 282 ;                            command)))
 283
 284 (defun elmo-imap4-send-command-wait (session command)
 285   "Send COMMAND to the SESSION.
 286 Returns RESPONSE (parsed lisp object) of IMAP session.
 287 If response is not `OK', causes error with IMAP response text."
 288   (elmo-imap4-accept-ok session
 289                         (elmo-imap4-send-command
 290                          session
 291                          command)))
 292
 293 (defun elmo-imap4-send-command (session command)
 294   "Send COMMAND to the SESSION.
 295 Returns a TAG string which is assigned to the COMMAND."
 296   (let* ((command-args (if (listp command)
 297                            command
 298                          (list command)))
 299          (process (elmo-network-session-process-internal session))
 300          cmdstr tag token kind)
 301     (with-current-buffer (process-buffer process)
 302       (setq tag (concat elmo-imap4-seq-prefix
 303                         (number-to-string
 304                          (setq elmo-imap4-seqno (+ 1 elmo-imap4-seqno)))))
 305       (setq cmdstr (concat tag " "))
 306       ;; (erase-buffer) No need.
 307       (goto-char (point-min))
 308       (when (elmo-imap4-response-bye-p elmo-imap4-current-response)
 309         (elmo-imap4-process-bye session))
 310       (setq elmo-imap4-current-response nil)
 311       (when elmo-imap4-parsing
 312         (message "Waiting for IMAP response...")
 313         (accept-process-output (elmo-network-session-process-internal
 314                                 session))
 315         (message "Waiting for IMAP response...done"))
 316       (setq elmo-imap4-parsing t)
 317       (elmo-imap4-debug "<-(%s)- %s" tag command)
 318       (while (setq token (car command-args))
 319         (cond ((stringp token)   ; formatted
 320                (setq cmdstr (concat cmdstr token)))
 321               ((listp token)     ; unformatted
 322                (setq kind (car token))
 323                (cond ((eq kind 'atom)
 324                       (setq cmdstr (concat cmdstr (nth 1 token))))
 325                      ((eq kind 'quoted)
 326                       (setq cmdstr (concat
 327                                     cmdstr
 328                                     (elmo-imap4-format-quoted (nth 1 token)))))
 329                      ((eq kind 'literal)
 330                       (if (elmo-imap4-session-capable-p session 'literal+)
 331                           ;; rfc2088
 332                           (progn
 333                             (setq cmdstr (concat cmdstr
 334                                                  (format "{%d+}" (nth 2 token))))
 335                             (process-send-string process cmdstr)
 336                             (process-send-string process "\r\n")
 337                             (setq cmdstr nil))
 338                         (setq cmdstr (concat cmdstr
 339                                              (format "{%d}" (nth 2 token))))
 340                         (process-send-string process cmdstr)
 341                         (process-send-string process "\r\n")
 342                         (setq cmdstr nil)
 343                         (elmo-imap4-accept-continue-req session))
 344                       (cond ((stringp (nth 1 token))
 345                              (setq cmdstr (nth 1 token)))
 346                             ((bufferp (nth 1 token))
 347                              (with-current-buffer (nth 1 token)
 348                                (process-send-region
 349                                 process
 350                                 (point-min)
 351                                 (+ (point-min) (nth 2 token)))))
 352                             (t
 353                              (error "Wrong argument for literal"))))
 354                      (t
 355                       (error "Unknown token kind %s" kind))))
 356               (t
 357                (error "Invalid argument")))
 358         (setq command-args (cdr command-args)))
 359       (if cmdstr
 360           (process-send-string process cmdstr))
 361       (process-send-string process "\r\n")
 362       tag)))
 363
 364 (defun elmo-imap4-send-string (session string)
 365   "Send STRING to the SESSION."
 366   (with-current-buffer (process-buffer
 367                         (elmo-network-session-process-internal session))
 368     (setq elmo-imap4-current-response nil)
 369     (goto-char (point-min))
 370     (elmo-imap4-debug "<-- %s" string)
 371     (process-send-string (elmo-network-session-process-internal session)
 372                          string)
 373     (process-send-string (elmo-network-session-process-internal session)
 374                          "\r\n")))
 375
 376 (defun elmo-imap4-read-response (session tag)
 377   "Read parsed response from SESSION.
 378 TAG is the tag of the command"
 379   (with-current-buffer (process-buffer
 380                         (elmo-network-session-process-internal session))
 381     (while (not (or (string= tag elmo-imap4-reached-tag)
 382                     (elmo-imap4-response-bye-p elmo-imap4-current-response)
 383                     (when (elmo-imap4-response-garbage-p
 384                            elmo-imap4-current-response)
 385                       (message "Garbage response: %s"
 386                                (elmo-imap4-response-value
 387                                 elmo-imap4-current-response
 388                                 'garbage))
 389                       t)))
 390       (when (memq (process-status
 391                    (elmo-network-session-process-internal session))
 392                   '(open run))
 393         (accept-process-output (elmo-network-session-process-internal session)
 394                                1)))
 395     (elmo-imap4-debug "=>%s" (prin1-to-string elmo-imap4-current-response))
 396     (setq elmo-imap4-parsing nil)
 397     elmo-imap4-current-response))
 398
 399 (defsubst elmo-imap4-read-untagged (process)
 400   (with-current-buffer (process-buffer process)
 401     (while (not elmo-imap4-current-response)
 402       (accept-process-output process 1))
 403     (elmo-imap4-debug "=>%s" (prin1-to-string elmo-imap4-current-response))
 404     elmo-imap4-current-response))
 405
 406 (defun elmo-imap4-read-continue-req (session)
 407   "Returns a text following to continue-req in SESSION.
 408 If response is not `+' response, returns nil."
 409   (elmo-imap4-response-value
 410    (elmo-imap4-read-untagged
 411     (elmo-network-session-process-internal session))
 412    'continue-req))
 413
 414 (defun elmo-imap4-process-bye (session)
 415   (with-current-buffer (elmo-network-session-buffer session)
 416     (let ((r elmo-imap4-current-response))
 417       (setq elmo-imap4-current-response nil)
 418       (elmo-network-close-session session)
 419       (signal 'elmo-imap4-bye-error
 420               (list (concat (elmo-imap4-response-error-text r))
 421                     "Try Again")))))
 422
 423 (defun elmo-imap4-accept-continue-req (session)
 424   "Returns non-nil if `+' (continue-req) response is arrived in SESSION.
 425 If response is not `+' response, cause an error."
 426   (let (response)
 427     (setq response
 428           (elmo-imap4-read-untagged
 429            (elmo-network-session-process-internal session)))
 430     (or (elmo-imap4-response-continue-req-p response)
 431         (error "IMAP error: %s"
 432                (or (elmo-imap4-response-error-text response)
 433                    "No continut-req from server.")))))
 434
 435 (defun elmo-imap4-read-ok (session tag)
 436   "Returns non-nil if `OK' response of the command with TAG is arrived
 437 in SESSION. If response is not `OK' response, returns nil."
 438   (elmo-imap4-response-ok-p
 439    (elmo-imap4-read-response session tag)))
 440
 441 (defun elmo-imap4-accept-ok (session tag)
 442   "Accept only `OK' response from SESSION.
 443 If response is not `OK' response, causes error with IMAP response text."
 444   (let ((response (elmo-imap4-read-response session tag)))
 445     (if (elmo-imap4-response-ok-p response)
 446         response
 447       (if (elmo-imap4-response-bye-p response)
 448           (elmo-imap4-process-bye session)
 449         (error "IMAP error: %s"
 450                (or (elmo-imap4-response-error-text response)
 451                    "No `OK' response from server."))))))
 452
 453 ;;; MIME-ELMO-IMAP Location
 454 (luna-define-method mime-imap-location-section-body ((location
 455                                                       mime-elmo-imap-location)
 456                                                      section)
 457   (if (and (stringp section)
 458            (string= section "HEADER"))
 459       ;; Even in the section mode, header fields should be saved to the
 460       ;; raw buffer .
 461       (with-current-buffer (mime-elmo-imap-location-rawbuf-internal location)
 462         (erase-buffer)
 463         (elmo-message-fetch
 464          (mime-elmo-imap-location-folder-internal location)
 465          (mime-elmo-imap-location-number-internal location)
 466          (mime-elmo-imap-location-strategy-internal location)
 467          'unseen
 468          section)
 469         (buffer-string))
 470     (elmo-message-fetch-string
 471      (mime-elmo-imap-location-folder-internal location)
 472      (mime-elmo-imap-location-number-internal location)
 473      (mime-elmo-imap-location-strategy-internal location)
 474      'unseen
 475      section)))
 476
 477
 478 (luna-define-method mime-imap-location-bodystructure
 479   ((location mime-elmo-imap-location))
 480   (elmo-message-fetch-bodystructure
 481    (mime-elmo-imap-location-folder-internal location)
 482    (mime-elmo-imap-location-number-internal location)
 483    (mime-elmo-imap-location-strategy-internal location)))
 484
 485 (luna-define-method mime-imap-location-fetch-entity-p
 486   ((location mime-elmo-imap-location) entity)
 487   (or (not elmo-message-displaying) ; Fetching entity to save or force display.
 488       ;; cache exists
 489       (file-exists-p
 490        (expand-file-name
 491         (mmimap-entity-section (mime-entity-node-id-internal entity))
 492         (elmo-fetch-strategy-cache-path
 493          (mime-elmo-imap-location-strategy-internal location))))
 494       ;; not too large to fetch.
 495       (> elmo-message-fetch-threshold
 496          (or (mime-imap-entity-size-internal entity) 0))))
 497
 498 ;;;
 499
 500 (defun elmo-imap4-session-check (session)
 501   (with-current-buffer (elmo-network-session-buffer session)
 502     (setq elmo-imap4-fetch-callback nil)
 503     (setq elmo-imap4-fetch-callback-data nil))
 504   (elmo-imap4-send-command session "check"))
 505
 506 (defun elmo-imap4-atom-p (string)
 507   "Return t if STRING is an atom defined in rfc2060."
 508   (if (string= string "")
 509       nil
 510     (save-match-data
 511       (not (string-match elmo-imap4-non-atom-char-regex string)))))
 512
 513 (defun elmo-imap4-quotable-p (string)
 514   "Return t if STRING can be formatted as a quoted defined in rfc2060."
 515   (save-match-data
 516     (not (string-match elmo-imap4-non-text-char-regex string))))
 517
 518 (defun elmo-imap4-nil (string)
 519   "Return a list represents the special atom \"NIL\" defined in rfc2060, \
 520 if STRING is nil.
 521 Otherwise return nil."
 522   (if (eq string nil)
 523       (list 'atom "NIL")))
 524
 525 (defun elmo-imap4-atom (string)
 526   "Return a list represents STRING as an atom defined in rfc2060.
 527 Return nil if STRING is not an atom.  See `elmo-imap4-atom-p'."
 528   (if (elmo-imap4-atom-p string)
 529       (list 'atom string)))
 530
 531 (defun elmo-imap4-quoted (string)
 532   "Return a list represents STRING as a quoted defined in rfc2060.
 533 Return nil if STRING can not be formatted as a quoted.  See `elmo-imap4-quotable-p'."
 534   (if (elmo-imap4-quotable-p string)
 535       (list 'quoted string)))
 536
 537 (defun elmo-imap4-literal-1 (string-or-buffer length)
 538   "Internal function for `elmo-imap4-literal' and `elmo-imap4-buffer-literal'.
 539 Return a list represents STRING-OR-BUFFER as a literal defined in rfc2060.
 540 STRING-OR-BUFFER must be an encoded string or a single-byte string or a single-byte buffer.
 541 LENGTH must be the number of octets for STRING-OR-BUFFER."
 542   (list 'literal string-or-buffer length))
 543
 544 (defun elmo-imap4-literal (string)
 545   "Return a list represents STRING as a literal defined in rfc2060.
 546 STRING must be an encoded or a single-byte string."
 547   (elmo-imap4-literal-1 string (length string)))
 548
 549 (defun elmo-imap4-buffer-literal (buffer)
 550   "Return a list represents BUFFER as a literal defined in rfc2060.
 551 BUFFER must be a single-byte buffer."
 552   (elmo-imap4-literal-1 buffer (with-current-buffer buffer
 553                                  (buffer-size))))
 554
 555 (defun elmo-imap4-string-1 (string length)
 556   "Internal function for `elmo-imap4-string' and `elmo-imap4-buffer-string'.
 557 Return a list represents STRING as a string defined in rfc2060.
 558 STRING must be an encoded or a single-byte string.
 559 LENGTH must be the number of octets for STRING."
 560   (or (elmo-imap4-quoted string)
 561       (elmo-imap4-literal-1 string length)))
 562
 563 (defun elmo-imap4-string (string)
 564   "Return a list represents STRING as a string defined in rfc2060.
 565 STRING must be an encoded or a single-byte string."
 566   (let ((length (length string)))
 567     (if (< elmo-imap4-literal-threshold length)
 568         (elmo-imap4-literal-1 string length)
 569       (elmo-imap4-string-1 string length))))
 570
 571 (defun elmo-imap4-buffer-string (buffer)
 572   "Return a list represents BUFFER as a string defined in rfc2060.
 573 BUFFER must be a single-byte buffer."
 574   (let ((length (with-current-buffer buffer
 575                   (buffer-size))))
 576     (if (< elmo-imap4-literal-threshold length)
 577         (elmo-imap4-literal-1 buffer length)
 578       (elmo-imap4-string-1 (with-current-buffer buffer
 579                              (buffer-string))
 580                            length))))
 581
 582 (defun elmo-imap4-astring-1 (string length)
 583   "Internal function for `elmo-imap4-astring' and `elmo-imap4-buffer-astring'.
 584 Return a list represents STRING as an astring defined in rfc2060.
 585 STRING must be an encoded or a single-byte string.
 586 LENGTH must be the number of octets for STRING."
 587   (or (elmo-imap4-atom string)
 588       (elmo-imap4-string-1 string length)))
 589
 590 (defun elmo-imap4-astring (string)
 591   "Return a list represents STRING as an astring defined in rfc2060.
 592 STRING must be an encoded or a single-byte string."
 593   (let ((length (length string)))
 594     (if (< elmo-imap4-literal-threshold length)
 595         (elmo-imap4-literal-1 string length)
 596       (elmo-imap4-astring-1 string length))))
 597
 598 (defun elmo-imap4-buffer-astring (buffer)
 599   "Return a list represents BUFFER as an astring defined in rfc2060.
 600 BUFFER must be a single-byte buffer."
 601   (let ((length (with-current-buffer buffer
 602                   (buffer-size))))
 603     (if (< elmo-imap4-literal-threshold length)
 604         (elmo-imap4-literal-1 buffer length)
 605       (elmo-imap4-astring-1 (with-current-buffer buffer
 606                               (buffer-string))
 607                             length))))
 608
 609 (defun elmo-imap4-nstring (string)
 610   "Return a list represents STRING as a nstring defined in rfc2060.
 611 STRING must be an encoded or a single-byte string."
 612    (or (elmo-imap4-nil string)
 613        (elmo-imap4-string string)))
 614
 615 (defun elmo-imap4-buffer-nstring (buffer)
 616   "Return a list represents BUFFER as a nstring defined in rfc2060.
 617 BUFFER must be a single-byte buffer."
 618    (or (elmo-imap4-nil buffer)
 619        (elmo-imap4-buffer-string buffer)))
 620
 621 (defalias 'elmo-imap4-mailbox 'elmo-imap4-astring)
 622 (defalias 'elmo-imap4-field-body 'elmo-imap4-astring)
 623 (defalias 'elmo-imap4-userid 'elmo-imap4-astring)
 624 (defalias 'elmo-imap4-password 'elmo-imap4-astring)
 625
 626 (defun elmo-imap4-format-quoted (string)
 627   "Return STRING in a form of the quoted-string defined in rfc2060."
 628   (concat "\""
 629           (std11-wrap-as-quoted-pairs string elmo-imap4-quoted-specials-list)
 630           "\""))
 631
 632 (defsubst elmo-imap4-response-get-selectable-mailbox-list (response)
 633   (delq nil
 634         (mapcar
 635          (lambda (entry)
 636            (if (and (eq 'list (car entry))
 637                     (not (elmo-string-member-ignore-case "\\Noselect" (nth 1 (nth 1 entry)))))
 638                (car (nth 1 entry))))
 639          response)))
 640
 641 (luna-define-method elmo-message-fetch-bodystructure ((folder
 642                                                        elmo-imap4-folder)
 643                                                       number strategy)
 644   (if (elmo-fetch-strategy-use-cache strategy)
 645       (elmo-object-load
 646        (elmo-file-cache-expand-path
 647         (elmo-fetch-strategy-cache-path strategy)
 648         "bodystructure"))
 649     (let ((session (elmo-imap4-get-session folder))
 650           bodystructure)
 651       (elmo-imap4-session-select-mailbox
 652        session
 653        (elmo-imap4-folder-mailbox-internal folder))
 654       (with-current-buffer (elmo-network-session-buffer session)
 655         (setq elmo-imap4-fetch-callback nil)
 656         (setq elmo-imap4-fetch-callback-data nil))
 657       (prog1 (setq bodystructure
 658                    (elmo-imap4-response-value
 659                     (elmo-imap4-response-value
 660                      (elmo-imap4-send-command-wait
 661                       session
 662                       (format
 663                        (if elmo-imap4-use-uid
 664                            "uid fetch %s bodystructure"
 665                          "fetch %s bodystructure")
 666                        number))
 667                      'fetch)
 668                     'bodystructure))
 669         (when (elmo-fetch-strategy-save-cache strategy)
 670           (elmo-file-cache-delete
 671            (elmo-fetch-strategy-cache-path strategy))
 672           (elmo-object-save
 673            (elmo-file-cache-expand-path
 674             (elmo-fetch-strategy-cache-path strategy)
 675             "bodystructure")
 676            bodystructure))))))
 677
 678 ;;; Backend methods.
 679 (luna-define-method elmo-create-folder-plugged ((folder elmo-imap4-folder))
 680   (elmo-imap4-send-command-wait
 681    (elmo-imap4-get-session folder)
 682    (list "create " (elmo-imap4-mailbox
 683                     (elmo-imap4-folder-mailbox-internal folder)))))
 684
 685 (defun elmo-imap4-get-session (folder &optional if-exists)
 686   (elmo-network-get-session 'elmo-imap4-session
 687                             (concat
 688                              (if (elmo-folder-biff-internal folder)
 689                                  "BIFF-")
 690                              "IMAP")
 691                             folder if-exists))
 692
 693 (defun elmo-imap4-session-select-mailbox (session mailbox
 694                                                   &optional force no-error)
 695   "Select MAILBOX in SESSION.
 696 If optional argument FORCE is non-nil, select mailbox even if current mailbox
 697 is same as MAILBOX.
 698 If second optional argument NO-ERROR is non-nil, don't cause an error when
 699 selecting folder was failed.
 700 If NO-ERROR is 'notify-bye, only BYE response is reported as error.
 701 Returns response value if selecting folder succeed. "
 702   (when (or force
 703             (not (string=
 704                   (elmo-imap4-session-current-mailbox-internal session)
 705                   mailbox)))
 706     (let (response result)
 707       (unwind-protect
 708           (setq response
 709                 (elmo-imap4-read-response
 710                  session
 711                  (elmo-imap4-send-command
 712                   session
 713                   (list
 714                    "select "
 715                    (elmo-imap4-mailbox mailbox)))))
 716         (if (setq result (elmo-imap4-response-ok-p response))
 717             (progn
 718               (elmo-imap4-session-set-current-mailbox-internal session mailbox)
 719               (elmo-imap4-session-set-read-only-internal
 720                session
 721                (nth 1 (assq 'read-only (assq 'ok response))))
 722               (elmo-imap4-session-set-flags-internal
 723                session
 724                (nth 1 (or (assq 'permanentflags response)
 725                           (assq 'flags response)))))
 726           (elmo-imap4-session-set-current-mailbox-internal session nil)
 727           (if (and (eq no-error 'notify-bye)
 728                    (elmo-imap4-response-bye-p response))
 729               (elmo-imap4-process-bye session)
 730             (unless no-error
 731               (error "%s"
 732                      (or (elmo-imap4-response-error-text response)
 733                          (format "Select %s failed" mailbox)))))))
 734       (and result response))))
 735
 736 (defun elmo-imap4-check-validity (spec validity-file)
 737 ;;; Not used.
 738 ;;;(elmo-imap4-send-command-wait
 739 ;;;(elmo-imap4-get-session spec)
 740 ;;;(list "status "
 741 ;;;      (elmo-imap4-mailbox
 742 ;;;       (elmo-imap4-spec-mailbox spec))
 743 ;;;      " (uidvalidity)")))
 744   )
 745
 746 (defun elmo-imap4-sync-validity  (spec validity-file)
 747   ;; Not used.
 748   )
 749
 750 (defun elmo-imap4-list (folder flag)
 751   (let ((session (elmo-imap4-get-session folder)))
 752     (elmo-imap4-session-select-mailbox
 753      session
 754      (elmo-imap4-folder-mailbox-internal folder))
 755     (elmo-imap4-response-value
 756      (elmo-imap4-send-command-wait
 757       session
 758       (format (if elmo-imap4-use-uid "uid search %s"
 759                 "search %s") flag))
 760      'search)))
 761
 762 (defun elmo-imap4-session-flag-available-p (session flag)
 763   (case flag
 764     ((read unread) (elmo-string-member-ignore-case
 765                     "\\seen" (elmo-imap4-session-flags-internal session)))
 766     (important
 767      (elmo-string-member-ignore-case
 768       "\\flagged" (elmo-imap4-session-flags-internal session)))
 769     (digest
 770      (or (elmo-string-member-ignore-case
 771           "\\seen" (elmo-imap4-session-flags-internal session))
 772          (elmo-string-member-ignore-case
 773           "\\flagged" (elmo-imap4-session-flags-internal session))))
 774     (answered
 775      (elmo-string-member-ignore-case
 776       (concat "\\" (symbol-name flag))
 777       (elmo-imap4-session-flags-internal session)))
 778     (t
 779      (member "\\*" (elmo-imap4-session-flags-internal session)))))
 780
 781 (defun elmo-imap4-flag-to-imap-search-key (flag)
 782   (case flag
 783     (read "seen")
 784     (unread "unseen")
 785     (important "flagged")
 786     (answered "answered")
 787     (new "new")
 788     (t (concat
 789         "keyword "
 790         (or (car (cdr (assq flag elmo-imap4-flag-specs)))
 791             (symbol-name flag))))))
 792
 793 (defun elmo-imap4-flag-to-imap-criteria (flag)
 794   (case flag
 795     ((any digest)
 796      (let ((criteria "flagged")
 797            (global-flags (delq 'important (elmo-get-global-flags t t))))
 798        (dolist (flag (delete 'new
 799                              (delete 'cached
 800                                      (copy-sequence
 801                                       (case flag
 802                                         (any
 803                                          elmo-preserved-flags)
 804                                         (digest
 805                                          elmo-digest-flags))))))
 806          (setq criteria (concat "or "
 807                                 (elmo-imap4-flag-to-imap-search-key flag)
 808                                 " "
 809                                 criteria)))
 810        (while global-flags
 811          (setq criteria (concat "or keyword "
 812                                 (symbol-name (car global-flags))
 813                                 " "
 814                                 criteria))
 815          (setq global-flags (cdr global-flags)))
 816        criteria))
 817     (t
 818      (elmo-imap4-flag-to-imap-search-key flag))))
 819
 820 (defun elmo-imap4-folder-list-flagged (folder flag)
 821   "List flagged message numbers in the FOLDER.
 822 FLAG is one of the `unread', `read', `important', `answered', `any'."
 823   (let ((session (elmo-imap4-get-session folder))
 824         (criteria (elmo-imap4-flag-to-imap-criteria flag)))
 825     (if (elmo-imap4-session-flag-available-p session flag)
 826         (progn
 827           (elmo-imap4-session-select-mailbox
 828            session
 829            (elmo-imap4-folder-mailbox-internal folder))
 830           (elmo-imap4-response-value
 831            (elmo-imap4-send-command-wait
 832             session
 833             (format (if elmo-imap4-use-uid "uid search %s"
 834                       "search %s") criteria))
 835            'search))
 836       ;; List flagged messages in the msgdb.
 837       (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))))
 838
 839 (defvar elmo-imap4-rfc822-size "RFC822\.SIZE")
 840 (defvar elmo-imap4-rfc822-text "RFC822\.TEXT")
 841 (defvar elmo-imap4-rfc822-header "RFC822\.HEADER")
 842 (defvar elmo-imap4-header-fields "HEADER\.FIELDS")
 843
 844 (defun elmo-imap4-make-number-set-list (msg-list &optional chop-length)
 845   "Make RFC2060's message set specifier from MSG-LIST.
 846 Returns a list of (NUMBER . SET-STRING).
 847 SET-STRING is the message set specifier described in RFC2060.
 848 NUMBER is contained message number in SET-STRING.
 849 Every SET-STRING does not contain number of messages longer than CHOP-LENGTH.
 850 If CHOP-LENGTH is not specified, message set is not chopped."
 851   (let (count cont-list set-list)
 852     (setq msg-list (sort (copy-sequence msg-list) '<))
 853     (while msg-list
 854       (setq cont-list nil)
 855       (setq count 0)
 856       (unless chop-length
 857         (setq chop-length (length msg-list)))
 858       (while (and (not (null msg-list))
 859                   (< count chop-length))
 860         (setq cont-list
 861               (elmo-number-set-append
 862                cont-list (car msg-list)))
 863         (incf count)
 864         (setq msg-list (cdr msg-list)))
 865       (setq set-list
 866             (cons
 867              (cons
 868               count
 869               (mapconcat
 870                (lambda (x)
 871                  (cond ((consp x)
 872                         (format "%s:%s" (car x) (cdr x)))
 873                        ((integerp x)
 874                         (int-to-string x))))
 875                cont-list
 876                ","))
 877              set-list)))
 878     (nreverse set-list)))
 879
 880 ;;
 881 ;; app-data:
 882 ;; cons of flag-table and folder structure
 883 (defsubst elmo-imap4-fetch-callback-1-subr (entity flags app-data)
 884   "A msgdb entity callback function."
 885   (let ((use-flag (elmo-folder-use-flag-p (cdr app-data)))
 886         (flag-table (car app-data))
 887         (msg-id (elmo-message-entity-field entity 'message-id))
 888         saved-flags flag-list)
 889 ;;    (when (elmo-string-member-ignore-case "\\Flagged" flags)
 890 ;;      (elmo-msgdb-global-mark-set msg-id elmo-msgdb-important-mark))
 891     (setq saved-flags (elmo-flag-table-get flag-table msg-id)
 892           flag-list
 893           (if use-flag
 894               (append
 895                (and (memq 'new saved-flags)
 896                     (not (elmo-string-member-ignore-case "\\Seen" flags))
 897                     '(new))
 898                (and (elmo-string-member-ignore-case "\\Flagged" flags)
 899                     '(important))
 900                (and (not (elmo-string-member-ignore-case "\\Seen" flags))
 901                     '(unread))
 902                (and (elmo-string-member-ignore-case "\\Answered" flags)
 903                     '(answered))
 904                (and (elmo-file-cache-exists-p msg-id)
 905                     '(cached)))
 906             saved-flags))
 907     (when (and (or (memq 'important flag-list)
 908                    (memq 'answered flag-list))
 909                (memq 'unread flag-list))
 910       (setq elmo-imap4-seen-messages
 911             (cons (elmo-message-entity-number entity)
 912                   elmo-imap4-seen-messages)))
 913     (elmo-msgdb-append-entity elmo-imap4-current-msgdb
 914                               entity
 915                               flag-list)))
 916
 917 ;; Current buffer is process buffer.
 918 (defun elmo-imap4-fetch-callback-1 (element app-data)
 919   (let ((handler (elmo-msgdb-message-entity-handler elmo-imap4-current-msgdb)))
 920     (elmo-imap4-fetch-callback-1-subr
 921      (with-temp-buffer
 922        (insert (or (elmo-imap4-response-bodydetail-text element)
 923                    ""))
 924        ;; Replace all CRLF with LF.
 925        (elmo-delete-cr-buffer)
 926        (elmo-msgdb-create-message-entity-from-buffer
 927         handler
 928         (elmo-imap4-response-value element 'uid)
 929         :size (elmo-imap4-response-value element 'rfc822size)))
 930      (elmo-imap4-response-value element 'flags)
 931      app-data)
 932     (elmo-progress-notify 'elmo-folder-msgdb-create)))
 933
 934 (defun elmo-imap4-parse-capability (string)
 935   (if (string-match "^\\*\\(.*\\)$" string)
 936       (read
 937        (concat "(" (downcase (elmo-match-string 1 string)) ")"))))
 938
 939 (defun elmo-imap4-clear-login (session)
 940   (let ((elmo-imap4-debug-inhibit-logging t))
 941     (or
 942      (elmo-imap4-read-ok
 943       session
 944       (elmo-imap4-send-command
 945        session
 946        (list "login "
 947              (elmo-imap4-userid (elmo-network-session-user-internal session))
 948              " "
 949              (elmo-imap4-password
 950               (elmo-get-passwd (elmo-network-session-password-key session))))))
 951      (signal 'elmo-authenticate-error '(elmo-imap4-clear-login)))))
 952
 953 (defun elmo-imap4-auth-login (session)
 954   (let ((tag (elmo-imap4-send-command session "authenticate login"))
 955         (elmo-imap4-debug-inhibit-logging t))
 956     (or (elmo-imap4-read-continue-req session)
 957         (signal 'elmo-authenticate-error '(elmo-imap4-auth-login)))
 958     (elmo-imap4-send-string session
 959                             (elmo-base64-encode-string
 960                              (elmo-network-session-user-internal session)))
 961     (or (elmo-imap4-read-continue-req session)
 962         (signal 'elmo-authenticate-error '(elmo-imap4-auth-login)))
 963     (elmo-imap4-send-string session
 964                             (elmo-base64-encode-string
 965                              (elmo-get-passwd
 966                               (elmo-network-session-password-key session))))
 967     (or (elmo-imap4-read-ok session tag)
 968         (signal 'elmo-authenticate-error '(elmo-imap4-auth-login)))
 969     (setq elmo-imap4-status 'auth)))
 970
 971 (luna-define-method
 972   elmo-network-initialize-session-buffer :after ((session
 973                                                   elmo-imap4-session) buffer)
 974   (with-current-buffer buffer
 975     (mapcar 'make-variable-buffer-local elmo-imap4-local-variables)
 976     (setq elmo-imap4-seqno 0)
 977     (setq elmo-imap4-status 'initial)))
 978
 979 (luna-define-method elmo-network-initialize-session ((session
 980                                                       elmo-imap4-session))
 981   (let ((process (elmo-network-session-process-internal session)))
 982     (with-current-buffer (process-buffer process)
 983       ;; Skip garbage output from process before greeting.
 984       (while (and (memq (process-status process) '(open run))
 985                   (goto-char (point-max))
 986                   (forward-line -1)
 987                   (not (elmo-imap4-parse-greeting)))
 988         (accept-process-output process 1))
 989       (erase-buffer)
 990       (set-process-filter process 'elmo-imap4-arrival-filter)
 991       (set-process-sentinel process 'elmo-imap4-sentinel)
 992 ;;;   (while (and (memq (process-status process) '(open run))
 993 ;;;               (eq elmo-imap4-status 'initial))
 994 ;;;     (message "Waiting for server response...")
 995 ;;;     (accept-process-output process 1))
 996 ;;;   (message "")
 997       (unless (memq elmo-imap4-status '(nonauth auth))
 998         (signal 'elmo-open-error
 999                 (list 'elmo-network-initialize-session)))
1000       (elmo-imap4-session-set-capability-internal
1001        session
1002        (elmo-imap4-response-value
1003         (elmo-imap4-send-command-wait session "capability")
1004         'capability))
1005       (when (eq (elmo-network-stream-type-symbol
1006                  (elmo-network-session-stream-type-internal session))
1007                 'starttls)
1008         (or (elmo-imap4-session-capable-p session 'starttls)
1009             (signal 'elmo-open-error
1010                     '(elmo-imap4-starttls-error)))
1011         (elmo-imap4-send-command-wait session "starttls")
1012         (starttls-negotiate process)
1013         (elmo-imap4-session-set-capability-internal
1014          session
1015          (elmo-imap4-response-value
1016           (elmo-imap4-send-command-wait session "capability")
1017           'capability))))))
1018
1019 (luna-define-method elmo-network-authenticate-session ((session
1020                                                         elmo-imap4-session))
1021   (with-current-buffer (process-buffer
1022                         (elmo-network-session-process-internal session))
1023     (let* ((auth (elmo-network-session-auth-internal session))
1024            (auth (if (listp auth) auth (list auth))))
1025       (unless (or (eq elmo-imap4-status 'auth)
1026                   (null auth))
1027         (cond
1028          ((eq 'clear (car auth))
1029           (elmo-imap4-clear-login session))
1030          ((eq 'login (car auth))
1031           (elmo-imap4-auth-login session))
1032          (t
1033           (let* ((elmo-imap4-debug-inhibit-logging t)
1034                  (sasl-mechanisms
1035                   (delq nil
1036                         (mapcar
1037                          '(lambda (cap)
1038                             (if (string-match "^auth=\\(.*\\)$"
1039                                               (symbol-name cap))
1040                                 (match-string 1 (upcase (symbol-name cap)))))
1041                          (elmo-imap4-session-capability-internal session))))
1042                  (mechanism
1043                   (sasl-find-mechanism
1044                    (delq nil
1045                          (mapcar '(lambda (cap) (upcase (symbol-name cap)))
1046                                  (if (listp auth)
1047                                      auth
1048                                    (list auth)))))) ;)
1049                  client name step response tag
1050                  sasl-read-passphrase)
1051             (unless mechanism
1052               (if (or elmo-imap4-force-login
1053                       (y-or-n-p
1054                        (format
1055                         "There's no %s capability in server. continue?"
1056                         (elmo-list-to-string
1057                          (elmo-network-session-auth-internal session)))))
1058                   (setq mechanism (sasl-find-mechanism
1059                                    sasl-mechanisms))
1060                 (signal 'elmo-authenticate-error
1061                         '(elmo-imap4-auth-no-mechanisms))))
1062             (setq client
1063                   (sasl-make-client
1064                    mechanism
1065                    (elmo-network-session-user-internal session)
1066                    "imap"
1067                    (elmo-network-session-server-internal session)))
1068 ;;;         (if elmo-imap4-auth-user-realm
1069 ;;;             (sasl-client-set-property client 'realm elmo-imap4-auth-user-realm))
1070             (setq name (sasl-mechanism-name mechanism)
1071                   step (sasl-next-step client nil))
1072             (elmo-network-session-set-auth-internal
1073              session
1074              (intern (downcase name)))
1075             (setq sasl-read-passphrase
1076                   (function
1077                    (lambda (prompt)
1078                      (elmo-get-passwd
1079                       (elmo-network-session-password-key session)))))
1080             (setq tag
1081                   (elmo-imap4-send-command
1082                    session
1083                    (concat "AUTHENTICATE " name
1084                            (and (sasl-step-data step)
1085                                 (concat
1086                                  " "
1087                                  (elmo-base64-encode-string
1088                                   (sasl-step-data step)
1089                                   'no-lin-break))))))
1090             (catch 'done
1091               (while t
1092                 (setq response
1093                       (elmo-imap4-read-untagged
1094                        (elmo-network-session-process-internal session)))
1095                 (if (elmo-imap4-response-ok-p response)
1096                     (if (sasl-next-step client step)
1097                         ;; Bogus server?
1098                         (signal 'elmo-authenticate-error
1099                                 (list (intern
1100                                        (concat "elmo-imap4-auth-"
1101                                                (downcase name)))))
1102                       ;; The authentication process is finished.
1103                       (throw 'done nil)))
1104                 (unless (elmo-imap4-response-continue-req-p response)
1105                   ;; response is NO or BAD.
1106                   (signal 'elmo-authenticate-error
1107                           (list (intern
1108                                  (concat "elmo-imap4-auth-"
1109                                          (downcase name))))))
1110                 (sasl-step-set-data
1111                  step
1112                  (elmo-base64-decode-string
1113                   (elmo-imap4-response-value response 'continue-req)))
1114                 (setq step (sasl-next-step client step))
1115                 (setq tag
1116                       (elmo-imap4-send-string
1117                        session
1118                        (if (sasl-step-data step)
1119                            (elmo-base64-encode-string (sasl-step-data step)
1120                                                       'no-line-break)
1121                          ""))))))))))))
1122
1123 (luna-define-method elmo-network-setup-session ((session
1124                                                  elmo-imap4-session))
1125   (with-current-buffer (elmo-network-session-buffer session)
1126     (when (elmo-imap4-session-capable-p session 'namespace)
1127       (setq elmo-imap4-server-namespace
1128             (elmo-imap4-response-value
1129              (elmo-imap4-send-command-wait session "namespace")
1130              'namespace)))))
1131
1132 (defun elmo-imap4-setup-send-buffer (&optional string)
1133   (let ((send-buf (get-buffer-create " *elmo-imap4-setup-send-buffer*"))
1134         (source-buf (unless string (current-buffer))))
1135     (save-excursion
1136       (save-match-data
1137         (set-buffer send-buf)
1138         (erase-buffer)
1139         (set-buffer-multibyte nil)
1140         (if string
1141             (insert string)
1142           (with-current-buffer source-buf
1143             (copy-to-buffer send-buf (point-min) (point-max))))
1144         (goto-char (point-min))
1145         (if (eq (re-search-forward "^$" nil t)
1146                 (point-max))
1147             (insert "\n"))
1148         (goto-char (point-min))
1149         (while (search-forward "\n" nil t)
1150           (replace-match "\r\n"))))
1151     send-buf))
1152
1153 (defun elmo-imap4-setup-send-buffer-from-file (file)
1154   (let ((tmp-buf (get-buffer-create
1155                   " *elmo-imap4-setup-send-buffer-from-file*")))
1156     (save-excursion
1157       (save-match-data
1158         (set-buffer tmp-buf)
1159         (erase-buffer)
1160         (as-binary-input-file
1161          (insert-file-contents file))
1162         (goto-char (point-min))
1163         (if (eq (re-search-forward "^$" nil t)
1164                 (point-max))
1165             (insert "\n"))
1166         (goto-char (point-min))
1167         (while (search-forward "\n" nil t)
1168           (replace-match "\r\n"))))
1169     tmp-buf))
1170
1171 (luna-define-method elmo-delete-message-safe ((folder elmo-imap4-folder)
1172                                               number msgid)
1173   (let ((session (elmo-imap4-get-session folder))
1174         candidates)
1175     (elmo-imap4-session-select-mailbox
1176      session
1177      (elmo-imap4-folder-mailbox-internal folder))
1178     (setq candidates
1179           (elmo-imap4-response-value
1180            (elmo-imap4-send-command-wait session
1181                                          (list
1182                                           (if elmo-imap4-use-uid
1183                                               "uid search header message-id "
1184                                             "search header message-id ")
1185                                           (elmo-imap4-field-body msgid)))
1186            'search))
1187     (if (memq number candidates)
1188         (elmo-folder-delete-messages folder (list number)))))
1189
1190 (defun elmo-imap4-server-diff-async-callback-1 (status data)
1191   (funcall elmo-imap4-server-diff-async-callback
1192            (list (elmo-imap4-response-value status 'recent)
1193                  (elmo-imap4-response-value status 'unseen)
1194                  (elmo-imap4-response-value status 'messages))
1195            data))
1196
1197 (defun elmo-imap4-server-diff-async (folder)
1198   (let ((session (elmo-imap4-get-session folder)))
1199     ;; We should `check' folder to obtain newest information here.
1200     ;; But since there's no asynchronous check mechanism in elmo yet,
1201     ;; checking is not done here.
1202     (with-current-buffer (elmo-network-session-buffer session)
1203       (setq elmo-imap4-status-callback
1204             'elmo-imap4-server-diff-async-callback-1)
1205       (setq elmo-imap4-status-callback-data
1206             elmo-imap4-server-diff-async-callback-data))
1207     (elmo-imap4-send-command session
1208                              (list
1209                               "status "
1210                               (elmo-imap4-mailbox
1211                                (elmo-imap4-folder-mailbox-internal folder))
1212                               " (recent unseen messages)"))))
1213
1214 (luna-define-method elmo-server-diff-async ((folder elmo-imap4-folder))
1215   (let ((session (elmo-imap4-get-session folder)))
1216     ;; commit.
1217     ;; (elmo-imap4-commit spec)
1218     (with-current-buffer (elmo-network-session-buffer session)
1219       (setq elmo-imap4-status-callback
1220             'elmo-imap4-server-diff-async-callback-1)
1221       (setq elmo-imap4-status-callback-data
1222             elmo-imap4-server-diff-async-callback-data))
1223     (elmo-imap4-send-command session
1224                              (list
1225                               "status "
1226                               (elmo-imap4-mailbox
1227                                (elmo-imap4-folder-mailbox-internal folder))
1228                               " (recent unseen messages)"))))
1229
1230 ;;; IMAP parser.
1231
1232 (defvar elmo-imap4-server-eol "\r\n"
1233   "The EOL string sent from the server.")
1234
1235 (defvar elmo-imap4-client-eol "\r\n"
1236   "The EOL string we send to the server.")
1237
1238 (defvar elmo-imap4-literal-progress-reporter nil)
1239
1240 (defun elmo-imap4-find-next-line ()
1241   "Return point at end of current line, taking into account literals.
1242 Return nil if no complete line has arrived."
1243   (when (re-search-forward (concat elmo-imap4-server-eol "\\|{\\([0-9]+\\)}"
1244                                    elmo-imap4-server-eol)
1245                            nil t)
1246     (if (match-string 1)
1247         (if (< (point-max) (+ (point) (string-to-number (match-string 1))))
1248             (progn
1249               (when (elmo-progress-counter-label
1250                      elmo-imap4-literal-progress-reporter)
1251                 (elmo-progress-counter-set-total
1252                  elmo-imap4-literal-progress-reporter
1253                  (string-to-number (match-string 1)))
1254                 (elmo-progress-notify 'elmo-retrieve-message
1255                                       :set (- (point-max) (point))))
1256               nil)
1257           (goto-char (+ (point) (string-to-number (match-string 1))))
1258           (elmo-imap4-find-next-line))
1259       (point))))
1260
1261 (defun elmo-imap4-sentinel (process string)
1262   (delete-process process))
1263
1264 (defun elmo-imap4-arrival-filter (proc string)
1265   "IMAP process filter."
1266   (when (buffer-live-p (process-buffer proc))
1267   (with-current-buffer (process-buffer proc)
1268     (elmo-imap4-debug "-> %s" string)
1269     (goto-char (point-max))
1270     (insert string)
1271     (let (end)
1272       (goto-char (point-min))
1273       (while (setq end (elmo-imap4-find-next-line))
1274         (save-restriction
1275           (narrow-to-region (point-min) end)
1276           (delete-backward-char (length elmo-imap4-server-eol))
1277           (goto-char (point-min))
1278           (unwind-protect
1279               (case elmo-imap4-status
1280                 (initial
1281                  (setq elmo-imap4-current-response
1282                        (list
1283                         (list 'greeting (elmo-imap4-parse-greeting)))))
1284                 ((auth nonauth selected examine)
1285                  (setq elmo-imap4-current-response
1286                        (cons (elmo-imap4-parse-response)
1287                              elmo-imap4-current-response)))
1288                 (t
1289                  (message "Unknown state %s in arrival filter"
1290                           elmo-imap4-status)))
1291             (delete-region (point-min) (point-max)))))))))
1292
1293 ;; IMAP parser.
1294
1295 (defsubst elmo-imap4-forward ()
1296   (or (eobp) (forward-char 1)))
1297
1298 (defsubst elmo-imap4-parse-number ()
1299   (when (looking-at "[0-9]+")
1300     (prog1
1301         (string-to-number (match-string 0))
1302       (goto-char (match-end 0)))))
1303
1304 (defsubst elmo-imap4-parse-literal ()
1305   (when (looking-at "{\\([0-9]+\\)}\r\n")
1306     (let ((pos (match-end 0))
1307           (len (string-to-number (match-string 1))))
1308       (if (< (point-max) (+ pos len))
1309           nil
1310         (goto-char (+ pos len))
1311         (buffer-substring pos (+ pos len))))))
1312 ;;;     (list ' pos (+ pos len))))))
1313
1314 (defsubst elmo-imap4-parse-string ()
1315   (cond ((eq (char-after (point)) ?\")
1316          (forward-char 1)
1317          (let ((p (point)) (name ""))
1318            (skip-chars-forward "^\"\\\\")
1319            (setq name (buffer-substring p (point)))
1320            (while (eq (char-after (point)) ?\\)
1321              (setq p (1+ (point)))
1322              (forward-char 2)
1323              (skip-chars-forward "^\"\\\\")
1324              (setq name (concat name (buffer-substring p (point)))))
1325            (forward-char 1)
1326            name))
1327         ((eq (char-after (point)) ?{)
1328          (elmo-imap4-parse-literal))))
1329
1330 (defsubst elmo-imap4-parse-nil ()
1331   (if (looking-at "NIL")
1332       (goto-char (match-end 0))))
1333
1334 (defsubst elmo-imap4-parse-nstring ()
1335   (or (elmo-imap4-parse-string)
1336       (and (elmo-imap4-parse-nil)
1337            nil)))
1338
1339 (defsubst elmo-imap4-parse-astring ()
1340   (or (elmo-imap4-parse-string)
1341       (buffer-substring (point)
1342                         (if (re-search-forward "[(){ \r\n%*\"\\]" nil t)
1343                             (goto-char (1- (match-end 0)))
1344                           (end-of-line)
1345                           (point)))))
1346
1347 (defsubst elmo-imap4-parse-address ()
1348   (let (address)
1349     (when (eq (char-after (point)) ?\()
1350       (elmo-imap4-forward)
1351       (setq address (vector (prog1 (elmo-imap4-parse-nstring)
1352                               (elmo-imap4-forward))
1353                             (prog1 (elmo-imap4-parse-nstring)
1354                               (elmo-imap4-forward))
1355                             (prog1 (elmo-imap4-parse-nstring)
1356                               (elmo-imap4-forward))
1357                             (elmo-imap4-parse-nstring)))
1358       (when (eq (char-after (point)) ?\))
1359         (elmo-imap4-forward)
1360         address))))
1361
1362 (defsubst elmo-imap4-parse-address-list ()
1363   (if (eq (char-after (point)) ?\()
1364       (let (address addresses)
1365         (elmo-imap4-forward)
1366         (while (and (not (eq (char-after (point)) ?\)))
1367                     ;; next line for MS Exchange bug
1368                     (progn (and (eq (char-after (point)) ? ) (elmo-imap4-forward)) t)
1369                     (setq address (elmo-imap4-parse-address)))
1370           (setq addresses (cons address addresses)))
1371         (when (eq (char-after (point)) ?\))
1372           (elmo-imap4-forward)
1373           (nreverse addresses)))
1374     (assert (elmo-imap4-parse-nil))))
1375
1376 (defsubst elmo-imap4-parse-mailbox ()
1377   (let ((mailbox (elmo-imap4-parse-astring)))
1378     (if (string-equal "INBOX" (upcase mailbox))
1379         "INBOX"
1380       mailbox)))
1381
1382 (defun elmo-imap4-parse-greeting ()
1383   "Parse a IMAP greeting."
1384   (cond ((looking-at "\\* OK ")
1385          (setq elmo-imap4-status 'nonauth))
1386         ((looking-at "\\* PREAUTH ")
1387          (setq elmo-imap4-status 'auth))
1388         ((looking-at "\\* BYE ")
1389          (setq elmo-imap4-status 'closed))))
1390
1391 (defun elmo-imap4-parse-response ()
1392   "Parse a IMAP command response."
1393   (let (token)
1394     (case (setq token (read (current-buffer)))
1395       (+ (progn
1396            (skip-chars-forward " ")
1397            (list 'continue-req (buffer-substring (point) (point-max)))))
1398       (* (case (prog1 (setq token (read (current-buffer)))
1399                  (elmo-imap4-forward))
1400            (OK         (elmo-imap4-parse-resp-text-code))
1401            (NO         (elmo-imap4-parse-resp-text-code))
1402            (BAD        (elmo-imap4-parse-resp-text-code))
1403            (BYE        (elmo-imap4-parse-bye))
1404            (FLAGS      (list 'flags
1405                              (elmo-imap4-parse-flag-list)))
1406            (LIST       (list 'list (elmo-imap4-parse-data-list)))
1407            (LSUB       (list 'lsub (elmo-imap4-parse-data-list)))
1408            (SEARCH     (list
1409                         'search
1410                         (read (concat "("
1411                                       (buffer-substring (point) (point-max))
1412                                       ")"))))
1413            (STATUS     (elmo-imap4-parse-status))
1414            ;; Added
1415            (NAMESPACE  (elmo-imap4-parse-namespace))
1416            (CAPABILITY (list 'capability
1417                              (read
1418                               (concat "(" (downcase (buffer-substring
1419                                                      (point) (point-max)))
1420                                       ")"))))
1421            (ACL (elmo-imap4-parse-acl))
1422            (t       (case (prog1 (read (current-buffer))
1423                             (elmo-imap4-forward))
1424                       (EXISTS  (list 'exists token))
1425                       (RECENT  (list 'recent token))
1426                       (EXPUNGE (list 'expunge token))
1427                       (FETCH   (elmo-imap4-parse-fetch token))
1428                       (t       (list 'garbage (buffer-string)))))))
1429       (t (if (not (string-match elmo-imap4-seq-prefix (symbol-name token)))
1430              (list 'garbage (buffer-string))
1431            (case (prog1 (read (current-buffer))
1432                    (elmo-imap4-forward))
1433              (OK  (progn
1434                     (setq elmo-imap4-parsing nil)
1435                     (setq token (symbol-name token))
1436                     (elmo-unintern token)
1437                     (elmo-imap4-debug "*%s* OK arrived" token)
1438                     (setq elmo-imap4-reached-tag token)
1439                     (list 'ok (elmo-imap4-parse-resp-text-code))))
1440              (NO  (progn
1441                     (setq elmo-imap4-parsing nil)
1442                     (setq token (symbol-name token))
1443                     (elmo-unintern token)
1444                     (elmo-imap4-debug "*%s* NO arrived" token)
1445                     (setq elmo-imap4-reached-tag token)
1446                     (let (code text)
1447                       (when (eq (char-after (point)) ?\[)
1448                         (setq code (buffer-substring (point)
1449                                                      (search-forward "]")))
1450                         (elmo-imap4-forward))
1451                       (setq text (buffer-substring (point) (point-max)))
1452                       (list 'no (list code text)))))
1453              (BAD (progn
1454                     (setq elmo-imap4-parsing nil)
1455                     (elmo-imap4-debug "*%s* BAD arrived" token)
1456                     (setq token (symbol-name token))
1457                     (elmo-unintern token)
1458                     (setq elmo-imap4-reached-tag token)
1459                     (let (code text)
1460                       (when (eq (char-after (point)) ?\[)
1461                         (setq code (buffer-substring (point)
1462                                                      (search-forward "]")))
1463                         (elmo-imap4-forward))
1464                       (setq text (buffer-substring (point) (point-max)))
1465                       (list 'bad (list code text)))))
1466              (t   (list 'garbage (buffer-string)))))))))
1467
1468 (defun elmo-imap4-parse-bye ()
1469   (let (code text)
1470     (when (eq (char-after (point)) ?\[)
1471       (setq code (buffer-substring (point)
1472                                    (search-forward "]")))
1473       (elmo-imap4-forward))
1474     (setq text (buffer-substring (point) (point-max)))
1475     (list 'bye (list code text))))
1476
1477 (defun elmo-imap4-parse-text ()
1478   (goto-char (point-min))
1479   (when (search-forward "[" nil t)
1480     (search-forward "]")
1481     (elmo-imap4-forward))
1482   (list 'text (buffer-substring (point) (point-max))))
1483
1484 (defun elmo-imap4-parse-resp-text-code ()
1485   (when (eq (char-after (point)) ?\[)
1486     (elmo-imap4-forward)
1487     (cond ((search-forward "PERMANENTFLAGS " nil t)
1488            (list 'permanentflags (elmo-imap4-parse-flag-list)))
1489           ((search-forward "UIDNEXT " nil t)
1490            (list 'uidnext (read (current-buffer))))
1491           ((search-forward "UNSEEN " nil t)
1492            (list 'unseen (read (current-buffer))))
1493           ((looking-at "UIDVALIDITY \\([0-9]+\\)")
1494            (list 'uidvalidity (match-string 1)))
1495           ((search-forward "READ-ONLY" nil t)
1496            (list 'read-only t))
1497           ((search-forward "READ-WRITE" nil t)
1498            (list 'read-write t))
1499           ((search-forward "NEWNAME " nil t)
1500            (let (oldname newname)
1501              (setq oldname (elmo-imap4-parse-string))
1502              (elmo-imap4-forward)
1503              (setq newname (elmo-imap4-parse-string))
1504              (list 'newname newname oldname)))
1505           ((search-forward "TRYCREATE" nil t)
1506            (list 'trycreate t))
1507           ((looking-at "APPENDUID \\([0-9]+\\) \\([0-9]+\\)")
1508            (list 'appenduid
1509                  (list (match-string 1)
1510                        (string-to-number (match-string 2)))))
1511           ((looking-at "COPYUID \\([0-9]+\\) \\([0-9,:]+\\) \\([0-9,:]+\\)")
1512            (list 'copyuid (list (match-string 1)
1513                                 (match-string 2)
1514                                 (match-string 3))))
1515           ((search-forward "ALERT] " nil t)
1516            (message "IMAP server information: %s"
1517                     (buffer-substring (point) (point-max))))
1518           (t (list 'unknown)))))
1519
1520 (defun elmo-imap4-parse-data-list ()
1521   (let (flags delimiter mailbox)
1522     (setq flags (elmo-imap4-parse-flag-list))
1523     (when (looking-at " NIL\\| \"\\\\?\\(.\\)\"")
1524       (setq delimiter (match-string 1))
1525       (goto-char (1+ (match-end 0)))
1526       (when (setq mailbox (elmo-imap4-parse-mailbox))
1527         (list mailbox flags delimiter)))))
1528
1529 (defsubst elmo-imap4-parse-header-list ()
1530   (when (eq (char-after (point)) ?\()
1531     (let (strlist)
1532       (while (not (eq (char-after (point)) ?\)))
1533         (elmo-imap4-forward)
1534         (push (elmo-imap4-parse-astring) strlist))
1535       (elmo-imap4-forward)
1536       (nreverse strlist))))
1537
1538 (defsubst elmo-imap4-parse-fetch-body-section ()
1539   (let ((section
1540          (buffer-substring (point)
1541                            (1-
1542                             (progn (re-search-forward "[] ]" nil t)
1543                                    (point))))))
1544     (if (eq (char-before) ? )
1545         (prog1
1546             (mapconcat 'identity
1547                        (cons section (elmo-imap4-parse-header-list)) " ")
1548           (search-forward "]" nil t))
1549       section)))
1550
1551 (defun elmo-imap4-parse-fetch (response)
1552   (when (eq (char-after (point)) ?\()
1553     (let (element list)
1554       (while (not (eq (char-after (point)) ?\)))
1555         (elmo-imap4-forward)
1556         (let ((token (read (current-buffer))))
1557           (elmo-imap4-forward)
1558           (setq element
1559                 (cond ((eq token 'UID)
1560                        (list 'uid (condition-case nil
1561                                       (read (current-buffer))
1562                                     (error nil))))
1563                       ((eq token 'FLAGS)
1564                        (list 'flags (elmo-imap4-parse-flag-list)))
1565                       ((eq token 'ENVELOPE)
1566                        (list 'envelope (elmo-imap4-parse-envelope)))
1567                       ((eq token 'INTERNALDATE)
1568                        (list 'internaldate (elmo-imap4-parse-string)))
1569                       ((eq token 'RFC822)
1570                        (list 'rfc822 (elmo-imap4-parse-nstring)))
1571                       ((eq token (intern elmo-imap4-rfc822-header))
1572                        (list 'rfc822header (elmo-imap4-parse-nstring)))
1573                       ((eq token (intern elmo-imap4-rfc822-text))
1574                        (list 'rfc822text (elmo-imap4-parse-nstring)))
1575                       ((eq token (intern elmo-imap4-rfc822-size))
1576                        (list 'rfc822size (read (current-buffer))))
1577                       ((eq token 'BODY)
1578                        (if (eq (char-before) ?\[)
1579                            (list
1580                             'bodydetail
1581                             (upcase (elmo-imap4-parse-fetch-body-section))
1582                             (and
1583                              (eq (char-after (point)) ?<)
1584                              (buffer-substring (1+ (point))
1585                                                (progn
1586                                                  (search-forward ">" nil t)
1587                                                  (point))))
1588                             (progn (elmo-imap4-forward)
1589                                    (elmo-imap4-parse-nstring)))
1590                          (list 'body (elmo-imap4-parse-body))))
1591                       ((eq token 'BODYSTRUCTURE)
1592                        (list 'bodystructure (elmo-imap4-parse-body)))))
1593           (setq list (cons element list))))
1594       (and elmo-imap4-fetch-callback
1595            (funcall elmo-imap4-fetch-callback
1596                     list elmo-imap4-fetch-callback-data))
1597       (list 'fetch list))))
1598
1599 (defun elmo-imap4-parse-status ()
1600   (let ((mailbox (elmo-imap4-parse-mailbox))
1601         status)
1602     (when (and mailbox (search-forward "(" nil t))
1603       (while (not (eq (char-after (point)) ?\)))
1604         (setq status
1605               (cons
1606                (let ((token (read (current-buffer))))
1607                  (cond ((eq token 'MESSAGES)
1608                         (list 'messages (read (current-buffer))))
1609                        ((eq token 'RECENT)
1610                         (list 'recent (read (current-buffer))))
1611                        ((eq token 'UIDNEXT)
1612                         (list 'uidnext (read (current-buffer))))
1613                        ((eq token 'UIDVALIDITY)
1614                         (and (looking-at " \\([0-9]+\\)")
1615                              (prog1 (list 'uidvalidity (match-string 1))
1616                                (goto-char (match-end 1)))))
1617                        ((eq token 'UNSEEN)
1618                         (list 'unseen (read (current-buffer))))
1619                        (t
1620                         (message
1621                          "Unknown status data %s in mailbox %s ignored"
1622                          token mailbox))))
1623                status))
1624         (skip-chars-forward " ")))
1625     (and elmo-imap4-status-callback
1626          (funcall elmo-imap4-status-callback
1627                   status
1628                   elmo-imap4-status-callback-data))
1629     (list 'status status)))
1630
1631
1632 (defmacro elmo-imap4-value (value)
1633   (` (if (eq (, value) 'NIL) nil
1634        (, value))))
1635
1636 (defmacro elmo-imap4-nth (pos list)
1637   (` (let ((value (nth (, pos) (, list))))
1638        (elmo-imap4-value value))))
1639
1640 (defun elmo-imap4-parse-namespace ()
1641   (list 'namespace
1642         (nconc
1643          (copy-sequence elmo-imap4-extra-namespace-alist)
1644          (elmo-imap4-parse-namespace-subr
1645           (read (concat "(" (buffer-substring
1646                              (point) (point-max))
1647                         ")"))))))
1648
1649 (defun elmo-imap4-parse-namespace-subr (ns)
1650   (let (prefix delim namespace-alist default-delim)
1651     ;; 0: personal, 1: other, 2: shared
1652     (dotimes (i 3)
1653       (setq namespace-alist
1654             (nconc namespace-alist
1655                    (delq nil
1656                          (mapcar
1657                           (lambda (namespace)
1658                             (setq prefix (elmo-imap4-nth 0 namespace)
1659                                   delim (elmo-imap4-nth 1 namespace))
1660                             (if (and prefix delim
1661                                      (string-match
1662                                       (concat (regexp-quote delim) "\\'")
1663                                       prefix))
1664                                 (setq prefix (substring prefix 0
1665                                                         (match-beginning 0))))
1666                             (if (eq (length prefix) 0)
1667                                 (progn (setq default-delim delim) nil)
1668                               (cons
1669                                (concat "^\\("
1670                                        (if (string= (downcase prefix) "inbox")
1671                                            "[Ii][Nn][Bb][Oo][Xx]"
1672                                          (regexp-quote prefix))
1673                                        "\\).*$")
1674                                delim)))
1675                           (elmo-imap4-nth i ns))))))
1676     (if default-delim
1677         (setq namespace-alist
1678               (nconc namespace-alist
1679                      (list (cons "^.*$" default-delim)))))
1680     namespace-alist))
1681
1682 (defun elmo-imap4-parse-acl ()
1683   (let ((mailbox (elmo-imap4-parse-mailbox))
1684         identifier rights acl)
1685     (while (eq (char-after (point)) ?\ )
1686       (elmo-imap4-forward)
1687       (setq identifier (elmo-imap4-parse-astring))
1688       (elmo-imap4-forward)
1689       (setq rights (elmo-imap4-parse-astring))
1690       (setq acl (append acl (list (cons identifier rights)))))
1691     (list 'acl acl mailbox)))
1692
1693 (defun elmo-imap4-parse-flag-list ()
1694   (let ((str (buffer-substring (+ (point) 1)
1695                                (progn (search-forward ")" nil t)
1696                                       (- (point) 1)))))
1697     (unless (eq (length str) 0)
1698       (split-string str))))
1699
1700 (defun elmo-imap4-parse-envelope ()
1701   (when (eq (char-after (point)) ?\()
1702     (elmo-imap4-forward)
1703     (vector (prog1 (elmo-imap4-parse-nstring);; date
1704               (elmo-imap4-forward))
1705             (prog1 (elmo-imap4-parse-nstring);; subject
1706               (elmo-imap4-forward))
1707             (prog1 (elmo-imap4-parse-address-list);; from
1708               (elmo-imap4-forward))
1709             (prog1 (elmo-imap4-parse-address-list);; sender
1710               (elmo-imap4-forward))
1711             (prog1 (elmo-imap4-parse-address-list);; reply-to
1712               (elmo-imap4-forward))
1713             (prog1 (elmo-imap4-parse-address-list);; to
1714               (elmo-imap4-forward))
1715             (prog1 (elmo-imap4-parse-address-list);; cc
1716               (elmo-imap4-forward))
1717             (prog1 (elmo-imap4-parse-address-list);; bcc
1718               (elmo-imap4-forward))
1719             (prog1 (elmo-imap4-parse-nstring);; in-reply-to
1720               (elmo-imap4-forward))
1721             (prog1 (elmo-imap4-parse-nstring);; message-id
1722               (elmo-imap4-forward)))))
1723
1724 (defsubst elmo-imap4-parse-string-list ()
1725   (cond ((eq (char-after (point)) ?\();; body-fld-param
1726          (let (strlist str)
1727            (elmo-imap4-forward)
1728            (while (setq str (elmo-imap4-parse-string))
1729              (push str strlist)
1730              (elmo-imap4-forward))
1731            (nreverse strlist)))
1732         ((elmo-imap4-parse-nil)
1733          nil)))
1734
1735 (defun elmo-imap4-parse-body-extension ()
1736   (if (eq (char-after (point)) ?\()
1737       (let (b-e)
1738         (elmo-imap4-forward)
1739         (push (elmo-imap4-parse-body-extension) b-e)
1740         (while (eq (char-after (point)) ?\ )
1741           (elmo-imap4-forward)
1742           (push (elmo-imap4-parse-body-extension) b-e))
1743         (assert (eq (char-after (point)) ?\)))
1744         (elmo-imap4-forward)
1745         (nreverse b-e))
1746     (or (elmo-imap4-parse-number)
1747         (elmo-imap4-parse-nstring))))
1748
1749 (defsubst elmo-imap4-parse-body-ext ()
1750   (let (ext)
1751     (when (eq (char-after (point)) ?\ );; body-fld-dsp
1752       (elmo-imap4-forward)
1753       (let (dsp)
1754         (if (eq (char-after (point)) ?\()
1755             (progn
1756               (elmo-imap4-forward)
1757               (push (elmo-imap4-parse-string) dsp)
1758               (elmo-imap4-forward)
1759               (push (elmo-imap4-parse-string-list) dsp)
1760               (elmo-imap4-forward))
1761           (assert (elmo-imap4-parse-nil)))
1762         (push (nreverse dsp) ext))
1763       (when (eq (char-after (point)) ?\ );; body-fld-lang
1764         (elmo-imap4-forward)
1765         (if (eq (char-after (point)) ?\()
1766             (push (elmo-imap4-parse-string-list) ext)
1767           (push (elmo-imap4-parse-nstring) ext))
1768         (while (eq (char-after (point)) ?\ );; body-extension
1769           (elmo-imap4-forward)
1770           (setq ext (append (elmo-imap4-parse-body-extension) ext)))))
1771     ext))
1772
1773 (defun elmo-imap4-parse-body ()
1774   (let (body)
1775     (when (eq (char-after (point)) ?\()
1776       (elmo-imap4-forward)
1777       (if (eq (char-after (point)) ?\()
1778           (let (subbody)
1779             (while (and (eq (char-after (point)) ?\()
1780                         (setq subbody (elmo-imap4-parse-body)))
1781               (push subbody body))
1782             (elmo-imap4-forward)
1783             (push (elmo-imap4-parse-string) body);; media-subtype
1784             (when (eq (char-after (point)) ?\ );; body-ext-mpart:
1785               (elmo-imap4-forward)
1786               (if (eq (char-after (point)) ?\();; body-fld-param
1787                   (push (elmo-imap4-parse-string-list) body)
1788                 (push (and (elmo-imap4-parse-nil) nil) body))
1789               (setq body
1790                     (append (elmo-imap4-parse-body-ext) body)));; body-ext-...
1791             (assert (eq (char-after (point)) ?\)))
1792             (elmo-imap4-forward)
1793             (nreverse body))
1794
1795         (push (elmo-imap4-parse-string) body);; media-type
1796         (elmo-imap4-forward)
1797         (push (elmo-imap4-parse-string) body);; media-subtype
1798         (elmo-imap4-forward)
1799         ;; next line for Sun SIMS bug
1800         (and (eq (char-after (point)) ? ) (elmo-imap4-forward))
1801         (if (eq (char-after (point)) ?\();; body-fld-param
1802             (push (elmo-imap4-parse-string-list) body)
1803           (push (and (elmo-imap4-parse-nil) nil) body))
1804         (elmo-imap4-forward)
1805         (push (elmo-imap4-parse-nstring) body);; body-fld-id
1806         (elmo-imap4-forward)
1807         (push (elmo-imap4-parse-nstring) body);; body-fld-desc
1808         (elmo-imap4-forward)
1809         (push (elmo-imap4-parse-string) body);; body-fld-enc
1810         (elmo-imap4-forward)
1811         (push (elmo-imap4-parse-number) body);; body-fld-octets
1812
1813         ;; ok, we're done parsing the required parts, what comes now is one
1814         ;; of three things:
1815         ;;
1816         ;; envelope       (then we're parsing body-type-msg)
1817         ;; body-fld-lines (then we're parsing body-type-text)
1818         ;; body-ext-1part (then we're parsing body-type-basic)
1819         ;;
1820         ;; the problem is that the two first are in turn optionally followed
1821         ;; by the third.  So we parse the first two here (if there are any)...
1822
1823         (when (eq (char-after (point)) ?\ )
1824           (elmo-imap4-forward)
1825           (let (lines)
1826             (cond ((eq (char-after (point)) ?\();; body-type-msg:
1827                    (push (elmo-imap4-parse-envelope) body);; envelope
1828                    (elmo-imap4-forward)
1829                    (push (elmo-imap4-parse-body) body);; body
1830                    (elmo-imap4-forward)
1831                    (push (elmo-imap4-parse-number) body));; body-fld-lines
1832                   ((setq lines (elmo-imap4-parse-number));; body-type-text:
1833                    (push lines body));; body-fld-lines
1834                   (t
1835                    (backward-char)))));; no match...
1836
1837         ;; ...and then parse the third one here...
1838
1839         (when (eq (char-after (point)) ?\ );; body-ext-1part:
1840           (elmo-imap4-forward)
1841           (push (elmo-imap4-parse-nstring) body);; body-fld-md5
1842           (setq body
1843                 (append (elmo-imap4-parse-body-ext) body)));; body-ext-1part..
1844
1845         (assert (eq (char-after (point)) ?\)))
1846         (elmo-imap4-forward)
1847         (nreverse body)))))
1848
1849 (luna-define-method elmo-folder-initialize ((folder elmo-imap4-folder) name)
1850   (let ((default-user   elmo-imap4-default-user)
1851         (default-server elmo-imap4-default-server)
1852         (default-port   elmo-imap4-default-port)
1853         (elmo-network-stream-type-alist
1854          (if elmo-imap4-stream-type-alist
1855              (append elmo-imap4-stream-type-alist
1856                      elmo-network-stream-type-alist)
1857            elmo-network-stream-type-alist))
1858         tokens)
1859     (when (string-match "\\(.*\\)@\\(.*\\)" default-server)
1860       ;; case: imap4-default-server is specified like
1861       ;; "hoge%imap.server@gateway".
1862       (setq default-user (elmo-match-string 1 default-server))
1863       (setq default-server (elmo-match-string 2 default-server)))
1864     (setq tokens (car (elmo-parse-separated-tokens
1865                        name
1866                        elmo-imap4-folder-name-syntax)))
1867     ;; mailbox
1868     (elmo-imap4-folder-set-mailbox-internal folder
1869                                             (elmo-imap4-encode-folder-string
1870                                              (cdr (assq 'mailbox tokens))))
1871     ;; user
1872     (elmo-net-folder-set-user-internal folder
1873                                        (or (cdr (assq 'user tokens))
1874                                            default-user))
1875     ;; auth
1876     (elmo-net-folder-set-auth-internal
1877      folder
1878      (let ((auth (cdr (assq 'auth tokens))))
1879        (or (and auth (intern auth))
1880            elmo-imap4-default-authenticate-type
1881            'clear)))
1882     ;; network
1883     (elmo-net-folder-set-parameters
1884      folder
1885      tokens
1886      (list :server      default-server
1887            :port        default-port
1888            :stream-type
1889            (elmo-get-network-stream-type elmo-imap4-default-stream-type)))
1890     folder))
1891
1892 ;;; ELMO IMAP4 folder
1893 (luna-define-method elmo-folder-expand-msgdb-path ((folder
1894                                                     elmo-imap4-folder))
1895   (convert-standard-filename
1896    (let ((mailbox (elmo-imap4-folder-mailbox-internal folder)))
1897      (if (string= "inbox" (downcase mailbox))
1898          (setq mailbox "inbox"))
1899      (if (eq (string-to-char mailbox) ?/)
1900          (setq mailbox (substring mailbox 1 (length mailbox))))
1901      ;; don't use expand-file-name (e.g. %~/something)
1902      (concat
1903       (expand-file-name
1904        (or (elmo-net-folder-user-internal folder) "nobody")
1905        (expand-file-name (or (elmo-net-folder-server-internal folder)
1906                              "nowhere")
1907                          (expand-file-name
1908                           "imap"
1909                           elmo-msgdb-directory)))
1910       "/" mailbox))))
1911
1912 (luna-define-method elmo-folder-status-plugged ((folder
1913                                                  elmo-imap4-folder))
1914   (elmo-imap4-folder-status-plugged folder))
1915
1916 (defun elmo-imap4-folder-status-plugged (folder)
1917   (let ((session (elmo-imap4-get-session folder))
1918         (killed (elmo-msgdb-killed-list-load
1919                  (elmo-folder-msgdb-path folder)))
1920         status)
1921     (with-current-buffer (elmo-network-session-buffer session)
1922       (setq elmo-imap4-status-callback nil)
1923       (setq elmo-imap4-status-callback-data nil))
1924     (setq status (elmo-imap4-response-value
1925                   (elmo-imap4-send-command-wait
1926                    session
1927                    (list "status "
1928                          (elmo-imap4-mailbox
1929                           (elmo-imap4-folder-mailbox-internal folder))
1930                          " (uidnext messages)"))
1931                   'status))
1932     (cons
1933      (- (elmo-imap4-response-value status 'uidnext) 1)
1934      (if killed
1935          (-
1936           (elmo-imap4-response-value status 'messages)
1937           (elmo-msgdb-killed-list-length killed))
1938        (elmo-imap4-response-value status 'messages)))))
1939
1940 (luna-define-method elmo-folder-list-messages-plugged ((folder
1941                                                         elmo-imap4-folder)
1942                                                        &optional
1943                                                        enable-killed)
1944   (elmo-imap4-list folder
1945                    (let ((killed
1946                           (elmo-folder-killed-list-internal
1947                            folder)))
1948                      (if (and killed
1949                               (eq (length killed) 1)
1950                               (consp (car killed))
1951                               (eq (car (car killed)) 1))
1952                          (format "uid %d:*" (cdr (car killed)))
1953                        "all"))))
1954
1955 (luna-define-method elmo-folder-list-flagged-plugged
1956   ((folder elmo-imap4-folder) flag)
1957   (elmo-imap4-folder-list-flagged folder flag))
1958
1959 (luna-define-method elmo-folder-use-flag-p ((folder elmo-imap4-folder))
1960   (not (string-match elmo-imap4-disuse-server-flag-mailbox-regexp
1961                      (elmo-imap4-folder-mailbox-internal folder))))
1962
1963 (luna-define-method elmo-folder-list-subfolders ((folder elmo-imap4-folder)
1964                                                  &optional one-level)
1965   (let* ((root (elmo-imap4-folder-mailbox-internal folder))
1966          (session (elmo-imap4-get-session folder))
1967          (prefix (elmo-folder-prefix-internal folder))
1968          (namespace-assoc
1969                   (elmo-string-matched-assoc
1970                    root
1971                    (with-current-buffer (elmo-network-session-buffer session)
1972                      elmo-imap4-server-namespace)))
1973          (delim (or (cdr namespace-assoc)
1974                  elmo-imap4-default-hierarchy-delimiter))
1975          ;; Append delimiter when root with namespace.
1976          (root-nodelim root)
1977          (root (if (and namespace-assoc
1978                         (match-end 1)
1979                         (string= (substring root (match-end 1))
1980                                  ""))
1981                    (concat root delim)
1982                  root))
1983          result append-serv type)
1984     (setq result (elmo-imap4-response-get-selectable-mailbox-list
1985                   (elmo-imap4-send-command-wait
1986                    session
1987                    (list "list " (elmo-imap4-mailbox root) " *"))))
1988     ;; The response of Courier-imap doesn't contain a specified folder itself.
1989     (unless (member root result)
1990       (setq result
1991             (append result
1992                     (elmo-imap4-response-get-selectable-mailbox-list
1993                      (elmo-imap4-send-command-wait
1994                       session
1995                       (list "list \"\" " (elmo-imap4-mailbox
1996                                           root-nodelim)))))))
1997     (when (or (not (string= (elmo-net-folder-user-internal folder)
1998                             elmo-imap4-default-user))
1999               (not (eq (elmo-net-folder-auth-internal folder)
2000                        (or elmo-imap4-default-authenticate-type 'clear))))
2001       (setq append-serv (concat ":"
2002                                 (elmo-quote-syntactical-element
2003                                  (elmo-net-folder-user-internal folder)
2004                                  'user elmo-imap4-folder-name-syntax))))
2005     (unless (eq (elmo-net-folder-auth-internal folder)
2006                 (or elmo-imap4-default-authenticate-type 'clear))
2007       (setq append-serv
2008             (concat append-serv "/"
2009                     (symbol-name (elmo-net-folder-auth-internal folder)))))
2010     (unless (string= (elmo-net-folder-server-internal folder)
2011                      elmo-imap4-default-server)
2012       (setq append-serv (concat append-serv "@"
2013                                 (elmo-net-folder-server-internal folder))))
2014     (unless (eq (elmo-net-folder-port-internal folder) elmo-imap4-default-port)
2015       (setq append-serv (concat append-serv ":"
2016                                 (int-to-string
2017                                  (elmo-net-folder-port-internal folder)))))
2018     (setq type (elmo-net-folder-stream-type-internal folder))
2019     (unless (eq (elmo-network-stream-type-symbol type)
2020                 elmo-imap4-default-stream-type)
2021       (if type
2022           (setq append-serv (concat append-serv
2023                                     (elmo-network-stream-type-spec-string
2024                                      type)))))
2025     (if one-level
2026         (let ((re-delim (regexp-quote delim))
2027               (case-fold-search nil)
2028               folder ret has-child-p)
2029           ;; Append delimiter
2030           (when (and root
2031                      (not (string= root ""))
2032                      (not (string-match
2033                            (concat "\\(.*\\)" re-delim "\\'")
2034                            root)))
2035             (setq root (concat root delim)))
2036           (while (setq folder (car result))
2037             (when (string-match
2038                    (concat "^\\(" (regexp-quote root) "[^" re-delim "]" "+\\)"
2039                            re-delim)
2040                    folder)
2041               (setq folder (match-string 1 folder)))
2042             (setq has-child-p nil
2043                   result (delq
2044                           nil
2045                           (mapcar (lambda (fld)
2046                                     (if (string-match
2047                                          (concat "^" (regexp-quote folder)
2048                                                  "\\(" re-delim "\\|\\'\\)")
2049                                          fld)
2050                                         (progn (setq has-child-p t) nil)
2051                                       fld))
2052                                   (cdr result)))
2053                   folder (concat prefix
2054                                  (elmo-quote-syntactical-element
2055                                   (elmo-imap4-decode-folder-string folder)
2056                                   'mailbox elmo-imap4-folder-name-syntax)
2057                                  (and append-serv
2058                                       (eval append-serv)))
2059                   ret (append ret (if has-child-p
2060                                       (list (list folder))
2061                                     (list folder)))))
2062           ret)
2063       (mapcar (lambda (fld)
2064                 (concat prefix
2065                         (elmo-quote-syntactical-element
2066                          (elmo-imap4-decode-folder-string fld)
2067                          'mailbox elmo-imap4-folder-name-syntax)
2068                         (and append-serv
2069                              (eval append-serv))))
2070               result))))
2071
2072 (luna-define-method elmo-folder-exists-p-plugged ((folder elmo-imap4-folder))
2073   (let ((session (elmo-imap4-get-session folder)))
2074     (if (string=
2075          (elmo-imap4-session-current-mailbox-internal session)
2076          (elmo-imap4-folder-mailbox-internal folder))
2077         t
2078       (elmo-imap4-session-select-mailbox
2079        session
2080        (elmo-imap4-folder-mailbox-internal folder)
2081        'force 'notify-bye))))
2082
2083 (luna-define-method elmo-folder-creatable-p ((folder elmo-imap4-folder))
2084   t)
2085
2086 (luna-define-method elmo-folder-writable-p ((folder elmo-imap4-folder))
2087   t)
2088
2089 (luna-define-method elmo-folder-delete ((folder elmo-imap4-folder))
2090   (let ((msgs (and (elmo-folder-exists-p folder)
2091                    (elmo-folder-list-messages folder))))
2092     (when (yes-or-no-p (format "%sDelete msgdb and substance of \"%s\"? "
2093                                (if (> (length msgs) 0)
2094                                    (format "%d msg(s) exists. " (length msgs))
2095                                  "")
2096                                (elmo-folder-name-internal folder)))
2097       (let ((session (elmo-imap4-get-session folder)))
2098         (when (elmo-imap4-folder-mailbox-internal folder)
2099           (when msgs (elmo-folder-delete-messages-internal folder msgs))
2100           (elmo-imap4-send-command-wait session "close")
2101           (elmo-imap4-send-command-wait
2102            session
2103            (list "delete "
2104                  (elmo-imap4-mailbox
2105                   (elmo-imap4-folder-mailbox-internal folder)))))
2106         (elmo-imap4-session-set-current-mailbox-internal session nil))
2107       (elmo-msgdb-delete-path folder)
2108       t)))
2109
2110 (luna-define-method elmo-folder-rename-internal ((folder elmo-imap4-folder)
2111                                                  new-folder)
2112   (let ((session (elmo-imap4-get-session folder)))
2113     ;; make sure the folder is selected.
2114     (elmo-imap4-session-select-mailbox session
2115                                        (elmo-imap4-folder-mailbox-internal
2116                                         folder))
2117     (elmo-imap4-send-command-wait session "close")
2118     (elmo-imap4-send-command-wait
2119      session
2120      (list "rename "
2121            (elmo-imap4-mailbox
2122             (elmo-imap4-folder-mailbox-internal folder))
2123            " "
2124            (elmo-imap4-mailbox
2125             (elmo-imap4-folder-mailbox-internal new-folder))))
2126     (elmo-imap4-session-set-current-mailbox-internal
2127      session (elmo-imap4-folder-mailbox-internal new-folder))))
2128
2129 (defun elmo-imap4-copy-messages (src-folder dst-folder numbers)
2130   (let ((session (elmo-imap4-get-session src-folder))
2131         (set-list (elmo-imap4-make-number-set-list
2132                    numbers
2133                    elmo-imap4-number-set-chop-length))
2134         succeeds)
2135     (elmo-imap4-session-select-mailbox session
2136                                        (elmo-imap4-folder-mailbox-internal
2137                                         src-folder))
2138     (while set-list
2139       (if (elmo-imap4-send-command-wait session
2140                                         (list
2141                                          (format
2142                                           (if elmo-imap4-use-uid
2143                                               "uid copy %s "
2144                                             "copy %s ")
2145                                           (cdr (car set-list)))
2146                                          (elmo-imap4-mailbox
2147                                           (elmo-imap4-folder-mailbox-internal
2148                                            dst-folder))))
2149           (setq succeeds (append succeeds numbers)))
2150       (setq set-list (cdr set-list)))
2151     succeeds))
2152
2153 (defun elmo-imap4-set-flag (folder numbers flag &optional remove)
2154   "Set flag on messages.
2155 FOLDER is the ELMO folder structure.
2156 NUMBERS is the message numbers to be flagged.
2157 FLAG is the flag name.
2158 If optional argument REMOVE is non-nil, remove FLAG."
2159   (let ((session (elmo-imap4-get-session folder))
2160         response set-list)
2161     (elmo-imap4-session-select-mailbox session
2162                                        (elmo-imap4-folder-mailbox-internal
2163                                         folder))
2164     (when (or (elmo-string-member-ignore-case
2165                flag
2166                (elmo-imap4-session-flags-internal session))
2167               (member "\\*" (elmo-imap4-session-flags-internal session))
2168               (string= flag "\\Deleted")) ; XXX Humm..
2169       (setq set-list (elmo-imap4-make-number-set-list
2170                       numbers
2171                       elmo-imap4-number-set-chop-length))
2172       (while set-list
2173         (with-current-buffer (elmo-network-session-buffer session)
2174           (setq elmo-imap4-fetch-callback nil)
2175           (setq elmo-imap4-fetch-callback-data nil))
2176         (unless (elmo-imap4-response-ok-p
2177                  (elmo-imap4-send-command-wait
2178                   session
2179                   (format
2180                    (if elmo-imap4-use-uid
2181                        "uid store %s %sflags.silent (%s)"
2182                      "store %s %sflags.silent (%s)")
2183                    (cdr (car set-list))
2184                    (if remove "-" "+")
2185                    flag)))
2186           (setq response 'fail))
2187         (setq set-list (cdr set-list)))
2188       (not (eq response 'fail)))))
2189
2190 (luna-define-method elmo-folder-delete-messages-plugged
2191   ((folder elmo-imap4-folder) numbers)
2192   (let ((session (elmo-imap4-get-session folder)))
2193     (elmo-imap4-session-select-mailbox
2194      session
2195      (elmo-imap4-folder-mailbox-internal folder))
2196     (unless (elmo-imap4-set-flag folder numbers "\\Deleted")
2197       (error "Failed to set deleted flag"))
2198     (elmo-imap4-send-command session "expunge")))
2199
2200 (defmacro elmo-imap4-detect-search-charset (string)
2201   (` (with-temp-buffer
2202        (insert (, string))
2203        (detect-mime-charset-region (point-min) (point-max)))))
2204
2205 (defun elmo-imap4-search-internal-primitive (folder session filter from-msgs)
2206   (let ((search-key (elmo-filter-key filter))
2207         (imap-search-keys '("bcc" "body" "cc" "from" "subject" "to"
2208                             "larger" "smaller" "flag"))
2209         (total 0)
2210         (length (length from-msgs))
2211         charset set-list end results)
2212     (cond
2213      ((string= "last" search-key)
2214       (let ((numbers (or from-msgs (elmo-folder-list-messages folder))))
2215         (nthcdr (max (- (length numbers)
2216                         (string-to-int (elmo-filter-value filter)))
2217                      0)
2218                 numbers)))
2219      ((string= "first" search-key)
2220       (let* ((numbers (or from-msgs (elmo-folder-list-messages folder)))
2221              (rest (nthcdr (string-to-int (elmo-filter-value filter) )
2222                            numbers)))
2223         (mapcar '(lambda (x) (delete x numbers)) rest)
2224         numbers))
2225      ((string= "flag" search-key)
2226       (elmo-imap4-folder-list-flagged
2227        folder (intern (elmo-filter-value filter))))
2228      ((or (string= "since" search-key)
2229           (string= "before" search-key))
2230       (setq search-key (concat "sent" search-key)
2231             set-list (elmo-imap4-make-number-set-list
2232                       from-msgs
2233                       elmo-imap4-number-set-chop-length)
2234             end nil)
2235       (while (not end)
2236         (setq results
2237               (append
2238                results
2239                (elmo-imap4-response-value
2240                 (elmo-imap4-send-command-wait
2241                  session
2242                  (format
2243                   (if elmo-imap4-use-uid
2244                       "uid search %s%s%s %s"
2245                     "search %s%s%s %s")
2246                   (if from-msgs
2247                       (concat
2248                        (if elmo-imap4-use-uid "uid ")
2249                        (cdr (car set-list))
2250                        " ")
2251                     "")
2252                   (if (eq (elmo-filter-type filter)
2253                           'unmatch)
2254                       "not " "")
2255                   search-key
2256                   (elmo-date-get-description
2257                    (elmo-date-get-datevec
2258                     (elmo-filter-value filter)))))
2259                 'search)))
2260         (setq set-list (cdr set-list)
2261               end (null set-list)))
2262       results)
2263      (t
2264       (setq charset
2265             (if (eq (length (elmo-filter-value filter)) 0)
2266                 (setq charset 'us-ascii)
2267               (elmo-imap4-detect-search-charset
2268                (elmo-filter-value filter)))
2269             set-list (elmo-imap4-make-number-set-list
2270                       from-msgs
2271                       elmo-imap4-number-set-chop-length)
2272             end nil)
2273       (while (not end)
2274         (setq results
2275               (append
2276                results
2277                (elmo-imap4-response-value
2278                 (elmo-imap4-send-command-wait
2279                  session
2280                  (list
2281                   (if elmo-imap4-use-uid "uid ")
2282                   "search "
2283                   "CHARSET "
2284                   (elmo-imap4-astring
2285                    (symbol-name charset))
2286                   " "
2287                   (if from-msgs
2288                       (concat
2289                        (if elmo-imap4-use-uid "uid ")
2290                        (cdr (car set-list))
2291                        " ")
2292                     "")
2293                   (if (eq (elmo-filter-type filter)
2294                           'unmatch)
2295                       "not " "")
2296                   (format "%s%s "
2297                           (if (member
2298                                (elmo-filter-key filter)
2299                                imap-search-keys)
2300                               ""
2301                             "header ")
2302                           (elmo-filter-key filter))
2303                   (elmo-imap4-astring
2304                    (encode-mime-charset-string
2305                     (elmo-filter-value filter) charset))))
2306                 'search)))
2307         (setq set-list (cdr set-list)
2308               end (null set-list)))
2309       results))))
2310
2311 (defun elmo-imap4-search-internal (folder session condition from-msgs)
2312   (let (result)
2313     (cond
2314      ((vectorp condition)
2315       (setq result (elmo-imap4-search-internal-primitive
2316                     folder session condition from-msgs)))
2317      ((eq (car condition) 'and)
2318       (setq result (elmo-imap4-search-internal folder session (nth 1 condition)
2319                                                from-msgs)
2320             result (elmo-list-filter result
2321                                      (elmo-imap4-search-internal
2322                                       folder session (nth 2 condition)
2323                                       from-msgs))))
2324      ((eq (car condition) 'or)
2325       (setq result (elmo-imap4-search-internal
2326                     folder session (nth 1 condition) from-msgs)
2327             result (elmo-uniq-list
2328                     (nconc result
2329                            (elmo-imap4-search-internal
2330                             folder session (nth 2 condition) from-msgs)))
2331             result (sort result '<))))))
2332
2333 (luna-define-method elmo-folder-search :around ((folder elmo-imap4-folder)
2334                                                 condition &optional numbers)
2335   (if (elmo-folder-plugged-p folder)
2336       (save-excursion
2337         (let ((session (elmo-imap4-get-session folder))
2338               ret)
2339           (message "Searching...")
2340           (elmo-imap4-session-select-mailbox
2341            session
2342            (elmo-imap4-folder-mailbox-internal folder))
2343           (setq ret (elmo-imap4-search-internal folder session condition numbers))
2344           (message "Searching...done")
2345           ret))
2346     (luna-call-next-method)))
2347
2348 (luna-define-method elmo-folder-msgdb-create-plugged
2349   ((folder elmo-imap4-folder) numbers flag-table)
2350   (when numbers
2351     (let ((session (elmo-imap4-get-session folder))
2352           (headers
2353            (elmo-uniq-list
2354             (append
2355              '("Subject" "From" "To" "Cc" "Date"
2356                "Message-Id" "References" "In-Reply-To")
2357              (mapcar #'capitalize (elmo-msgdb-extra-fields 'non-virtual)))))
2358           (total 0)
2359           print-length print-depth
2360           rfc2060 set-list)
2361       (setq rfc2060 (elmo-imap4-session-capable-p session 'imap4rev1))
2362       (elmo-with-progress-display (elmo-folder-msgdb-create (length numbers))
2363           "Creating msgdb"
2364         (elmo-imap4-session-select-mailbox
2365          session (elmo-imap4-folder-mailbox-internal folder))
2366         (setq set-list (elmo-imap4-make-number-set-list
2367                         numbers
2368                         elmo-imap4-overview-fetch-chop-length))
2369         ;; Setup callback.
2370         (with-current-buffer (elmo-network-session-buffer session)
2371           (setq elmo-imap4-current-msgdb (elmo-make-msgdb)
2372                 elmo-imap4-seen-messages nil
2373                 elmo-imap4-fetch-callback 'elmo-imap4-fetch-callback-1
2374                 elmo-imap4-fetch-callback-data (cons flag-table folder))
2375           (while set-list
2376             (elmo-imap4-send-command-wait
2377              session
2378              ;; get overview entity from IMAP4
2379              (format "%sfetch %s (%s rfc822.size flags)"
2380                      (if elmo-imap4-use-uid "uid " "")
2381                      (cdr (car set-list))
2382                      (if rfc2060
2383                          (format "body.peek[header.fields %s]" headers)
2384                        (format "%s" headers))))
2385             (setq set-list (cdr set-list)))
2386           (when elmo-imap4-seen-messages
2387             (elmo-imap4-set-flag folder elmo-imap4-seen-messages "\\Seen"))
2388           ;; cannot setup the global flag while retrieval.
2389           (dolist (number (elmo-msgdb-list-messages elmo-imap4-current-msgdb))
2390             (elmo-global-flags-set (elmo-msgdb-flags elmo-imap4-current-msgdb
2391                                                      number)
2392                                    folder number
2393                                    (elmo-message-entity-field
2394                                     (elmo-msgdb-message-entity
2395                                      elmo-imap4-current-msgdb number)
2396                                     'message-id)))
2397           elmo-imap4-current-msgdb)))))
2398
2399 (luna-define-method elmo-folder-set-flag-plugged ((folder elmo-imap4-folder)
2400                                                   numbers flag)
2401   (let ((spec (cdr (assq flag elmo-imap4-flag-specs))))
2402     (elmo-imap4-set-flag folder numbers (or (car spec)
2403                                             (capitalize (symbol-name flag)))
2404                          (nth 1 spec))))
2405
2406 (luna-define-method elmo-folder-unset-flag-plugged ((folder elmo-imap4-folder)
2407                                                     numbers flag)
2408   (let ((spec (cdr (assq flag elmo-imap4-flag-specs))))
2409     (elmo-imap4-set-flag folder numbers (or (car spec)
2410                                             (capitalize (symbol-name flag)))
2411                          (not (nth 1 spec)))))
2412
2413 (luna-define-method elmo-message-use-cache-p ((folder elmo-imap4-folder)
2414                                               number)
2415   elmo-imap4-use-cache)
2416
2417 (luna-define-method elmo-folder-message-appendable-p ((folder elmo-imap4-folder))
2418   (if (elmo-folder-plugged-p folder)
2419       (not (elmo-imap4-session-read-only-internal
2420             (elmo-imap4-get-session folder)))
2421     elmo-enable-disconnected-operation)) ; offline refile.
2422
2423 (luna-define-method elmo-folder-check-plugged ((folder elmo-imap4-folder))
2424   (let ((session (elmo-imap4-get-session folder 'if-exists)))
2425     (when session
2426       (if (string=
2427            (elmo-imap4-session-current-mailbox-internal session)
2428            (elmo-imap4-folder-mailbox-internal folder))
2429           (if elmo-imap4-use-select-to-update-status
2430               (elmo-imap4-session-select-mailbox
2431                session
2432                (elmo-imap4-folder-mailbox-internal folder)
2433                'force)
2434             (elmo-imap4-session-check session))))))
2435
2436 (defsubst elmo-imap4-folder-diff-plugged (folder)
2437   (let ((session (elmo-imap4-get-session folder))
2438         messages new unread response killed uidnext)
2439 ;;; (elmo-imap4-commit spec)
2440     (with-current-buffer (elmo-network-session-buffer session)
2441       (setq elmo-imap4-status-callback nil)
2442       (setq elmo-imap4-status-callback-data nil))
2443     (if elmo-imap4-use-select-to-update-status
2444         (elmo-imap4-session-select-mailbox
2445          session
2446          (elmo-imap4-folder-mailbox-internal folder)))
2447     (setq response
2448           (elmo-imap4-send-command-wait session
2449                                         (list
2450                                          "status "
2451                                          (elmo-imap4-mailbox
2452                                           (elmo-imap4-folder-mailbox-internal
2453                                            folder))
2454                                          " (recent unseen messages uidnext)")))
2455     (setq response (elmo-imap4-response-value response 'status))
2456     (setq messages (elmo-imap4-response-value response 'messages))
2457     (setq uidnext (elmo-imap4-response-value response 'uidnext))
2458     (setq killed (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder)))
2459     ;;
2460     (when killed
2461       (when (and (consp (car killed))
2462                  (eq (car (car killed)) 1))
2463         (setq messages (- uidnext (cdr (car killed)) 1)))
2464       (setq messages (- messages
2465                         (elmo-msgdb-killed-list-length (cdr killed)))))
2466     (setq new (elmo-imap4-response-value response 'recent)
2467           unread (elmo-imap4-response-value response 'unseen))
2468     (if (< unread new) (setq new unread))
2469     (list new unread messages)))
2470
2471 (luna-define-method elmo-folder-diff-plugged ((folder elmo-imap4-folder))
2472   (elmo-imap4-folder-diff-plugged folder))
2473
2474 (luna-define-method elmo-folder-diff-async ((folder elmo-imap4-folder))
2475   (setq elmo-imap4-server-diff-async-callback
2476         elmo-folder-diff-async-callback)
2477   (setq elmo-imap4-server-diff-async-callback-data
2478         elmo-folder-diff-async-callback-data)
2479   (elmo-imap4-server-diff-async folder))
2480
2481 (luna-define-method elmo-folder-open :around ((folder elmo-imap4-folder)
2482                                               &optional load-msgdb)
2483   (if (elmo-folder-plugged-p folder)
2484       (let (session mailbox msgdb result response tag)
2485         (condition-case err
2486             (progn
2487               (setq session (elmo-imap4-get-session folder)
2488                     mailbox (elmo-imap4-folder-mailbox-internal folder)
2489                     tag (elmo-imap4-send-command session
2490                                                  (list "select "
2491                                                        (elmo-imap4-mailbox
2492                                                         mailbox))))
2493               (message "Selecting %s..."
2494                        (elmo-folder-name-internal folder))
2495               (if load-msgdb
2496                   (setq msgdb (elmo-folder-msgdb-load folder 'silent)))
2497               (elmo-folder-set-killed-list-internal
2498                folder
2499                (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder)))
2500               (if (setq result (elmo-imap4-response-ok-p
2501                                 (setq response
2502                                       (elmo-imap4-read-response session tag))))
2503                   (progn
2504                     (elmo-imap4-session-set-current-mailbox-internal
2505                      session mailbox)
2506                     (elmo-imap4-session-set-read-only-internal
2507                      session
2508                      (nth 1 (assq 'read-only (assq 'ok response))))
2509                     (elmo-imap4-session-set-flags-internal
2510                      session
2511                      (nth 1 (or (assq 'permanentflags response)
2512                                 (assq 'flags response)))))
2513                 (elmo-imap4-session-set-current-mailbox-internal session nil)
2514                 (if (elmo-imap4-response-bye-p response)
2515                     (elmo-imap4-process-bye session)
2516                   (error "%s"
2517                          (or (elmo-imap4-response-error-text response)
2518                              (format "Select %s failed" mailbox)))))
2519               (message "Selecting %s...done"
2520                        (elmo-folder-name-internal folder))
2521               (elmo-folder-set-msgdb-internal
2522                folder msgdb))
2523           (quit
2524            (if (elmo-imap4-response-ok-p response)
2525                (elmo-imap4-session-set-current-mailbox-internal
2526                 session mailbox)
2527              (and session
2528                   (elmo-imap4-session-set-current-mailbox-internal
2529                    session nil))))
2530           (error
2531            (if (elmo-imap4-response-ok-p response)
2532                (elmo-imap4-session-set-current-mailbox-internal
2533                 session mailbox)
2534              (and session
2535                   (elmo-imap4-session-set-current-mailbox-internal
2536                    session nil))))))
2537     (luna-call-next-method)))
2538
2539 ;; elmo-folder-open-internal: do nothing.
2540
2541 (luna-define-method elmo-find-fetch-strategy ((folder elmo-imap4-folder) number
2542                                               &optional
2543                                               ignore-cache
2544                                               require-entireness)
2545   (let ((entity (elmo-message-entity folder number)))
2546     (if (null entity)
2547         (elmo-make-fetch-strategy 'entire)
2548       (let* ((size (elmo-message-entity-field entity 'size))
2549              (message-id (elmo-message-entity-field entity 'message-id))
2550              (cache-file (elmo-file-cache-get message-id))
2551              (use-cache (and (not ignore-cache)
2552                              (elmo-message-use-cache-p folder number)
2553                              (if require-entireness
2554                                  (eq (elmo-file-cache-status cache-file)
2555                                      'entire)
2556                                (elmo-file-cache-status cache-file)))))
2557         (elmo-make-fetch-strategy
2558          (if use-cache
2559              (elmo-file-cache-status cache-file)
2560            (if (and (not require-entireness)
2561                     elmo-message-fetch-threshold
2562                     (integerp size)
2563                     (>= size elmo-message-fetch-threshold)
2564                     (or (not elmo-message-fetch-confirm)
2565                         (not (prog1
2566                                  (y-or-n-p
2567                                   (format
2568                                    "Fetch entire message at once? (%dbytes)"
2569                                    size))
2570                                (message "")))))
2571                'section
2572              'entire))
2573          use-cache
2574          (elmo-message-use-cache-p folder number)
2575          (elmo-file-cache-path cache-file))))))
2576
2577 (luna-define-method elmo-folder-create-plugged ((folder elmo-imap4-folder))
2578   (elmo-imap4-send-command-wait
2579    (elmo-imap4-get-session folder)
2580    (list "create "
2581          (elmo-imap4-mailbox
2582           (elmo-imap4-folder-mailbox-internal folder)))))
2583
2584 (defun elmo-imap4-flags-to-imap (flags)
2585   "Convert FLAGS to the IMAP flag string."
2586   (let ((imap-flag (if (not (memq 'unread flags)) "\\Seen")))
2587     (dolist (flag flags)
2588       (unless (memq flag '(new read unread cached))
2589         (setq imap-flag
2590               (concat imap-flag
2591                       (if imap-flag " ")
2592                       (or (car (cdr (assq flag elmo-imap4-flag-specs)))
2593                           (capitalize (symbol-name flag)))))))
2594     imap-flag))
2595
2596 (luna-define-method elmo-folder-append-buffer
2597   ((folder elmo-imap4-folder) &optional flags number)
2598   (if (elmo-folder-plugged-p folder)
2599       (let ((session (elmo-imap4-get-session folder))
2600             send-buffer result)
2601         (elmo-imap4-session-select-mailbox session
2602                                            (elmo-imap4-folder-mailbox-internal
2603                                             folder))
2604         (setq send-buffer (elmo-imap4-setup-send-buffer))
2605         (unwind-protect
2606             (setq result
2607                   (elmo-imap4-send-command-wait
2608                    session
2609                    (list
2610                     "append "
2611                     (elmo-imap4-mailbox (elmo-imap4-folder-mailbox-internal
2612                                          folder))
2613                     (if (and flags (elmo-folder-use-flag-p folder))
2614                         (concat " (" (elmo-imap4-flags-to-imap flags) ") ")
2615                       " () ")
2616                     (elmo-imap4-buffer-literal send-buffer))))
2617           (kill-buffer send-buffer))
2618         (when result
2619           (elmo-folder-preserve-flags
2620            folder (elmo-msgdb-get-message-id-from-buffer) flags))
2621         result)
2622     ;; Unplugged
2623     (if elmo-enable-disconnected-operation
2624         (elmo-folder-append-buffer-dop folder flags number)
2625       (error "Unplugged"))))
2626
2627 (eval-when-compile
2628   (defmacro elmo-imap4-identical-system-p (folder1 folder2)
2629     "Return t if FOLDER1 and FOLDER2 are in the same IMAP4 system."
2630     (` (and (string= (elmo-net-folder-server-internal (, folder1))
2631                      (elmo-net-folder-server-internal (, folder2)))
2632             (eq (elmo-net-folder-port-internal (, folder1))
2633                 (elmo-net-folder-port-internal (, folder2)))
2634             (string= (elmo-net-folder-user-internal (, folder1))
2635                      (elmo-net-folder-user-internal (, folder2)))))))
2636
2637 (luna-define-method elmo-folder-next-message-number-plugged
2638   ((folder elmo-imap4-folder))
2639   (let ((session (elmo-imap4-get-session folder))
2640         messages new unread response killed uidnext)
2641     (with-current-buffer (elmo-network-session-buffer session)
2642       (setq elmo-imap4-status-callback nil)
2643       (setq elmo-imap4-status-callback-data nil))
2644     (if elmo-imap4-use-select-to-update-status
2645         (elmo-imap4-session-select-mailbox
2646          session
2647          (elmo-imap4-folder-mailbox-internal folder)))
2648     (setq response
2649           (elmo-imap4-send-command-wait session
2650                                         (list
2651                                          "status "
2652                                          (elmo-imap4-mailbox
2653                                           (elmo-imap4-folder-mailbox-internal
2654                                            folder))
2655                                          " (uidnext)"))
2656           response (elmo-imap4-response-value response 'status))
2657     (elmo-imap4-response-value response 'uidnext)))
2658
2659 (defun elmo-folder-append-messages-imap4-imap4 (dst-folder
2660                                                 src-folder
2661                                                 numbers
2662                                                 same-number)
2663   (if (and (elmo-imap4-identical-system-p dst-folder src-folder)
2664            (elmo-folder-plugged-p dst-folder))
2665       ;; Plugged
2666       (prog1
2667           (elmo-imap4-copy-messages src-folder dst-folder numbers)
2668         (elmo-progress-notify 'elmo-folder-move-messages (length numbers)))
2669     (elmo-folder-append-messages dst-folder src-folder numbers same-number
2670                                  'elmo-folder-append-messages-imap4-imap4)))
2671
2672 (luna-define-method elmo-message-deletable-p ((folder elmo-imap4-folder)
2673                                               number)
2674   (if (elmo-folder-plugged-p folder)
2675       (not (elmo-imap4-session-read-only-internal
2676             (elmo-imap4-get-session folder)))
2677     elmo-enable-disconnected-operation)) ; offline refile.
2678
2679 ;(luna-define-method elmo-message-fetch-unplugged
2680 ;  ((folder elmo-imap4-folder)
2681 ;   number strategy  &optional section outbuf unseen)
2682 ;  (error "%d%s is not cached." number (if section
2683 ;                                         (format "(%s)" section)
2684 ;                                       "")))
2685
2686 (defsubst elmo-imap4-message-fetch (folder number strategy
2687                                            section outbuf unseen)
2688   (let ((session (elmo-imap4-get-session folder))
2689         response)
2690     (elmo-imap4-session-select-mailbox session
2691                                        (elmo-imap4-folder-mailbox-internal
2692                                         folder))
2693     (with-current-buffer (elmo-network-session-buffer session)
2694       (setq elmo-imap4-fetch-callback nil)
2695       (setq elmo-imap4-fetch-callback-data nil))
2696     (elmo-with-progress-display (elmo-retrieve-message
2697                                  (or (elmo-message-field folder number :size)
2698                                      0)
2699                                  elmo-imap4-literal-progress-reporter)
2700         "Retrieving"
2701       (setq response
2702             (elmo-imap4-send-command-wait session
2703                                           (format
2704                                            (if elmo-imap4-use-uid
2705                                                "uid fetch %s body%s[%s]"
2706                                              "fetch %s body%s[%s]")
2707                                            number
2708                                            (if unseen ".peek" "")
2709                                            (or section "")))))
2710     (if (setq response (elmo-imap4-response-bodydetail-text
2711                         (elmo-imap4-response-value-all
2712                          response 'fetch)))
2713         (with-current-buffer outbuf
2714           (erase-buffer)
2715           (insert response)
2716           (elmo-delete-cr-buffer)
2717           t))))
2718
2719 (luna-define-method elmo-message-fetch-plugged ((folder elmo-imap4-folder)
2720                                                 number strategy
2721                                                 &optional section
2722                                                 outbuf unseen)
2723   (elmo-imap4-message-fetch folder number strategy section outbuf unseen))
2724
2725 (luna-define-method elmo-message-fetch-field ((folder elmo-imap4-folder)
2726                                               number field)
2727   (let ((session (elmo-imap4-get-session folder)))
2728     (elmo-imap4-session-select-mailbox session
2729                                        (elmo-imap4-folder-mailbox-internal
2730                                         folder))
2731     (with-current-buffer (elmo-network-session-buffer session)
2732       (setq elmo-imap4-fetch-callback nil)
2733       (setq elmo-imap4-fetch-callback-data nil))
2734     (with-temp-buffer
2735       (insert
2736        (elmo-imap4-response-bodydetail-text
2737         (elmo-imap4-response-value
2738          (elmo-imap4-send-command-wait session
2739                                        (concat
2740                                         (if elmo-imap4-use-uid
2741                                             "uid ")
2742                                         (format
2743                                          "fetch %s (body.peek[header.fields (%s)])"
2744                                          number field)))
2745          'fetch)))
2746       (elmo-delete-cr-buffer)
2747       (goto-char (point-min))
2748       (std11-field-body (symbol-name field)))))
2749
2750 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder
2751                                                           elmo-imap4-folder)
2752                                                          condition)
2753   nil)
2754
2755 (autoload 'elmo-global-flags-set "elmo-flag")
2756 (autoload 'elmo-get-global-flags "elmo-flag")
2757
2758 (require 'product)
2759 (product-provide (provide 'elmo-imap4) (require 'elmo-version))
2760
2761 ;;; elmo-imap4.el ends here