elmo/elmo-multi.el

   1 ;;; elmo-multi.el --- Multiple Folder Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'elmo)
  34 (require 'elmo-signal)
  35 (require 'luna)
  36
  37 (defvar elmo-multi-divide-number 100000
  38   "*Multi divider number.")
  39
  40 ;;; ELMO Multi folder
  41 (eval-and-compile
  42   (luna-define-class elmo-multi-folder (elmo-folder)
  43                      (children divide-number))
  44   (luna-define-internal-accessors 'elmo-multi-folder))
  45
  46 (defmacro elmo-multi-real-folder-number (folder number)
  47   "Returns a cons cell of real FOLDER and NUMBER."
  48   `(cons (nth (-
  49                (/ ,number
  50                   (elmo-multi-folder-divide-number-internal ,folder))
  51                1) (elmo-multi-folder-children-internal ,folder))
  52          (% ,number (elmo-multi-folder-divide-number-internal
  53                      ,folder))))
  54
  55 (luna-define-method elmo-folder-initialize ((folder
  56                                              elmo-multi-folder)
  57                                             name)
  58   (while (> (length (car (setq name (elmo-parse-token name ",")))) 0)
  59     (elmo-multi-folder-set-children-internal
  60      folder
  61      (nconc (elmo-multi-folder-children-internal
  62              folder)
  63             (list (elmo-get-folder (car name)))))
  64     (setq name (cdr name))
  65     (when (and (> (length name) 0)
  66                (eq (aref name 0) ?,))
  67       (setq name (substring name 1))))
  68   (elmo-multi-folder-set-divide-number-internal
  69    folder
  70    elmo-multi-divide-number)
  71   (elmo-multi-connect-signals folder)
  72   folder)
  73
  74 (defun elmo-multi-connect-signals (folder)
  75   (elmo-connect-signal
  76    nil 'flag-changing folder
  77    (elmo-define-signal-handler (folder child number old-flags new-flags)
  78      (elmo-emit-signal 'flag-changing folder
  79                        (car (elmo-multi-map-numbers folder child (list number)))
  80                        old-flags new-flags))
  81    (elmo-define-signal-filter (folder sender)
  82      (memq sender (elmo-multi-folder-children-internal folder))))
  83   (elmo-connect-signal
  84    nil 'flag-changed folder
  85    (elmo-define-signal-handler (folder child numbers)
  86      (elmo-emit-signal 'flag-changed folder
  87                        (elmo-multi-map-numbers folder child numbers)))
  88    (elmo-define-signal-filter (folder sender)
  89      (memq sender (elmo-multi-folder-children-internal folder))))
  90   (elmo-connect-signal
  91    nil 'status-changed folder
  92    (elmo-define-signal-handler (folder child numbers)
  93      (elmo-emit-signal 'status-changed folder
  94                        (elmo-multi-map-numbers folder child numbers)))
  95    (elmo-define-signal-filter (folder sender)
  96      (memq sender (elmo-multi-folder-children-internal folder))))
  97   (elmo-connect-signal
  98    nil 'update-overview folder
  99    (elmo-define-signal-handler (folder child number)
 100      (elmo-emit-signal
 101       'update-overview folder
 102       (car (elmo-multi-map-numbers folder child (list number)))))
 103    (elmo-define-signal-filter (folder sender)
 104      (memq sender (elmo-multi-folder-children-internal folder)))))
 105
 106 (defun elmo-multi-map-numbers (folder child numbers)
 107   (let ((multi (catch 'found
 108                  (let ((children (elmo-multi-folder-children-internal folder))
 109                        (index 0))
 110                    (while children
 111                      (setq index (1+ index))
 112                      (when (eq (car children) child)
 113                        (throw 'found index))
 114                      (setq children (cdr children)))))))
 115     (when multi
 116       (let ((offset (* (elmo-multi-folder-divide-number-internal folder)
 117                        multi)))
 118       (mapcar (lambda (number) (+ offset number))
 119               numbers)))))
 120
 121
 122 (luna-define-method elmo-folder-open-internal ((folder elmo-multi-folder))
 123   (dolist (fld (elmo-multi-folder-children-internal folder))
 124     (elmo-folder-open-internal fld)))
 125
 126 (luna-define-method elmo-folder-check ((folder elmo-multi-folder))
 127   (dolist (fld (elmo-multi-folder-children-internal folder))
 128     (elmo-folder-check fld)))
 129
 130 (luna-define-method elmo-folder-close-internal ((folder elmo-multi-folder))
 131   (dolist (fld (elmo-multi-folder-children-internal folder))
 132     (elmo-folder-close-internal fld)))
 133
 134 (luna-define-method elmo-folder-close ((folder elmo-multi-folder))
 135   (elmo-generic-folder-close folder)
 136   (dolist (fld (elmo-multi-folder-children-internal folder))
 137     (elmo-folder-close fld)))
 138
 139 (luna-define-method elmo-message-killed-p ((folder elmo-multi-folder) number)
 140   (let ((pair (elmo-multi-real-folder-number folder number)))
 141     (elmo-message-killed-p (car pair) (cdr pair))))
 142
 143 (luna-define-method elmo-folder-synchronize ((folder elmo-multi-folder)
 144                                              &optional
 145                                              disable-killed
 146                                              ignore-msgdb
 147                                              no-check
 148                                              mask)
 149   (if mask
 150       (dolist (element (elmo-multi-split-numbers folder mask))
 151         (when (cdr element)
 152           (elmo-folder-synchronize (car element)
 153                                    disable-killed
 154                                    ignore-msgdb
 155                                    no-check
 156                                    (cdr element))))
 157     (dolist (fld (elmo-multi-folder-children-internal folder))
 158       (elmo-folder-synchronize fld disable-killed ignore-msgdb no-check)))
 159   0)
 160
 161 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 162                                                     elmo-multi-folder))
 163   (expand-file-name (elmo-replace-string-as-filename
 164                      (elmo-folder-name-internal folder))
 165                     (expand-file-name "multi"
 166                                       elmo-msgdb-directory)))
 167
 168 (luna-define-method elmo-folder-newsgroups ((folder elmo-multi-folder))
 169   (apply  #'nconc
 170           (mapcar
 171            'elmo-folder-newsgroups
 172            (elmo-multi-folder-children-internal folder))))
 173
 174 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-multi-folder))
 175   (elmo-flatten
 176    (mapcar
 177     'elmo-folder-get-primitive-list
 178     (elmo-multi-folder-children-internal folder))))
 179
 180 (luna-define-method elmo-folder-contains-type ((folder elmo-multi-folder) type)
 181   (let ((children (elmo-multi-folder-children-internal folder))
 182         match)
 183     (while children
 184       (when (elmo-folder-contains-type (car children) type)
 185         (setq match t)
 186         (setq children nil))
 187       (setq children (cdr children)))
 188     match))
 189
 190 (luna-define-method elmo-message-folder ((folder elmo-multi-folder)
 191                                          number)
 192   (nth (- (/ number (elmo-multi-folder-divide-number-internal folder)) 1)
 193        (elmo-multi-folder-children-internal folder)))
 194
 195 (luna-define-method elmo-message-cached-p ((folder elmo-multi-folder) number)
 196   (let ((pair (elmo-multi-real-folder-number folder number)))
 197     (elmo-message-cached-p (car pair) (cdr pair))))
 198
 199 (luna-define-method elmo-message-set-cached ((folder elmo-multi-folder)
 200                                              number cached)
 201   (let ((pair (elmo-multi-real-folder-number folder number)))
 202     (elmo-message-set-cached (car pair) (cdr pair) cached)))
 203
 204 (luna-define-method elmo-find-fetch-strategy ((folder elmo-multi-folder)
 205                                               number
 206                                               &optional
 207                                               ignore-cache
 208                                               require-entireness)
 209   (let ((pair (elmo-multi-real-folder-number folder number)))
 210     (elmo-find-fetch-strategy (car pair)
 211                               (cdr pair)
 212                               ignore-cache
 213                               require-entireness)))
 214
 215 (luna-define-method elmo-message-number ((folder elmo-multi-folder)
 216                                          message-id)
 217   (let ((children (elmo-multi-folder-children-internal folder))
 218         match)
 219     (while children
 220       (when (setq match (elmo-message-number (car children) message-id))
 221         (setq children nil))
 222       (setq children (cdr children)))
 223     match))
 224
 225 (luna-define-method elmo-message-entity ((folder elmo-multi-folder) key)
 226   (cond
 227    ((numberp key)
 228     (let* ((pair (elmo-multi-real-folder-number folder key))
 229            (entity (elmo-message-entity (car pair) (cdr pair))))
 230       (when entity
 231         (setq entity (elmo-message-copy-entity entity))
 232         (elmo-message-entity-set-number entity key)
 233         entity)))
 234    ((stringp key)
 235     (let ((children (elmo-multi-folder-children-internal folder))
 236           (cur-number 0)
 237           match)
 238       (while children
 239         (setq cur-number (+ cur-number 1))
 240         (when (setq match (elmo-message-entity (car children) key))
 241           (setq match (elmo-message-copy-entity match))
 242           (elmo-message-entity-set-number
 243            match
 244            (+ (* (elmo-multi-folder-divide-number-internal folder)
 245                  cur-number)
 246               (elmo-message-entity-number match)))
 247           (setq children nil))
 248         (setq children (cdr children)))
 249       match))))
 250
 251 (luna-define-method elmo-message-entity-parent ((folder
 252                                                  elmo-multi-folder) entity)
 253   (elmo-message-entity
 254    folder
 255    (elmo-message-entity-field entity 'references)))
 256
 257 (luna-define-method elmo-message-field ((folder elmo-multi-folder)
 258                                         number field &optional type)
 259   (let ((pair (elmo-multi-real-folder-number folder number)))
 260     (elmo-message-field (car pair) (cdr pair) field type)))
 261
 262 (luna-define-method elmo-message-flag-available-p ((folder
 263                                                     elmo-multi-folder) number
 264                                                     flag)
 265   (let ((pair (elmo-multi-real-folder-number folder number)))
 266     (elmo-message-flag-available-p (car pair) (cdr pair) flag)))
 267
 268 (luna-define-method elmo-message-flags ((folder elmo-multi-folder) number)
 269   (let ((pair (elmo-multi-real-folder-number folder number)))
 270     (elmo-message-flags (car pair) (cdr pair))))
 271
 272 (defun elmo-multi-split-numbers (folder numlist &optional as-is)
 273   (let ((numbers (sort numlist '<))
 274         (folders (elmo-multi-folder-children-internal folder))
 275         (divider (elmo-multi-folder-divide-number-internal folder))
 276         (cur-number 0)
 277         one-list numbers-list)
 278     (while numbers
 279       (setq one-list (list (nth cur-number folders)))
 280       (setq cur-number (+ cur-number 1))
 281       (while (and numbers
 282                   (eq 0
 283                       (/ (- (car numbers)
 284                             (* divider cur-number))
 285                          divider)))
 286         (setq one-list (nconc
 287                         one-list
 288                         (list
 289                          (if as-is
 290                              (car numbers)
 291                            (% (car numbers)
 292                               (* divider cur-number))))))
 293         (setq numbers (cdr numbers)))
 294       (setq numbers-list (nconc numbers-list (list one-list))))
 295     numbers-list))
 296
 297 (luna-define-method elmo-folder-process-crosspost ((folder elmo-multi-folder))
 298   (dolist (child (elmo-multi-folder-children-internal folder))
 299     (elmo-folder-process-crosspost child)))
 300
 301 (luna-define-method elmo-message-fetch ((folder elmo-multi-folder)
 302                                         number strategy
 303                                         &optional unseen section)
 304   (let ((pair (elmo-multi-real-folder-number folder number)))
 305     (elmo-message-fetch (car pair) (cdr pair) strategy unseen section)))
 306
 307 (luna-define-method elmo-folder-delete-messages ((folder elmo-multi-folder)
 308                                                  numbers)
 309   (dolist (element (elmo-multi-split-numbers folder numbers))
 310     (when (cdr element)
 311       (elmo-folder-delete-messages (car element) (cdr element))))
 312   t)
 313
 314 (luna-define-method elmo-folder-detach-messages ((folder elmo-multi-folder)
 315                                                  numbers)
 316   (dolist (element (elmo-multi-split-numbers folder numbers))
 317     (when (cdr element)
 318       (elmo-folder-detach-messages (car element) (cdr element))))
 319   t)
 320
 321 (luna-define-method elmo-folder-diff ((folder elmo-multi-folder))
 322   (elmo-multi-folder-diff folder))
 323
 324 (defun elmo-multi-folder-diff (folder)
 325   (let ((news 0)
 326         (unreads 0)
 327         (alls 0)
 328         diff value)
 329     (dolist (child (elmo-multi-folder-children-internal folder))
 330       (setq diff (elmo-folder-diff child))
 331       (setq news    (and news
 332                          (setq value (elmo-diff-new diff))
 333                          (+ news value))
 334             unreads (and unreads
 335                          (setq value (elmo-diff-unread diff))
 336                          (+ unreads value))
 337             alls    (and alls
 338                          (setq value (elmo-diff-all diff))
 339                          (+ alls value))))
 340     (if unreads
 341         (list news unreads alls)
 342       (cons news alls))))
 343
 344 (luna-define-method elmo-folder-list-messages
 345   ((folder elmo-multi-folder) &optional visible-only in-msgdb)
 346   (let* ((flds (elmo-multi-folder-children-internal folder))
 347          (cur-number 0)
 348          list numbers)
 349     (while flds
 350       (setq cur-number (+ cur-number 1))
 351       (setq list (elmo-folder-list-messages (car flds) visible-only in-msgdb))
 352       (setq numbers
 353             (nconc
 354              numbers
 355              (mapcar
 356               (lambda (x)
 357                 (+
 358                  (* (elmo-multi-folder-divide-number-internal
 359                      folder) cur-number) x))
 360               list)))
 361       (setq flds (cdr flds)))
 362     numbers))
 363
 364 (luna-define-method elmo-folder-exists-p ((folder elmo-multi-folder))
 365   (let ((flds (elmo-multi-folder-children-internal folder)))
 366     (catch 'exists
 367       (while flds
 368         (unless (elmo-folder-exists-p (car flds))
 369           (throw 'exists nil))
 370         (setq flds (cdr flds)))
 371       t)))
 372
 373 (luna-define-method elmo-folder-creatable-p ((folder elmo-multi-folder))
 374   (let ((flds (elmo-multi-folder-children-internal folder)))
 375     (catch 'creatable
 376       (while flds
 377         (when (and (elmo-folder-creatable-p (car flds))
 378                    (not (elmo-folder-exists-p (car flds))))
 379           ;; If folder already exists, don't to `creatable'.
 380           ;; Because this function is called, when folder doesn't exists.
 381           (throw 'creatable t))
 382         (setq flds (cdr flds)))
 383       nil)))
 384
 385 (luna-define-method elmo-folder-create ((folder elmo-multi-folder))
 386   (let ((flds (elmo-multi-folder-children-internal folder)))
 387     (catch 'create
 388       (while flds
 389         (unless (or (elmo-folder-exists-p (car flds))
 390                     (elmo-folder-create (car flds)))
 391           (throw 'create nil))
 392         (setq flds (cdr flds)))
 393       t)))
 394
 395 (luna-define-method elmo-folder-search ((folder elmo-multi-folder)
 396                                         condition &optional numbers)
 397   (let* ((flds (elmo-multi-folder-children-internal folder))
 398          (cur-number 0)
 399          numlist
 400          matches)
 401     (setq numbers (or numbers
 402                       (elmo-folder-list-messages folder)))
 403     (while flds
 404       (setq cur-number (+ cur-number 1))
 405       (setq matches (append matches
 406                             (mapcar
 407                              (lambda (x)
 408                                (+
 409                                 (* (elmo-multi-folder-divide-number-internal
 410                                     folder)
 411                                    cur-number)
 412                                 x))
 413                              (elmo-folder-search
 414                               (car flds) condition))))
 415       (setq flds (cdr flds)))
 416     (elmo-list-filter numbers matches)))
 417
 418 (luna-define-method elmo-message-use-cache-p ((folder elmo-multi-folder)
 419                                               number)
 420   (let ((pair (elmo-multi-real-folder-number folder number)))
 421     (elmo-message-use-cache-p (car pair) (cdr pair))))
 422
 423 (luna-define-method elmo-message-file-p ((folder elmo-multi-folder) number)
 424   (let ((pair (elmo-multi-real-folder-number folder number)))
 425     (elmo-message-file-p (car pair) (cdr pair))))
 426
 427 (luna-define-method elmo-message-file-name ((folder elmo-multi-folder) number)
 428   (let ((pair (elmo-multi-real-folder-number folder number)))
 429     (elmo-message-file-name (car pair) (cdr pair))))
 430
 431 (luna-define-method elmo-folder-plugged-p ((folder elmo-multi-folder))
 432   (let ((flds (elmo-multi-folder-children-internal folder)))
 433     (catch 'plugged
 434       (while flds
 435         (unless (elmo-folder-plugged-p (car flds))
 436           (throw 'plugged nil))
 437         (setq flds (cdr flds)))
 438       t)))
 439
 440 (luna-define-method elmo-folder-set-plugged ((folder elmo-multi-folder)
 441                                              plugged add)
 442   (let ((flds  (elmo-multi-folder-children-internal folder)))
 443     (dolist (fld flds)
 444       (elmo-folder-set-plugged fld plugged add))))
 445
 446 (defun elmo-multi-folder-numbers-list-assoc (folder folder-numbers)
 447   (let (ent)
 448     (while folder-numbers
 449       (when (string= (elmo-folder-name-internal (car (car folder-numbers)))
 450                      (elmo-folder-name-internal folder))
 451         (setq ent (car folder-numbers)
 452               folder-numbers nil))
 453       (setq folder-numbers (cdr folder-numbers)))
 454     ent))
 455
 456 (defun elmo-multi-make-folder-numbers-list (folder msgs)
 457   (let ((msg-list msgs)
 458         pair fld-list
 459         ret-val)
 460     (while msg-list
 461       (when (and (numberp (car msg-list))
 462                  (> (car msg-list) 0))
 463         (setq pair (elmo-multi-real-folder-number folder (car msg-list)))
 464         (if (setq fld-list (elmo-multi-folder-numbers-list-assoc
 465                             (car pair)
 466                             ret-val))
 467             (setcdr fld-list (cons (cdr pair) (cdr fld-list)))
 468           (setq ret-val (cons (cons (car pair) (list (cdr pair))) ret-val))))
 469       (setq msg-list (cdr msg-list)))
 470     ret-val))
 471
 472 (luna-define-method elmo-folder-set-flag ((folder elmo-multi-folder)
 473                                           numbers
 474                                           flag
 475                                           &optional is-local)
 476   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 477     (elmo-folder-set-flag (car pair) (cdr pair) flag is-local)))
 478
 479 (luna-define-method elmo-folder-unset-flag ((folder elmo-multi-folder)
 480                                             numbers
 481                                             flag
 482                                             &optional is-local)
 483   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 484     (ignore-errors
 485      (elmo-folder-unset-flag (car pair) (cdr pair) flag is-local))))
 486
 487 (luna-define-method elmo-folder-list-flagged ((folder elmo-multi-folder)
 488                                               flag
 489                                               &optional in-msgdb)
 490   (let ((cur-number 0)
 491         numbers)
 492     (dolist (child (elmo-multi-folder-children-internal folder))
 493       (setq cur-number (+ cur-number 1)
 494             numbers
 495             (nconc
 496              numbers
 497              (mapcar
 498               (lambda (x)
 499                 (+
 500                  (* (elmo-multi-folder-divide-number-internal folder)
 501                     cur-number) x))
 502               (elmo-folder-list-flagged child flag in-msgdb)))))
 503     numbers))
 504
 505 (luna-define-method elmo-folder-commit ((folder elmo-multi-folder))
 506   (dolist (child (elmo-multi-folder-children-internal folder))
 507     (elmo-folder-commit child)))
 508
 509 (luna-define-method elmo-folder-length ((folder elmo-multi-folder))
 510   (let ((sum 0))
 511     (dolist (child (elmo-multi-folder-children-internal folder))
 512       (setq sum (+ sum (elmo-folder-length child))))
 513     sum))
 514
 515 (luna-define-method elmo-folder-count-flags ((folder elmo-multi-folder))
 516   (let (flag-alist element)
 517     (dolist (child (elmo-multi-folder-children-internal folder))
 518       (dolist (pair (elmo-folder-count-flags child))
 519         (if (setq element (assq (car pair) flag-alist))
 520             (setcdr element (+ (cdr element) (cdr pair)))
 521           (setq flag-alist (cons pair flag-alist)))))
 522     flag-alist))
 523
 524 (luna-define-method elmo-folder-recover-messages ((folder elmo-multi-folder)
 525                                                   numbers)
 526   (dolist (element (elmo-multi-split-numbers folder numbers))
 527     (when (cdr element)
 528       (elmo-folder-recover-messages (car element) (cdr element)))))
 529
 530 (defun elmo-folder-append-messages-multi-* (dst-folder
 531                                             src-folder
 532                                             numbers
 533                                             same-number)
 534   (if same-number
 535       (elmo-folder-append-messages dst-folder src-folder numbers same-number
 536                                    'elmo-folder-append-messages-multi-*)
 537     (let ((divider (elmo-multi-folder-divide-number-internal src-folder))
 538           (cur-number 0)
 539           succeeds)
 540       (dolist (element (elmo-multi-split-numbers src-folder numbers))
 541         (setq cur-number (+ cur-number 1))
 542         (when (cdr element)
 543           (setq succeeds
 544                 (nconc
 545                  succeeds
 546                  (mapcar
 547                   (lambda (x)
 548                     (+ (* divider cur-number) x))
 549                   (elmo-folder-append-messages
 550                    dst-folder (car element) (cdr element)))))))
 551       succeeds)))
 552
 553 (require 'product)
 554 (product-provide (provide 'elmo-multi) (require 'elmo-version))
 555
 556 ;;; elmo-multi.el ends here