elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38
  39 (eval-when-compile (require 'cl))
  40
  41 (if (or (featurep 'dbm)
  42         (featurep 'gnudbm)
  43         (featurep 'berkdb)
  44         (featurep 'berkeley-db))
  45     (require 'elmo-database))
  46
  47 (defcustom elmo-message-fetch-threshold 30000
  48   "Fetch threshold."
  49   :type 'integer
  50   :group 'elmo)
  51
  52 (defcustom elmo-message-fetch-confirm t
  53   "If non-nil, confirm fetching if message size is larger than
  54 `elmo-message-fetch-threshold'.
  55 Otherwise, entire fetching of the message is aborted without confirmation."
  56   :type 'boolean
  57   :group 'elmo)
  58
  59 (defcustom elmo-folder-update-threshold 500
  60   "Update threshold."
  61   :type 'integer
  62   :group 'elmo)
  63
  64 (defcustom elmo-folder-update-confirm t
  65   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  66   :type 'boolean
  67   :group 'elmo)
  68
  69 (defvar elmo-message-displaying nil
  70   "A global switch to indicate message is displaying or not.")
  71
  72 ;;; internal
  73 (defvar elmo-folder-type-alist nil)
  74
  75 (defvar elmo-newsgroups-hashtb nil)
  76
  77 (elmo-define-error 'elmo-error "Error" 'error)
  78 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  79 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  80 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  81
  82 (defun elmo-define-folder (prefix backend)
  83   "Define a folder.
  84 If a folder name begins with PREFIX, use BACKEND."
  85   (let ((pair (assq prefix elmo-folder-type-alist)))
  86     (if pair
  87         (progn
  88           (setcar pair prefix)
  89           (setcdr pair backend))
  90       (setq elmo-folder-type-alist (cons (cons prefix backend)
  91                                          elmo-folder-type-alist)))))
  92
  93 (defmacro elmo-folder-type (name)
  94   "Get folder type from NAME string."
  95   (` (and (stringp (, name))
  96           (cdr (assoc (string-to-char (, name)) elmo-folder-type-alist)))))
  97
  98 ;;; ELMO folder
  99 ;; A elmo folder provides uniformed (orchestrated) access
 100 ;; to the internet messages.
 101 (eval-and-compile
 102   (luna-define-class elmo-folder () (type   ; folder type symbol.
 103                                      name   ; orignal folder name string.
 104                                      prefix ; prefix for folder name
 105                                      path   ; directory path for msgdb.
 106                                      msgdb  ; msgdb (may be nil).
 107                                      killed-list  ; killed list.
 108                                      persistent   ; non-nil if persistent.
 109                                      message-modified ; message is modified.
 110                                      mark-modified    ; mark is modified.
 111                                      process-duplicates  ; read or hide
 112                                      biff   ; folder for biff
 113                                      ))
 114   (luna-define-internal-accessors 'elmo-folder))
 115
 116 (luna-define-generic elmo-folder-initialize (folder name)
 117   ;; Initialize a FOLDER structure with NAME."
 118   )
 119
 120 (defmacro elmo-folder-send (folder message &rest args)
 121   "Let FOLDER receive the MESSAGE with ARGS."
 122   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 123
 124 ;;;###autoload
 125 (defun elmo-make-folder (name &optional non-persistent)
 126   "Make an ELMO folder structure specified by NAME.
 127 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 128   (let ((type (elmo-folder-type name))
 129         prefix split class folder original)
 130     (setq original (elmo-string name))
 131     (if type
 132         (progn
 133           (setq prefix (substring name 0 1))
 134           (setq name (substring name 1)))
 135       (setq type (intern (car (setq split (split-string name ":")))))
 136       (if (> (length split) 2)
 137           (setq name (substring name (+ 1 (length (car split)))))
 138         (error "Error in folder name `%s'" original))
 139       (setq prefix (concat (car split) ":")))
 140     (setq class (format "elmo-%s" (symbol-name type)))
 141     (require (intern class))
 142     (setq folder (luna-make-entity (intern (concat class "-folder"))
 143                                    :type   type
 144                                    :prefix prefix
 145                                    :name original
 146                                    :persistent (not non-persistent)))
 147     (save-match-data
 148       (elmo-folder-send folder 'elmo-folder-initialize name))))
 149
 150 ;; Note that this function is for internal use only.
 151 (luna-define-generic elmo-folder-msgdb (folder)
 152   "Return the msgdb of FOLDER (on-demand loading).
 153 \(For internal use only.\)")
 154
 155 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 156   (or (elmo-folder-msgdb-internal folder)
 157       (elmo-folder-set-msgdb-internal folder
 158                                       (elmo-msgdb-load folder))))
 159 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 160   "Open and setup (load saved status) FOLDER.
 161 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 162 (otherwise, msgdb is loaded on-demand)")
 163
 164 (luna-define-generic elmo-folder-open-internal (folder)
 165   "Open FOLDER (without loading saved folder status).")
 166
 167 (luna-define-generic elmo-folder-check (folder)
 168   "Check the FOLDER to obtain newest information at the next list operation.")
 169
 170 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 171   "Clear FOLDER to the initial state.
 172 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 173
 174 (luna-define-generic elmo-folder-commit (folder)
 175   "Save current status of FOLDER.")
 176
 177 (luna-define-generic elmo-folder-close (folder)
 178   "Close, save and clearnup FOLDER.")
 179
 180 (luna-define-generic elmo-folder-close-internal (folder)
 181   "Close FOLDER (without saving folder status).")
 182
 183 (luna-define-generic elmo-folder-plugged-p (folder)
 184   "Returns t if FOLDER is plugged.")
 185
 186 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 187   "Set FOLDER as plugged.")
 188
 189 (luna-define-generic elmo-net-port-info (folder)
 190   "Get port information of FOLDER.")
 191
 192 (luna-define-generic elmo-folder-use-flag-p (folder)
 193   "Returns t if FOLDER treats unread/important flag itself.")
 194
 195 (luna-define-generic elmo-folder-diff (folder &optional numbers)
 196   "Get diff of FOLDER.
 197 If optional NUMBERS is set, it is used as current NUMBERS.
 198 Otherwise, saved status for folder is used for comparison.
 199 Return value is cons cell or list:
 200  - a cons cell (new . all)
 201  - a list (new unread all)")
 202
 203 (luna-define-generic elmo-folder-status (folder)
 204   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 205
 206 (luna-define-generic elmo-folder-reserve-status-p (folder)
 207   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 208
 209 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 210                                                        in-msgdb)
 211   "Return a list of message numbers contained in FOLDER.
 212 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 213 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 214 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 215                                                &optional visible-only in-msgdb)
 216   (let ((list (if in-msgdb
 217                   t
 218                 (elmo-folder-list-messages-internal folder visible-only))))
 219     (elmo-living-messages
 220      (if (listp list)
 221          list
 222        ;; Use current list.
 223        (elmo-msgdb-list-messages (elmo-folder-msgdb folder)))
 224      (elmo-folder-killed-list-internal folder))))
 225
 226 (luna-define-generic elmo-folder-list-unreads (folder)
 227   "Return a list of unread message numbers contained in FOLDER.")
 228 (luna-define-generic elmo-folder-list-importants (folder)
 229   "Return a list of important message numbers contained in FOLDER.")
 230 (luna-define-generic elmo-folder-list-answereds (folder)
 231   "Return a list of answered message numbers contained in FOLDER.")
 232
 233 ;; TODO: Should reconsider the structure of global mark.
 234 (defun elmo-folder-list-messages-with-global-mark (folder mark)
 235   (let (entity msgs)
 236     (dolist (mark-pair (or elmo-msgdb-global-mark-alist
 237                            (setq elmo-msgdb-global-mark-alist
 238                                  (elmo-object-load
 239                                   (expand-file-name
 240                                    elmo-msgdb-global-mark-filename
 241                                    elmo-msgdb-directory)))))
 242       (if (and (string= mark (cdr mark-pair))
 243                (setq entity
 244                      (elmo-msgdb-overview-get-entity (car mark-pair)
 245                                                      (elmo-folder-msgdb
 246                                                       folder))))
 247           (setq msgs (cons (elmo-msgdb-overview-entity-get-number entity)
 248                            msgs))))
 249     msgs))
 250
 251 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 252   "List messages in the FOLDER with FLAG.
 253 FLAG is a symbol which is one of the following:
 254   `new'        (new messages)
 255   `unread'     (unread messages (new messages are included))
 256   `answered'   (answered or forwarded)
 257   `important'  (marked as important)
 258 'sugar' flags:
 259   `read'       (not unread)
 260   `digest'     (unread + important)
 261   `any'        (digest + answered)
 262
 263 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 264
 265 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 266                                               &optional in-msgdb)
 267   ;; Currently, only in-msgdb is implemented.
 268   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag))
 269
 270 (luna-define-method elmo-folder-list-unreads ((folder elmo-folder))
 271   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) 'unread))
 272
 273 (luna-define-method elmo-folder-list-importants ((folder elmo-folder))
 274   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) 'important))
 275
 276 (luna-define-method elmo-folder-list-answereds ((folder elmo-folder))
 277   (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) 'answered))
 278
 279 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 280                                                                 visible-only)
 281   ;; Return a list of message numbers contained in FOLDER.
 282   ;; Return t if the message list is not available.
 283   )
 284
 285 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 286   "Returns a list of subfolders contained in FOLDER.
 287 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 288 \(a folder which have children is returned as a list\)
 289 Otherwise, all descendent folders are returned.")
 290
 291 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 292   "Return non-nil when FOLDER has subfolders.")
 293
 294 (luna-define-generic elmo-folder-exists-p (folder)
 295   "Returns non-nil when FOLDER exists.")
 296
 297 (luna-define-generic elmo-folder-creatable-p (folder)
 298   "Returns non-nil when FOLDER is creatable.")
 299
 300 (luna-define-generic elmo-folder-writable-p (folder)
 301   "Returns non-nil when FOLDER is writable.")
 302
 303 (luna-define-generic elmo-folder-persistent-p (folder)
 304   "Return non-nil when FOLDER is persistent.")
 305
 306 (luna-define-generic elmo-folder-create (folder)
 307   "Create a FOLDER.")
 308
 309 (luna-define-generic elmo-message-deletable-p (folder number)
 310   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 311
 312 (luna-define-generic elmo-folder-delete (folder)
 313   "Delete FOLDER completely.")
 314
 315 (luna-define-generic elmo-folder-rename (folder new-name)
 316   "Rename FOLDER to NEW-NAME (string).")
 317
 318 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 319   "Delete messages.
 320 FOLDER is the ELMO folder structure.
 321 NUMBERS is a list of message numbers to be deleted.")
 322
 323 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 324   "Search and return list of message numbers.
 325 FOLDER is the ELMO folder structure.
 326 CONDITION is a condition structure for searching.
 327 If optional argument NUMBERS is specified and is a list of message numbers,
 328 messages are searched from the list.")
 329
 330 (luna-define-generic elmo-message-match-condition (folder number
 331                                                           condition
 332                                                           numbers)
 333   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 334 CONDITION is a condition structure for testing.
 335 NUMBERS is a list of message numbers,
 336 use to be test for \"last\" and \"first\" predicates.")
 337
 338 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 339   "Create a message database (implemented in each backends).
 340 FOLDER is the ELMO folder structure.
 341 NUMBERS is a list of message numbers to create msgdb.
 342 FLAG-TABLE is a hashtable of message-id and flag.")
 343
 344 (luna-define-generic elmo-folder-unmark-important (folder
 345                                                    numbers
 346                                                    &optional ignore-flags)
 347   "Un-mark messages as important.
 348 FOLDER is the ELMO folder structure.
 349 NUMBERS is a list of message numbers to be processed.
 350 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 351
 352 (luna-define-generic elmo-folder-mark-as-important (folder
 353                                                     numbers
 354                                                     &optional ignore-flags)
 355   "Mark messages as important.
 356 FOLDER is the ELMO folder structure.
 357 NUMBERS is a list of message numbers to be processed.
 358 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 359
 360 (luna-define-generic elmo-folder-unmark-read (folder numbers
 361                                                      &optional ignore-flags)
 362   "Un-mark messages as read.
 363 FOLDER is the ELMO folder structure.
 364 NUMBERS is a list of message numbers to be processed.
 365 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 366
 367 (luna-define-generic elmo-folder-mark-as-read (folder numbers
 368                                                       &optional ignore-flags)
 369   "Mark messages as read.
 370 FOLDER is the ELMO folder structure.
 371 NUMBERS is a list of message numbers to be processed.
 372 If IGNORE-FLAGS is non-nil, folder flags are not updated.")
 373
 374 (luna-define-generic elmo-folder-unmark-answered (folder numbers)
 375   "Un-mark messages as answered.
 376 FOLDER is the ELMO folder structure.
 377 NUMBERS is a list of message numbers to be processed.")
 378
 379 (luna-define-generic elmo-folder-mark-as-answered (folder numbers)
 380   "Mark messages as answered.
 381 FOLDER is the ELMO folder structure.
 382 NUMBERS is a list of message numbers to be processed.")
 383
 384 (luna-define-generic elmo-folder-append-buffer (folder &optional flag
 385                                                        number)
 386   "Append current buffer as a new message.
 387 FOLDER is the destination folder(ELMO folder structure).
 388 FLAG is the status of appended message.
 389 If optional argument NUMBER is specified, the new message number is set
 390 \(if possible\).")
 391
 392 (luna-define-generic elmo-folder-append-messages (folder
 393                                                   src-folder
 394                                                   numbers
 395                                                   &optional
 396                                                   same-number)
 397   "Append messages from folder.
 398 FOLDER is the ELMO folder structure.
 399 Caller should make sure FOLDER is `writable'.
 400 (Can be checked with `elmo-folder-writable-p').
 401 SRC-FOLDER is the source ELMO folder structure.
 402 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 403 If second optional argument SAME-NUMBER is specified,
 404 message number is preserved (if possible).")
 405
 406 (luna-define-generic elmo-folder-pack-numbers (folder)
 407   "Pack message numbers of FOLDER.")
 408
 409 (luna-define-generic elmo-folder-update-number (folder)
 410   "Update number of FOLDER.")
 411
 412 (luna-define-generic elmo-folder-diff-async (folder)
 413   "Get diff of FOLDER asynchronously.")
 414
 415 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 416   "Expand path for FOLDER.")
 417
 418 (luna-define-generic elmo-folder-get-primitive-list (folder)
 419   "Get primitive folder structure list contained in FOLDER.")
 420
 421 (luna-define-generic elmo-folder-contains-type (folder type)
 422   "Returns t if FOLDER contains TYPE.")
 423
 424 (luna-define-generic elmo-folder-local-p (folder)
 425   "Returns t if FOLDER is local.")
 426
 427 (luna-define-generic elmo-folder-message-file-p (folder)
 428   "Returns t if all messages in the FOLDER are files.")
 429
 430 ;;; Message methods.
 431 (luna-define-generic elmo-message-use-cache-p (folder number)
 432   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 433
 434 (luna-define-generic elmo-message-file-name (folder number)
 435   "Return the file name of a message specified by FOLDER and NUMBER.")
 436
 437 ;;; For archive
 438
 439 ;;; Use original file
 440 (luna-define-generic elmo-folder-message-file-number-p (folder)
 441   "Return t if the file name in the FOLDER is the message number.")
 442
 443 (luna-define-generic elmo-folder-message-file-directory (folder)
 444   "Return the directory of the message files of FOLDER.")
 445
 446 ;;; Use temporary file
 447 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 448   "Return t if the messages in the FOLDER makes local temporary file.")
 449
 450 (luna-define-generic elmo-folder-message-make-temp-files (folder
 451                                                           numbers
 452                                                           &optional
 453                                                           start-number)
 454   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 455 If START-NUMBER is specified, temporary files begin from the number.
 456 Otherwise, same number is used for temporary files.
 457 Return newly created temporary directory name which contains temporary files.")
 458
 459 (luna-define-generic elmo-message-file-p (folder number)
 460   "Return t if message in the FOLDER with NUMBER is a file.")
 461
 462 (luna-define-generic elmo-find-fetch-strategy
 463   (folder entity &optional ignore-cache)
 464 ;; Returns the message fetching strategy suitable for the message.
 465 ;; FOLDER is the ELMO folder structure.
 466 ;; ENTITY is the overview entity of the message in the folder.
 467 ;; If optional argument IGNORE-CACHE is non-nil, cache is ignored.
 468 ;; Returned value is a elmo-fetch-strategy object.
 469 ;; If return value is nil, message should not be nil.
 470   )
 471
 472 (defmacro elmo-make-fetch-strategy (entireness
 473                                     &optional
 474                                     use-cache
 475                                     save-cache
 476                                     cache-path)
 477 ;; Make elmo-message-fetching strategy.
 478 ;; ENTIRENESS is 'entire or 'section.
 479 ;; 'entire means fetch message entirely at once.
 480 ;; 'section means fetch message section by section.
 481 ;; If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 482 ;; existing cache is thrown away.
 483 ;; If SAVE-CACHE is non-nil, fetched message is saved.
 484 ;; CACHE-PATH is the cache path to be used as a message cache file.
 485   (` (vector (, entireness)
 486              (, use-cache) (, save-cache) (, cache-path))))
 487
 488 (defmacro elmo-fetch-strategy-entireness (strategy)
 489   ;; Return entireness of STRATEGY.
 490   (` (aref (, strategy) 0)))
 491
 492 (defmacro elmo-fetch-strategy-use-cache (strategy)
 493   ;; Return use-cache of STRATEGY.
 494   (` (aref (, strategy) 1)))
 495
 496 (defmacro elmo-fetch-strategy-save-cache (strategy)
 497   ;; Return save-cache of STRATEGY.
 498   (` (aref (, strategy) 2)))
 499
 500 (defmacro elmo-fetch-strategy-cache-path (strategy)
 501   ;;  Return cache-path of STRATEGY.
 502   (` (aref (, strategy) 3)))
 503
 504 (luna-define-method elmo-find-fetch-strategy
 505   ((folder elmo-folder) entity &optional ignore-cache)
 506   (let (cache-file size message-id number)
 507     (setq size (elmo-msgdb-overview-entity-get-size entity))
 508     (setq message-id (elmo-msgdb-overview-entity-get-id entity))
 509     (setq number (elmo-msgdb-overview-entity-get-number entity))
 510     (setq cache-file (elmo-file-cache-get message-id))
 511     (setq ignore-cache (or ignore-cache
 512                            (null (elmo-message-use-cache-p folder number))))
 513     (if (or ignore-cache
 514             (null (elmo-file-cache-status cache-file)))
 515         ;; No cache or ignore-cache.
 516         (if (and (not (elmo-folder-local-p folder))
 517                  elmo-message-fetch-threshold
 518                  (integerp size)
 519                  (>= size elmo-message-fetch-threshold)
 520                  (or (not elmo-message-fetch-confirm)
 521                      (not (prog1 (y-or-n-p
 522                                   (format "Fetch entire message(%dbytes)? "
 523                                           size))
 524                             (message "")))))
 525             ;; Don't fetch message at all.
 526             nil
 527           ;; Don't use existing cache and fetch entire message at once.
 528           (elmo-make-fetch-strategy
 529            'entire nil
 530            (elmo-message-use-cache-p folder number)
 531            (elmo-file-cache-path cache-file)))
 532       ;; Cache exists.
 533       (if (not ignore-cache)
 534           (elmo-make-fetch-strategy
 535            'entire
 536            ;; ...But ignore current section cache and re-fetch
 537            ;; if section cache.
 538            (not (eq (elmo-file-cache-status cache-file) 'section))
 539            ;; Save cache.
 540            (elmo-message-use-cache-p folder number)
 541            (elmo-file-cache-path cache-file))))))
 542
 543 (luna-define-method elmo-folder-list-messages-internal
 544   ((folder elmo-folder) &optional visible-only)
 545   t)
 546
 547 (defun elmo-folder-encache (folder numbers &optional unread)
 548   "Encache messages in the FOLDER with NUMBERS.
 549 If UNREAD is non-nil, messages are not marked as read."
 550   (dolist (number numbers)
 551     (elmo-message-encache folder number unread)))
 552
 553 (luna-define-generic elmo-message-encache (folder number &optional read)
 554   "Encache message in the FOLDER with NUMBER.
 555 If READ is non-nil, message is marked as read.")
 556
 557 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 558                                           &optional read)
 559   (elmo-message-fetch
 560    folder number
 561    (elmo-make-fetch-strategy 'entire
 562                              nil ;use-cache
 563                              t   ;save-cache
 564                              (elmo-file-cache-get-path
 565                               (elmo-message-field
 566                                folder number 'message-id)))
 567    nil nil (not read)))
 568
 569 (luna-define-generic elmo-message-fetch (folder number strategy
 570                                                 &optional
 571                                                 section
 572                                                 outbuf
 573                                                 unread)
 574   "Fetch a message and return as a string.
 575 FOLDER is the ELMO folder structure.
 576 NUMBER is the number of the message in the FOLDER.
 577 STRATEGY is the message fetching strategy.
 578 If optional argument SECTION is specified, only the SECTION of the message
 579 is fetched (if possible).
 580 If second optional argument OUTBUF is specified, fetched message is
 581 inserted to the buffer and returns t if fetch was ended successfully.
 582 If third optional argument UNREAD is non-nil, message is not marked as read.
 583 Returns non-nil if fetching was succeed.")
 584
 585 (luna-define-generic elmo-message-fetch-with-cache-process (folder
 586                                                             number strategy
 587                                                             &optional
 588                                                             section
 589                                                             unread)
 590   "Fetch a message into current buffer with cache process.
 591 FOLDER is the ELMO folder structure.
 592 NUMBER is the number of the message in the FOLDER.
 593 STRATEGY is the message fetching strategy.
 594 If optional argument SECTION is specified, only the SECTION of the message
 595 is fetched (if possible).
 596 If second optional argument UNREAD is non-nil, message is not marked as read.
 597 Returns non-nil if fetching was succeed.")
 598
 599 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 600                                                          &optional
 601                                                          section
 602                                                          unread)
 603   "Fetch a message into current buffer.
 604 FOLDER is the ELMO folder structure.
 605 NUMBER is the number of the message in the FOLDER.
 606 STRATEGY is the message fetching strategy.
 607 If optional argument SECTION is specified, only the SECTION of the message
 608 is fetched (if possible).
 609 If second optional argument UNREAD is non-nil, message is not marked as read.
 610 Returns non-nil if fetching was succeed.")
 611
 612 (luna-define-generic elmo-message-fetch-field (folder number field)
 613   "Fetch a message field value.
 614 FOLDER is the ELMO folder structure.
 615 NUMBER is the number of the message in the FOLDER.
 616 FIELD is a symbol of the field name.")
 617
 618 (luna-define-generic elmo-message-folder (folder number)
 619   "Get primitive folder of the message.")
 620
 621 (luna-define-generic elmo-folder-process-crosspost (folder
 622                                                     &optional
 623                                                     number-alist)
 624   "Process crosspost for FOLDER.
 625 If NUMBER-ALIST is set, it is used as number-alist.
 626 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).")
 627
 628 (luna-define-generic elmo-folder-append-msgdb (folder append-msgdb)
 629   "Append  APPEND-MSGDB to the current msgdb of the folder.")
 630
 631 (luna-define-generic elmo-folder-newsgroups (folder)
 632   "Return list of newsgroup name of FOLDER.")
 633
 634 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 635   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 636
 637 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 638   (if (listp condition)
 639       (or (elmo-folder-search-requires-msgdb-p-internal
 640            folder (nth 1 condition))
 641           (elmo-folder-search-requires-msgdb-p-internal
 642            folder (nth 2 condition)))
 643     (and (not (string= (elmo-filter-key condition) "last"))
 644          (not (string= (elmo-filter-key condition) "first")))))
 645
 646 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 647                                                          condition)
 648   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 649
 650 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 651   nil)
 652
 653 (luna-define-method elmo-folder-open ((folder elmo-folder)
 654                                       &optional load-msgdb)
 655   (elmo-generic-folder-open folder load-msgdb))
 656
 657 (defun elmo-generic-folder-open (folder load-msgdb)
 658   (let ((inhibit-quit t))
 659     (if load-msgdb (elmo-folder-msgdb folder))
 660     (elmo-folder-set-killed-list-internal
 661      folder
 662      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 663   (elmo-folder-open-internal folder))
 664
 665 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 666   nil ; default is do nothing.
 667   )
 668
 669 (luna-define-method elmo-folder-check ((folder elmo-folder))
 670   nil) ; default is noop.
 671
 672 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 673   (elmo-generic-folder-commit folder))
 674
 675 (defun elmo-generic-folder-commit (folder)
 676   (when (elmo-folder-persistent-p folder)
 677     (when (elmo-folder-message-modified-internal folder)
 678       (elmo-msgdb-overview-save
 679        (elmo-folder-msgdb-path folder)
 680        (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
 681       (elmo-msgdb-number-save
 682        (elmo-folder-msgdb-path folder)
 683        (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 684       (elmo-folder-set-info-max-by-numdb
 685        folder
 686        (elmo-msgdb-get-number-alist
 687         (elmo-folder-msgdb folder)))
 688       (elmo-folder-set-message-modified-internal folder nil)
 689       (elmo-msgdb-killed-list-save
 690        (elmo-folder-msgdb-path folder)
 691        (elmo-folder-killed-list-internal folder)))
 692     (when (elmo-folder-mark-modified-internal folder)
 693       (elmo-msgdb-mark-save
 694        (elmo-folder-msgdb-path folder)
 695        (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
 696       (elmo-folder-set-mark-modified-internal folder nil))))
 697
 698 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 699   ;; do nothing.
 700   )
 701
 702 (luna-define-method elmo-folder-close ((folder elmo-folder))
 703   (elmo-generic-folder-close folder)
 704   (elmo-folder-close-internal folder))
 705
 706 (defun elmo-generic-folder-close (folder)
 707   (elmo-folder-commit folder)
 708   (elmo-folder-set-msgdb-internal folder nil)
 709   (elmo-folder-set-killed-list-internal folder nil))
 710
 711 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 712   t) ; default is plugged.
 713
 714 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 715                                              &optional add)
 716   nil) ; default is do nothing.
 717
 718 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 719   nil) ; default is no flag.
 720
 721 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 722   (elmo-folder-persistent-internal folder))
 723
 724 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 725   nil) ; default is not creatable.
 726
 727 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 728   nil) ; default is not writable.
 729
 730 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 731   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 732                              (elmo-folder-name-internal folder)))
 733     (elmo-msgdb-delete-path folder)
 734     t))
 735
 736 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 737   (let* ((new-folder (elmo-make-folder new-name)))
 738     (unless (eq (elmo-folder-type-internal folder)
 739                 (elmo-folder-type-internal new-folder))
 740       (error "Not same folder type"))
 741     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 742             (elmo-folder-exists-p new-folder))
 743         (error "Already exists folder: %s" new-name))
 744     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 745     (elmo-msgdb-rename-path folder new-folder)))
 746
 747 (defsubst elmo-folder-search-fast (folder condition numbers)
 748   (when (and numbers
 749              (vectorp condition)
 750              (member (elmo-filter-key condition) '("first" "last" "mark")))
 751     (if (string= (elmo-filter-key condition) "flag")
 752         (let ((msgdb (elmo-folder-msgdb folder)))
 753           ;; msgdb should be synchronized at this point.
 754           (cond
 755            ((string= (elmo-filter-value condition) "unread")
 756             (elmo-folder-list-unreads folder))
 757            ((string= (elmo-filter-value condition) "important")
 758             (elmo-folder-list-importants folder))
 759            ((string= (elmo-filter-value condition) "answered")
 760             (elmo-folder-list-answereds folder))
 761            ((string= (elmo-filter-value condition) "digest")
 762             (nconc (elmo-folder-list-unreads folder)
 763                    (elmo-folder-list-importants folder)))
 764            ((string= (elmo-filter-value condition) "any")
 765             (nconc (elmo-folder-list-unreads folder)
 766                    (elmo-folder-list-importants folder)
 767                    (elmo-folder-list-answereds folder)))))
 768       (let ((len (length numbers))
 769             (lastp (string= (elmo-filter-key condition) "last"))
 770             (value (string-to-number (elmo-filter-value condition))))
 771         (when (eq (elmo-filter-type condition) 'unmatch)
 772           (setq lastp (not lastp)
 773                 value  (- len value)))
 774         (if lastp
 775             (nthcdr (max (- len value) 0) numbers)
 776           (when (> value 0)
 777             (let ((last (nthcdr (1- value) numbers)))
 778               (when last
 779                 (setcdr last nil))
 780               numbers)))))))
 781
 782 (luna-define-method elmo-folder-search ((folder elmo-folder)
 783                                         condition
 784                                         &optional numbers)
 785   (let ((numbers (or numbers (elmo-folder-list-messages folder))))
 786     (or (elmo-folder-search-fast folder condition numbers)
 787         (let ((msgdb (elmo-folder-msgdb folder))
 788               (len (length numbers))
 789               matched)
 790           (when (> len elmo-display-progress-threshold)
 791             (elmo-progress-set 'elmo-folder-search len "Searching..."))
 792           (unwind-protect
 793               (dolist (number numbers)
 794                 (let (result)
 795                   (setq result (elmo-msgdb-match-condition
 796                                 msgdb
 797                                 condition
 798                                 number
 799                                 numbers))
 800                   (when (elmo-filter-condition-p result)
 801                     (setq result (elmo-message-match-condition
 802                                   folder
 803                                   number
 804                                   condition
 805                                   numbers)))
 806                   (when result
 807                     (setq matched (cons number matched))))
 808                 (elmo-progress-notify 'elmo-folder-search))
 809             (elmo-progress-clear 'elmo-folder-search))
 810           (nreverse matched)))))
 811
 812 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 813                                                   number condition
 814                                                   numbers)
 815   (let ((filename (cond
 816                    ((elmo-message-file-name folder number))
 817                    ((let* ((cache (elmo-file-cache-get
 818                                    (elmo-message-field folder number
 819                                                        'message-id)))
 820                            (cache-path (elmo-file-cache-path cache)))
 821                       (when (and cache-path
 822                                  (not (elmo-cache-path-section-p cache-path)))
 823                         cache-path))))))
 824     (when (and filename
 825                (file-readable-p filename))
 826       (with-temp-buffer
 827         (insert-file-contents-as-binary filename)
 828         (elmo-set-buffer-multibyte default-enable-multibyte-characters)
 829         ;; Should consider charset?
 830         (decode-mime-charset-region (point-min) (point-max) elmo-mime-charset)
 831         (elmo-buffer-field-condition-match condition number numbers)))))
 832
 833 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 834   nil) ; default is noop.
 835
 836 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 837   nil) ; default is noop.
 838
 839 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 840   nil) ; default is not file.
 841
 842 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 843   nil) ; default is not number.
 844
 845 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 846   nil) ; default is not make temp file.
 847
 848 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 849                                                    number)
 850   nil) ; default is no name.
 851
 852 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 853   t)   ; default is local.
 854
 855 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 856   t)
 857
 858 ;;; Folder info
 859 ;; Folder info is a message number information cache (hashtable)
 860 (defsubst elmo-folder-get-info (folder &optional hashtb)
 861   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 862   (elmo-get-hash-val (elmo-folder-name-internal folder)
 863                      (or hashtb elmo-folder-info-hashtb)))
 864
 865 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 866   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 867   (let ((info (elmo-folder-get-info folder)))
 868     (when info
 869       (or new     (setq new     (nth 0 info)))
 870       (or unread  (setq unread  (nth 1 info)))
 871       (or numbers (setq numbers (nth 2 info)))
 872       (or max     (setq max     (nth 3 info))))
 873     (elmo-set-hash-val (elmo-folder-name-internal folder)
 874                        (list new unread numbers max)
 875                        elmo-folder-info-hashtb)))
 876
 877 (defun elmo-folder-set-info-max-by-numdb (folder msgdb-number)
 878   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 879   (let ((num-db (sort (mapcar 'car msgdb-number) '<)))
 880     (elmo-folder-set-info-hashtb
 881      folder
 882      (or (nth (max 0 (1- (length num-db))) num-db) 0)
 883      nil ;;(length num-db)
 884      )))
 885
 886 (defun elmo-folder-get-info-max (folder)
 887   "Return max number of FODLER from folder info."
 888   (nth 3 (elmo-folder-get-info folder)))
 889
 890 (defun elmo-folder-get-info-length (folder)
 891   "Return length of FODLER from folder info."
 892   (nth 2 (elmo-folder-get-info folder)))
 893
 894 (defun elmo-folder-get-info-unread (folder)
 895   "Return unread of FODLER from folder info."
 896   (nth 1 (elmo-folder-get-info folder)))
 897
 898 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 899   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 900   (let* ((hashtb (or hashtb
 901                      (elmo-make-hash (length info-alist)))))
 902     (mapcar
 903      (lambda (x)
 904        (let ((info (cadr x)))
 905          (and (intern-soft (car x) hashtb)
 906               (elmo-set-hash-val (car x)
 907                                  (list (nth 2 info)   ;; new
 908                                        (nth 3 info)   ;; unread
 909                                        (nth 1 info)   ;; length
 910                                        (nth 0 info))  ;; max
 911                                  hashtb))))
 912      info-alist)
 913     (setq elmo-folder-info-hashtb hashtb)))
 914
 915 (defsubst elmo-diff-new (diff)
 916   (car diff))
 917
 918 (defsubst elmo-diff-unread (diff)
 919   (when (consp (cdr diff))
 920     (nth 1 diff)))
 921
 922 (defsubst elmo-diff-all (diff)
 923   (if (consp (cdr diff))
 924       (nth 2 diff)
 925     (cdr diff)))
 926
 927 (defsubst elmo-strict-folder-diff (folder)
 928   "Return folder diff information strictly from FOLDER."
 929   (let* ((dir (elmo-folder-msgdb-path folder))
 930          (nalist (elmo-msgdb-get-number-alist (elmo-folder-msgdb folder)))
 931          (in-db (sort (mapcar 'car nalist) '<))
 932          (in-folder  (elmo-folder-list-messages folder))
 933          append-list delete-list diff)
 934     (cons (if (equal in-folder in-db)
 935               0
 936             (setq diff (elmo-list-diff
 937                         in-folder in-db
 938                         nil
 939                         ))
 940             (setq append-list (car diff))
 941             (setq delete-list (cadr diff))
 942             (if append-list
 943                 (length append-list)
 944               (if delete-list
 945                   (- 0 (length delete-list))
 946                 0)))
 947           (length in-folder))))
 948
 949 (luna-define-method elmo-folder-diff ((folder elmo-folder)
 950                                       &optional numbers)
 951   (elmo-generic-folder-diff folder numbers))
 952
 953 (defun elmo-generic-folder-diff (folder numbers)
 954   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 955                                 elmo-strict-diff-folder-list)
 956       (elmo-strict-folder-diff folder)
 957     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 958           (in-folder (elmo-folder-status folder))
 959           (in-db t)
 960           unsync messages
 961           in-db-max)
 962       (if numbers
 963           (setq in-db-max (or (nth (max 0 (1- (length numbers))) numbers)
 964                               0))
 965         (if (not cached-in-db-max)
 966             (let ((number-list (mapcar 'car
 967                                        (elmo-msgdb-number-load
 968                                         (elmo-folder-msgdb-path folder)))))
 969               ;; No info-cache.
 970               (setq in-db (sort number-list '<))
 971               (setq in-db-max (or (nth (max 0 (1- (length in-db))) in-db)
 972                                   0))
 973               (elmo-folder-set-info-hashtb folder in-db-max nil))
 974           (setq in-db-max cached-in-db-max)))
 975       (setq unsync (if (and in-db (car in-folder))
 976                        (- (car in-folder) in-db-max)
 977                      (if (and in-folder (null in-db))
 978                          (cdr in-folder)
 979                        (car in-folder))))
 980       (setq messages (cdr in-folder))
 981       (if (and unsync messages (> unsync messages))
 982           (setq unsync messages))
 983       (cons (or unsync 0) (or messages 0)))))
 984
 985 (defvar elmo-folder-diff-async-callback nil)
 986 (defvar elmo-folder-diff-async-callback-data nil)
 987
 988 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
 989   (and elmo-folder-diff-async-callback
 990        (funcall elmo-folder-diff-async-callback
 991                 folder
 992                 (elmo-folder-diff folder))))
 993
 994 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
 995   (list folder))
 996
 997 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
 998   (eq (elmo-folder-type-internal folder) type))
 999
1000 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1001                                                  src-folder
1002                                                  numbers
1003                                                  &optional
1004                                                  same-number)
1005   (elmo-generic-folder-append-messages folder src-folder numbers
1006                                        same-number))
1007
1008 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1009                                                    same-number)
1010   (let (unseen table flag mark
1011                succeed-numbers failure cache)
1012     (setq table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1013     (with-temp-buffer
1014       (set-buffer-multibyte nil)
1015       (while numbers
1016         (setq failure nil
1017               mark (elmo-message-mark src-folder (car numbers))
1018               flag (cond
1019                     ((member mark (elmo-msgdb-answered-marks))
1020                      'answered)
1021                     ;;
1022                     ((not (member mark (elmo-msgdb-unread-marks)))
1023                      'read)))
1024         (condition-case nil
1025             (setq cache (elmo-file-cache-get
1026                          (elmo-message-field src-folder
1027                                              (car numbers)
1028                                              'message-id))
1029                   failure
1030                   (not
1031                    (and
1032                     (elmo-message-fetch
1033                      src-folder (car numbers)
1034                      (if (elmo-folder-plugged-p src-folder)
1035                          (elmo-make-fetch-strategy
1036                           'entire 'maybe nil
1037                           (and cache (elmo-file-cache-path cache)))
1038                        (or (and elmo-enable-disconnected-operation
1039                                 cache
1040                                 (eq (elmo-file-cache-status cache) 'entire)
1041                                 (elmo-make-fetch-strategy
1042                                  'entire t nil
1043                                  (elmo-file-cache-path cache)))
1044                            (error "Unplugged")))
1045                      nil (current-buffer)
1046                      'unread)
1047                     (> (buffer-size) 0)
1048                     (elmo-folder-append-buffer
1049                      folder
1050                      flag
1051                      (if same-number (car numbers))))))
1052           (error (setq failure t)))
1053         ;; FETCH & APPEND finished
1054         (unless failure
1055           (when flag
1056             (elmo-flag-table-set table
1057                                  (elmo-message-field
1058                                   src-folder (car numbers)
1059                                   'message-id)
1060                                  flag))
1061           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1062         (elmo-progress-notify 'elmo-folder-move-messages)
1063         (setq numbers (cdr numbers)))
1064       (when (elmo-folder-persistent-p folder)
1065         (elmo-flag-table-save (elmo-folder-msgdb-path folder) table))
1066       succeed-numbers)))
1067
1068 ;; Arguments should be reduced.
1069 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1070                                              &optional msgdb
1071                                              no-delete-info
1072                                              no-delete
1073                                              same-number
1074                                              save-unread)
1075   (save-excursion
1076     (let* ((messages msgs)
1077            (elmo-inhibit-display-retrieval-progress t)
1078            (len (length msgs))
1079            succeeds i result)
1080       (if (eq dst-folder 'null)
1081           (setq succeeds messages)
1082         (unless (elmo-folder-writable-p dst-folder)
1083           (error "move: %d is not writable"
1084                  (elmo-folder-name-internal dst-folder)))
1085         (when messages
1086           ;; src is already opened.
1087           (elmo-folder-open-internal dst-folder)
1088           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1089                                                               src-folder
1090                                                               messages
1091                                                               same-number))
1092             (error "move: append message to %s failed"
1093                    (elmo-folder-name-internal dst-folder)))
1094           (elmo-folder-close dst-folder)))
1095       (if (and (not no-delete) succeeds)
1096           (progn
1097             (if (not no-delete-info)
1098                 (message "Cleaning up src folder..."))
1099             (if (and (elmo-folder-delete-messages src-folder succeeds)
1100                      (elmo-msgdb-delete-msgs
1101                       (elmo-folder-msgdb src-folder) succeeds))
1102                 (setq result t)
1103               (message "move: delete messages from %s failed."
1104                        (elmo-folder-name-internal src-folder))
1105               (setq result nil))
1106             (if (and result
1107                      (not no-delete-info))
1108                 (message "Cleaning up src folder...done"))
1109             result)
1110         (if no-delete
1111             (progn
1112               (message "Copying messages...done")
1113               t)
1114           (if (eq len 0)
1115               (message "No message was moved.")
1116             (message "Moving messages failed.")
1117             nil ; failure
1118             ))))))
1119
1120 (defun elmo-folder-msgdb-path (folder)
1121   "Return the msgdb path for FOLDER."
1122   (or (elmo-folder-path-internal folder)
1123       (elmo-folder-set-path-internal
1124        folder
1125        (elmo-folder-expand-msgdb-path folder))))
1126
1127 (defun elmo-message-accessible-p (folder number)
1128   "Get accessibility of the message.
1129 Return non-nil when message is accessible."
1130   (or (elmo-folder-plugged-p folder)
1131       (elmo-folder-local-p folder)
1132       (elmo-msgdb-get-cached (elmo-folder-msgdb folder) number)))
1133
1134 (defun elmo-message-set-cached (folder number cached)
1135   "Set cache status of the message in the msgdb.
1136 FOLDER is the ELMO folder structure.
1137 NUMBER is a number of the message.
1138 If CACHED is t, message is set as cached."
1139   (when (elmo-msgdb-set-cached (elmo-folder-msgdb folder)
1140                                number
1141                                cached
1142                                (elmo-message-use-cache-p folder number))
1143     (elmo-folder-set-mark-modified-internal folder t)))
1144
1145 ;;; APIs for message-entity
1146 (luna-define-generic elmo-folder-list-message-entities (folder)
1147   "Return the all list of message-entity structure of FOLDER.")
1148
1149 (luna-define-method elmo-folder-list-message-entities ((folder elmo-folder))
1150   (elmo-msgdb-get-overview (elmo-folder-msgdb folder)))
1151
1152 (luna-define-generic elmo-message-entity (folder key)
1153   "Return the message-entity structure which matches to the KEY.
1154 KEY is a number or a string.
1155 A number is for message number in the FOLDER.
1156 A string is for message-d of the message.")
1157
1158 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1159   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1160
1161 (luna-define-generic elmo-message-entity-parent (folder entity)
1162   "Return the parent message-entity structure in the FOLDER.
1163 ENTITY is the message-entity to get the parent.")
1164
1165 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1166   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1167
1168 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1169 (def-edebug-spec elmo-folder-do-each-message-entity
1170   ((symbolp form &rest form) &rest form))
1171
1172 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1173   "Iterator for message entity in the folder.
1174 \(elmo-folder-do-each-message-entity \(entity folder\)
1175  ... do the process using entity...
1176 \)"
1177   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1178      ,@form))
1179
1180 (defmacro elmo-message-entity-number (entity)
1181   `(elmo-msgdb-overview-entity-get-number ,entity))
1182
1183 (defun elmo-message-entity-field (entity field &optional decode)
1184   "Get message entity field value.
1185 ENTITY is the message entity structure obtained by `elmo-message-entity'.
1186 FIELD is the symbol of the field name.
1187 if optional DECODE is non-nil, returned value is decoded."
1188   (elmo-msgdb-message-entity-field entity field decode))
1189
1190 (defun elmo-message-entity-set-field (entity field value)
1191   "Set message entity field value.
1192 ENTITY is the message entity structure.
1193 FIELD is the symbol of the field name.
1194 VALUE is the field value (raw)."
1195   (elmo-msgdb-message-entity-set-field entity field value))
1196
1197 (luna-define-generic elmo-folder-count-flags (folder)
1198   "Count flagged message number in the msgdb of the FOLDER.
1199 Return a list of numbers (`new' `unread' `answered')")
1200
1201 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1202   (let ((new 0)
1203         (unreads 0)
1204         (answered 0))
1205     (dolist (elem (elmo-msgdb-get-mark-alist (elmo-folder-msgdb folder)))
1206       (cond
1207        ((string= (cadr elem) elmo-msgdb-new-mark)
1208         (incf new))
1209        ((member (cadr elem) (elmo-msgdb-unread-marks))
1210         (incf unreads))
1211        ((member (cadr elem) (elmo-msgdb-answered-marks))
1212         (incf answered))))
1213     (list new unreads answered)))
1214
1215 (defun elmo-message-set-flag (folder number flag)
1216   "Set message flag.
1217 FOLDER is a ELMO folder structure.
1218 NUMBER is a message number to set flag.
1219
1220 FLAG is a symbol which is one of the following:
1221   `unread'    (set the message as unread)
1222   `answered'  (set the message as answered)
1223   `important' (set the message as important)
1224 'sugar' flag:
1225   `read'      (remove new and unread flags)")
1226
1227 (defun elmo-message-unset-flag (folder number flag)
1228   "Unset message flag.
1229 FOLDER is a ELMO folder structure.
1230 NUMBER is a message number to set flag.
1231
1232 FLAG is a symbol which is one of the following:
1233   `unread'    (remove unread and new flag)
1234   `answered'  (remove answered flag)
1235   `important' (remove important flag)
1236 'sugar' flag:
1237   `read'      (set unread flag)")
1238
1239 (defun elmo-message-mark (folder number)
1240   "Get mark of the message.
1241 FOLDER is the ELMO folder structure.
1242 NUMBER is a number of the message."
1243   (elmo-msgdb-get-mark (elmo-folder-msgdb folder) number))
1244
1245 (defun elmo-message-field (folder number field)
1246   "Get message field value in the msgdb.
1247 FOLDER is the ELMO folder structure.
1248 NUMBER is a number of the message.
1249 FIELD is a symbol of the field."
1250   (elmo-msgdb-get-field (elmo-folder-msgdb folder) number field))
1251
1252 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1253   nil) ; default is not use cache.
1254
1255 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1256   folder) ; default is folder
1257
1258 (luna-define-method elmo-folder-unmark-important ((folder elmo-folder)
1259                                                   numbers
1260                                                   &optional ignore-flags)
1261   (when (elmo-folder-msgdb-internal folder)
1262     (dolist (number numbers)
1263       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1264                              folder
1265                              number
1266                              'important))))
1267
1268 (luna-define-method elmo-folder-mark-as-important ((folder elmo-folder)
1269                                                    numbers
1270                                                    &optional ignore-flags)
1271   (when (elmo-folder-msgdb-internal folder)
1272     (dolist (number numbers)
1273       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1274                            folder
1275                            number
1276                            'important))))
1277
1278 (luna-define-method elmo-folder-unmark-read ((folder elmo-folder)
1279                                              numbers
1280                                              &optional ignore-flags)
1281   (when (elmo-folder-msgdb-internal folder)
1282     (dolist (number numbers)
1283       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1284                              folder
1285                              number
1286                              'read))))
1287
1288 (luna-define-method elmo-folder-mark-as-read ((folder elmo-folder)
1289                                               numbers
1290                                               &optional ignore-flag)
1291   (when (elmo-folder-msgdb-internal folder)
1292     (dolist (number numbers)
1293       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1294                            folder
1295                            number
1296                            'read))))
1297
1298 (luna-define-method elmo-folder-unmark-answered ((folder elmo-folder) numbers)
1299   (when (elmo-folder-msgdb-internal folder)
1300     (dolist (number numbers)
1301       (elmo-msgdb-unset-flag (elmo-folder-msgdb folder)
1302                              folder
1303                              number
1304                              'answered))))
1305
1306 (luna-define-method elmo-folder-mark-as-answered ((folder elmo-folder) numbers)
1307   (when (elmo-folder-msgdb-internal folder)
1308     (dolist (number numbers)
1309       (elmo-msgdb-set-flag (elmo-folder-msgdb folder)
1310                            folder
1311                            number
1312                            'answered))))
1313
1314 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder)
1315                                                    &optional
1316                                                    number-alist)
1317   ;; Do nothing.
1318   )
1319
1320 (defun elmo-generic-folder-append-msgdb (folder append-msgdb)
1321   (if append-msgdb
1322       (let* ((number-alist (elmo-msgdb-get-number-alist append-msgdb))
1323              (all-alist (copy-sequence (append
1324                                         (elmo-msgdb-get-number-alist
1325                                          (elmo-folder-msgdb folder))
1326                                         number-alist)))
1327              (cur number-alist)
1328              pair overview
1329              to-be-deleted
1330              mark-alist)
1331         (elmo-folder-set-msgdb-internal folder
1332                                         (elmo-msgdb-append
1333                                          (elmo-folder-msgdb folder)
1334                                          append-msgdb))
1335         (while cur
1336           (setq all-alist (delq (car cur) all-alist))
1337           ;; same message id exists.
1338           (if (setq pair (rassoc (cdr (car cur)) all-alist))
1339               (setq to-be-deleted (nconc to-be-deleted (list (car pair)))))
1340           (setq cur (cdr cur)))
1341         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1342                    'hide)
1343                ;; Hide duplicates.
1344                (setq overview (elmo-delete-if
1345                                (lambda (x)
1346                                  (memq (elmo-msgdb-overview-entity-get-number
1347                                         x)
1348                                        to-be-deleted))
1349                                (elmo-msgdb-get-overview append-msgdb)))
1350                ;; Should be mark as read.
1351                (elmo-folder-mark-as-read folder to-be-deleted)
1352                (elmo-msgdb-set-overview append-msgdb overview))
1353               ((eq (elmo-folder-process-duplicates-internal folder)
1354                    'read)
1355                ;; Mark as read duplicates.
1356                (elmo-folder-mark-as-read folder to-be-deleted))
1357               (t
1358                ;; Do nothing.
1359                (setq to-be-deleted nil)))
1360         (length to-be-deleted))
1361     0))
1362
1363 (luna-define-method elmo-folder-append-msgdb ((folder elmo-folder)
1364                                               append-msgdb)
1365   (elmo-generic-folder-append-msgdb folder append-msgdb))
1366
1367 (defun elmo-folder-confirm-appends (appends)
1368   (let ((len (length appends))
1369         in)
1370     (if (and elmo-folder-update-threshold
1371              (> len elmo-folder-update-threshold)
1372              elmo-folder-update-confirm)
1373         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1374             appends
1375           (setq in elmo-folder-update-threshold)
1376           (catch 'end
1377             (while t
1378               (setq in (read-from-minibuffer "Update number: "
1379                                              (int-to-string in))
1380                     in (string-to-int in))
1381               (if (< len in)
1382                   (throw 'end len))
1383               (if (y-or-n-p (format "%d messages are not appeared.  OK? "
1384                                     (max (- len in) 0)))
1385                   (throw 'end in))))
1386           (nthcdr (max (- len in) 0) appends))
1387       (if (and elmo-folder-update-threshold
1388                (> len elmo-folder-update-threshold)
1389                (not elmo-folder-update-confirm))
1390           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1391         appends))))
1392
1393 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1394                                         number strategy
1395                                         &optional
1396                                         section
1397                                         outbuf
1398                                         unread)
1399   (if outbuf
1400       (with-current-buffer outbuf
1401         (erase-buffer)
1402         (elmo-message-fetch-with-cache-process folder number
1403                                                strategy section unread))
1404     (with-temp-buffer
1405       (elmo-message-fetch-with-cache-process folder number
1406                                              strategy section unread)
1407       (buffer-string))))
1408
1409 (luna-define-method elmo-message-fetch-with-cache-process ((folder elmo-folder)
1410                                                            number strategy
1411                                                            &optional
1412                                                            section unread)
1413   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1414         (method-priorities
1415          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1416                 '(entity cache))
1417                ((elmo-fetch-strategy-use-cache strategy)
1418                 '(cache entity))
1419                (t
1420                 '(entity))))
1421         result err)
1422     (while (and method-priorities
1423                 (null result))
1424       (setq result
1425             (case (car method-priorities)
1426               (cache
1427                (elmo-file-cache-load cache-path section))
1428               (entity
1429                (when (and (condition-case error
1430                               (elmo-message-fetch-internal folder number
1431                                                            strategy
1432                                                            section
1433                                                            unread)
1434                             (error (setq err error) nil))
1435                           (> (buffer-size) 0))
1436                  (elmo-delete-cr-buffer)
1437                  (when (and (elmo-fetch-strategy-save-cache strategy)
1438                             cache-path)
1439                    (elmo-file-cache-save cache-path section))
1440                  t)))
1441             method-priorities (cdr method-priorities)))
1442     (or result
1443         (and err (signal (car err) (cdr err))))))
1444
1445 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1446                                        &optional keep-killed)
1447   (unless keep-killed
1448     (elmo-folder-set-killed-list-internal folder nil))
1449   (elmo-folder-set-msgdb-internal folder (elmo-msgdb-clear)))
1450
1451 (defun elmo-folder-synchronize (folder
1452                                 &optional ignore-msgdb
1453                                 no-check)
1454   "Synchronize the folder data to the newest status.
1455 FOLDER is the ELMO folder structure.
1456 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1457 flag status. If IGNORE-MSGDB is 'visible-only, only visible messages
1458 \(the messages which are not in the killed-list\) are thrown away and
1459 synchronized.
1460 If NO-CHECK is non-nil, rechecking folder is skipped.
1461
1462 Return a list of a cross-posted message number.
1463 If update process is interrupted, return nil."
1464   (let ((killed-list (elmo-folder-killed-list-internal folder))
1465         (before-append t)
1466         number-alist mark-alist
1467         old-msgdb diff diff-2 delete-list new-list new-msgdb mark
1468         flag-table crossed after-append)
1469     (setq old-msgdb (elmo-folder-msgdb folder))
1470     (setq flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1471     (setq number-alist (elmo-msgdb-get-number-alist
1472                         (elmo-folder-msgdb folder)))
1473     (setq mark-alist (elmo-msgdb-get-mark-alist
1474                       (elmo-folder-msgdb folder)))
1475     (when ignore-msgdb
1476       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1477       (elmo-folder-clear folder (eq ignore-msgdb 'visible-only)))
1478     (unless no-check (elmo-folder-check folder))
1479     (condition-case nil
1480         (progn
1481           (message "Checking folder diff...")
1482           ;; TODO: killed list is loaded in elmo-folder-open and
1483           ;; list-messages use internal killed-list-folder.
1484           (setq diff (elmo-list-diff (elmo-folder-list-messages
1485                                       folder
1486                                       (eq 'visible-only ignore-msgdb))
1487                                      (unless ignore-msgdb
1488                                        (sort (mapcar
1489                                               'car
1490                                               number-alist)
1491                                              '<))))
1492           (message "Checking folder diff...done")
1493           (setq new-list (elmo-folder-confirm-appends (car diff)))
1494           ;; Set killed list.
1495           (when (and (not (eq (length (car diff))
1496                               (length new-list)))
1497                      (setq diff-2 (elmo-list-diff (car diff) new-list)))
1498             (elmo-msgdb-append-to-killed-list folder (car diff-2)))
1499           (setq delete-list (cadr diff))
1500           (if (or (equal diff '(nil nil))
1501                   (equal diff '(nil))
1502                   (and (eq (length (car diff)) 0)
1503                        (eq (length (cadr diff)) 0)))
1504               (progn
1505                 (elmo-folder-update-number folder)
1506                 (elmo-folder-process-crosspost folder)
1507                 0 ; no updates.
1508                 )
1509             (if delete-list (elmo-msgdb-delete-msgs
1510                              (elmo-folder-msgdb folder) delete-list))
1511             (when new-list
1512               (setq new-msgdb (elmo-folder-msgdb-create
1513                                folder new-list flag-table))
1514               (elmo-msgdb-change-mark (elmo-folder-msgdb folder)
1515                                       elmo-msgdb-new-mark
1516                                       elmo-msgdb-unread-uncached-mark)
1517               ;; Clear flag-table
1518               (if (elmo-folder-persistent-p folder)
1519                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1520                                         nil))
1521               (setq before-append nil)
1522               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1523               ;; process crosspost.
1524               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-MARK-ALIST).
1525               (elmo-folder-process-crosspost folder)
1526               (elmo-folder-set-message-modified-internal folder t)
1527               (elmo-folder-set-mark-modified-internal folder t))
1528             ;; return value.
1529             (or crossed 0)))
1530       (quit
1531        ;; Resume to the original status.
1532        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1533        (elmo-folder-set-killed-list-internal folder killed-list)
1534        nil))))
1535
1536 (defun elmo-folder-messages (folder)
1537   "Return number of messages in the FOLDER."
1538   (length
1539    (elmo-msgdb-get-number-alist
1540     (elmo-folder-msgdb folder))))
1541
1542 (luna-define-generic elmo-folder-length (folder)
1543   "Return number of messages in the FOLDER.")
1544
1545 (luna-define-method elmo-folder-length ((folder elmo-folder))
1546   (elmo-msgdb-length (elmo-folder-msgdb folder)))
1547
1548 (defun elmo-msgdb-load (folder &optional silent)
1549   (unless silent
1550     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1551   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1552     (elmo-folder-set-info-max-by-numdb folder
1553                                        (elmo-msgdb-get-number-alist msgdb))
1554
1555     (unless silent
1556       (message "Loading msgdb for %s...done"
1557                (elmo-folder-name-internal folder)))
1558     msgdb))
1559
1560 (defun elmo-msgdb-delete-path (folder)
1561   (let ((path (elmo-folder-msgdb-path folder)))
1562     (if (file-directory-p path)
1563         (elmo-delete-directory path t))))
1564
1565 (defun elmo-msgdb-rename-path (old-folder new-folder)
1566   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1567          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1568          (new-dir (directory-file-name (file-name-directory new))))
1569     (if (not (file-directory-p old))
1570         ()
1571       (if (file-exists-p new)
1572           (error "Already exists directory: %s" new)
1573         (if (not (file-exists-p new-dir))
1574             (elmo-make-directory new-dir))
1575         (rename-file old new)))))
1576
1577 (defun elmo-setup-subscribed-newsgroups (groups)
1578   "Setup subscribed newsgroups.
1579 GROUPS is a list of newsgroup name string.
1580 Return a hashtable for newsgroups."
1581   (let ((hashtb (or elmo-newsgroups-hashtb
1582                     (setq elmo-newsgroups-hashtb
1583                           (elmo-make-hash (length groups))))))
1584     (dolist (group groups)
1585       (or (elmo-get-hash-val group hashtb)
1586           (elmo-set-hash-val group nil hashtb)))
1587     (setq elmo-newsgroups-hashtb hashtb)))
1588
1589 (defvar elmo-crosspost-message-alist-modified nil)
1590 (defun elmo-crosspost-message-alist-load ()
1591   "Load crosspost message alist."
1592   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1593   (setq elmo-crosspost-message-alist-modified nil))
1594
1595 (defun elmo-crosspost-message-alist-save ()
1596   "Save crosspost message alist."
1597   (when elmo-crosspost-message-alist-modified
1598     (let ((alist elmo-crosspost-message-alist)
1599           newsgroups)
1600       (while alist
1601         (setq newsgroups
1602               (elmo-delete-if
1603                '(lambda (x)
1604                   (not (intern-soft x elmo-newsgroups-hashtb)))
1605                (nth 1 (car alist))))
1606         (if newsgroups
1607             (setcar (cdar alist) newsgroups)
1608           (setq elmo-crosspost-message-alist
1609                 (delete (car alist) elmo-crosspost-message-alist)))
1610         (setq alist (cdr alist)))
1611       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1612       (setq elmo-crosspost-message-alist-modified nil))))
1613
1614 (defun elmo-folder-make-temporary-directory (folder)
1615   ;; Make a temporary directory for FOLDER.
1616   (let ((temp-dir (make-temp-name
1617                    (concat
1618                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1619                     "elmo"))))
1620     (elmo-make-directory temp-dir)
1621     temp-dir))
1622
1623 (defun elmo-init ()
1624   "Initialize ELMO module."
1625   (elmo-crosspost-message-alist-load)
1626   (elmo-resque-obsolete-variables)
1627   (elmo-dop-queue-load))
1628
1629 (defun elmo-quit ()
1630   "Quit and cleanup ELMO."
1631   (elmo-crosspost-message-alist-save)
1632   (elmo-dop-queue-save)
1633   ;; Not implemented yet.
1634   (let ((types elmo-folder-type-alist)
1635         class)
1636     (while types
1637       (setq class
1638             (luna-find-class
1639              (intern (format "elmo-%s-folder" (symbol-name (cdr (car types)))))))
1640       ;; Call all folder's `elmo-quit' method.
1641       (if class
1642           (dolist (func (luna-class-find-functions class 'elmo-quit))
1643             (funcall func nil)))
1644       (setq types (cdr types)))))
1645
1646 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1647                                                  new-folder)
1648   (error "Cannot rename %s folder"
1649          (symbol-name (elmo-folder-type-internal folder))))
1650
1651
1652 ;;; Define folders.
1653 (elmo-define-folder ?% 'imap4)
1654 (elmo-define-folder ?-  'nntp)
1655 (elmo-define-folder ?\+ 'localdir)
1656 (elmo-define-folder ?\* 'multi)
1657 (elmo-define-folder ?\/ 'filter)
1658 (elmo-define-folder ?\$ 'archive)
1659 (elmo-define-folder ?&  'pop3)
1660 (elmo-define-folder ?=  'localnews)
1661 (elmo-define-folder ?|  'pipe)
1662 (elmo-define-folder ?.  'maildir)
1663 (elmo-define-folder ?'  'internal)
1664 (elmo-define-folder ?\[  'nmz)
1665 (elmo-define-folder ?@  'shimbun)
1666
1667 ;;; Obsolete variables.
1668 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1669                                'elmo-imap4-default-mailbox)
1670 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1671                                'elmo-imap4-default-server)
1672 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1673                                'elmo-imap4-default-authenticate-type)
1674 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1675                                'elmo-imap4-default-user)
1676 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1677                                'elmo-imap4-default-port)
1678 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1679                                'elmo-imap4-default-stream-type)
1680 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1681                                'elmo-nntp-default-server)
1682 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1683                                'elmo-nntp-default-user)
1684 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1685                                'elmo-nntp-default-port)
1686 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1687                                'elmo-nntp-default-stream-type)
1688 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1689                                'elmo-pop3-default-server)
1690 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1691                                'elmo-pop3-default-user)
1692 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1693                                'elmo-pop3-default-authenticate-type)
1694 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1695                                'elmo-pop3-default-port)
1696 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1697                                'elmo-pop3-default-stream-type)
1698 (elmo-define-obsolete-variable 'elmo-cache-dirname
1699                                'elmo-cache-directory)
1700 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1701                                'elmo-msgdb-directory)
1702
1703 ;; Obsolete functions.
1704 ;; 2001-12-11: *-dir -> *-directory
1705 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1706 (make-obsolete 'elmo-folder-make-temp-dir
1707                'elmo-folder-make-temporary-directory)
1708
1709
1710 ;; autoloads
1711 (autoload 'elmo-dop-queue-flush "elmo-dop")
1712 (autoload 'elmo-nntp-post "elmo-nntp")
1713
1714 (require 'product)
1715 (product-provide (provide 'elmo) (require 'elmo-version))
1716
1717 ;;; elmo.el ends here