elmo/elmo-pop3.el

   1 ;;; elmo-pop3.el -- POP3 Interface for ELMO.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4 ;; Copyright (C) 1999,2000      Kenichi OKADA <okada@opaopa.org>
   5
   6 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   7 ;;      Kenichi OKADA <okada@opaopa.org>
   8 ;; Keywords: mail, net news
   9
  10 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
  11
  12 ;; This program is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16 ;;
  17 ;; This program is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21 ;;
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 ;;
  27
  28 ;;; Commentary:
  29 ;;
  30
  31 ;;; Code:
  32 ;;
  33
  34 (require 'elmo-msgdb)
  35 (require 'elmo-net)
  36 (eval-when-compile
  37   (require 'elmo-util)
  38   (condition-case nil
  39       (progn
  40         (require 'starttls)
  41         (require 'sasl))
  42     (error))
  43   (defun-maybe md5 (a))
  44   (defun-maybe sasl-digest-md5-digest-response
  45     (digest-challenge username passwd serv-type host &optional realm))
  46   (defun-maybe sasl-scram-md5-client-msg-1
  47     (authenticate-id &optional authorize-id))
  48   (defun-maybe sasl-scram-md5-client-msg-2
  49     (server-msg-1 client-msg-1 salted-pass))
  50   (defun-maybe sasl-scram-md5-make-salted-pass
  51     (server-msg-1 passphrase))
  52   (defun-maybe sasl-cram-md5 (username passphrase challenge))
  53   (defun-maybe sasl-scram-md5-authenticate-server
  54     (server-msg-1 server-msg-2 client-msg-1 salted-pass))
  55   (defun-maybe starttls-negotiate (a)))
  56 (condition-case nil
  57     (progn
  58       (require 'sasl))
  59   (error))
  60
  61 (defvar elmo-pop3-use-uidl t
  62   "*If non-nil, use UIDL.")
  63
  64 (defvar elmo-pop3-exists-exactly t)
  65
  66 (defvar elmo-pop3-authenticator-alist
  67   '((user        elmo-pop3-auth-user)
  68     (apop        elmo-pop3-auth-apop)
  69     (cram-md5    elmo-pop3-auth-cram-md5)
  70     (scram-md5   elmo-pop3-auth-scram-md5)
  71     (digest-md5  elmo-pop3-auth-digest-md5))
  72   "Definition of authenticators.")
  73
  74 (eval-and-compile
  75   (luna-define-class elmo-pop3-session (elmo-network-session) ()))
  76
  77 ;; buffer-local
  78 (defvar elmo-pop3-read-point nil)
  79 (defvar elmo-pop3-number-uidl-hash nil) ; number -> uidl
  80 (defvar elmo-pop3-uidl-number-hash nil) ; uidl -> number
  81 (defvar elmo-pop3-size-hash nil) ; number -> size
  82 (defvar elmo-pop3-uidl-done nil)
  83 (defvar elmo-pop3-list-done nil)
  84
  85 (defvar elmo-pop3-local-variables '(elmo-pop3-read-point
  86                                     elmo-pop3-uidl-number-hash
  87                                     elmo-pop3-number-uidl-hash
  88                                     elmo-pop3-uidl-done
  89                                     elmo-pop3-size-hash
  90                                     elmo-pop3-list-done))
  91
  92 (luna-define-method elmo-network-close-session ((session elmo-pop3-session))
  93   (unless (memq (process-status
  94                  (elmo-network-session-process-internal session))
  95                 '(closed exit))
  96     (elmo-pop3-send-command (elmo-network-session-process-internal session)
  97                             "quit")
  98     (or (elmo-pop3-read-response
  99          (elmo-network-session-process-internal session) t)
 100         (error "POP error: QUIT failed")))
 101   (kill-buffer (process-buffer
 102                 (elmo-network-session-process-internal session)))
 103   (delete-process (elmo-network-session-process-internal session)))
 104
 105 (defun elmo-pop3-get-session (spec &optional if-exists)
 106   (elmo-network-get-session
 107    'elmo-pop3-session
 108    "POP3"
 109    (elmo-pop3-spec-hostname spec)
 110    (elmo-pop3-spec-port spec)
 111    (elmo-pop3-spec-username spec)
 112    (elmo-pop3-spec-auth spec)
 113    (elmo-pop3-spec-stream-type spec)
 114    if-exists))
 115
 116 (defun elmo-pop3-send-command (process command &optional no-erase)
 117   (with-current-buffer (process-buffer process)
 118     (unless no-erase
 119       (erase-buffer))
 120     (goto-char (point-min))
 121     (setq elmo-pop3-read-point (point))
 122     (process-send-string process command)
 123     (process-send-string process "\r\n")))
 124
 125 (defun elmo-pop3-read-response (process &optional not-command)
 126   (with-current-buffer (process-buffer process)
 127     (let ((case-fold-search nil)
 128           (response-string nil)
 129           (response-continue t)
 130           (return-value nil)
 131           match-end)
 132       (while response-continue
 133         (goto-char elmo-pop3-read-point)
 134         (while (not (re-search-forward "\r?\n" nil t))
 135           (accept-process-output process)
 136           (goto-char elmo-pop3-read-point))
 137         (setq match-end (point))
 138         (setq response-string
 139               (buffer-substring elmo-pop3-read-point (- match-end 2)))
 140         (goto-char elmo-pop3-read-point)
 141         (if (looking-at "\\+.*$")
 142             (progn
 143               (setq response-continue nil)
 144               (setq elmo-pop3-read-point match-end)
 145               (setq return-value
 146                     (if return-value
 147                         (concat return-value "\n" response-string)
 148                       response-string)))
 149           (if (looking-at "\\-.*$")
 150               (progn
 151                 (setq response-continue nil)
 152                 (setq elmo-pop3-read-point match-end)
 153                 (setq return-value nil))
 154             (setq elmo-pop3-read-point match-end)
 155             (if not-command
 156                 (setq response-continue nil))
 157             (setq return-value
 158                   (if return-value
 159                       (concat return-value "\n" response-string)
 160                     response-string)))
 161           (setq elmo-pop3-read-point match-end)))
 162       return-value)))
 163
 164 (defun elmo-pop3-process-filter (process output)
 165   (save-excursion
 166     (set-buffer (process-buffer process))
 167     (goto-char (point-max))
 168     (insert output)))
 169
 170 (defun elmo-pop3-auth-user (session)
 171   (let ((process (elmo-network-session-process-internal session)))
 172     ;; try USER/PASS
 173     (elmo-pop3-send-command
 174      process
 175      (format "user %s" (elmo-network-session-user-internal session)))
 176     (or (elmo-pop3-read-response process t)
 177         (signal 'elmo-authenticate-error
 178                 '(elmo-pop-auth-user)))
 179     (elmo-pop3-send-command  process
 180                              (format
 181                               "pass %s"
 182                               (elmo-get-passwd
 183                                (elmo-network-session-password-key session))))
 184     (or (elmo-pop3-read-response process t)
 185         (signal 'elmo-authenticate-error
 186                 '(elmo-pop-auth-user)))))
 187
 188 (defun elmo-pop3-auth-apop (session)
 189   (if (string-match "^\+OK .*\\(<[^\>]+>\\)"
 190                     (elmo-network-session-greeting-internal session))
 191       ;; good, APOP ready server
 192       (progn
 193         (require 'md5)
 194         (elmo-pop3-send-command
 195          (elmo-network-session-process-internal session)
 196          (format "apop %s %s"
 197                  (elmo-network-session-user-internal session)
 198                  (md5
 199                   (concat (match-string
 200                            1
 201                            (elmo-network-session-greeting-internal session))
 202                           (elmo-get-passwd
 203                            (elmo-network-session-password-key session))))))
 204         (or (elmo-pop3-read-response
 205              (elmo-network-session-process-internal session)
 206              t)
 207             (signal 'elmo-authenticate-error
 208                     '(elmo-pop3-auth-apop))))
 209     (signal 'elmo-open-error '(elmo-pop-auth-user))))
 210
 211 (defun elmo-pop3-auth-cram-md5 (session)
 212   (let ((process (elmo-network-session-process-internal session))
 213         response)
 214     (elmo-pop3-send-command  process "auth cram-md5")
 215     (or (setq response
 216               (elmo-pop3-read-response process t))
 217         (signal 'elmo-open-error '(elmo-pop-auth-cram-md5)))
 218     (elmo-pop3-send-command
 219      process
 220      (elmo-base64-encode-string
 221       (sasl-cram-md5 (elmo-network-session-user-internal session)
 222                      (elmo-get-passwd
 223                       (elmo-network-session-password-key session))
 224                      (elmo-base64-decode-string
 225                       (cadr (split-string response " "))))))
 226     (or (elmo-pop3-read-response process t)
 227         (signal 'elmo-authenticate-error
 228                 '(elmo-pop-auth-cram-md5)))))
 229
 230 (defun elmo-pop3-auth-scram-md5 (session)
 231   (let ((process (elmo-network-session-process-internal session))
 232         server-msg-1 server-msg-2 client-msg-1 client-msg-2
 233         salted-pass response)
 234     (elmo-pop3-send-command
 235      process
 236      (format "auth scram-md5 %s"
 237              (elmo-base64-encode-string
 238               (setq client-msg-1
 239                     (sasl-scram-md5-client-msg-1
 240                      (elmo-network-session-user-internal session))))))
 241     (or (elmo-pop3-read-response process t)
 242         (signal 'elmo-open-error '(elmo-pop-auth-scram-md5)))
 243     (setq server-msg-1
 244           (elmo-base64-decode-string (cadr (split-string response " "))))
 245     (elmo-pop3-send-command
 246      process
 247      (elmo-base64-encode-string
 248       (sasl-scram-md5-client-msg-2
 249        server-msg-1
 250        client-msg-1
 251        (setq salted-pass
 252              (sasl-scram-md5-make-salted-pass
 253               server-msg-1
 254               (elmo-get-passwd
 255                (elmo-network-session-password-key session)))))))
 256     (or (setq response (elmo-pop3-read-response process t))
 257         (signal 'elmo-authenticate-error
 258                 '(elmo-pop-auth-scram-md5)))
 259     (setq server-msg-2 (elmo-base64-decode-string
 260                         (cadr (split-string response " "))))
 261     (or (sasl-scram-md5-authenticate-server server-msg-1
 262                                             server-msg-2
 263                                             client-msg-1
 264                                             salted-pass)
 265         (signal 'elmo-authenticate-error
 266                 '(elmo-pop-auth-scram-md5)))
 267     (elmo-pop3-send-command process "")
 268     (or (setq response (elmo-pop3-read-response process t))
 269         (signal 'elmo-authenticate-error
 270                 '(elmo-pop-auth-scram-md5)))))
 271
 272 (defun elmo-pop3-auth-digest-md5 (session)
 273   (let ((process (elmo-network-session-process-internal session))
 274         response)
 275     (elmo-pop3-send-command process "auth digest-md5")
 276     (or (setq response
 277               (elmo-pop3-read-response process t))
 278         (signal 'elmo-open-error
 279                 '(elmo-pop-auth-digest-md5)))
 280     (elmo-pop3-send-command
 281      process
 282      (elmo-base64-encode-string
 283       (sasl-digest-md5-digest-response
 284        (elmo-base64-decode-string
 285         (cadr (split-string response " ")))
 286        (elmo-network-session-user-internal session)
 287        (elmo-get-passwd
 288         (elmo-network-session-password-key session))
 289        "pop"
 290        (elmo-network-session-host-internal session))
 291       'no-line-break))
 292     (or (elmo-pop3-read-response process t)
 293         (signal 'elmo-authenticate-error
 294                 '(elmo-pop-auth-digest-md5)))
 295     (elmo-pop3-send-command process "")
 296     (or (elmo-pop3-read-response process t)
 297         (signal 'elmo-open-error
 298                 '(elmo-pop-auth-digest-md5)))))
 299
 300 (luna-define-method elmo-network-initialize-session-buffer :after
 301   ((session elmo-pop3-session) buffer)
 302   (with-current-buffer buffer
 303     (mapcar 'make-variable-buffer-local elmo-pop3-local-variables)))
 304
 305 (luna-define-method elmo-network-initialize-session ((session
 306                                                       elmo-pop3-session))
 307   (let ((process (elmo-network-session-process-internal session))
 308         response mechanism)
 309     (with-current-buffer (process-buffer process)
 310       (set-process-filter process 'elmo-pop3-process-filter)
 311       (setq elmo-pop3-read-point (point-min))
 312       (or (elmo-network-session-set-greeting-internal
 313            session
 314            (elmo-pop3-read-response process t))
 315           (signal 'elmo-open-error
 316                   '(elmo-network-intialize-session)))
 317       (when (eq (elmo-network-stream-type-symbol
 318                  (elmo-network-session-stream-type-internal session))
 319                 'starttls)
 320         (elmo-pop3-send-command process "stls")
 321         (if (string-match "^\+OK"
 322                           (elmo-pop3-read-response process))
 323             (starttls-negotiate process)
 324           (signal 'elmo-open-error
 325                   '(elmo-pop3-starttls-error)))))))
 326
 327 (luna-define-method elmo-network-authenticate-session ((session
 328                                                         elmo-pop3-session))
 329   (let (authenticator)
 330     ;; defaults to 'user.
 331     (unless (elmo-network-session-auth-internal session)
 332       (elmo-network-session-set-auth-internal session 'user))
 333     (setq authenticator
 334           (nth 1 (assq (elmo-network-session-auth-internal session)
 335                        elmo-pop3-authenticator-alist)))
 336     (unless authenticator (error "There's no authenticator for %s"
 337                                  (elmo-network-session-auth-internal session)))
 338     (funcall authenticator session)))
 339
 340 (luna-define-method elmo-network-setup-session ((session
 341                                                  elmo-pop3-session))
 342   (let ((process (elmo-network-session-process-internal session))
 343         response)
 344     (with-current-buffer (process-buffer process)
 345       (setq elmo-pop3-size-hash (make-vector 31 0))
 346       ;; To get obarray of uidl and size
 347       (elmo-pop3-send-command process "list")
 348       (if (null (elmo-pop3-read-response process))
 349           (error "POP List folder failed"))
 350       (if (null (setq response
 351                       (elmo-pop3-read-contents
 352                        (current-buffer) process)))
 353           (error "POP List folder failed"))
 354       ;; POP server always returns a sequence of serial numbers.
 355       (elmo-pop3-parse-list-response response)
 356       ;; UIDL
 357       (when elmo-pop3-use-uidl
 358         (setq elmo-pop3-uidl-number-hash (make-vector 31 0))
 359         (setq elmo-pop3-number-uidl-hash (make-vector 31 0))
 360         ;; UIDL
 361         (elmo-pop3-send-command process "uidl")
 362         (unless (elmo-pop3-read-response process)
 363           (error "UIDL failed"))
 364         (unless (setq response (elmo-pop3-read-contents
 365                                 (current-buffer) process))
 366           (error "UIDL failed"))
 367         (elmo-pop3-parse-uidl-response response)))))
 368
 369 (defun elmo-pop3-read-contents (buffer process)
 370   (save-excursion
 371     (set-buffer buffer)
 372     (let ((case-fold-search nil)
 373           match-end)
 374       (goto-char elmo-pop3-read-point)
 375       (while (not (re-search-forward "^\\.\r\n" nil t))
 376         (accept-process-output process)
 377         (goto-char elmo-pop3-read-point))
 378       (setq match-end (point))
 379       (elmo-delete-cr
 380        (buffer-substring elmo-pop3-read-point
 381                          (- match-end 3))))))
 382
 383 ;; dummy functions
 384 (defun elmo-pop3-list-folders (spec &optional hierarchy) nil)
 385 (defun elmo-pop3-append-msg (spec string) nil nil)
 386 (defun elmo-pop3-folder-creatable-p (spec) nil)
 387 (defun elmo-pop3-create-folder (spec) nil)
 388
 389 (defun elmo-pop3-folder-exists-p (spec)
 390   (if (and elmo-pop3-exists-exactly
 391            (elmo-pop3-plugged-p spec))
 392       (save-excursion
 393         (let (elmo-auto-change-plugged ; don't change plug status.
 394               session)
 395           (prog1
 396               (setq session (elmo-pop3-get-session spec))
 397             (if session
 398                 (elmo-network-close-session session)))))
 399     t))
 400
 401 (defun elmo-pop3-parse-uidl-response (string)
 402   (let ((buffer (current-buffer))
 403         number list size)
 404     (with-temp-buffer
 405       (let (number uid list)
 406         (insert string)
 407         (goto-char (point-min))
 408         (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([^ \n]+\\)$" nil t)
 409           (setq number  (elmo-match-buffer 1))
 410           (setq uid (elmo-match-buffer 2))
 411           (with-current-buffer buffer
 412             (elmo-set-hash-val uid number elmo-pop3-uidl-number-hash)
 413             (elmo-set-hash-val (concat "#" number) uid
 414                                elmo-pop3-number-uidl-hash))
 415           (setq list (cons uid list)))
 416         (with-current-buffer buffer (setq elmo-pop3-uidl-done t))
 417         (nreverse list)))))
 418
 419 (defun elmo-pop3-parse-list-response (string)
 420   (let ((buffer (current-buffer))
 421         number list size)
 422     (with-temp-buffer
 423       (insert string)
 424       (goto-char (point-min))
 425       (while (re-search-forward "^\\([0-9]+\\)[\t ]\\([0-9]+\\)$" nil t)
 426         (setq list
 427               (cons
 428                (string-to-int (setq number (elmo-match-buffer 1)))
 429                list))
 430         (setq size (elmo-match-buffer 2))
 431         (with-current-buffer buffer
 432           (elmo-set-hash-val (concat "#" number)
 433                              size
 434                              elmo-pop3-size-hash)))
 435       (with-current-buffer buffer (setq elmo-pop3-list-done t))
 436       (nreverse list))))
 437
 438 (defun elmo-pop3-list-location (spec)
 439   (with-current-buffer (process-buffer
 440                         (elmo-network-session-process-internal
 441                          (elmo-pop3-get-session spec)))
 442     (let (list)
 443       (if elmo-pop3-uidl-done
 444           (progn
 445             (mapatoms
 446              (lambda (atom)
 447                (setq list (cons (symbol-name atom) list)))
 448              elmo-pop3-uidl-number-hash)
 449             (nreverse list))
 450         (error "POP3: Error in UIDL")))))
 451
 452 (defun elmo-pop3-list-by-uidl-subr (spec &optional nonsort)
 453   (let ((flist (elmo-list-folder-by-location
 454                 spec
 455                 (elmo-pop3-list-location spec))))
 456     (if nonsort
 457         (cons (elmo-max-of-list flist) (length flist))
 458       (sort flist '<))))
 459
 460 (defun elmo-pop3-list-by-list (spec)
 461   (with-current-buffer (process-buffer
 462                         (elmo-network-session-process-internal
 463                          (elmo-pop3-get-session spec)))
 464     (let (list)
 465       (if elmo-pop3-list-done
 466           (progn
 467             (mapatoms (lambda (atom)
 468                         (setq list (cons (string-to-int
 469                                           (substring (symbol-name atom) 1))
 470                                          list)))
 471                       elmo-pop3-size-hash)
 472             (sort list '<))
 473         (error "POP3: Error in list")))))
 474
 475 (defun elmo-pop3-list-folder (spec)
 476   (let ((killed (and elmo-use-killed-list
 477                      (elmo-msgdb-killed-list-load
 478                       (elmo-msgdb-expand-path spec))))
 479         numbers)
 480     (elmo-pop3-commit spec)
 481     (setq numbers (if elmo-pop3-use-uidl
 482                       (progn
 483                         (elmo-pop3-list-by-uidl-subr spec))
 484                     (elmo-pop3-list-by-list spec)))
 485     (elmo-living-messages numbers killed)))
 486
 487 (defun elmo-pop3-max-of-folder (spec)
 488   (elmo-pop3-commit spec)
 489   (if elmo-pop3-use-uidl
 490       (elmo-pop3-list-by-uidl-subr spec 'nonsort)
 491     (let* ((process
 492             (elmo-network-session-process-internal
 493              (elmo-pop3-get-session spec)))
 494            (total 0)
 495            response)
 496       (with-current-buffer (process-buffer process)
 497         (elmo-pop3-send-command process "STAT")
 498         (setq response (elmo-pop3-read-response process))
 499         ;; response: "^\+OK 2 7570$"
 500         (if (not (string-match "^\+OK[ \t]*\\([0-9]*\\)" response))
 501             (error "POP STAT command failed")
 502           (setq total
 503                 (string-to-int
 504                  (substring response (match-beginning 1)(match-end 1 ))))
 505           (cons total total))))))
 506
 507 (defvar elmo-pop3-header-fetch-chop-length 200)
 508
 509 (defsubst elmo-pop3-next-result-arrived-p ()
 510   (cond
 511    ((eq (following-char) ?+)
 512     (if (re-search-forward "\n\\.\r?\n" nil t)
 513         t
 514       nil))
 515    ((looking-at "-")
 516     (if (search-forward "\n" nil t)
 517         t
 518       nil))
 519    (t
 520     nil)))
 521
 522 (defun elmo-pop3-retrieve-headers (buffer tobuffer process articles)
 523   (save-excursion
 524     (set-buffer buffer)
 525     (erase-buffer)
 526     (let ((number (length articles))
 527           (count 0)
 528           (received 0)
 529           (last-point (point-min)))
 530       ;; Send HEAD commands.
 531       (while articles
 532         (elmo-pop3-send-command process (format
 533                                          "top %s 0" (car articles))
 534                                 'no-erase)
 535 ;;;     (accept-process-output process 1)
 536         (setq articles (cdr articles))
 537         (setq count (1+ count))
 538         ;; Every 200 requests we have to read the stream in
 539         ;; order to avoid deadlocks.
 540         (when (or elmo-pop3-send-command-synchronously
 541                   (null articles)       ;All requests have been sent.
 542                   (zerop (% count elmo-pop3-header-fetch-chop-length)))
 543           (unless elmo-pop3-send-command-synchronously
 544             (accept-process-output process 1))
 545           (discard-input)
 546           (while (progn
 547                    (set-buffer buffer)
 548                    (goto-char last-point)
 549                    ;; Count replies.
 550                    (while (elmo-pop3-next-result-arrived-p)
 551                      (setq last-point (point))
 552                      (setq received (1+ received)))
 553                    (< received count))
 554             (when (> number elmo-display-progress-threshold)
 555               (if (or (zerop (% received 5)) (= received number))
 556                   (elmo-display-progress
 557                    'elmo-pop3-retrieve-headers "Getting headers..."
 558                    (/ (* received 100) number))))
 559             (accept-process-output process 1)
 560 ;;;         (accept-process-output process)
 561             (discard-input))))
 562       ;; Remove all "\r"'s.
 563       (goto-char (point-min))
 564       (while (search-forward "\r\n" nil t)
 565         (replace-match "\n"))
 566       (copy-to-buffer tobuffer (point-min) (point-max)))))
 567
 568 (defalias 'elmo-pop3-msgdb-create 'elmo-pop3-msgdb-create-as-numlist)
 569
 570 (defun elmo-pop3-msgdb-create-as-numlist (spec numlist new-mark
 571                                                already-mark seen-mark
 572                                                important-mark seen-list
 573                                                &optional msgdb)
 574   (when numlist
 575     (let ((process (elmo-network-session-process-internal
 576                     (elmo-pop3-get-session spec)))
 577           loc-alist)
 578       (if elmo-pop3-use-uidl
 579           (setq loc-alist (if msgdb (elmo-msgdb-get-location msgdb)
 580                             (elmo-msgdb-location-load
 581                              (elmo-msgdb-expand-path spec)))))
 582       (elmo-pop3-msgdb-create-by-header process numlist
 583                                         new-mark already-mark
 584                                         seen-mark seen-list
 585                                         loc-alist))))
 586
 587 (defun elmo-pop3-uidl-to-number (uidl)
 588   (string-to-number (elmo-get-hash-val uidl
 589                                        elmo-pop3-uidl-number-hash)))
 590
 591 (defun elmo-pop3-number-to-uidl (number)
 592   (elmo-get-hash-val (format "#%d" number)
 593                      elmo-pop3-number-uidl-hash))
 594
 595 (defun elmo-pop3-number-to-size (number)
 596   (elmo-get-hash-val (format "#%d" number)
 597                      elmo-pop3-size-hash))
 598
 599 (defun elmo-pop3-msgdb-create-by-header (process numlist
 600                                                  new-mark already-mark
 601                                                  seen-mark
 602                                                  seen-list
 603                                                  loc-alist)
 604   (let ((tmp-buffer (get-buffer-create " *ELMO Overview TMP*")))
 605     (with-current-buffer (process-buffer process)
 606       (if loc-alist ; use uidl.
 607           (setq numlist
 608                 (delq
 609                  nil
 610                  (mapcar
 611                   (lambda (number)
 612                     (elmo-pop3-uidl-to-number (cdr (assq number loc-alist))))
 613                   numlist))))
 614       (elmo-pop3-retrieve-headers (process-buffer process)
 615                                   tmp-buffer process numlist)
 616       (prog1
 617           (elmo-pop3-msgdb-create-message
 618            tmp-buffer
 619            process
 620            (length numlist)
 621            numlist
 622            new-mark already-mark seen-mark seen-list loc-alist)
 623         (kill-buffer tmp-buffer)))))
 624
 625 (defun elmo-pop3-msgdb-create-message (buffer
 626                                        process
 627                                        num
 628                                        numlist new-mark already-mark
 629                                        seen-mark
 630                                        seen-list
 631                                        loc-alist)
 632   (save-excursion
 633     (let (beg overview number-alist mark-alist
 634               entity i number message-id gmark seen size)
 635       (set-buffer buffer)
 636       (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 637       (goto-char (point-min))
 638       (setq i 0)
 639       (message "Creating msgdb...")
 640       (while (not (eobp))
 641         (setq beg (save-excursion (forward-line 1) (point)))
 642         (elmo-pop3-next-result-arrived-p)
 643         (save-excursion
 644           (forward-line -1)
 645           (save-restriction
 646             (narrow-to-region beg (point))
 647             (setq entity
 648                   (elmo-msgdb-create-overview-from-buffer
 649                    (car numlist)))
 650             (setq numlist (cdr numlist))
 651             (when entity
 652               (setq overview
 653                     (elmo-msgdb-append-element
 654                      overview entity))
 655               (with-current-buffer (process-buffer process)
 656                 (elmo-msgdb-overview-entity-set-size
 657                  entity
 658                  (string-to-number
 659                   (elmo-pop3-number-to-size
 660                    (elmo-msgdb-overview-entity-get-number entity))))
 661                 (if (setq number
 662                           (car
 663                            (rassoc
 664                             (elmo-pop3-number-to-uidl
 665                              (elmo-msgdb-overview-entity-get-number entity))
 666                             loc-alist)))
 667                     (elmo-msgdb-overview-entity-set-number entity number)))
 668               (setq number-alist
 669                     (elmo-msgdb-number-add
 670                      number-alist
 671                      (elmo-msgdb-overview-entity-get-number entity)
 672                      (car entity)))
 673               (setq message-id (car entity))
 674               (setq seen (member message-id seen-list))
 675               (if (setq gmark (or (elmo-msgdb-global-mark-get message-id)
 676                                   (if (elmo-cache-exists-p
 677                                        message-id) ; XXX
 678                                       (if seen
 679                                           nil
 680                                         already-mark)
 681                                     (if seen
 682                                         (if elmo-pop3-use-cache
 683                                             seen-mark)
 684                                       new-mark))))
 685                   (setq mark-alist
 686                         (elmo-msgdb-mark-append
 687                          mark-alist
 688                          (elmo-msgdb-overview-entity-get-number entity)
 689                          gmark))))))
 690         (when (> num elmo-display-progress-threshold)
 691           (setq i (1+ i))
 692           (if (or (zerop (% i 5)) (= i num))
 693               (elmo-display-progress
 694                'elmo-pop3-msgdb-create-message "Creating msgdb..."
 695                (/ (* i 100) num)))))
 696       (list overview number-alist mark-alist loc-alist))))
 697
 698 (defun elmo-pop3-read-body (process outbuf)
 699   (with-current-buffer (process-buffer process)
 700     (let ((start elmo-pop3-read-point)
 701           end)
 702       (goto-char start)
 703       (while (not (re-search-forward "^\\.\r?\n" nil t))
 704         (accept-process-output process)
 705         (goto-char start))
 706       (setq end (point))
 707       (with-current-buffer outbuf
 708         (erase-buffer)
 709         (insert-buffer-substring (process-buffer process) start (- end 3))
 710         (elmo-delete-cr-get-content-type)))))
 711
 712 (defun elmo-pop3-read-msg (spec number outbuf &optional msgdb)
 713   (let* ((loc-alist (if elmo-pop3-use-uidl
 714                         (if msgdb
 715                             (elmo-msgdb-get-location msgdb)
 716                           (elmo-msgdb-location-load
 717                            (elmo-msgdb-expand-path spec)))))
 718          (process (elmo-network-session-process-internal
 719                    (elmo-pop3-get-session spec)))
 720          response errmsg msg)
 721     (with-current-buffer (process-buffer process)
 722       (if loc-alist
 723           (setq number (elmo-pop3-uidl-to-number
 724                         (cdr (assq number loc-alist)))))
 725       (when number
 726         (elmo-pop3-send-command process
 727                                 (format "retr %s" number))
 728         (when (null (setq response (elmo-pop3-read-response
 729                                     process t)))
 730           (error "Fetching message failed"))
 731         (setq response (elmo-pop3-read-body process outbuf))
 732         (set-buffer outbuf)
 733         (goto-char (point-min))
 734         (while (re-search-forward "^\\." nil t)
 735           (replace-match "")
 736           (forward-line))
 737         response))))
 738
 739 (defun elmo-pop3-delete-msg (process number loc-alist)
 740   (with-current-buffer (process-buffer process)
 741     (let (response errmsg msg)
 742       (if loc-alist
 743           (setq number (elmo-pop3-uidl-to-number
 744                         (cdr (assq number loc-alist)))))
 745       (if number
 746           (progn
 747             (elmo-pop3-send-command process
 748                                     (format "dele %s" number))
 749             (when (null (setq response (elmo-pop3-read-response
 750                                         process t)))
 751               (error "Deleting message failed")))
 752         (error "Deleting message failed")))))
 753
 754 (defun elmo-pop3-delete-msgs (spec msgs &optional msgdb)
 755   (let ((loc-alist (if elmo-pop3-use-uidl
 756                        (if msgdb
 757                            (elmo-msgdb-get-location msgdb)
 758                          (elmo-msgdb-location-load
 759                           (elmo-msgdb-expand-path spec)))))
 760         (process (elmo-network-session-process-internal
 761                   (elmo-pop3-get-session spec))))
 762     (mapcar '(lambda (msg) (elmo-pop3-delete-msg
 763                             process msg loc-alist))
 764             msgs)))
 765
 766 (defun elmo-pop3-search (spec condition &optional numlist)
 767   (error "Searching in pop3 folder is not implemented yet"))
 768
 769 (defun elmo-pop3-use-cache-p (spec number)
 770   elmo-pop3-use-cache)
 771
 772 (defun elmo-pop3-local-file-p (spec number)
 773   nil)
 774
 775 (defun elmo-pop3-port-label (spec)
 776   (concat "pop3"
 777           (if (elmo-pop3-spec-stream-type spec)
 778               (concat "!" (symbol-name
 779                            (elmo-network-stream-type-symbol
 780                             (elmo-pop3-spec-stream-type spec)))))))
 781
 782 (defsubst elmo-pop3-portinfo (spec)
 783   (list (elmo-pop3-spec-hostname spec)
 784         (elmo-pop3-spec-port spec)))
 785
 786 (defun elmo-pop3-plugged-p (spec)
 787   (apply 'elmo-plugged-p
 788          (append (elmo-pop3-portinfo spec)
 789                  (list nil (quote (elmo-pop3-port-label spec))))))
 790
 791 (defun elmo-pop3-set-plugged (spec plugged add)
 792   (apply 'elmo-set-plugged plugged
 793          (append (elmo-pop3-portinfo spec)
 794                  (list nil nil (quote (elmo-pop3-port-label spec)) add))))
 795
 796 (defalias 'elmo-pop3-sync-number-alist
 797   'elmo-generic-sync-number-alist)
 798 (defalias 'elmo-pop3-list-folder-unread
 799   'elmo-generic-list-folder-unread)
 800 (defalias 'elmo-pop3-list-folder-important
 801   'elmo-generic-list-folder-important)
 802 (defalias 'elmo-pop3-folder-diff 'elmo-generic-folder-diff)
 803
 804 (defun elmo-pop3-commit (spec)
 805   (if (elmo-pop3-plugged-p spec)
 806       (let ((session (elmo-pop3-get-session spec 'if-exists)))
 807         (and session
 808              (elmo-network-close-session session)))))
 809
 810
 811 (require 'product)
 812 (product-provide (provide 'elmo-pop3) (require 'elmo-version))
 813
 814 ;;; elmo-pop3.el ends here