elmo/elmo-multi.el

   1 ;;; elmo-multi.el --- Multiple Folder Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'elmo)
  34 (require 'elmo-signal)
  35 (require 'luna)
  36
  37 (defvar elmo-multi-divide-number 100000
  38   "*Multi divider number.")
  39
  40 ;;; ELMO Multi folder
  41 (eval-and-compile
  42   (luna-define-class elmo-multi-folder (elmo-folder)
  43                      (children divide-number))
  44   (luna-define-internal-accessors 'elmo-multi-folder))
  45
  46 (defmacro elmo-multi-real-folder-number (folder number)
  47   "Returns a cons cell of real FOLDER and NUMBER."
  48   (` (cons (nth (-
  49                  (/ (, number)
  50                     (elmo-multi-folder-divide-number-internal (, folder)))
  51                  1) (elmo-multi-folder-children-internal (, folder)))
  52            (% (, number) (elmo-multi-folder-divide-number-internal
  53                           (, folder))))))
  54
  55 (luna-define-method elmo-folder-initialize ((folder
  56                                              elmo-multi-folder)
  57                                             name)
  58   (while (> (length (car (setq name (elmo-parse-token name ",")))) 0)
  59     (elmo-multi-folder-set-children-internal
  60      folder
  61      (nconc (elmo-multi-folder-children-internal
  62              folder)
  63             (list (elmo-make-folder (car name)))))
  64     (setq name (cdr name))
  65     (when (and (> (length name) 0)
  66                (eq (aref name 0) ?,))
  67       (setq name (substring name 1))))
  68   (elmo-multi-folder-set-divide-number-internal
  69    folder
  70    elmo-multi-divide-number)
  71   (elmo-multi-connect-signals folder)
  72   folder)
  73
  74 (defun elmo-multi-connect-signals (folder)
  75   (elmo-connect-signal
  76    nil 'flag-changing folder
  77    (elmo-define-signal-handler (folder child number old-flags new-flags)
  78      (elmo-emit-signal 'flag-changing folder
  79                        (car (elmo-multi-map-numbers folder child (list number)))
  80                        old-flags new-flags))
  81    (elmo-define-signal-filter (folder sender)
  82      (memq sender (elmo-multi-folder-children-internal folder))))
  83   (elmo-connect-signal
  84    nil 'flag-changed folder
  85    (elmo-define-signal-handler (folder child numbers)
  86      (elmo-emit-signal 'flag-changed folder
  87                        (elmo-multi-map-numbers folder child numbers)))
  88    (elmo-define-signal-filter (folder sender)
  89      (memq sender (elmo-multi-folder-children-internal folder))))
  90   (elmo-connect-signal
  91    nil 'cache-changed folder
  92    (elmo-define-signal-handler (folder child number)
  93      (elmo-emit-signal
  94       'flag-changed folder
  95       (car (elmo-multi-map-numbers folder child (list number)))))
  96    (elmo-define-signal-filter (folder sender)
  97      (memq sender (elmo-multi-folder-children-internal folder))))
  98   (elmo-connect-signal
  99    nil 'update-overview folder
 100    (elmo-define-signal-handler (folder child number)
 101      (elmo-emit-signal
 102       'update-overview folder
 103       (car (elmo-multi-map-numbers folder child (list number)))))
 104    (elmo-define-signal-filter (folder sender)
 105      (memq sender (elmo-multi-folder-children-internal folder)))))
 106
 107 (defun elmo-multi-map-numbers (folder child numbers)
 108   (let ((multi (catch 'found
 109                  (let ((children (elmo-multi-folder-children-internal folder))
 110                        (index 0))
 111                    (while children
 112                      (setq index (1+ index))
 113                      (when (eq (car children) child)
 114                        (throw 'found index))
 115                      (setq children (cdr children)))))))
 116     (when multi
 117       (let ((offset (* (elmo-multi-folder-divide-number-internal folder)
 118                        multi)))
 119       (mapcar (lambda (number) (+ offset number))
 120               numbers)))))
 121
 122
 123 (luna-define-method elmo-folder-open-internal ((folder elmo-multi-folder))
 124   (dolist (fld (elmo-multi-folder-children-internal folder))
 125     (elmo-folder-open-internal fld)))
 126
 127 (luna-define-method elmo-folder-check ((folder elmo-multi-folder))
 128   (dolist (fld (elmo-multi-folder-children-internal folder))
 129     (elmo-folder-check fld)))
 130
 131 (luna-define-method elmo-folder-close-internal ((folder elmo-multi-folder))
 132   (dolist (fld (elmo-multi-folder-children-internal folder))
 133     (elmo-folder-close-internal fld)))
 134
 135 (luna-define-method elmo-folder-close :after ((folder elmo-multi-folder))
 136   (dolist (fld (elmo-multi-folder-children-internal folder))
 137     (elmo-folder-set-msgdb-internal fld nil)))
 138
 139 (luna-define-method elmo-folder-synchronize ((folder elmo-multi-folder)
 140                                              &optional
 141                                              disable-killed
 142                                              ignore-msgdb
 143                                              no-check
 144                                              mask)
 145   (if mask
 146       (dolist (element (elmo-multi-split-numbers folder mask))
 147         (when (cdr element)
 148           (elmo-folder-synchronize (car element)
 149                                    disable-killed
 150                                    ignore-msgdb
 151                                    no-check
 152                                    (cdr element))))
 153     (dolist (fld (elmo-multi-folder-children-internal folder))
 154       (elmo-folder-synchronize fld disable-killed ignore-msgdb no-check)))
 155   0)
 156
 157 (luna-define-method elmo-folder-expand-msgdb-path ((folder
 158                                                     elmo-multi-folder))
 159   (expand-file-name (elmo-replace-string-as-filename
 160                      (elmo-folder-name-internal folder))
 161                     (expand-file-name "multi"
 162                                       elmo-msgdb-directory)))
 163
 164 (luna-define-method elmo-folder-newsgroups ((folder elmo-multi-folder))
 165   (apply  #'nconc
 166           (mapcar
 167            'elmo-folder-newsgroups
 168            (elmo-multi-folder-children-internal folder))))
 169
 170 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-multi-folder))
 171   (elmo-flatten
 172    (mapcar
 173     'elmo-folder-get-primitive-list
 174     (elmo-multi-folder-children-internal folder))))
 175
 176 (luna-define-method elmo-folder-contains-type ((folder elmo-multi-folder) type)
 177   (let ((children (elmo-multi-folder-children-internal folder))
 178         match)
 179     (while children
 180       (when (elmo-folder-contains-type (car children) type)
 181         (setq match t)
 182         (setq children nil))
 183       (setq children (cdr children)))
 184     match))
 185
 186 (luna-define-method elmo-message-folder ((folder elmo-multi-folder)
 187                                          number)
 188   (nth (- (/ number (elmo-multi-folder-divide-number-internal folder)) 1)
 189        (elmo-multi-folder-children-internal folder)))
 190
 191 (luna-define-method elmo-message-cached-p ((folder elmo-multi-folder) number)
 192   (let ((pair (elmo-multi-real-folder-number folder number)))
 193     (elmo-message-cached-p (car pair) (cdr pair))))
 194
 195 (luna-define-method elmo-message-set-cached ((folder elmo-multi-folder)
 196                                              number cached)
 197   (let ((pair (elmo-multi-real-folder-number folder number)))
 198     (elmo-message-set-cached (car pair) (cdr pair) cached)))
 199
 200 (luna-define-method elmo-find-fetch-strategy ((folder elmo-multi-folder)
 201                                               number
 202                                               &optional
 203                                               ignore-cache
 204                                               require-entireness)
 205   (let ((pair (elmo-multi-real-folder-number folder number)))
 206     (elmo-find-fetch-strategy (car pair)
 207                               (cdr pair)
 208                               ignore-cache
 209                               require-entireness)))
 210
 211 (luna-define-method elmo-message-number ((folder elmo-multi-folder)
 212                                          message-id)
 213   (let ((children (elmo-multi-folder-children-internal folder))
 214         match)
 215     (while children
 216       (when (setq match (elmo-message-number (car children) message-id))
 217         (setq children nil))
 218       (setq children (cdr children)))
 219     match))
 220
 221 (luna-define-method elmo-message-entity ((folder elmo-multi-folder) key)
 222   (cond
 223    ((numberp key)
 224     (let* ((pair (elmo-multi-real-folder-number folder key))
 225            (entity (elmo-message-entity (car pair) (cdr pair))))
 226       (when entity
 227         (setq entity (elmo-message-copy-entity entity))
 228         (elmo-message-entity-set-number entity key)
 229         entity)))
 230    ((stringp key)
 231     (let ((children (elmo-multi-folder-children-internal folder))
 232           (cur-number 0)
 233           match)
 234       (while children
 235         (setq cur-number (+ cur-number 1))
 236         (when (setq match (elmo-message-entity (car children) key))
 237           (setq match (elmo-message-copy-entity match))
 238           (elmo-message-entity-set-number
 239            match
 240            (+ (* (elmo-multi-folder-divide-number-internal folder)
 241                  cur-number)
 242               (elmo-message-entity-number match)))
 243           (setq children nil))
 244         (setq children (cdr children)))
 245       match))))
 246
 247 (luna-define-method elmo-message-entity-parent ((folder
 248                                                  elmo-multi-folder) entity)
 249   (elmo-message-entity
 250    folder
 251    (elmo-message-entity-field entity 'references)))
 252
 253 (luna-define-method elmo-message-field ((folder elmo-multi-folder)
 254                                         number field &optional type)
 255   (let ((pair (elmo-multi-real-folder-number folder number)))
 256     (elmo-message-field (car pair) (cdr pair) field type)))
 257
 258 (luna-define-method elmo-message-flag-available-p ((folder
 259                                                     elmo-multi-folder) number
 260                                                     flag)
 261   (let ((pair (elmo-multi-real-folder-number folder number)))
 262     (elmo-message-flag-available-p (car pair) (cdr pair) flag)))
 263
 264 (luna-define-method elmo-message-flags ((folder elmo-multi-folder) number)
 265   (let ((pair (elmo-multi-real-folder-number folder number)))
 266     (elmo-message-flags (car pair) (cdr pair))))
 267
 268 (defun elmo-multi-split-numbers (folder numlist &optional as-is)
 269   (let ((numbers (sort numlist '<))
 270         (folders (elmo-multi-folder-children-internal folder))
 271         (divider (elmo-multi-folder-divide-number-internal folder))
 272         (cur-number 0)
 273         one-list numbers-list)
 274     (while numbers
 275       (setq one-list (list (nth cur-number folders)))
 276       (setq cur-number (+ cur-number 1))
 277       (while (and numbers
 278                   (eq 0
 279                       (/ (- (car numbers)
 280                             (* divider cur-number))
 281                          divider)))
 282         (setq one-list (nconc
 283                         one-list
 284                         (list
 285                          (if as-is
 286                              (car numbers)
 287                            (% (car numbers)
 288                               (* divider cur-number))))))
 289         (setq numbers (cdr numbers)))
 290       (setq numbers-list (nconc numbers-list (list one-list))))
 291     numbers-list))
 292
 293 (luna-define-method elmo-folder-process-crosspost ((folder elmo-multi-folder))
 294   (dolist (child (elmo-multi-folder-children-internal folder))
 295     (elmo-folder-process-crosspost child)))
 296
 297 (luna-define-method elmo-message-fetch ((folder elmo-multi-folder)
 298                                         number strategy
 299                                         &optional unseen section)
 300   (let ((pair (elmo-multi-real-folder-number folder number)))
 301     (elmo-message-fetch (car pair) (cdr pair) strategy unseen section)))
 302
 303 (luna-define-method elmo-folder-delete-messages ((folder elmo-multi-folder)
 304                                                  numbers)
 305   (dolist (element (elmo-multi-split-numbers folder numbers))
 306     (when (cdr element)
 307       (elmo-folder-delete-messages (car element) (cdr element))))
 308   t)
 309
 310 (luna-define-method elmo-folder-detach-messages ((folder elmo-multi-folder)
 311                                                  numbers)
 312   (dolist (element (elmo-multi-split-numbers folder numbers))
 313     (when (cdr element)
 314       (elmo-folder-detach-messages (car element) (cdr element))))
 315   t)
 316
 317 (luna-define-method elmo-folder-diff ((folder elmo-multi-folder))
 318   (elmo-multi-folder-diff folder))
 319
 320 (defun elmo-multi-folder-diff (folder)
 321   (let ((news 0)
 322         (unreads 0)
 323         (alls 0)
 324         diff value)
 325     (dolist (child (elmo-multi-folder-children-internal folder))
 326       (setq diff (elmo-folder-diff child))
 327       (setq news    (and news
 328                          (setq value (elmo-diff-new diff))
 329                          (+ news value))
 330             unreads (and unreads
 331                          (setq value (elmo-diff-unread diff))
 332                          (+ unreads value))
 333             alls    (and alls
 334                          (setq value (elmo-diff-all diff))
 335                          (+ alls value))))
 336     (if unreads
 337         (list news unreads alls)
 338       (cons news alls))))
 339
 340 (luna-define-method elmo-folder-list-messages
 341   ((folder elmo-multi-folder) &optional visible-only in-msgdb)
 342   (let* ((flds (elmo-multi-folder-children-internal folder))
 343          (cur-number 0)
 344          list numbers)
 345     (while flds
 346       (setq cur-number (+ cur-number 1))
 347       (setq list (elmo-folder-list-messages (car flds) visible-only in-msgdb))
 348       (setq numbers
 349             (nconc
 350              numbers
 351              (mapcar
 352               (function
 353                (lambda (x)
 354                  (+
 355                   (* (elmo-multi-folder-divide-number-internal
 356                       folder) cur-number) x)))
 357               list)))
 358       (setq flds (cdr flds)))
 359     numbers))
 360
 361 (luna-define-method elmo-folder-exists-p ((folder elmo-multi-folder))
 362   (let ((flds (elmo-multi-folder-children-internal folder)))
 363     (catch 'exists
 364       (while flds
 365         (unless (elmo-folder-exists-p (car flds))
 366           (throw 'exists nil))
 367         (setq flds (cdr flds)))
 368       t)))
 369
 370 (luna-define-method elmo-folder-creatable-p ((folder elmo-multi-folder))
 371   (let ((flds (elmo-multi-folder-children-internal folder)))
 372     (catch 'creatable
 373       (while flds
 374         (when (and (elmo-folder-creatable-p (car flds))
 375                    (not (elmo-folder-exists-p (car flds))))
 376           ;; If folder already exists, don't to `creatable'.
 377           ;; Because this function is called, when folder doesn't exists.
 378           (throw 'creatable t))
 379         (setq flds (cdr flds)))
 380       nil)))
 381
 382 (luna-define-method elmo-folder-create ((folder elmo-multi-folder))
 383   (let ((flds (elmo-multi-folder-children-internal folder)))
 384     (catch 'create
 385       (while flds
 386         (unless (or (elmo-folder-exists-p (car flds))
 387                     (elmo-folder-create (car flds)))
 388           (throw 'create nil))
 389         (setq flds (cdr flds)))
 390       t)))
 391
 392 (luna-define-method elmo-folder-search ((folder elmo-multi-folder)
 393                                         condition &optional numbers)
 394   (let* ((flds (elmo-multi-folder-children-internal folder))
 395          (cur-number 0)
 396          numlist
 397          matches)
 398     (setq numbers (or numbers
 399                       (elmo-folder-list-messages folder)))
 400     (while flds
 401       (setq cur-number (+ cur-number 1))
 402       (setq matches (append matches
 403                             (mapcar
 404                              (function
 405                               (lambda (x)
 406                                 (+
 407                                  (* (elmo-multi-folder-divide-number-internal
 408                                      folder)
 409                                     cur-number)
 410                                  x)))
 411                              (elmo-folder-search
 412                               (car flds) condition))))
 413       (setq flds (cdr flds)))
 414     (elmo-list-filter numbers matches)))
 415
 416 (luna-define-method elmo-message-use-cache-p ((folder elmo-multi-folder)
 417                                               number)
 418   (let ((pair (elmo-multi-real-folder-number folder number)))
 419     (elmo-message-use-cache-p (car pair) (cdr pair))))
 420
 421 (luna-define-method elmo-message-file-p ((folder elmo-multi-folder) number)
 422   (let ((pair (elmo-multi-real-folder-number folder number)))
 423     (elmo-message-file-p (car pair) (cdr pair))))
 424
 425 (luna-define-method elmo-message-file-name ((folder elmo-multi-folder) number)
 426   (let ((pair (elmo-multi-real-folder-number folder number)))
 427     (elmo-message-file-name (car pair) (cdr pair))))
 428
 429 (luna-define-method elmo-folder-plugged-p ((folder elmo-multi-folder))
 430   (let ((flds (elmo-multi-folder-children-internal folder)))
 431     (catch 'plugged
 432       (while flds
 433         (unless (elmo-folder-plugged-p (car flds))
 434           (throw 'plugged nil))
 435         (setq flds (cdr flds)))
 436       t)))
 437
 438 (luna-define-method elmo-folder-set-plugged ((folder elmo-multi-folder)
 439                                              plugged add)
 440   (let ((flds  (elmo-multi-folder-children-internal folder)))
 441     (dolist (fld flds)
 442       (elmo-folder-set-plugged fld plugged add))))
 443
 444 (defun elmo-multi-folder-numbers-list-assoc (folder folder-numbers)
 445   (let (ent)
 446     (while folder-numbers
 447       (when (string= (elmo-folder-name-internal (car (car folder-numbers)))
 448                      (elmo-folder-name-internal folder))
 449         (setq ent (car folder-numbers)
 450               folder-numbers nil))
 451       (setq folder-numbers (cdr folder-numbers)))
 452     ent))
 453
 454 (defun elmo-multi-make-folder-numbers-list (folder msgs)
 455   (let ((msg-list msgs)
 456         pair fld-list
 457         ret-val)
 458     (while msg-list
 459       (when (and (numberp (car msg-list))
 460                  (> (car msg-list) 0))
 461         (setq pair (elmo-multi-real-folder-number folder (car msg-list)))
 462         (if (setq fld-list (elmo-multi-folder-numbers-list-assoc
 463                             (car pair)
 464                             ret-val))
 465             (setcdr fld-list (cons (cdr pair) (cdr fld-list)))
 466           (setq ret-val (cons (cons (car pair) (list (cdr pair))) ret-val))))
 467       (setq msg-list (cdr msg-list)))
 468     ret-val))
 469
 470 (luna-define-method elmo-folder-set-flag ((folder elmo-multi-folder)
 471                                           numbers
 472                                           flag
 473                                           &optional is-local)
 474   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 475     (elmo-folder-set-flag (car pair) (cdr pair) flag is-local)))
 476
 477 (luna-define-method elmo-folder-unset-flag ((folder elmo-multi-folder)
 478                                             numbers
 479                                             flag
 480                                             &optional is-local)
 481   (dolist (pair (elmo-multi-make-folder-numbers-list folder numbers))
 482     (ignore-errors
 483      (elmo-folder-unset-flag (car pair) (cdr pair) flag is-local))))
 484
 485 (luna-define-method elmo-folder-list-flagged ((folder elmo-multi-folder)
 486                                               flag
 487                                               &optional in-msgdb)
 488   (let ((cur-number 0)
 489         numbers)
 490     (dolist (child (elmo-multi-folder-children-internal folder))
 491       (setq cur-number (+ cur-number 1)
 492             numbers
 493             (nconc
 494              numbers
 495              (mapcar
 496               (function
 497                (lambda (x)
 498                  (+
 499                   (* (elmo-multi-folder-divide-number-internal folder)
 500                      cur-number) x)))
 501               (elmo-folder-list-flagged child flag in-msgdb)))))
 502     numbers))
 503
 504 (luna-define-method elmo-folder-commit ((folder elmo-multi-folder))
 505   (dolist (child (elmo-multi-folder-children-internal folder))
 506     (elmo-folder-commit child)))
 507
 508 (luna-define-method elmo-folder-length ((folder elmo-multi-folder))
 509   (let ((sum 0))
 510     (dolist (child (elmo-multi-folder-children-internal folder))
 511       (setq sum (+ sum (elmo-folder-length child))))
 512     sum))
 513
 514 (luna-define-method elmo-folder-count-flags ((folder elmo-multi-folder))
 515   (let (flag-alist element)
 516     (dolist (child (elmo-multi-folder-children-internal folder))
 517       (dolist (pair (elmo-folder-count-flags child))
 518         (if (setq element (assq (car pair) flag-alist))
 519             (setcdr element (+ (cdr element) (cdr pair)))
 520           (setq flag-alist (cons pair flag-alist)))))
 521     flag-alist))
 522
 523 (require 'product)
 524 (product-provide (provide 'elmo-multi) (require 'elmo-version))
 525
 526 ;;; elmo-multi.el ends here