elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      mark-modified    ; mark is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, folder is treated as
 128  non-persistent."
 129   (let ((type (elmo-folder-type name))
 130         prefix split class folder original)
 131     (setq original (elmo-string name))
 132     (if type
 133         (progn
 134           (setq prefix (substring name 0 1))
 135           (setq name (substring name 1)))
 136       (setq type (intern (car (setq split (split-string name ":")))))
 137       (if (> (length split) 2)
 138           (setq name (substring name (+ 1 (length (car split)))))
 139         (error "Error in folder name `%s'" original))
 140       (setq prefix (concat (car split) ":")))
 141     (setq class (format "elmo-%s" (symbol-name type)))
 142     (require (intern class))
 143     (setq folder (luna-make-entity (intern (concat class "-folder"))
 144                                    :type   type
 145                                    :prefix prefix
 146                                    :name original
 147                                    :persistent (not non-persistent)))
 148     (save-match-data
 149       (elmo-folder-send folder 'elmo-folder-initialize name))))
 150
 151 (defmacro elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading)."
 153   (` (or (elmo-folder-msgdb-internal (, folder))
 154          (elmo-folder-set-msgdb-internal (, folder)
 155                                          (elmo-msgdb-load (, folder))))))
 156
 157 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 158   "Open and setup (load saved status) FOLDER.
 159 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 160 (otherwise, msgdb is loaded on-demand)")
 161
 162 (luna-define-generic elmo-folder-open-internal (folder)
 163   "Open FOLDER (without loading saved folder status).")
 164
 165 (luna-define-generic elmo-folder-check (folder)
 166   "Check the FOLDER to obtain newest information at the next list operation.")
 167
 168 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 169   "Clear FOLDER to the initial state.
 170 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 171
 172 (luna-define-generic elmo-folder-commit (folder)
 173   "Save current status of FOLDER.")
 174
 175 (luna-define-generic elmo-folder-close (folder)
 176   "Close, save and clearnup FOLDER.")
 177
 178 (luna-define-generic elmo-folder-close-internal (folder)
 179   "Close FOLDER (without saving folder status).")
 180
 181 (luna-define-generic elmo-folder-plugged-p (folder)
 182   "Returns t if FOLDER is plugged.")
 183
 184 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 185   "Set FOLDER as plugged.")
 186
 187 (luna-define-generic elmo-net-port-info (folder)
 188   "Get port information of FOLDER.")
 189
 190 (luna-define-generic elmo-folder-use-flag-p (folder)
 191   "Returns t if FOLDER treats unread/important flag itself.")
 192
 193 (luna-define-generic elmo-folder-diff (folder &optional numbers)
 194   "Get diff of FOLDER.
 195 If optional NUMBERS is set, it is used as current NUMBERS.
 196 Otherwise, saved status for folder is used for comparison.
 197 Return value is cons cell or list:
 198  - a cons cell (NEWS . MESSAGES)
 199  - a list (RECENT UNSEEN MESSAGES) ; RECENT means NEWS, UNSEEN means UNREAD.")
 200
 201 (luna-define-generic elmo-folder-status (folder)
 202   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 203
 204 (luna-define-generic elmo-folder-reserve-status-p (folder)
 205   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 206
 207 (defun elmo-folder-list-messages (folder &optional visible-only)
 208   "Return a list of message numbers contained in FOLDER.
 209 If optional VISIBLE-ONLY is non-nil, killed messages are not listed."
 210   (let ((list (elmo-folder-list-messages-internal folder visible-only))
 211         (killed (elmo-folder-killed-list-internal folder))
 212         numbers)
 213     (setq numbers
 214           (if (listp list)
 215               list
 216             ;; Not available, use current list.
 217             (mapcar
 218              'car
 219              (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))))
 220     (elmo-living-messages numbers killed)))
 221
 222 (defun elmo-folder-list-unreads (folder unread-marks)
 223   "Return a list of unread message numbers contained in FOLDER.
 224 UNREAD-MARKS is the unread marks."
 225   (let ((list (elmo-folder-list-unreads-internal folder
 226                                                  unread-marks)))
 227     (if (listp list)
 228         list
 229       ;; Not available, use current mark.
 230       (delq nil
 231             (mapcar
 232              (function
 233               (lambda (x)
 234                 (if (member (cadr x) unread-marks)
 235                     (car x))))
 236              (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))))))
 237
 238 (defun elmo-folder-list-importants (folder important-mark)
 239   "Returns a list of important message numbers contained in FOLDER.
 240 IMPORTANT-MARK is the important mark."
 241   (let ((importants (elmo-folder-list-importants-internal folder important-mark))
 242         (number-alist (elmo-msgdb-get-number-alist
 243                        (elmo-folder-msgdb folder)))
 244         num-pair result)
 245     (dolist (mark-pair (or elmo-msgdb-global-mark-alist
 246                            (setq elmo-msgdb-global-mark-alist
 247                                  (elmo-object-load
 248                                   (expand-file-name
 249                                    elmo-msgdb-global-mark-filename
 250                                    elmo-msgdb-directory)))))
 251       (if (and (string= important-mark (cdr mark-pair))
 252                (setq num-pair (rassoc (car mark-pair) number-alist)))
 253           (setq result (cons (car num-pair) result))))
 254     (if (listp importants)
 255         (elmo-uniq-list (nconc result importants))
 256       result)))
 257
 258 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 259                                                                 visible-only)
 260   ;; Return a list of message numbers contained in FOLDER.
 261   ;; Return t if the message list is not available.
 262   )
 263
 264 (luna-define-generic elmo-folder-list-unreads-internal (folder
 265                                                         unread-marks
 266                                                         &optional mark-alist)
 267   ;; Return a list of unread message numbers contained in FOLDER.
 268   ;; If optional MARK-ALIST is set, it is used as mark-alist.
 269   ;; Return t if this feature is not available.
 270   )
 271
 272 (luna-define-generic elmo-folder-list-importants-internal (folder
 273                                                            important-mark)
 274   ;; Return a list of important message numbers contained in FOLDER.
 275   ;; Return t if this feature is not available.
 276   )
 277
 278 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 279   "Returns a list of subfolders contained in FOLDER.
 280 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 281 \(a folder which have children is returned as a list\)
 282 Otherwise, all descendent folders are returned.")
 283
 284 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 285   "Return non-nil when FOLDER has subfolders.")
 286
 287 (luna-define-generic elmo-folder-exists-p (folder)
 288   "Returns non-nil when FOLDER exists.")
 289
 290 (luna-define-generic elmo-folder-creatable-p (folder)
 291   "Returns non-nil when FOLDER is creatable.")
 292
 293 (luna-define-generic elmo-folder-writable-p (folder)
 294   "Returns non-nil when FOLDER is writable.")
 295
 296 (luna-define-generic elmo-folder-persistent-p (folder)
 297   "Return non-nil when FOLDER is persistent.")
 298
 299 (luna-define-generic elmo-folder-create (folder)
 300   "Create a FOLDER.")
 301
 302 (luna-define-generic elmo-message-deletable-p (folder number)
 303   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 304
 305 (luna-define-generic elmo-folder-delete (folder)
 306   "Delete FOLDER completely.")
 307
 308 (luna-define-generic elmo-folder-rename (folder new-name)
 309   "Rename FOLDER to NEW-NAME (string).")
 310
 311 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 312   "Delete messages.
 313 FOLDER is the ELMO folder structure.
 314 NUMBERS is a list of message numbers to be deleted.")
 315
 316 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 317   "Search and return list of message numbers.
 318 FOLDER is the ELMO folder structure.
 319 CONDITION is a condition structure for searching.
 320 If optional argument NUMBERS is specified and is a list of message numbers,
 321 messages are searched from the list.")
 322
 323 (luna-define-generic elmo-message-match-condition (folder number
 324                                                           condition
 325                                                           numbers)
 326   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 327 CONDITION is a condition structure for testing.
 328 NUMBERS is a list of message numbers,
 329 use to be test for \"last\" and \"first\" predicates.")
 330
 331 (luna-define-generic elmo-folder-msgdb-create
 332   (folder numbers new-mark already-mark seen-mark important-mark seen-list)
 333   "Create a message database (implemented in each backends).
 334 FOLDER is the ELMO folder structure.
 335 NUMBERS is a list of message numbers to create msgdb.
 336 NEW-MARK, ALREADY-MARK, SEEN-MARK, and IMPORTANT-MARK are mark string for
 337 new message, unread but cached message, read message and important message.
 338 SEEN-LIST is a list of message-id string which should be treated as read.")
 339
 340 (luna-define-generic elmo-folder-unmark-important (folder numbers)
 341   "Un-mark messages as important.
 342 FOLDER is the ELMO folder structure.
 343 NUMBERS is a list of message numbers to be processed.")
 344
 345 (luna-define-generic elmo-folder-mark-as-important (folder numbers)
 346   "Mark messages as important.
 347 FOLDER is the ELMO folder structure.
 348 NUMBERS is a list of message numbers to be processed.")
 349
 350 (luna-define-generic elmo-folder-unmark-read (folder numbers)
 351   "Un-mark messages as read.
 352 FOLDER is the ELMO folder structure.
 353 NUMBERS is a list of message numbers to be processed.")
 354
 355 (luna-define-generic elmo-folder-mark-as-read (folder numbers)
 356   "Mark messages as read.
 357 FOLDER is the ELMO folder structure.
 358 NUMBERS is a list of message numbers to be processed.")
 359
 360 (luna-define-generic elmo-folder-append-buffer (folder unread &optional number)
 361   "Append current buffer as a new message.
 362 FOLDER is the destination folder(ELMO folder structure).
 363 If UNREAD is non-nil, message is appended as unread.
 364 If optional argument NUMBER is specified, the new message number is set
 365 \(if possible\).")
 366
 367 (luna-define-generic elmo-folder-append-messages (folder
 368                                                   src-folder
 369                                                   numbers
 370                                                   unread-marks
 371                                                   &optional
 372                                                   same-number)
 373   "Append messages from folder.
 374 FOLDER is the ELMO folder structure.
 375 Caller should make sure FOLDER is `writable'.
 376 (Can be checked with `elmo-folder-writable-p').
 377 SRC-FOLDER is the source ELMO folder structure.
 378 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 379 UNREAD-MARKS is a list of unread mark string.
 380 If second optional argument SAME-NUMBER is specified,
 381 message number is preserved (if possible).")
 382
 383 (luna-define-generic elmo-folder-pack-numbers (folder)
 384   "Pack message numbers of FOLDER.")
 385
 386 (luna-define-generic elmo-folder-update-number (folder)
 387   "Update number of FOLDER.")
 388
 389 (luna-define-generic elmo-folder-diff-async (folder)
 390   "Get diff of FOLDER asynchronously.")
 391
 392 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 393   "Expand path for FOLDER.")
 394
 395 (luna-define-generic elmo-folder-get-primitive-list (folder)
 396   "Get primitive folder structure list contained in FOLDER.")
 397
 398 (luna-define-generic elmo-folder-contains-type (folder type)
 399   "Returns t if FOLDER contains TYPE.")
 400
 401 (luna-define-generic elmo-folder-local-p (folder)
 402   "Returns t if FOLDER is local.")
 403
 404 (luna-define-generic elmo-folder-message-file-p (folder)
 405   "Returns t if all messages in the FOLDER are files.")
 406
 407 ;;; Message methods.
 408 (luna-define-generic elmo-message-use-cache-p (folder number)
 409   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 410
 411 (luna-define-generic elmo-message-file-name (folder number)
 412   "Return the file name of a message specified by FOLDER and NUMBER.")
 413
 414 ;;; For archive
 415
 416 ;;; Use original file
 417 (luna-define-generic elmo-folder-message-file-number-p (folder)
 418   "Return t if the file name in the FOLDER is the message number.")
 419
 420 (luna-define-generic elmo-folder-message-file-directory (folder)
 421   "Return the directory of the message files of FOLDER.")
 422
 423 ;;; Use temporary file
 424 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 425   "Return t if the messages in the FOLDER makes local temporary file.")
 426
 427 (luna-define-generic elmo-folder-message-make-temp-files (folder
 428                                                           numbers
 429                                                           &optional
 430                                                           start-number)
 431   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 432 If START-NUMBER is specified, temporary files begin from the number.
 433 Otherwise, same number is used for temporary files.
 434 Return newly created temporary directory name which contains temporary files.")
 435
 436 (luna-define-generic elmo-message-file-p (folder number)
 437   "Return t if message in the FOLDER with NUMBER is a file.")
 438
 439 (luna-define-generic elmo-find-fetch-strategy
 440   (folder entity &optional ignore-cache)
 441 ;; Returns the message fetching strategy suitable for the message.
 442 ;; FOLDER is the ELMO folder structure.
 443 ;; ENTITY is the overview entity of the message in the folder.
 444 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 445 ;; Returned value is a elmo-fetch-strategy object.
 446 ;; If return value is nil, message should not be nil.
 447   )
 448
 449 (defmacro elmo-make-fetch-strategy (entireness
 450                                     &optional
 451                                     use-cache
 452                                     save-cache
 453                                     cache-path)
 454 ;; Make elmo-message-fetching strategy.
 455 ;; ENTIRENESS is 'entire or 'section.
 456 ;; 'entire means fetch message entirely at once.
 457 ;; 'section means fetch message section by section.
 458 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 459 ;; existing cache is thrown away.
 460 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 461 ;; CACHE-PATH is the cache path to be used as a message cache file.
 462   (` (vector (, entireness)
 463              (, use-cache) (, save-cache) (, cache-path))))
 464
 465 (defmacro elmo-fetch-strategy-entireness (strategy)
 466   ;; Return entireness of STRATEGY.
 467   (` (aref (, strategy) 0)))
 468
 469 (defmacro elmo-fetch-strategy-use-cache (strategy)
 470   ;; Return use-cache of STRATEGY.
 471   (` (aref (, strategy) 1)))
 472
 473 (defmacro elmo-fetch-strategy-save-cache (strategy)
 474   ;; Return save-cache of STRATEGY.
 475   (` (aref (, strategy) 2)))
 476
 477 (defmacro elmo-fetch-strategy-cache-path (strategy)
 478   ;;  Return cache-path of STRATEGY.
 479   (` (aref (, strategy) 3)))
 480
 481 (luna-define-method elmo-find-fetch-strategy
 482   ((folder elmo-folder) entity &optional ignore-cache)
 483   (let (cache-file size message-id number)
 484     (setq size (elmo-msgdb-overview-entity-get-size entity))
 485     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 486     (setq number (elmo-msgdb-overview-entity-get-number entity))
 487     (setq cache-file (elmo-file-cache-get message-id))
 488     (setq ignore-cache (or ignore-cache
 489                            (null (elmo-message-use-cache-p folder number))))
 490     (if (or ignore-cache
 491             (null (elmo-file-cache-status cache-file)))
 492         ;; No cache or ignore-cache.
 493         (if (and (not (elmo-folder-local-p folder))
 494                  elmo-message-fetch-threshold
 495                  (integerp size)
 496                  (>= size elmo-message-fetch-threshold)
 497                  (or (not elmo-message-fetch-confirm)
 498                      (not (prog1 (y-or-n-p
 499                                   (format "Fetch entire message(%dbytes)? "
 500                                           size))
 501                             (message "")))))
 502             ;; Don't fetch message at all.
 503             nil
 504           ;; Don't use existing cache and fetch entire message at once.
 505           (elmo-make-fetch-strategy
 506            'entire nil
 507            (elmo-message-use-cache-p folder number)
 508            (elmo-file-cache-path cache-file)))
 509       ;; Cache exists.
 510       (if (not ignore-cache)
 511           (elmo-make-fetch-strategy
 512            'entire
 513            ;; ...But ignore current section cache and re-fetch
 514            ;; if section cache.
 515            (not (eq (elmo-file-cache-status cache-file) 'section))
 516            ;; Save cache.
 517            (elmo-message-use-cache-p folder number)
 518            (elmo-file-cache-path cache-file))))))
 519
 520 (luna-define-method elmo-folder-list-messages-internal
 521   ((folder elmo-folder) &optional visible-only)
 522   t)
 523
 524 (luna-define-method elmo-folder-list-unreads-internal
 525   ((folder elmo-folder) unread-marks &optional mark-alist)
 526   t)
 527
 528 (luna-define-method elmo-folder-list-importants-internal
 529   ((folder elmo-folder) important-mark)
 530   t)
 531
 532 (defun elmo-folder-encache (folder numbers &optional unread)
 533   "Encache messages in the FOLDER with NUMBERS.
 534 If UNREAD is non-nil, messages are not marked as read."
 535   (dolist (number numbers)
 536     (elmo-message-encache folder number unread)))
 537
 538 (luna-define-generic elmo-message-encache (folder number &optional read)
 539   "Encache message in the FOLDER with NUMBER.
 540 If READ is non-nil, message is marked as read.")
 541
 542 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 543                                           &optional read)
 544   (elmo-message-fetch
 545    folder number
 546    (elmo-make-fetch-strategy 'entire
 547                              nil ;use-cache
 548                              t   ;save-cache
 549                              (elmo-file-cache-get-path
 550                               (elmo-message-field
 551                                folder number 'message-id)))
 552    nil nil (not read)))
 553
 554 (luna-define-generic elmo-message-fetch (folder number strategy
 555                                                 &optional
 556                                                 section
 557                                                 outbuf
 558                                                 unread)
 559   "Fetch a message and return as a string.
 560 FOLDER is the ELMO folder structure.
 561 NUMBER is the number of the message in the FOLDER.
 562 STRATEGY is the message fetching strategy.
 563 If optional argument SECTION is specified, only the SECTION of the message
 564 is fetched (if possible).
 565 If second optional argument OUTBUF is specified, fetched message is
 566 inserted to the buffer and returns t if fetch was ended successfully.
 567 If third optional argument UNREAD is non-nil, message is not marked as read.
 568 Returns non-nil if fetching was succeed.")
 569
 570 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 571                                                             number strategy
 572                                                             &optional
 573                                                             section
 574                                                             unread)
 575   "Fetch a message into current buffer with cache process.
 576 FOLDER is the ELMO folder structure.
 577 NUMBER is the number of the message in the FOLDER.
 578 STRATEGY is the message fetching strategy.
 579 If optional argument SECTION is specified, only the SECTION of the message
 580 is fetched (if possible).
 581 If second optional argument UNREAD is non-nil, message is not marked as read.
 582 Returns non-nil if fetching was succeed.")
 583
 584 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 585                                                          &optional
 586                                                          section
 587                                                          unread)
 588   "Fetch a message into current buffer.
 589 FOLDER is the ELMO folder structure.
 590 NUMBER is the number of the message in the FOLDER.
 591 STRATEGY is the message fetching strategy.
 592 If optional argument SECTION is specified, only the SECTION of the message
 593 is fetched (if possible).
 594 If second optional argument UNREAD is non-nil, message is not marked as read.
 595 Returns non-nil if fetching was succeed.")
 596
 597 (luna-define-generic elmo-message-fetch-field (folder number field)
 598   "Fetch a message field value.
 599 FOLDER is the ELMO folder structure.
 600 NUMBER is the number of the message in the FOLDER.
 601 FIELD is a symbol of the field name.")
 602
 603 (luna-define-generic elmo-message-folder (folder number)
 604   "Get primitive folder of the message.")
 605
 606 (luna-define-generic elmo-folder-process-crosspost (folder
 607                                                     &optional
 608                                                     number-alist)
 609   "Process crosspost for FOLDER.
 610 If NUMBER-ALIST is set, it is used as number-alist.
 611 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 612
 613 (luna-define-generic elmo-folder-append-msgdb (folder append-msgdb)
 614   "Append  APPEND-MSGDB to the current msgdb of the folder.")
 615
 616 (luna-define-generic elmo-folder-newsgroups (folder)
 617   "Return list of newsgroup name of FOLDER.")
 618
 619 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 620   nil)
 621
 622 (luna-define-method elmo-folder-open ((folder elmo-folder)
 623                                       &optional load-msgdb)
 624   (elmo-generic-folder-open folder load-msgdb))
 625
 626 (defun elmo-generic-folder-open (folder load-msgdb)
 627   (let ((inhibit-quit t))
 628     (if load-msgdb
 629         (elmo-folder-set-msgdb-internal folder (elmo-msgdb-load folder)))
 630     (elmo-folder-set-killed-list-internal
 631      folder
 632      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 633   (elmo-folder-open-internal folder))
 634
 635 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 636   nil ; default is do nothing.
 637   )
 638
 639 (luna-define-method elmo-folder-check ((folder elmo-folder))
 640   nil) ; default is noop.
 641
 642 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 643   (elmo-generic-folder-commit folder))
 644
 645 (defun elmo-generic-folder-commit (folder)
 646   (when (elmo-folder-persistent-p folder)
 647     (when (elmo-folder-message-modified-internal folder)
 648       (elmo-msgdb-overview-save
 649        (elmo-folder-msgdb-path folder)
 650        (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
 651       (elmo-msgdb-number-save
 652        (elmo-folder-msgdb-path folder)
 653        (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 654       (elmo-folder-set-info-max-by-numdb
 655        folder
 656        (elmo-msgdb-get-number-alist
 657         (elmo-folder-msgdb folder)))
 658       (elmo-folder-set-message-modified-internal folder nil)
 659       (elmo-msgdb-killed-list-save
 660        (elmo-folder-msgdb-path folder)
 661        (elmo-folder-killed-list-internal folder)))
 662     (when (elmo-folder-mark-modified-internal folder)
 663       (elmo-msgdb-mark-save
 664        (elmo-folder-msgdb-path folder)
 665        (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
 666       (elmo-folder-set-mark-modified-internal folder nil))))
 667
 668 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 669   ;; do nothing.
 670   )
 671
 672 (luna-define-method elmo-folder-close ((folder elmo-folder))
 673   (elmo-generic-folder-close folder)
 674   (elmo-folder-close-internal folder))
 675
 676 (defun elmo-generic-folder-close (folder)
 677   (elmo-folder-commit folder)
 678   (elmo-folder-set-msgdb-internal folder nil)
 679   (elmo-folder-set-killed-list-internal folder nil))
 680
 681 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 682   t) ; default is plugged.
 683
 684 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 685                                              &optional add)
 686   nil) ; default is do nothing.
 687
 688 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 689   nil) ; default is no flag.
 690
 691 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 692   (elmo-folder-persistent-internal folder))
 693
 694 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 695   nil) ; default is not creatable.
 696
 697 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 698   nil) ; default is not writable.
 699
 700 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 701   (elmo-msgdb-delete-path folder))
 702
 703 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 704   (let* ((new-folder (elmo-make-folder new-name)))
 705     (unless (eq (elmo-folder-type-internal folder)
 706                 (elmo-folder-type-internal new-folder))
 707       (error "Not same folder type"))
 708     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 709             (elmo-folder-exists-p new-folder))
 710         (error "Already exists folder: %s" new-name))
 711     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 712     (elmo-msgdb-rename-path folder new-folder)))
 713
 714 (defsubst elmo-folder-search-fast (folder condition numbers)
 715   (when (and numbers
 716              (vectorp condition)
 717              (member (elmo-filter-key condition) '("first" "last")))
 718     (let ((len (length numbers))
 719           (lastp (string= (elmo-filter-key condition) "last"))
 720           (value (string-to-number (elmo-filter-value condition))))
 721       (when (eq (elmo-filter-type condition) 'unmatch)
 722         (setq lastp (not lastp)
 723               value  (- len value)))
 724       (if lastp
 725           (nthcdr (max (- len value) 0) numbers)
 726         (when (> value 0)
 727           (let ((last (nthcdr (1- value) numbers)))
 728             (when last
 729               (setcdr last nil))
 730             numbers))))))
 731
 732 (luna-define-method elmo-folder-search ((folder elmo-folder)
 733                                         condition
 734                                         &optional numbers)
 735   (let ((numbers (or numbers (elmo-folder-list-messages folder))))
 736     (or (elmo-folder-search-fast folder condition numbers)
 737         (let ((msgdb (elmo-folder-msgdb folder))
 738               (len (length numbers))
 739               matched)
 740           (when (> len elmo-display-progress-threshold)
 741             (elmo-progress-set 'elmo-folder-search len "Searching..."))
 742           (unwind-protect
 743               (dolist (number numbers)
 744                 (let ((entity (elmo-msgdb-overview-get-entity number msgdb))
 745                       result)
 746                   (if entity
 747                       (setq result (elmo-msgdb-match-condition
 748                                     condition
 749                                     entity
 750                                     numbers))
 751                     (setq result condition))
 752                   (when (elmo-filter-condition-p result)
 753                     (setq result (elmo-message-match-condition
 754                                   folder
 755                                   number
 756                                   condition
 757                                   numbers)))
 758                   (when result
 759                     (setq matched (cons number matched))))
 760                 (elmo-progress-notify 'elmo-folder-search))
 761             (elmo-progress-clear 'elmo-folder-search))
 762           (nreverse matched)))))
 763
 764 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 765                                                   number condition
 766                                                   numbers)
 767   (let ((filename (cond
 768                    ((elmo-message-file-name folder number))
 769                    ((let* ((cache (elmo-file-cache-get
 770                                    (elmo-message-field folder number
 771                                                        'message-id)))
 772                            (cache-path (elmo-file-cache-path cache)))
 773                       (when (and cache-path
 774                                  (not (elmo-cache-path-section-p cache-path)))
 775                         cache-path))))))
 776     (when (and filename
 777                (file-readable-p filename))
 778       (with-temp-buffer
 779         (insert-file-contents-as-binary filename)
 780         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 781         ;; Should consider charset?
 782         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 783         (elmo-buffer-field-condition-match condition number numbers)))))
 784
 785 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 786   nil) ; default is noop.
 787
 788 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 789   nil) ; default is noop.
 790
 791 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 792   nil) ; default is not file.
 793
 794 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 795   nil) ; default is not number.
 796
 797 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 798   nil) ; default is not make temp file.
 799
 800 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 801                                                    number)
 802   nil) ; default is no name.
 803
 804 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 805   t)   ; default is local.
 806
 807 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 808   t)
 809
 810 ;;; Folder info
 811 ;; Folder info is a message number information cache (hashtable)
 812 (defsubst elmo-folder-get-info (folder &optional hashtb)
 813   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 814   (elmo-get-hash-val (elmo-folder-name-internal folder)
 815                      (or hashtb elmo-folder-info-hashtb)))
 816
 817 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 818   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 819   (let ((info (elmo-folder-get-info folder)))
 820     (when info
 821       (or new     (setq new     (nth 0 info)))
 822       (or unread  (setq unread  (nth 1 info)))
 823       (or numbers (setq numbers (nth 2 info)))
 824       (or max     (setq max     (nth 3 info))))
 825     (elmo-set-hash-val (elmo-folder-name-internal folder)
 826                        (list new unread numbers max)
 827                        elmo-folder-info-hashtb)))
 828
 829 (defun elmo-folder-set-info-max-by-numdb (folder msgdb-number)
 830   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 831   (let ((num-db (sort (mapcar 'car msgdb-number) '<)))
 832     (elmo-folder-set-info-hashtb
 833      folder
 834      (or (nth (max 0 (1- (length num-db))) num-db) 0)
 835      nil ;;(length num-db)
 836      )))
 837
 838 (defun elmo-folder-get-info-max (folder)
 839   "Return max number of FODLER from folder info."
 840   (nth 3 (elmo-folder-get-info folder)))
 841
 842 (defun elmo-folder-get-info-length (folder)
 843   "Return length of FODLER from folder info."
 844   (nth 2 (elmo-folder-get-info folder)))
 845
 846 (defun elmo-folder-get-info-unread (folder)
 847   "Return unread of FODLER from folder info."
 848   (nth 1 (elmo-folder-get-info folder)))
 849
 850 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 851   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 852   (let* ((hashtb (or hashtb
 853                      (elmo-make-hash (length info-alist)))))
 854     (mapcar
 855      (lambda (x)
 856        (let ((info (cadr x)))
 857          (and (intern-soft (car x) hashtb)
 858               (elmo-set-hash-val (car x)
 859                                  (list (nth 2 info)   ;; new
 860                                        (nth 3 info)   ;; unread
 861                                        (nth 1 info)   ;; length
 862                                        (nth 0 info))  ;; max
 863                                  hashtb))))
 864      info-alist)
 865     (setq elmo-folder-info-hashtb hashtb)))
 866
 867 (defsubst elmo-diff-new (diff)
 868   (car diff))
 869
 870 (defsubst elmo-diff-unread (diff)
 871   (when (consp (cdr diff))
 872     (nth 1 diff)))
 873
 874 (defsubst elmo-diff-all (diff)
 875   (if (consp (cdr diff))
 876       (nth 2 diff)
 877     (cdr diff)))
 878
 879 (defsubst elmo-strict-folder-diff (folder)
 880   "Return folder diff information strictly from FOLDER."
 881   (let* ((dir (elmo-folder-msgdb-path folder))
 882          (nalist (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 883          (in-db (sort (mapcar 'car nalist) '<))
 884          (in-folder  (elmo-folder-list-messages folder))
 885          append-list delete-list diff)
 886     (cons (if (equal in-folder in-db)
 887               0
 888             (setq diff (elmo-list-diff
 889                         in-folder in-db
 890                         nil
 891                         ))
 892             (setq append-list (car diff))
 893             (setq delete-list (cadr diff))
 894             (if append-list
 895                 (length append-list)
 896               (if delete-list
 897                   (- 0 (length delete-list))
 898                 0)))
 899           (length in-folder))))
 900
 901 (luna-define-method elmo-folder-diff ((folder elmo-folder)
 902                                       &optional numbers)
 903   (elmo-generic-folder-diff folder numbers))
 904
 905 (defun elmo-generic-folder-diff (folder numbers)
 906   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 907                                 elmo-strict-diff-folder-list)
 908       (elmo-strict-folder-diff folder)
 909     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 910           (in-folder (elmo-folder-status folder))
 911           (in-db t)
 912           unsync messages
 913           in-db-max)
 914       (if numbers
 915           (setq in-db-max (or (nth (max 0 (1- (length numbers))) numbers)
 916                               0))
 917         (if (not cached-in-db-max)
 918             (let ((number-list (mapcar 'car
 919                                        (elmo-msgdb-number-load
 920                                         (elmo-folder-msgdb-path folder)))))
 921               ;; No info-cache.
 922               (setq in-db (sort number-list '<))
 923               (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 924                                   0))
 925               (elmo-folder-set-info-hashtb folder in-db-max nil))
 926           (setq in-db-max cached-in-db-max)))
 927       (setq unsync (if (and in-db
 928                             (car in-folder))
 929                        (- (car in-folder) in-db-max)
 930                      (if (and in-folder
 931                               (null in-db))
 932                          (cdr in-folder)
 933                        (car in-folder))))
 934       (setq messages (cdr in-folder))
 935       (if (and unsync messages (> unsync messages))
 936           (setq unsync messages))
 937       (cons (or unsync 0) (or messages 0)))))
 938
 939 (defvar elmo-folder-diff-async-callback nil)
 940 (defvar elmo-folder-diff-async-callback-data nil)
 941
 942 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 943   (and elmo-folder-diff-async-callback
 944        (funcall elmo-folder-diff-async-callback
 945                 folder
 946                 (elmo-folder-diff folder))))
 947
 948 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 949   (list folder))
 950
 951 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
 952   (eq (elmo-folder-type-internal folder) type))
 953
 954 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
 955                                                  src-folder
 956                                                  numbers
 957                                                  unread-marks
 958                                                  &optional
 959                                                  same-number)
 960   (elmo-generic-folder-append-messages folder src-folder numbers
 961                                        unread-marks same-number))
 962
 963 (defun elmo-generic-folder-append-messages (folder src-folder numbers
 964                                                    unread-marks same-number)
 965   (let (unseen seen-list succeed-numbers failure cache)
 966     (with-temp-buffer
 967       (set-buffer-multibyte nil)
 968       (while numbers
 969         (setq failure nil)
 970         (condition-case nil
 971             (setq cache (elmo-file-cache-get
 972                          (elmo-message-field src-folder
 973                                              (car numbers)
 974                                              'message-id))
 975                   failure
 976                   (not
 977                    (and
 978                     (elmo-message-fetch
 979                      src-folder (car numbers)
 980                      (if (elmo-folder-plugged-p src-folder)
 981                          (elmo-make-fetch-strategy
 982                           'entire 'maybe nil
 983                           (and cache (elmo-file-cache-path cache)))
 984                        (or (and elmo-enable-disconnected-operation
 985                                 cache
 986                                 (eq (elmo-file-cache-status cache) 'entire)
 987                                 (elmo-make-fetch-strategy
 988                                  'entire t nil
 989                                  (elmo-file-cache-path cache)))
 990                            (error "Unplugged")))
 991                      nil (current-buffer)
 992                      'unread)
 993                     (> (buffer-size) 0)
 994                     (elmo-folder-append-buffer
 995                      folder
 996                      (setq unseen (member (elmo-message-mark
 997                                            src-folder (car numbers))
 998                                           unread-marks))
 999                      (if same-number (car numbers))))))
1000           (error (setq failure t)))
1001         ;; FETCH & APPEND finished
1002         (unless failure
1003           (unless unseen
1004             (setq seen-list (cons (elmo-message-field
1005                                    src-folder (car numbers)
1006                                    'message-id)
1007                                   seen-list)))
1008           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1009         (elmo-progress-notify 'elmo-folder-move-messages)
1010         (setq numbers (cdr numbers)))
1011       (if (and seen-list (elmo-folder-persistent-p folder))
1012           (elmo-msgdb-seen-save (elmo-folder-msgdb-path folder)
1013                                 (nconc (elmo-msgdb-seen-load
1014                                         (elmo-folder-msgdb-path folder))
1015                                        seen-list)))
1016       succeed-numbers)))
1017
1018 ;; Arguments should be reduced.
1019 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1020                                              &optional msgdb
1021                                              no-delete-info
1022                                              no-delete
1023                                              same-number
1024                                              unread-marks
1025                                              save-unread)
1026   (save-excursion
1027     (let* ((messages msgs)
1028            (elmo-inhibit-display-retrieval-progress t)
1029            (len (length msgs))
1030            succeeds i result)
1031       (if (eq dst-folder 'null)
1032           (setq succeeds messages)
1033         (unless (elmo-folder-writable-p dst-folder)
1034           (error "move: %d is not writable"
1035                  (elmo-folder-name-internal dst-folder)))
1036         (when messages
1037           ;; src is already opened.
1038           (elmo-folder-open-internal dst-folder)
1039           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1040                                                               src-folder
1041                                                               messages
1042                                                               unread-marks
1043                                                               same-number))
1044             (error "move: append message to %s failed"
1045                    (elmo-folder-name-internal dst-folder)))
1046           (elmo-folder-close dst-folder))
1047         (when (and (elmo-folder-persistent-p dst-folder)
1048                    save-unread)
1049           ;; Save to seen list.
1050           (let* ((dir (elmo-folder-msgdb-path dst-folder))
1051                  (seen-list (elmo-msgdb-seen-load dir)))
1052             (setq seen-list
1053                   (elmo-msgdb-add-msgs-to-seen-list
1054                    msgs (elmo-folder-msgdb src-folder)
1055                    unread-marks seen-list))
1056             (elmo-msgdb-seen-save dir seen-list))))
1057       (if (and (not no-delete) succeeds)
1058           (progn
1059             (if (not no-delete-info)
1060                 (message "Cleaning up src folder..."))
1061             (if (and (elmo-folder-delete-messages src-folder succeeds)
1062                      (elmo-msgdb-delete-msgs
1063                       (elmo-folder-msgdb src-folder) succeeds))
1064                 (setq result t)
1065               (message "move: delete messages from %s failed."
1066                        (elmo-folder-name-internal src-folder))
1067               (setq result nil))
1068             (if (and result
1069                      (not no-delete-info))
1070                 (message "Cleaning up src folder...done"))
1071             result)
1072         (if no-delete
1073             (progn
1074               (message "Copying messages...done")
1075               t)
1076           (if (eq len 0)
1077               (message "No message was moved.")
1078             (message "Moving messages failed.")
1079             nil ; failure
1080             ))))))
1081
1082 (defun elmo-folder-msgdb-path (folder)
1083   "Return the msgdb path for FOLDER."
1084   (or (elmo-folder-path-internal folder)
1085       (elmo-folder-set-path-internal
1086        folder
1087        (elmo-folder-expand-msgdb-path folder))))
1088
1089 (defun elmo-message-mark (folder number)
1090   "Get mark of the message.
1091 FOLDER is the ELMO folder structure.
1092 NUMBER is a number of the message."
1093   (elmo-msgdb-get-mark (elmo-folder-msgdb folder) number))
1094
1095 (defun elmo-folder-list-messages-mark-match (folder mark-regexp)
1096   "List messages in the FOLDER which have a mark that matches MARK-REGEXP"
1097   (let ((case-fold-search nil)
1098         matched)
1099     (if mark-regexp
1100         (dolist (elem (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
1101           (if (string-match mark-regexp (cadr elem))
1102               (setq matched (cons (car elem) matched)))))
1103     matched))
1104
1105 (defun elmo-message-field (folder number field)
1106   "Get message field value in the msgdb.
1107 FOLDER is the ELMO folder structure.
1108 NUMBER is a number of the message.
1109 FIELD is a symbol of the field."
1110   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1111
1112 (defun elmo-message-set-mark (folder number mark)
1113   "Set mark for the message in the FOLDER with NUMBER as MARK."
1114   (elmo-msgdb-set-mark
1115    (elmo-folder-msgdb folder)
1116    number mark))
1117
1118 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1119   nil) ; default is not use cache.
1120
1121 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1122   folder) ; default is folder
1123
1124 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder) numbers)
1125   t)
1126
1127 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
1128                                                    numbers)
1129   t)
1130
1131 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder) numbers)
1132   t)
1133
1134 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder) numbers)
1135   t)
1136
1137 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder)
1138                                                    &optional
1139                                                    number-alist)
1140   ;; Do nothing.
1141   )
1142
1143 (defsubst elmo-folder-replace-marks (folder alist)
1144   "Replace marks of the FOLDER according to ALIST."
1145   (let (pair)
1146     (dolist (elem (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
1147       (when (setq pair (assoc (cadr elem) alist))
1148         (if (elmo-message-use-cache-p folder (car elem))
1149             (elmo-msgdb-set-mark (elmo-folder-msgdb folder)
1150                                  (car elem)
1151                                  (cdr pair))
1152           (elmo-msgdb-set-mark (elmo-folder-msgdb folder)
1153                                (car elem)
1154                                nil))))))
1155
1156 (defun elmo-generic-folder-append-msgdb (folder append-msgdb)
1157   (if append-msgdb
1158       (let* ((number-alist (elmo-msgdb-get-number-alist append-msgdb))
1159              (all-alist (copy-sequence (append
1160                                         (elmo-msgdb-get-number-alist
1161                                          (elmo-folder-msgdb folder))
1162                                         number-alist)))
1163              (cur number-alist)
1164              pair overview
1165              to-be-deleted
1166              mark-alist)
1167         (while cur
1168           (setq all-alist (delq (car cur) all-alist))
1169           ;; same message id exists.
1170           (if (setq pair (rassoc (cdr (car cur)) all-alist))
1171               (setq to-be-deleted (nconc to-be-deleted (list (car pair)))))
1172           (setq cur (cdr cur)))
1173         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1174                    'hide)
1175                ;; Hide duplicates.
1176                (setq overview (elmo-delete-if
1177                                (lambda (x)
1178                                  (memq (elmo-msgdb-overview-entity-get-number
1179                                         x)
1180                                        to-be-deleted))
1181                                (elmo-msgdb-get-overview append-msgdb)))
1182                ;; Should be mark as read.
1183                (elmo-folder-mark-as-read folder to-be-deleted)
1184                (elmo-msgdb-set-overview append-msgdb overview))
1185               ((eq (elmo-folder-process-duplicates-internal folder)
1186                    'read)
1187                ;; Mark as read duplicates.
1188                (elmo-folder-mark-as-read folder to-be-deleted))
1189               (t
1190                ;; Do nothing.
1191                (setq to-be-deleted nil)))
1192         (elmo-folder-set-msgdb-internal folder
1193                                         (elmo-msgdb-append
1194                                          (elmo-folder-msgdb folder)
1195                                          append-msgdb))
1196         (length to-be-deleted))
1197     0))
1198
1199 (luna-define-method elmo-folder-append-msgdb ((folder elmo-folder)
1200                                               append-msgdb)
1201   (elmo-generic-folder-append-msgdb folder append-msgdb))
1202
1203 (defun elmo-folder-confirm-appends (appends)
1204   (let ((len (length appends))
1205         in)
1206     (if (and elmo-folder-update-threshold
1207              (> len elmo-folder-update-threshold)
1208              elmo-folder-update-confirm)
1209         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1210             appends
1211           (setq in elmo-folder-update-threshold)
1212           (catch 'end
1213             (while t
1214               (setq in (read-from-minibuffer "Update number: "
1215                                              (int-to-string in))
1216                     in (string-to-int in))
1217               (if (< len in)
1218                   (throw 'end len))
1219               (if (y-or-n-p (format "%d messages are not appeared.  OK? "
1220                                     (max (- len in) 0)))
1221                   (throw 'end in))))
1222           (nthcdr (max (- len in) 0) appends))
1223       (if (and elmo-folder-update-threshold
1224                (> len elmo-folder-update-threshold)
1225                (not elmo-folder-update-confirm))
1226           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1227         appends))))
1228
1229 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1230                                         number strategy
1231                                         &optional
1232                                         section
1233                                         outbuf
1234                                         unread)
1235   (if outbuf
1236       (with-current-buffer outbuf
1237         (erase-buffer)
1238         (elmo-message-fetch-with-cache-process folder number
1239                                                strategy section unread))
1240     (with-temp-buffer
1241       (elmo-message-fetch-with-cache-process folder number
1242                                              strategy section unread)
1243       (buffer-string))))
1244
1245 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1246                                                            number strategy
1247                                                            &optional
1248                                                            section unread)
1249   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1250         (method-priorities
1251          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1252                 '(entity cache))
1253                ((elmo-fetch-strategy-use-cache strategy)
1254                 '(cache entity))
1255                (t
1256                 '(entity))))
1257         result err)
1258     (while (and method-priorities
1259                 (null result))
1260       (setq result
1261             (case (car method-priorities)
1262               (cache
1263                (elmo-file-cache-load cache-path section))
1264               (entity
1265                (when (and (condition-case error
1266                               (elmo-message-fetch-internal folder number
1267                                                            strategy
1268                                                            section
1269                                                            unread)
1270                             (error (setq err error) nil))
1271                           (> (buffer-size) 0))
1272                  (elmo-delete-cr-buffer)
1273                  (when (and (elmo-fetch-strategy-save-cache strategy)
1274                             cache-path)
1275                    (elmo-file-cache-save cache-path section))
1276                  t)))
1277             method-priorities (cdr method-priorities)))
1278     (or result
1279         (and err (signal (car err) (cdr err))))))
1280
1281 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1282                                        &optional keep-killed)
1283   (unless keep-killed
1284     (elmo-folder-set-killed-list-internal folder nil))
1285   (elmo-folder-set-msgdb-internal folder (elmo-msgdb-clear)))
1286
1287 (defun elmo-folder-synchronize (folder
1288                                 new-mark             ;"N"
1289                                 unread-uncached-mark ;"U"
1290                                 unread-cached-mark   ;"!"
1291                                 read-uncached-mark   ;"u"
1292                                 important-mark       ;"$"
1293                                 &optional ignore-msgdb
1294                                 no-check)
1295   "Synchronize the folder data to the newest status.
1296 FOLDER is the ELMO folder structure.
1297 NEW-MARK, UNREAD-CACHED-MARK, READ-UNCACHED-MARK, and IMPORTANT-MARK
1298 are mark strings for new messages, unread but cached messages,
1299 read but not cached messages, and important messages.
1300 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1301 read mark status. If IGNORE-MSGDB is 'visible-only, only visible messages
1302 \(the messages which are not in the killed-list\) are thrown away and
1303 synchronized.
1304 If NO-CHECK is non-nil, rechecking folder is skipped.
1305
1306 Return a list of
1307 \(NEW-MSGDB DELETE-LIST CROSSED\)
1308 NEW-MSGDB is the newly appended msgdb.
1309 DELETE-LIST is a list of deleted message number.
1310 CROSSED is cross-posted message number.
1311 If update process is interrupted, return nil."
1312   (let ((killed-list (elmo-folder-killed-list-internal folder))
1313         (before-append t)
1314         number-alist mark-alist
1315         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1316         seen-list crossed after-append)
1317     (setq old-msgdb (elmo-folder-msgdb folder))
1318     ;; Load seen-list.
1319     (setq seen-list (elmo-msgdb-seen-load (elmo-folder-msgdb-path folder)))
1320     (setq number-alist (elmo-msgdb-get-number-alist
1321                         (elmo-folder-msgdb folder)))
1322     (setq mark-alist (elmo-msgdb-get-mark-alist
1323                       (elmo-folder-msgdb folder)))
1324     (if ignore-msgdb
1325         (progn
1326           (setq seen-list (nconc
1327                            (elmo-msgdb-seen-list
1328                             (elmo-folder-msgdb folder)
1329                             (list important-mark read-uncached-mark))
1330                            seen-list))
1331           (elmo-folder-clear folder (eq ignore-msgdb 'visible-only))))
1332     (unless no-check (elmo-folder-check folder))
1333     (condition-case nil
1334         (progn
1335           (message "Checking folder diff...")
1336           ;; TODO: killed list is loaded in elmo-folder-open and
1337           ;; list-messages use internal killed-list-folder.
1338           (setq diff (elmo-list-diff (elmo-folder-list-messages
1339                                       folder
1340                                       (eq 'visible-only ignore-msgdb))
1341                                      (unless ignore-msgdb
1342                                        (sort (mapcar
1343                                               'car
1344                                               number-alist)
1345                                              '<))))
1346           (message "Checking folder diff...done")
1347           (setq new-list (elmo-folder-confirm-appends (car diff)))
1348           ;; Set killed list.
1349           (when (and (not (eq (length (car diff))
1350                               (length new-list)))
1351                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1352             (elmo-msgdb-append-to-killed-list folder (car diff-2)))
1353           (setq delete-list (cadr diff))
1354           (if (or (equal diff '(nil nil))
1355                   (equal diff '(nil))
1356                   (and (eq (length (car diff)) 0)
1357                        (eq (length (cadr diff)) 0)))
1358               (progn
1359                 (elmo-folder-update-number folder)
1360                 (elmo-folder-process-crosspost folder)
1361                 (list nil nil nil) ; no updates.
1362                 )
1363             (if delete-list (elmo-msgdb-delete-msgs
1364                              (elmo-folder-msgdb folder) delete-list))
1365             (when new-list
1366               (setq new-msgdb (elmo-folder-msgdb-create
1367                                folder
1368                                new-list
1369                                new-mark unread-cached-mark
1370                                read-uncached-mark important-mark
1371                                seen-list))
1372               (elmo-msgdb-change-mark (elmo-folder-msgdb folder)
1373                                       new-mark unread-uncached-mark)
1374               ;; Clear seen-list.
1375               (if (elmo-folder-persistent-p folder)
1376                   (setq seen-list (elmo-msgdb-seen-save
1377                                    (elmo-folder-msgdb-path folder) nil)))
1378               (setq before-append nil)
1379               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1380               ;; process crosspost.
1381               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1382               (elmo-folder-process-crosspost folder)
1383               (elmo-folder-set-message-modified-internal folder t)
1384               (elmo-folder-set-mark-modified-internal folder t))
1385             ;; return value.
1386             (list new-msgdb delete-list crossed)))
1387       (quit
1388        ;; Resume to the original status.
1389        (if before-append
1390            (elmo-folder-set-msgdb-internal folder old-msgdb))
1391        (elmo-folder-set-killed-list-internal folder killed-list)
1392        nil))))
1393
1394 (defun elmo-folder-messages (folder)
1395   "Return number of messages in the FOLDER."
1396   (length
1397    (elmo-msgdb-get-number-alist
1398     (elmo-folder-msgdb folder))))
1399
1400 ;;;
1401 (defun elmo-msgdb-load (folder &optional silent)
1402   (unless silent
1403     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1404   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1405     (elmo-folder-set-info-max-by-numdb folder
1406                                        (elmo-msgdb-get-number-alist msgdb))
1407
1408     (unless silent
1409       (message "Loading msgdb for %s...done"
1410                (elmo-folder-name-internal folder)))
1411     msgdb))
1412
1413 (defun elmo-msgdb-delete-path (folder)
1414   (let ((path (elmo-folder-msgdb-path folder)))
1415     (if (file-directory-p path)
1416         (elmo-delete-directory path t))))
1417
1418 (defun elmo-msgdb-rename-path (old-folder new-folder)
1419   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1420          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1421          (new-dir (directory-file-name (file-name-directory new))))
1422     (if (not (file-directory-p old))
1423         ()
1424       (if (file-exists-p new)
1425           (error "Already exists directory: %s" new)
1426         (if (not (file-exists-p new-dir))
1427             (elmo-make-directory new-dir))
1428         (rename-file old new)))))
1429
1430 (defun elmo-setup-subscribed-newsgroups (groups)
1431   "Setup subscribed newsgroups.
1432 GROUPS is a list of newsgroup name string.
1433 Return a hashtable for newsgroups."
1434   (let ((hashtb (or elmo-newsgroups-hashtb
1435                     (setq elmo-newsgroups-hashtb
1436                           (elmo-make-hash (length groups))))))
1437     (dolist (group groups)
1438       (or (elmo-get-hash-val group hashtb)
1439           (elmo-set-hash-val group nil hashtb)))
1440     (setq elmo-newsgroups-hashtb hashtb)))
1441
1442 (defvar elmo-crosspost-message-alist-modified nil)
1443 (defun elmo-crosspost-message-alist-load ()
1444   "Load crosspost message alist."
1445   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1446   (setq elmo-crosspost-message-alist-modified nil))
1447
1448 (defun elmo-crosspost-message-alist-save ()
1449   "Save crosspost message alist."
1450   (when elmo-crosspost-message-alist-modified
1451     (let ((alist elmo-crosspost-message-alist)
1452           newsgroups)
1453       (while alist
1454         (setq newsgroups
1455               (elmo-delete-if
1456                '(lambda (x)
1457                   (not (intern-soft x elmo-newsgroups-hashtb)))
1458                (nth 1 (car alist))))
1459         (if newsgroups
1460             (setcar (cdar alist) newsgroups)
1461           (setq elmo-crosspost-message-alist
1462                 (delete (car alist) elmo-crosspost-message-alist)))
1463         (setq alist (cdr alist)))
1464       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1465       (setq elmo-crosspost-message-alist-modified nil))))
1466
1467 (defun elmo-folder-make-temporary-directory (folder)
1468   ;; Make a temporary directory for FOLDER.
1469   (let ((temp-dir (make-temp-name
1470                    (concat
1471                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1472                     "elmo"))))
1473     (elmo-make-directory temp-dir)
1474     temp-dir))
1475
1476 (defun elmo-init ()
1477   "Initialize ELMO module."
1478   (elmo-crosspost-message-alist-load)
1479   (elmo-resque-obsolete-variables)
1480   (elmo-dop-queue-load))
1481
1482 (defun elmo-quit ()
1483   "Quit and cleanup ELMO."
1484   (elmo-crosspost-message-alist-save)
1485   (elmo-dop-queue-save)
1486   ;; Not implemented yet.
1487   (let ((types elmo-folder-type-alist)
1488         class)
1489     (while types
1490       (setq class
1491             (luna-find-class
1492              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1493       ;; Call all folder's `elmo-quit' method.
1494       (if class
1495           (dolist (func (luna-class-find-functions class 'elmo-quit))
1496             (funcall func nil)))
1497       (setq types (cdr types)))))
1498
1499
1500 ;;; Define folders.
1501 (elmo-define-folder ?% 'imap4)
1502 (elmo-define-folder ?-  'nntp)
1503 (elmo-define-folder ?\+ 'localdir)
1504 (elmo-define-folder ?\* 'multi)
1505 (elmo-define-folder ?\/ 'filter)
1506 (elmo-define-folder ?\$ 'archive)
1507 (elmo-define-folder ?&  'pop3)
1508 (elmo-define-folder ?=  'localnews)
1509 (elmo-define-folder ?|  'pipe)
1510 (elmo-define-folder ?.  'maildir)
1511 (elmo-define-folder ?'  'internal)
1512 (elmo-define-folder ?\[  'nmz)
1513 (elmo-define-folder ?@  'shimbun)
1514
1515 ;;; Obsolete variables.
1516 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1517                                'elmo-imap4-default-mailbox)
1518 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1519                                'elmo-imap4-default-server)
1520 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1521                                'elmo-imap4-default-authenticate-type)
1522 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1523                                'elmo-imap4-default-user)
1524 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1525                                'elmo-imap4-default-port)
1526 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1527                                'elmo-imap4-default-stream-type)
1528 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1529                                'elmo-nntp-default-server)
1530 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1531                                'elmo-nntp-default-user)
1532 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1533                                'elmo-nntp-default-port)
1534 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1535                                'elmo-nntp-default-stream-type)
1536 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1537                                'elmo-pop3-default-server)
1538 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1539                                'elmo-pop3-default-user)
1540 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1541                                'elmo-pop3-default-authenticate-type)
1542 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1543                                'elmo-pop3-default-port)
1544 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1545                                'elmo-pop3-default-stream-type)
1546 (elmo-define-obsolete-variable 'elmo-cache-dirname
1547                                'elmo-cache-directory)
1548 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1549                                'elmo-msgdb-directory)
1550
1551 ;; Obsolete functions.
1552 ;; 2001-12-11: *-dir -> *-directory
1553 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1554 (make-obsolete 'elmo-folder-make-temp-dir
1555                'elmo-folder-make-temporary-directory)
1556
1557
1558 ;; autoloads
1559 (autoload 'elmo-dop-queue-flush "elmo-dop")
1560 (autoload 'elmo-nntp-post "elmo-nntp")
1561
1562 (require 'product)
1563 (product-provide (provide 'elmo) (require 'elmo-version))
1564
1565 ;;; elmo.el ends here