elmo/elmo.el

   1 ;;; elmo.el --- Elisp Library for Message Orchestration.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of ELMO (Elisp Library for Message Orchestration).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'luna)
  33
  34 (require 'elmo-version)                 ; reduce recursive-load-depth
  35 (require 'elmo-vars)
  36 (require 'elmo-util)
  37 (require 'elmo-msgdb)
  38 (require 'elmo-signal)
  39
  40 (eval-when-compile (require 'cl))
  41
  42 (if (or (featurep 'dbm)
  43         (featurep 'gnudbm)
  44         (featurep 'berkdb)
  45         (featurep 'berkeley-db))
  46     (require 'elmo-database))
  47
  48 (defcustom elmo-message-fetch-threshold 30000
  49   "Fetch threshold."
  50   :type '(choice (integer :tag "Threshold (bytes)")
  51                  (const :tag "No limitation" nil))
  52   :group 'elmo)
  53
  54 (defcustom elmo-message-fetch-confirm t
  55   "If non-nil, confirm fetching if message size is larger than
  56 `elmo-message-fetch-threshold'.
  57 Otherwise, entire fetching of the message is aborted without confirmation."
  58   :type 'boolean
  59   :group 'elmo)
  60
  61 (defcustom elmo-folder-update-threshold 500
  62   "Update threshold."
  63   :type '(choice (integer :tag "Number of messages")
  64                  (const :tag "No limitation" nil))
  65   :group 'elmo)
  66
  67 (defcustom elmo-folder-update-confirm t
  68   "Confirm if update number exceeds `elmo-folder-update-threshold'."
  69   :type 'boolean
  70   :group 'elmo)
  71
  72 (defcustom elmo-msgdb-path-encode-threshold nil
  73   "*Encode msgdb path if its length is longer than this value."
  74   :type '(choice (const :tag "No encode" nil)
  75                  number)
  76   :group 'elmo)
  77
  78 (defvar elmo-message-displaying nil
  79   "A global switch to indicate message is displaying or not.")
  80
  81 ;;; internal
  82 (defvar elmo-folder-type-alist nil)
  83
  84 (defvar elmo-newsgroups-hashtb nil)
  85
  86 (elmo-define-error 'elmo-error "Error" 'error)
  87 (elmo-define-error 'elmo-open-error "Cannot open" 'elmo-error)
  88 (elmo-define-error 'elmo-authenticate-error "Login failed" 'elmo-open-error)
  89 (elmo-define-error 'elmo-imap4-bye-error "IMAP4 session was terminated" 'elmo-open-error)
  90
  91 ;; Event declarations
  92 (elmo-define-signal flag-changing (number old-flags new-flags)
  93   "Notify the changing flag of the messages with NUMBER.")
  94
  95 (elmo-define-signal flag-changed (numbers)
  96   "Notify the change flag of the messages with NUMBERS.")
  97
  98 (elmo-define-signal cache-changed (number)
  99   "Notify the change cache status of the message with NUMBER.")
 100
 101 ;; autoloads
 102 (eval-and-compile
 103   (autoload 'md5 "md5")
 104   (autoload 'elmo-dop-queue-flush "elmo-dop")
 105   (autoload 'elmo-nntp-post "elmo-nntp")
 106   (autoload 'elmo-global-flag-p "elmo-flag")
 107   (autoload 'elmo-local-flag-p "elmo-flag")
 108   (autoload 'elmo-global-flag-detach "elmo-flag")
 109   (autoload 'elmo-global-flag-detach-messages "elmo-flag")
 110   (autoload 'elmo-global-flag-set "elmo-flag")
 111   (autoload 'elmo-get-global-flags "elmo-flag")
 112   (autoload 'elmo-global-mark-migrate "elmo-flag")
 113   (autoload 'elmo-folder-list-global-flag-messages "elmo-flag"))
 114
 115 (defun elmo-define-folder (prefix backend)
 116   "Define a folder.
 117 If a folder name begins with PREFIX, use BACKEND."
 118   (let ((pair (assq prefix elmo-folder-type-alist)))
 119     (if pair
 120         (progn
 121           (setcar pair prefix)
 122           (setcdr pair backend))
 123       (setq elmo-folder-type-alist (cons (cons prefix backend)
 124                                          elmo-folder-type-alist)))))
 125
 126 (defmacro elmo-folder-type (name)
 127   "Get folder type from NAME string."
 128   `(and (stringp ,name)
 129         (cdr (assoc (string-to-char ,name) elmo-folder-type-alist))))
 130
 131 ;;; ELMO folder
 132 ;; A elmo folder provides uniformed (orchestrated) access
 133 ;; to the internet messages.
 134 (eval-and-compile
 135   (luna-define-class elmo-folder () (type   ; folder type symbol.
 136                                      name   ; orignal folder name string.
 137                                      prefix ; prefix for folder name
 138                                      path   ; directory path for msgdb.
 139                                      msgdb  ; msgdb (may be nil).
 140                                      killed-list  ; killed list.
 141                                      flag-table   ; flag table.
 142                                      persistent   ; non-nil if persistent.
 143                                      process-duplicates  ; read or hide
 144                                      biff   ; folder for biff
 145                                      ))
 146   (luna-define-internal-accessors 'elmo-folder))
 147
 148 (luna-define-generic elmo-folder-initialize (folder name)
 149   ;; Initialize a FOLDER structure with NAME."
 150   )
 151
 152 (defmacro elmo-folder-send (folder message &rest args)
 153   "Let FOLDER receive the MESSAGE with ARGS."
 154   (` (luna-send (, folder) (, message) (, folder) (,@ args))))
 155
 156 ;;;###autoload
 157 (defun elmo-make-folder (name &optional non-persistent)
 158   "Make an ELMO folder structure specified by NAME.
 159 If optional argument NON-PERSISTENT is non-nil, the folder msgdb is not saved."
 160   (let ((type (elmo-folder-type name))
 161         prefix split class folder original)
 162     (setq original (elmo-string name))
 163     (if type
 164         (progn
 165           (setq prefix (elmo-string (substring name 0 1)))
 166           (setq name (elmo-string (substring name 1))))
 167       (setq type (intern (car (setq split (split-string name ":")))))
 168       (if (>= (length split) 2)
 169           (setq name (substring name (+ 1 (length (car split)))))
 170         (error "Error in folder name `%s'" original))
 171       (setq prefix (concat (car split) ":")))
 172     (setq class (format "elmo-%s" (symbol-name type)))
 173     (require (intern class))
 174     (setq folder (luna-make-entity (intern (concat class "-folder"))
 175                                    :type type
 176                                    :prefix prefix
 177                                    :name original
 178                                    :persistent (not non-persistent)))
 179     (save-match-data
 180       (elmo-folder-send folder 'elmo-folder-initialize name))))
 181
 182 ;; Note that this function is for internal use only.
 183 (luna-define-generic elmo-folder-msgdb (folder)
 184   "Return the msgdb of FOLDER (on-demand loading).
 185 \(For internal use only.\)")
 186
 187 (luna-define-method elmo-folder-msgdb ((folder elmo-folder))
 188   (or (elmo-folder-msgdb-internal folder)
 189       (elmo-folder-set-msgdb-internal folder
 190                                       (elmo-folder-msgdb-load folder))))
 191
 192 (luna-define-generic elmo-folder-open (folder &optional load-msgdb)
 193   "Open and setup (load saved status) FOLDER.
 194 If optional LOAD-MSGDB is non-nil, msgdb is loaded.
 195 \(otherwise, msgdb is loaded on-demand)")
 196
 197 (luna-define-generic elmo-folder-open-internal (folder)
 198   "Open FOLDER (without loading saved folder status).")
 199
 200 (luna-define-generic elmo-folder-check (folder)
 201   "Check the FOLDER to obtain newest information at the next list operation.")
 202
 203 (luna-define-generic elmo-folder-clear (folder &optional keep-killed)
 204   "Clear FOLDER to the initial state.
 205 If optional KEEP-KILLED is non-nil, killed-list is not cleared.")
 206
 207 (luna-define-generic elmo-folder-commit (folder)
 208   "Save current status of FOLDER.")
 209
 210 (luna-define-generic elmo-folder-close (folder)
 211   "Close, save and clearnup FOLDER.")
 212
 213 (luna-define-generic elmo-folder-close-internal (folder)
 214   "Close FOLDER (without saving folder status).")
 215
 216 (luna-define-generic elmo-folder-plugged-p (folder)
 217   "Returns t if FOLDER is plugged.")
 218
 219 (luna-define-generic elmo-folder-set-plugged (folder plugged &optional add)
 220   "Set FOLDER as plugged.")
 221
 222 (luna-define-generic elmo-net-port-info (folder)
 223   "Get port information of FOLDER.")
 224
 225 (luna-define-generic elmo-folder-use-flag-p (folder)
 226   "Returns t if FOLDER treats unread/important flag itself.")
 227
 228 (luna-define-generic elmo-folder-diff (folder)
 229   "Get diff of FOLDER.
 230 Return value is cons cell or list:
 231  - a cons cell (new . all)
 232  - a list (new unread all)")
 233
 234 (luna-define-generic elmo-folder-status (folder)
 235   "Returns a cons cell of (MAX-NUMBER . MESSAGES) in the FOLDER.")
 236
 237 (luna-define-generic elmo-folder-reserve-status-p (folder)
 238   "If non-nil, the folder should not close folder after `elmo-folder-status'.")
 239
 240 (luna-define-generic elmo-folder-list-messages (folder &optional visible-only
 241                                                        in-msgdb)
 242   "Return a list of message numbers contained in FOLDER.
 243 If optional VISIBLE-ONLY is non-nil, killed messages are not listed.
 244 If second optional IN-MSGDB is non-nil, only messages in the msgdb are listed.")
 245
 246 (luna-define-method elmo-folder-list-messages ((folder elmo-folder)
 247                                                &optional visible-only in-msgdb)
 248   (let ((list (if in-msgdb
 249                   t
 250                 (elmo-folder-list-messages-internal folder visible-only)))
 251         (killed-list (elmo-folder-killed-list-internal folder)))
 252     (unless (listp list)
 253       ;; Use current list.
 254       (setq list (elmo-msgdb-list-messages (elmo-folder-msgdb folder))))
 255     (if visible-only
 256         (elmo-living-messages list killed-list)
 257       (if (and in-msgdb killed-list)
 258           (elmo-uniq-sorted-list
 259            (sort (nconc (elmo-number-set-to-number-list killed-list) list) #'<)
 260            #'eq)
 261         list))))
 262
 263 (luna-define-generic elmo-folder-list-messages-internal (folder &optional
 264                                                                 visible-only)
 265   ;; Return a list of message numbers contained in FOLDER.
 266   ;; Return t if the message list is not available.
 267   )
 268
 269 (luna-define-generic elmo-folder-list-flagged (folder flag &optional in-msgdb)
 270   "List messages in the FOLDER with FLAG.
 271 FLAG is a symbol which is one of the following:
 272   `new'        (new messages)
 273   `unread'     (unread messages (new messages are included))
 274   `answered'   (answered or forwarded)
 275   `important'  (marked as important)
 276 'sugar' flags:
 277   `read'       (not unread)
 278   `digest'     (unread + important + other flags)
 279   `any'        (digest + answered + other flags)
 280 If optional IN-MSGDB is non-nil, retrieve flag information from msgdb.")
 281
 282 (luna-define-method elmo-folder-list-flagged ((folder elmo-folder) flag
 283                                               &optional in-msgdb)
 284   (let ((msgs (if in-msgdb
 285                   t
 286                 (elmo-folder-list-flagged-internal folder flag))))
 287     (unless (listp msgs)
 288       (setq msgs (elmo-msgdb-list-flagged (elmo-folder-msgdb folder) flag)))
 289     (if in-msgdb
 290         msgs
 291       (elmo-uniq-list
 292        (nconc (elmo-folder-list-global-flag-messages folder flag) msgs)
 293        #'delq))))
 294
 295 (luna-define-generic elmo-folder-list-flagged-internal (folder flag)
 296   "Return a list of message in the FOLDER with FLAG.
 297 Return t if the message list is not available.")
 298
 299 (luna-define-method elmo-folder-list-flagged-internal ((folder elmo-folder)
 300                                                        flag)
 301   t)
 302
 303 (luna-define-generic elmo-folder-list-subfolders (folder &optional one-level)
 304   "Returns a list of subfolders contained in FOLDER.
 305 If optional argument ONE-LEVEL is non-nil, only children of FOLDER is returned.
 306 \(a folder which have children is returned as a list\)
 307 Otherwise, all descendent folders are returned.")
 308
 309 (luna-define-generic elmo-folder-have-subfolder-p (folder)
 310   "Return non-nil when FOLDER has subfolders.")
 311
 312 (luna-define-generic elmo-folder-exists-p (folder)
 313   "Returns non-nil when FOLDER exists.")
 314
 315 (luna-define-generic elmo-folder-creatable-p (folder)
 316   "Returns non-nil when FOLDER is creatable.")
 317
 318 (luna-define-generic elmo-folder-writable-p (folder)
 319   "Returns non-nil when FOLDER is writable.")
 320
 321 (luna-define-generic elmo-folder-persistent-p (folder)
 322   "Return non-nil when FOLDER is persistent.")
 323
 324 (luna-define-generic elmo-folder-create (folder)
 325   "Create a FOLDER.")
 326
 327 (luna-define-generic elmo-message-deletable-p (folder number)
 328   "Returns non-nil when the message in the FOLDER with NUMBER is deletable.")
 329
 330 (luna-define-generic elmo-folder-delete (folder)
 331   "Delete FOLDER completely.")
 332
 333 (luna-define-generic elmo-folder-rename (folder new-name)
 334   "Rename FOLDER to NEW-NAME (string).")
 335
 336 (luna-define-generic elmo-folder-delete-messages (folder numbers)
 337   "Delete messages with msgdb entity.
 338 FOLDER is the ELMO folder structure.
 339 NUMBERS is a list of message numbers to be deleted.
 340 It is not recommended to use this function other than internal use.
 341 Use `elmo-folder-move-messages' with dst-folder 'null instead.")
 342
 343 (luna-define-generic elmo-folder-delete-messages-internal (folder numbers)
 344   "Delete messages, but no delete msgdb entity.
 345 FOLDER is the ELMO folder structure.
 346 NUMBERS is a list of message numbers to be deleted.
 347 Override this method by each implement of `elmo-folder'.")
 348
 349 (luna-define-generic elmo-folder-search (folder condition &optional numbers)
 350   "Search and return list of message numbers.
 351 FOLDER is the ELMO folder structure.
 352 CONDITION is a condition structure for searching.
 353 If optional argument NUMBERS is specified and is a list of message numbers,
 354 messages are searched from the list.")
 355
 356 (luna-define-generic elmo-message-match-condition (folder number
 357                                                           condition
 358                                                           numbers)
 359   "Return non-nil when the message in the FOLDER with NUMBER is matched.
 360 CONDITION is a condition structure for testing.
 361 NUMBERS is a list of message numbers,
 362 use to be test for \"last\" and \"first\" predicates.")
 363
 364 (luna-define-generic elmo-folder-msgdb-create (folder numbers flag-table)
 365   "Create a message database (implemented in each backends).
 366 FOLDER is the ELMO folder structure.
 367 NUMBERS is a list of message numbers to create msgdb.
 368 FLAG-TABLE is a hashtable of message-id and flag.")
 369
 370 (luna-define-generic elmo-folder-set-flag (folder numbers flag
 371                                                   &optional is-local)
 372   "Set messages flag.
 373 FOLDER is a ELMO folder structure.
 374 NUMBERS is a list of message number to set flag.
 375
 376 FLAG is a symbol which is one of the following:
 377   `unread'    (set the message as unread)
 378   `answered'  (set the message as answered)
 379   `important' (set the message as important)
 380 'sugar' flag:
 381   `read'      (remove new and unread flags)
 382 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 383
 384 (luna-define-generic elmo-folder-unset-flag (folder numbers flag
 385                                                     &optional is-local)
 386   "Unset messages flag.
 387 FOLDER is a ELMO folder structure.
 388 NUMBERS is a list of message number to unset flag.
 389
 390 FLAG is a symbol which is one of the following:
 391   `unread'    (remove unread and new flag)
 392   `answered'  (remove answered flag)
 393   `important' (remove important flag)
 394 'sugar' flag:
 395   `read'      (set unread flag)
 396   `all'       (remove all flags)
 397 If optional IS-LOCAL is non-nil, update only local (not server) status.")
 398
 399 (luna-define-generic elmo-message-flag-available-p (folder number flag)
 400   "Return non-nil when a message in the FOLDER with NUMBER treats FLAG.")
 401
 402 (luna-define-generic elmo-folder-next-message-number (folder)
 403   "The next message number that will be assigned to a new message.
 404 FOLDER is the ELMO folder structure.")
 405
 406 (luna-define-generic elmo-folder-append-buffer (folder &optional flags
 407                                                        number)
 408   "Append current buffer as a new message.
 409 FOLDER is the destination folder (ELMO folder structure).
 410 FLAGS is the flag list for the appended message (list of symbols).
 411 If FLAGS contain `read', the message is appended as `not-unread'.
 412 If it is nil, the appended message will be treated as `new'.
 413 If optional argument NUMBER is specified, the new message number is set
 414 \(if possible\).
 415 Return nil on failure.")
 416
 417 (luna-define-generic elmo-folder-append-messages (folder
 418                                                   src-folder
 419                                                   numbers
 420                                                   &optional
 421                                                   same-number)
 422   "Append messages from folder.
 423 FOLDER is the ELMO folder structure.
 424 Caller should make sure FOLDER is `writable'.
 425 \(Can be checked with `elmo-folder-writable-p'\).
 426 SRC-FOLDER is the source ELMO folder structure.
 427 NUMBERS is the message numbers to be appended in the SRC-FOLDER.
 428 If second optional argument SAME-NUMBER is specified,
 429 message number is preserved \(if possible\).
 430 Returns a list of message numbers successfully appended.")
 431
 432 (luna-define-generic elmo-folder-pack-numbers (folder)
 433   "Pack message numbers of FOLDER.")
 434
 435 (luna-define-generic elmo-folder-update-number (folder)
 436   "Update number of FOLDER.")
 437
 438 (luna-define-generic elmo-folder-diff-async (folder)
 439   "Get diff of FOLDER asynchronously.")
 440
 441 (luna-define-generic elmo-folder-expand-msgdb-path (folder)
 442   "Expand path for FOLDER.")
 443
 444 (luna-define-generic elmo-folder-get-primitive-list (folder)
 445   "Get primitive folder structure list contained in FOLDER.")
 446
 447 (luna-define-generic elmo-folder-contains-type (folder type)
 448   "Returns t if FOLDER contains TYPE.")
 449
 450 (luna-define-generic elmo-folder-local-p (folder)
 451   "Returns t if FOLDER is local.")
 452
 453 (luna-define-generic elmo-folder-message-file-p (folder)
 454   "Returns t if all messages in the FOLDER are files.")
 455
 456 ;;; Message methods.
 457 (luna-define-generic elmo-message-use-cache-p (folder number)
 458   "Returns t if the message in the FOLDER with NUMBER uses cache.")
 459
 460 (luna-define-generic elmo-message-file-name (folder number)
 461   "Return the file name of a message specified by FOLDER and NUMBER.")
 462
 463 ;;; For archive
 464
 465 ;;; Use original file
 466 (luna-define-generic elmo-folder-message-file-number-p (folder)
 467   "Return t if the file name in the FOLDER is the message number.")
 468
 469 (luna-define-generic elmo-folder-message-file-directory (folder)
 470   "Return the directory of the message files of FOLDER.")
 471
 472 ;;; Use temporary file
 473 (luna-define-generic elmo-folder-message-make-temp-file-p (folder)
 474   "Return t if the messages in the FOLDER makes local temporary file.")
 475
 476 (luna-define-generic elmo-folder-message-make-temp-files (folder
 477                                                           numbers
 478                                                           &optional
 479                                                           start-number)
 480   "Make a new temporary files from the messages in the FOLDER with NUMBERS.
 481 If START-NUMBER is specified, temporary files begin from the number.
 482 Otherwise, same number is used for temporary files.
 483 Return newly created temporary directory name which contains temporary files.")
 484
 485 (luna-define-generic elmo-message-file-p (folder number)
 486   "Return t if message in the FOLDER with NUMBER is a file.")
 487
 488 (luna-define-generic elmo-message-flags (folder number)
 489   "Return a list of flags.
 490 FOLDER is a ELMO folder structure.
 491 NUMBER is a number of the message.")
 492
 493 (defun elmo-message-flags-for-append (folder number &optional message-id)
 494   "Return a list of flags for `elmo-folder-append-buffer'.
 495 FOLDER is a ELMO folder structure.
 496 NUMBER is a number of the message.
 497 If optional argument MESSAGES-ID is not specified, get it from current buffer."
 498   (let ((this-id (elmo-message-field folder number 'message-id)))
 499     (and this-id
 500          (string= this-id (or message-id
 501                               (elmo-msgdb-get-message-id-from-buffer)))
 502          (or (elmo-message-flags folder number)
 503              ;; message exists, but no flag.
 504              '(read)))))
 505
 506 (luna-define-method elmo-message-flag-available-p ((folder elmo-folder) number
 507                                                    flag)
 508   (elmo-msgdb-flag-available-p (elmo-folder-msgdb folder) flag))
 509
 510 (luna-define-method elmo-message-flags ((folder elmo-folder) number)
 511   (elmo-msgdb-flags (elmo-folder-msgdb folder) number))
 512
 513 (defsubst elmo-message-flagged-p (folder number flag)
 514   "Return non-nil if the message is set FLAG.
 515 FOLDER is a ELMO folder structure.
 516 NUMBER is a message number to test."
 517   (let ((cur-flags (elmo-message-flags folder number)))
 518     (case flag
 519       (read
 520        (not (memq 'unread cur-flags)))
 521       (t
 522        (memq flag cur-flags)))))
 523
 524 (luna-define-generic elmo-find-fetch-strategy (folder number
 525                                                       &optional
 526                                                       ignore-cache
 527                                                       require-entireness)
 528   "Return the message fetching strategy suitable for the message with NUMBER.
 529 FOLDER is the ELMO folder structure.
 530 If optional argument IGNORE-CACHE is non-nil, existing cache is ignored.
 531 If second optional argument REQUIRE-ENTIRENESS is non-nil,
 532 ensure that entireness of the returned strategy is entire.
 533 Returned value is a elmo-fetch-strategy object.
 534 If return value is nil, message should not be nil.")
 535
 536 (defmacro elmo-make-fetch-strategy (entireness
 537                                     &optional
 538                                     use-cache
 539                                     save-cache
 540                                     cache-path)
 541   "Make elmo-message-fetching strategy.
 542 ENTIRENESS is 'entire or 'section.
 543 'entire means fetch message entirely at once.
 544 'section means fetch message section by section.
 545 If optional USE-CACHE is non-nil, existing cache is used and otherwise,
 546 existing cache is thrown away.
 547 If SAVE-CACHE is non-nil, fetched message is saved.
 548 CACHE-PATH is the cache path to be used as a message cache file."
 549   `(vector ,entireness ,use-cache ,save-cache ,cache-path))
 550
 551 (defmacro elmo-fetch-strategy-entireness (strategy)
 552   "Return entireness of STRATEGY."
 553   `(aref ,strategy 0))
 554
 555 (defmacro elmo-fetch-strategy-use-cache (strategy)
 556   "Return use-cache of STRATEGY."
 557   `(aref ,strategy 1))
 558
 559 (defmacro elmo-fetch-strategy-save-cache (strategy)
 560   "Return save-cache of STRATEGY."
 561   `(aref ,strategy 2))
 562
 563 (defmacro elmo-fetch-strategy-cache-path (strategy)
 564   "Return cache-path of STRATEGY."
 565   `(aref ,strategy 3))
 566
 567 (luna-define-method elmo-find-fetch-strategy ((folder elmo-folder) number
 568                                               &optional
 569                                               ignore-cache
 570                                               require-entireness)
 571   (let ((entity (elmo-message-entity folder number)))
 572     (if (null entity)
 573         (elmo-make-fetch-strategy 'entire)
 574       (let* ((size (elmo-message-entity-field entity 'size))
 575              (message-id (elmo-message-entity-field entity 'message-id))
 576              (cache-file (elmo-file-cache-get message-id))
 577              (use-cache (elmo-message-use-cache-p folder number)))
 578         (if (and (not ignore-cache)
 579                  use-cache
 580                  (eq (elmo-file-cache-status cache-file) 'entire))
 581             ;; Cache exists and use it.
 582             (elmo-make-fetch-strategy
 583              'entire
 584              t                          ; Use cache.
 585              use-cache                  ; Save cache.
 586              (elmo-file-cache-path cache-file))
 587           ;; No cache or ignore-cache.
 588           (if (and (not (elmo-folder-local-p folder))
 589                    (not require-entireness)
 590                    elmo-message-fetch-threshold
 591                    (integerp size)
 592                    (>= size elmo-message-fetch-threshold)
 593                    (or (not elmo-message-fetch-confirm)
 594                        (not (prog1
 595                                 (y-or-n-p
 596                                  (format "Fetch entire message(%dbytes)? "
 597                                          size))
 598                               (message "")))))
 599               ;; Don't fetch message at all.
 600               nil
 601             ;; Don't use existing cache and fetch entire message at once.
 602             (elmo-make-fetch-strategy
 603              'entire
 604              nil                        ; Don't use cache.
 605              use-cache                  ; Save cache.
 606              (elmo-file-cache-path cache-file))))))))
 607
 608 (luna-define-method elmo-folder-list-messages-internal
 609   ((folder elmo-folder) &optional visible-only)
 610   t)
 611
 612 (luna-define-generic elmo-message-encache (folder number &optional read)
 613   "Encache message in the FOLDER with NUMBER.
 614 If READ is non-nil, message is flaged as read.")
 615
 616 (luna-define-method elmo-message-encache ((folder elmo-folder) number
 617                                           &optional read)
 618   (let (path)
 619     (with-temp-buffer
 620       (elmo-message-fetch
 621        folder number
 622        (elmo-make-fetch-strategy 'entire
 623                                  nil ;use-cache
 624                                  t   ;save-cache
 625                                  (setq path (elmo-file-cache-get-path
 626                                              (elmo-message-field
 627                                               folder number 'message-id))))
 628        (not read)))
 629     path))
 630
 631 (luna-define-generic elmo-message-fetch-bodystructure (folder number strategy)
 632   "Fetch bodystructure of the message in FOLDER with NUMBER using STRATEGY.")
 633
 634 (luna-define-generic elmo-message-fetch (folder number strategy
 635                                                 &optional
 636                                                 unread
 637                                                 section)
 638   "Fetch a message into current buffer.
 639 FOLDER is the ELMO folder structure.
 640 NUMBER is the number of the message in the FOLDER.
 641 STRATEGY is the message fetching strategy.
 642 If optional argument UNREAD is non-nil, message is not flaged as read.
 643 If second optional argument SECTION is specified, only the
 644 SECTION of the message is fetched (if possible).
 645 Returns non-nil if fetching was succeed.")
 646
 647 (luna-define-generic elmo-message-fetch-internal (folder number strategy
 648                                                          &optional
 649                                                          section
 650                                                          unread)
 651   "Fetch a message into current buffer.
 652 FOLDER is the ELMO folder structure.
 653 NUMBER is the number of the message in the FOLDER.
 654 STRATEGY is the message fetching strategy.
 655 If optional argument SECTION is specified, only the SECTION of the message
 656 is fetched (if possible).
 657 If second optional argument UNREAD is non-nil, message is not flaged as read.
 658 Returns non-nil if fetching was succeed.")
 659
 660 (luna-define-generic elmo-message-fetch-field (folder number field)
 661   "Fetch a message field value.
 662 FOLDER is the ELMO folder structure.
 663 NUMBER is the number of the message in the FOLDER.
 664 FIELD is a symbol of the field name.")
 665
 666 (luna-define-generic elmo-message-folder (folder number)
 667   "Get primitive folder of the message.")
 668
 669 (luna-define-generic elmo-folder-process-crosspost (folder)
 670   "Process crosspost for FOLDER.
 671 Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).")
 672
 673 (luna-define-generic elmo-folder-newsgroups (folder)
 674   "Return list of newsgroup name of FOLDER.")
 675
 676 (luna-define-generic elmo-folder-search-requires-msgdb-p (folder condition)
 677   "Return non-nil if searching in FOLDER by CONDITION requires msgdb fetch.")
 678
 679 (defun elmo-folder-search-requires-msgdb-p-internal (folder condition)
 680   (if (listp condition)
 681       (or (elmo-folder-search-requires-msgdb-p-internal
 682            folder (nth 1 condition))
 683           (elmo-folder-search-requires-msgdb-p-internal
 684            folder (nth 2 condition)))
 685     (and (not (string= (elmo-filter-key condition) "last"))
 686          (not (string= (elmo-filter-key condition) "first")))))
 687
 688 (luna-define-method elmo-folder-search-requires-msgdb-p ((folder elmo-folder)
 689                                                          condition)
 690   (elmo-folder-search-requires-msgdb-p-internal folder condition))
 691
 692 (luna-define-method elmo-folder-newsgroups ((folder elmo-folder))
 693   nil)
 694
 695 (luna-define-method elmo-folder-open ((folder elmo-folder)
 696                                       &optional load-msgdb)
 697   (elmo-generic-folder-open folder load-msgdb))
 698
 699 (defun elmo-generic-folder-open (folder load-msgdb)
 700   (let ((inhibit-quit t))
 701     (if load-msgdb (elmo-folder-msgdb folder))
 702     (elmo-folder-set-killed-list-internal
 703      folder
 704      (elmo-msgdb-killed-list-load (elmo-folder-msgdb-path folder))))
 705   (elmo-folder-open-internal folder))
 706
 707 (luna-define-method elmo-folder-open-internal ((folder elmo-folder))
 708   nil ; default is do nothing.
 709   )
 710
 711 (luna-define-method elmo-folder-check ((folder elmo-folder))
 712   nil) ; default is noop.
 713
 714 (luna-define-method elmo-folder-commit ((folder elmo-folder))
 715   (elmo-generic-folder-commit folder))
 716
 717 (defun elmo-generic-folder-commit (folder)
 718   (when (elmo-folder-persistent-p folder)
 719     (let ((msgdb (elmo-folder-msgdb-internal folder)))
 720       (when msgdb
 721         (when (elmo-msgdb-message-modified-p msgdb)
 722           (elmo-folder-set-info-max-by-numdb
 723            folder
 724            (elmo-folder-list-messages folder nil 'in-msgdb)))
 725         (elmo-msgdb-save msgdb)))
 726     (elmo-msgdb-killed-list-save
 727      (elmo-folder-msgdb-path folder)
 728      (elmo-folder-killed-list-internal folder))))
 729
 730 (luna-define-method elmo-folder-close-internal ((folder elmo-folder))
 731   ;; do nothing.
 732   )
 733
 734 (luna-define-method elmo-folder-close ((folder elmo-folder))
 735   (elmo-generic-folder-close folder)
 736   (elmo-folder-close-internal folder))
 737
 738 (defun elmo-generic-folder-close (folder)
 739   (elmo-folder-commit folder)
 740   (elmo-folder-set-msgdb-internal folder nil)
 741   (elmo-folder-set-killed-list-internal folder nil))
 742
 743 (luna-define-method elmo-folder-plugged-p ((folder elmo-folder))
 744   t) ; default is plugged.
 745
 746 (luna-define-method elmo-folder-set-plugged ((folder elmo-folder) plugged
 747                                              &optional add)
 748   nil) ; default is do nothing.
 749
 750 (luna-define-method elmo-folder-use-flag-p ((folder elmo-folder))
 751   nil) ; default is no flag.
 752
 753 (luna-define-method elmo-folder-persistent-p ((folder elmo-folder))
 754   (elmo-folder-persistent-internal folder))
 755
 756 (luna-define-method elmo-folder-creatable-p ((folder elmo-folder))
 757   nil) ; default is not creatable.
 758
 759 (luna-define-method elmo-folder-writable-p ((folder elmo-folder))
 760   nil) ; default is not writable.
 761
 762 (luna-define-method elmo-folder-delete ((folder elmo-folder))
 763   (when (yes-or-no-p (format "Delete msgdb of \"%s\"? "
 764                              (elmo-folder-name-internal folder)))
 765     (elmo-msgdb-delete-path folder)
 766     t))
 767
 768 (luna-define-method elmo-folder-rename ((folder elmo-folder) new-name)
 769   (let* ((new-folder (elmo-make-folder new-name)))
 770     (unless (eq (elmo-folder-type-internal folder)
 771                 (elmo-folder-type-internal new-folder))
 772       (error "Not same folder type"))
 773     (if (or (file-exists-p (elmo-folder-msgdb-path new-folder))
 774             (elmo-folder-exists-p new-folder))
 775         (error "Already exists folder: %s" new-name))
 776     (elmo-folder-send folder 'elmo-folder-rename-internal new-folder)
 777     (elmo-msgdb-rename-path folder new-folder)))
 778
 779 (luna-define-method elmo-folder-delete-messages ((folder elmo-folder)
 780                                                  numbers)
 781   (and (elmo-folder-delete-messages-internal folder numbers)
 782        (elmo-folder-detach-messages folder numbers)))
 783
 784 (luna-define-method elmo-folder-search ((folder elmo-folder)
 785                                         condition
 786                                         &optional numbers)
 787   (let ((numbers (or numbers (elmo-folder-list-messages folder)))
 788         (msgdb (elmo-folder-msgdb folder))
 789         results)
 790     (setq results (elmo-msgdb-search msgdb condition numbers))
 791     (if (listp results)
 792         results
 793       (let ((len (length numbers))
 794             matched)
 795         (elmo-with-progress-display (> len elmo-display-progress-threshold)
 796             (elmo-folder-search len "Searching...")
 797           (dolist (number numbers)
 798             (let (result)
 799               (setq result (elmo-msgdb-match-condition msgdb
 800                                                        condition
 801                                                        number
 802                                                        numbers))
 803               (when (elmo-filter-condition-p result)
 804                 (setq result (elmo-message-match-condition folder
 805                                                            number
 806                                                            condition
 807                                                            numbers)))
 808               (when result
 809                 (setq matched (cons number matched))))
 810             (elmo-progress-notify 'elmo-folder-search)))
 811         (message "Searching...done")
 812         (nreverse matched)))))
 813
 814 (luna-define-method elmo-message-match-condition ((folder elmo-folder)
 815                                                   number condition
 816                                                   numbers)
 817   (let* (cache cache-path
 818          (filename (cond
 819                     ((elmo-message-file-name folder number))
 820                     ((progn
 821                        (setq cache (elmo-file-cache-get
 822                                     (elmo-message-field folder number
 823                                                         'message-id)))
 824                        (setq cache-path (elmo-file-cache-path cache))
 825                        (and cache-path
 826                             (not (elmo-cache-path-section-p cache-path))))
 827                      cache-path))))
 828     (when (and filename (file-readable-p filename))
 829       (with-temp-buffer
 830         (set-buffer-multibyte nil)
 831         ;;(insert-file-contents-as-binary filename)
 832         (elmo-message-fetch folder number
 833                             (elmo-make-fetch-strategy 'entire
 834                                                       (and cache t)
 835                                                       nil
 836                                                       cache-path)
 837                             'unread)
 838         (set-buffer-multibyte default-enable-multibyte-characters)
 839         (decode-coding-region (point-min) (point-max)
 840                               elmo-mime-display-as-is-coding-system)
 841         (elmo-buffer-field-condition-match condition number numbers)))))
 842
 843 (luna-define-method elmo-folder-pack-numbers ((folder elmo-folder))
 844   nil) ; default is noop.
 845
 846 (luna-define-method elmo-folder-update-number ((folder elmo-folder))
 847   nil) ; default is noop.
 848
 849 (luna-define-method elmo-folder-message-file-p ((folder elmo-folder))
 850   nil) ; default is not file.
 851
 852 (luna-define-method elmo-folder-message-file-number-p ((folder elmo-folder))
 853   nil) ; default is not number.
 854
 855 (luna-define-method elmo-folder-message-make-temp-file-p ((folder elmo-folder))
 856   nil) ; default is not make temp file.
 857
 858 (luna-define-method elmo-message-file-name ((folder elmo-folder)
 859                                                    number)
 860   nil) ; default is no name.
 861
 862 (luna-define-method elmo-folder-local-p ((folder elmo-folder))
 863   t)   ; default is local.
 864
 865 (luna-define-method elmo-folder-have-subfolder-p ((folder elmo-folder))
 866   t)
 867
 868 ;; Flag table
 869 (luna-define-generic elmo-folder-flag-table (folder &optional if-exists)
 870   "Return the flag-table of FOLDER.
 871 If optional argument IF-EXISTS is nil, load on demand.
 872 \(For internal use only.\)")
 873
 874 (luna-define-generic elmo-folder-close-flag-table (folder)
 875   "Close flag-table of FOLDER.")
 876
 877 (luna-define-method elmo-folder-flag-table ((folder elmo-folder)
 878                                             &optional if-exists)
 879   (or (elmo-folder-flag-table-internal folder)
 880       (unless if-exists
 881         (elmo-folder-set-flag-table-internal
 882          folder
 883          (elmo-flag-table-load (elmo-folder-msgdb-path folder))))))
 884
 885 (luna-define-method elmo-folder-close-flag-table ((folder elmo-folder))
 886   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
 887                         (elmo-folder-flag-table folder))
 888   (elmo-folder-set-flag-table-internal folder nil))
 889
 890 (defun elmo-folder-preserve-flags (folder msgid flags)
 891   "Preserve FLAGS into FOLDER for a message that has MSGID."
 892   (when (and msgid flags)
 893     (let ((flag-table (elmo-folder-flag-table folder 'if-exists))
 894           load-now)
 895       (when (setq load-now (null flag-table))
 896         (setq flag-table (elmo-folder-flag-table folder)))
 897       (elmo-flag-table-set flag-table msgid flags)
 898       (when load-now
 899         (elmo-folder-close-flag-table folder)))))
 900
 901 ;;; Folder info
 902 ;; Folder info is a message number information cache (hashtable)
 903 (defsubst elmo-folder-get-info (folder &optional hashtb)
 904   "Return FOLDER info from HASHTB (default is `elmo-folder-info-hashtb')."
 905   (elmo-get-hash-val (elmo-folder-name-internal folder)
 906                      (or hashtb elmo-folder-info-hashtb)))
 907
 908 (defun elmo-folder-set-info-hashtb (folder max numbers &optional new unread)
 909   "Set FOLDER info (means MAX, NUMBERS, NEW and UNREAD)."
 910   (let ((info (elmo-folder-get-info folder)))
 911     (when info
 912       (or new     (setq new     (nth 0 info)))
 913       (or unread  (setq unread  (nth 1 info)))
 914       (or numbers (setq numbers (nth 2 info)))
 915       (or max     (setq max     (nth 3 info))))
 916     (elmo-set-hash-val (elmo-folder-name-internal folder)
 917                        (list new unread numbers max)
 918                        elmo-folder-info-hashtb)))
 919
 920 (defun elmo-folder-set-info-max-by-numdb (folder numbers)
 921   "Set FOLDER info by MSGDB-NUMBER in msgdb."
 922   (elmo-folder-set-info-hashtb
 923    folder
 924    (if numbers (apply #'max numbers) 0)
 925    nil ;;(length num-db)
 926    ))
 927
 928 (defun elmo-folder-get-info-max (folder)
 929   "Return max number of FODLER from folder info."
 930   (nth 3 (elmo-folder-get-info folder)))
 931
 932 (defun elmo-folder-get-info-length (folder)
 933   "Return length of FODLER from folder info."
 934   (nth 2 (elmo-folder-get-info folder)))
 935
 936 (defun elmo-folder-get-info-unread (folder)
 937   "Return unread of FODLER from folder info."
 938   (nth 1 (elmo-folder-get-info folder)))
 939
 940 (defun elmo-folder-info-make-hashtb (info-alist hashtb)
 941   "Setup folder info hashtable by INFO-ALIST on HASHTB."
 942   (let* ((hashtb (or hashtb
 943                      (elmo-make-hash (length info-alist)))))
 944     (mapcar
 945      (lambda (x)
 946        (let ((info (cadr x)))
 947          (and (intern-soft (car x) hashtb)
 948               (elmo-set-hash-val (car x)
 949                                  (list (nth 2 info)   ;; new
 950                                        (nth 3 info)   ;; unread
 951                                        (nth 1 info)   ;; length
 952                                        (nth 0 info))  ;; max
 953                                  hashtb))))
 954      info-alist)
 955     (setq elmo-folder-info-hashtb hashtb)))
 956
 957 (defsubst elmo-diff-new (diff)
 958   (car diff))
 959
 960 (defsubst elmo-diff-unread (diff)
 961   (when (consp (cdr diff))
 962     (nth 1 diff)))
 963
 964 (defsubst elmo-diff-all (diff)
 965   (if (consp (cdr diff))
 966       (nth 2 diff)
 967     (cdr diff)))
 968
 969 (defsubst elmo-strict-folder-diff (folder)
 970   "Return folder diff information strictly from FOLDER."
 971   (let ((in-db (sort (elmo-folder-list-messages folder nil 'in-msgdb) '<))
 972         (in-folder  (elmo-folder-list-messages folder))
 973         append-list delete-list diff)
 974     (cons (if (equal in-folder in-db)
 975               0
 976             (setq diff (elmo-list-diff in-folder in-db nil))
 977             (setq append-list (car diff))
 978             (setq delete-list (cadr diff))
 979             (if append-list
 980                 (length append-list)
 981               (if delete-list
 982                   (- 0 (length delete-list))
 983                 0)))
 984           (length in-folder))))
 985
 986 (luna-define-method elmo-folder-diff ((folder elmo-folder))
 987   (elmo-generic-folder-diff folder))
 988
 989 (defun elmo-generic-folder-diff (folder)
 990   (if (elmo-string-match-member (elmo-folder-name-internal folder)
 991                                 elmo-strict-diff-folder-list)
 992       (elmo-strict-folder-diff folder)
 993     (let ((cached-in-db-max (elmo-folder-get-info-max folder))
 994           (in-folder (elmo-folder-status folder))
 995           (in-db t)
 996           unsync messages
 997           in-db-max)
 998       (if (not cached-in-db-max)
 999           (let ((number-list (elmo-folder-list-messages folder
1000                                                         nil 'in-msgdb)))
1001             ;; No info-cache.
1002             (setq in-db number-list)
1003             (setq in-db-max (if in-db (apply #'max in-db) 0))
1004             (elmo-folder-set-info-hashtb folder in-db-max nil))
1005         (setq in-db-max cached-in-db-max))
1006       (setq unsync (if (and in-db (car in-folder))
1007                        (- (car in-folder) in-db-max)
1008                      (if (and in-folder (null in-db))
1009                          (cdr in-folder)
1010                        (car in-folder))))
1011       (setq messages (cdr in-folder))
1012       (if (and unsync messages (> unsync messages))
1013           (setq unsync messages))
1014       (cons (or unsync 0) (or messages 0)))))
1015
1016 (defvar elmo-folder-diff-async-callback nil)
1017 (defvar elmo-folder-diff-async-callback-data nil)
1018
1019 (luna-define-method elmo-folder-diff-async ((folder elmo-folder))
1020   (and elmo-folder-diff-async-callback
1021        (funcall elmo-folder-diff-async-callback
1022                 folder
1023                 (elmo-folder-diff folder))))
1024
1025 (luna-define-method elmo-folder-get-primitive-list ((folder elmo-folder))
1026   (list folder))
1027
1028 (luna-define-method elmo-folder-contains-type ((folder elmo-folder) type)
1029   (eq (elmo-folder-type-internal folder) type))
1030
1031 (luna-define-method elmo-folder-next-message-number ((folder elmo-folder))
1032   (+ 1 (elmo-max-of-list (or (elmo-folder-list-messages folder)
1033                              '(0)))))
1034
1035 (luna-define-method elmo-folder-append-messages ((folder elmo-folder)
1036                                                  src-folder
1037                                                  numbers
1038                                                  &optional
1039                                                  same-number)
1040   (elmo-generic-folder-append-messages folder src-folder numbers
1041                                        same-number))
1042
1043 (defun elmo-generic-folder-append-messages (folder src-folder numbers
1044                                                    same-number)
1045   (let ((src-msgdb-exists (not (zerop (elmo-folder-length src-folder))))
1046         unseen table
1047         succeed-numbers failure cache id)
1048     (setq table (elmo-folder-flag-table folder))
1049     (with-temp-buffer
1050       (set-buffer-multibyte nil)
1051       (while numbers
1052         (setq failure nil
1053               id (and src-msgdb-exists
1054                       (elmo-message-field src-folder (car numbers)
1055                                           'message-id)))
1056         (condition-case nil
1057             (setq cache (elmo-file-cache-get id)
1058                   failure
1059                   (not
1060                    (and
1061                     (elmo-message-fetch
1062                      src-folder (car numbers)
1063                      (if (elmo-folder-plugged-p src-folder)
1064                          (elmo-make-fetch-strategy
1065                           'entire 'maybe nil
1066                           (and cache (elmo-file-cache-path cache)))
1067                        (or (and elmo-enable-disconnected-operation
1068                                 cache
1069                                 (eq (elmo-file-cache-status cache) 'entire)
1070                                 (elmo-make-fetch-strategy
1071                                  'entire t nil
1072                                  (elmo-file-cache-path cache)))
1073                            (error "Unplugged")))
1074                      'unread)
1075                     (> (buffer-size) 0)
1076                     (elmo-folder-append-buffer
1077                      folder
1078                      (elmo-message-flags-for-append src-folder (car numbers))
1079                      (if same-number (car numbers))))))
1080           (error (setq failure t)))
1081         ;; FETCH & APPEND finished
1082         (unless failure
1083           (setq succeed-numbers (cons (car numbers) succeed-numbers)))
1084         (elmo-progress-notify 'elmo-folder-move-messages)
1085         (setq numbers (cdr numbers)))
1086       (when (elmo-folder-persistent-p folder)
1087         (elmo-folder-close-flag-table folder))
1088       succeed-numbers)))
1089
1090 ;; Arguments should be reduced.
1091 (defun elmo-folder-move-messages (src-folder msgs dst-folder
1092                                              &optional
1093                                              no-delete
1094                                              same-number)
1095   (save-excursion
1096     (let* ((messages msgs)
1097            (elmo-inhibit-display-retrieval-progress t)
1098            (len (length msgs))
1099            succeeds i result)
1100       (if (eq dst-folder 'null)
1101           (setq succeeds messages)
1102         (unless (elmo-folder-writable-p dst-folder)
1103           (error "move: %d is not writable"
1104                  (elmo-folder-name-internal dst-folder)))
1105         (when messages
1106           ;; src is already opened.
1107           (elmo-folder-open-internal dst-folder)
1108           (unless (setq succeeds (elmo-folder-append-messages dst-folder
1109                                                               src-folder
1110                                                               messages
1111                                                               same-number))
1112             (error "move: append message to %s failed"
1113                    (elmo-folder-name-internal dst-folder)))
1114           (elmo-folder-close dst-folder)))
1115       (if (and (not no-delete) succeeds)
1116           (progn
1117             (if (elmo-folder-delete-messages src-folder succeeds)
1118                 (progn
1119                   (elmo-global-flag-detach-messages
1120                    src-folder succeeds (eq dst-folder 'null))
1121                   (setq result t))
1122               (message "move: delete messages from %s failed."
1123                        (elmo-folder-name-internal src-folder))
1124               (setq result nil))
1125             result)
1126         (if no-delete
1127             (progn
1128               ;; (message "Copying messages...done")
1129               t)
1130           (if (eq len 0)
1131               (message "No message was moved.")
1132             (message "Moving messages failed.")
1133             nil ; failure
1134             ))))))
1135
1136 (defun elmo-folder-msgdb-path (folder)
1137   "Return the msgdb path for FOLDER."
1138   (or (elmo-folder-path-internal folder)
1139       (elmo-folder-set-path-internal
1140        folder
1141        (if (null elmo-msgdb-path-encode-threshold)
1142            (elmo-folder-expand-msgdb-path folder)
1143          (let* ((path (directory-file-name
1144                        (elmo-folder-expand-msgdb-path folder)))
1145                 (dirname (file-name-nondirectory path)))
1146            (if (<= (length dirname) elmo-msgdb-path-encode-threshold)
1147                path
1148              (require 'md5)
1149              (setq dirname (md5 dirname))
1150              (when (> (length dirname) elmo-msgdb-path-encode-threshold)
1151                (error "Cannot shrink msgdb path for `%s'"
1152                       (elmo-folder-name-internal folder)))
1153              (expand-file-name dirname (file-name-directory path))))))))
1154
1155 (luna-define-generic elmo-message-cached-p (folder number)
1156   "Return non-nil if the message is cached.")
1157
1158 (luna-define-method elmo-message-cached-p ((folder elmo-folder) number)
1159   (elmo-message-flagged-p folder number 'cached))
1160
1161 (defun elmo-message-accessible-p (folder number)
1162   "Get accessibility of the message.
1163 Return non-nil when message is accessible."
1164   (or (elmo-folder-plugged-p folder)
1165       (elmo-folder-local-p folder)
1166       (< number 0) ; in dop spool
1167       (elmo-message-cached-p folder number)))
1168
1169 (luna-define-generic elmo-message-set-cached (folder number cached)
1170   "Set cache status of the message in the msgdb.
1171 FOLDER is the ELMO folder structure.
1172 NUMBER is a number of the message.
1173 If CACHED is t, message is set as cached.")
1174
1175 (luna-define-method elmo-message-set-cached ((folder elmo-folder)
1176                                              number cached)
1177   (if cached
1178       (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number 'cached)
1179     (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number 'cached))
1180   (elmo-emit-signal 'cache-changed folder number))
1181
1182 (defun elmo-message-copy-entity (entity)
1183   (elmo-msgdb-copy-message-entity (elmo-message-entity-handler entity)
1184                                   entity))
1185
1186 (luna-define-generic elmo-message-number (folder message-id)
1187   "Get message number from MSGDB which corresponds to MESSAGE-ID.")
1188
1189 (luna-define-method elmo-message-number ((folder elmo-folder) message-id)
1190   (elmo-msgdb-message-number (elmo-folder-msgdb folder) message-id))
1191
1192 (luna-define-generic elmo-message-entity (folder key)
1193   "Return the message-entity structure which matches to the KEY.
1194 KEY is a number or a string.
1195 A number is for message number in the FOLDER.
1196 A string is for message-id of the message.")
1197
1198 (luna-define-method elmo-message-entity ((folder elmo-folder) key)
1199   (elmo-msgdb-message-entity (elmo-folder-msgdb folder) key))
1200
1201 (luna-define-generic elmo-message-entity-parent (folder entity)
1202   "Return the parent message-entity structure in the FOLDER.
1203 ENTITY is the message-entity to get the parent.")
1204
1205 (luna-define-method elmo-message-entity-parent ((folder elmo-folder) entity)
1206   (elmo-msgdb-get-parent-entity entity (elmo-folder-msgdb folder)))
1207
1208 (put 'elmo-folder-do-each-message-entity 'lisp-indent-function '1)
1209 (def-edebug-spec elmo-folder-do-each-message-entity
1210   ((symbolp form &rest form) &rest form))
1211
1212 (defsubst elmo-folder-list-message-entities (folder)
1213   ;; List all message entities in the FOLDER.
1214   (mapcar
1215    (lambda (number) (elmo-message-entity folder number))
1216    (elmo-folder-list-messages folder nil t))) ; XXX killed-list is not used.
1217
1218 (defmacro elmo-folder-do-each-message-entity (spec &rest form)
1219   "Iterator for message entity in the folder.
1220 \(elmo-folder-do-each-message-entity \(entity folder\)
1221  ... do the process using entity...
1222 \)"
1223   `(dolist (,(car spec) (elmo-folder-list-message-entities ,(car (cdr spec))))
1224      ,@form))
1225
1226 (luna-define-generic elmo-folder-count-flags (folder)
1227   "Count flagged message number in the msgdb of the FOLDER.
1228 Return alist of flag and numbers.
1229 Example:
1230 \(\(new . 10\)
1231   \(unread . 20\)
1232   \(answered . 3\)\)")
1233
1234 (luna-define-method elmo-folder-count-flags ((folder elmo-folder))
1235   (elmo-msgdb-flag-count (elmo-folder-msgdb folder)))
1236
1237 (defun elmo-message-set-flag (folder number flag &optional is-local)
1238   "Set message flag.
1239 FOLDER is a ELMO folder structure.
1240 NUMBER is a message number to set flag.
1241
1242 FLAG is a symbol which is one of the following:
1243   `unread'    (set the message as unread)
1244   `answered'  (set the message as answered)
1245   `important' (set the message as important)
1246 'sugar' flag:
1247   `read'      (remove new and unread flags)
1248 If optional IS-LOCAL is non-nil, update only local (not server) status."
1249   ;; XXX Transitional implementation.
1250   (elmo-folder-set-flag folder (list number) flag is-local))
1251
1252 (defun elmo-message-unset-flag (folder number flag &optional is-local)
1253   "Unset message flag.
1254 FOLDER is a ELMO folder structure.
1255 NUMBER is a message number to set flag.
1256
1257 FLAG is a symbol which is one of the following:
1258   `unread'    (remove unread and new flag)
1259   `answered'  (remove answered flag)
1260   `important' (remove important flag)
1261 'sugar' flag:
1262   `read'      (set unread flag)
1263 If optional IS-LOCAL is non-nil, update only local (not server) status."
1264   ;; XXX Transitional implementation.
1265   (elmo-folder-unset-flag folder (list number) flag is-local))
1266
1267 (luna-define-generic elmo-message-field (folder number field)
1268   "Get message field value in the msgdb.
1269 FOLDER is the ELMO folder structure.
1270 NUMBER is a number of the message.
1271 FIELD is a symbol of the field.")
1272
1273 (luna-define-method elmo-message-field ((folder elmo-folder) number field)
1274   (elmo-msgdb-message-field (elmo-folder-msgdb folder) number field))
1275
1276 (luna-define-generic elmo-message-set-field (folder number field value)
1277   "Set message field value in the msgdb.
1278 FOLDER is the ELMO folder structure.
1279 NUMBER is a number of the message.
1280 FIELD is a symbol of the field.
1281 VALUE is a value to set.")
1282
1283 (luna-define-method elmo-message-set-field ((folder elmo-folder) number
1284                                             field value)
1285   (elmo-message-entity-set-field (elmo-message-entity folder number)
1286                                  field value))
1287
1288 (luna-define-method elmo-message-use-cache-p ((folder elmo-folder) number)
1289   nil) ; default is not use cache.
1290
1291 (luna-define-method elmo-message-folder ((folder elmo-folder) number)
1292   folder) ; default is folder
1293
1294 (luna-define-method elmo-folder-set-flag ((folder elmo-folder)
1295                                           numbers
1296                                           flag
1297                                           &optional is-local)
1298   (when (elmo-folder-msgdb-internal folder)
1299     (dolist (number numbers)
1300       (let ((old-flags (elmo-message-flags folder number)))
1301         (when (elmo-global-flag-p flag)
1302           (let ((message-id (elmo-message-field folder number 'message-id)))
1303             (elmo-global-flag-set flag folder number message-id)))
1304         (elmo-msgdb-set-flag (elmo-folder-msgdb folder) number flag)
1305         (elmo-emit-signal 'flag-changing
1306                           folder
1307                           number
1308                           old-flags
1309                           (elmo-message-flags folder number))))
1310     (elmo-emit-signal 'flag-changed folder numbers)))
1311
1312 (defun elmo-message-has-global-flag-p (folder number)
1313   "Return non-nil when the message in the FOLDER with NUMBER has global flag."
1314   (let ((flags (elmo-message-flags folder number))
1315         result)
1316     (while flags
1317       (when (and (elmo-global-flag-p (car flags))
1318                  (not (memq (car flags) '(answered unread cached))))
1319         (setq result t
1320               flags nil))
1321       (setq flags (cdr flags)))
1322     result))
1323
1324 (defun elmo-message-set-global-flags (folder number flags &optional local)
1325   "Set global flags of the message in the FOLDER with NUMBER as FLAGS.
1326 If Optional LOCAL is non-nil, don't update server flag."
1327   (dolist (flag flags)
1328     (unless (elmo-global-flag-p flag)
1329       (error "Not a global flag")))
1330   (let ((old-flags (elmo-get-global-flags (elmo-message-flags folder number))))
1331     (dolist (flag flags)
1332       (unless (memq flag old-flags)
1333         (elmo-message-set-flag folder number flag local)))
1334     (dolist (flag old-flags)
1335       (unless (memq flag flags)
1336         (elmo-message-unset-flag folder number flag local)))))
1337
1338 (luna-define-method elmo-folder-unset-flag ((folder elmo-folder)
1339                                             numbers
1340                                             flag
1341                                             &optional is-local)
1342   (when (elmo-folder-msgdb-internal folder)
1343     (dolist (number numbers)
1344       (let ((old-flags (elmo-message-flags folder number)))
1345         (when (elmo-global-flag-p flag)
1346           (elmo-global-flag-detach flag folder number 'always))
1347         (elmo-msgdb-unset-flag (elmo-folder-msgdb folder) number flag)
1348         (elmo-emit-signal 'flag-changing
1349                           folder
1350                           number
1351                           old-flags
1352                           (elmo-message-flags folder number))))
1353     (elmo-emit-signal 'flag-changed folder numbers)))
1354
1355 (luna-define-method elmo-folder-process-crosspost ((folder elmo-folder))
1356   ;; Do nothing.
1357   )
1358
1359 ;;(luna-define-generic elmo-folder-append-message-entity (folder entity
1360 ;;                                                             &optional
1361 ;;                                                             flag-table)
1362 ;;  "Append ENTITY to the folder.")
1363
1364 (defun elmo-msgdb-merge (folder msgdb-merge)
1365   "Return a list of messages which have duplicated message-id."
1366   (let (msgdb duplicates)
1367     (setq msgdb (or (elmo-folder-msgdb-internal folder)
1368                     (elmo-make-msgdb (elmo-folder-msgdb-path folder))))
1369     (setq duplicates (elmo-msgdb-append msgdb msgdb-merge))
1370     (elmo-folder-set-msgdb-internal folder msgdb)
1371     duplicates))
1372
1373 (defsubst elmo-folder-append-msgdb (folder append-msgdb)
1374   (if append-msgdb
1375       (let ((duplicates (elmo-msgdb-merge folder append-msgdb)))
1376         (cond ((eq (elmo-folder-process-duplicates-internal folder)
1377                    'hide)
1378                ;; Let duplicates be a temporary killed message.
1379                (elmo-folder-kill-messages folder duplicates)
1380                ;; Should be flag as read.
1381                (elmo-folder-unset-flag folder duplicates 'unread))
1382               ((eq (elmo-folder-process-duplicates-internal folder)
1383                    'read)
1384                ;; Flag as read duplicates.
1385                (elmo-folder-unset-flag folder duplicates 'unread))
1386               (t
1387                ;; Do nothing.
1388                (setq duplicates nil)))
1389         (length duplicates))
1390     0))
1391
1392 (defun elmo-folder-confirm-appends (appends)
1393   (let ((len (length appends))
1394         in)
1395     (if (and elmo-folder-update-threshold
1396              (> len elmo-folder-update-threshold)
1397              elmo-folder-update-confirm)
1398         (if (y-or-n-p (format "Too many messages(%d).  Update all? " len))
1399             appends
1400           (setq in elmo-folder-update-threshold)
1401           (catch 'end
1402             (while t
1403               (setq in (read-from-minibuffer "Update number: "
1404                                              (int-to-string in))
1405                     in (string-to-int in))
1406               (if (< len in)
1407                   (throw 'end len))
1408               (if (y-or-n-p (format
1409                              "%d messages are killed (not appeared). OK? "
1410                              (max (- len in) 0)))
1411                   (throw 'end in))))
1412           (nthcdr (max (- len in) 0) appends))
1413       (if (and elmo-folder-update-threshold
1414                (> len elmo-folder-update-threshold)
1415                (not elmo-folder-update-confirm))
1416           (nthcdr (max (- len elmo-folder-update-threshold) 0) appends)
1417         appends))))
1418
1419 (luna-define-method elmo-message-fetch-bodystructure ((folder elmo-folder)
1420                                                       number strategy)
1421   nil)
1422
1423 (defun elmo-message-fetch-string (folder number strategy
1424                                          &optional
1425                                          unread
1426                                          section)
1427   (with-temp-buffer
1428     (when (elmo-message-fetch folder number strategy unread section)
1429       (buffer-string))))
1430
1431 (luna-define-method elmo-message-fetch ((folder elmo-folder)
1432                                         number strategy
1433                                         &optional
1434                                         unread
1435                                         section)
1436   (erase-buffer)
1437   (let ((cache-path (elmo-fetch-strategy-cache-path strategy))
1438         (method-priorities
1439          (cond ((eq (elmo-fetch-strategy-use-cache strategy) 'maybe)
1440                 '(entity cache))
1441                ((elmo-fetch-strategy-use-cache strategy)
1442                 '(cache entity))
1443                (t
1444                 '(entity))))
1445         result err updated-server-flag)
1446     (while (and method-priorities
1447                 (not result))
1448       (setq result
1449             (case (car method-priorities)
1450               (cache
1451                (elmo-file-cache-load cache-path section))
1452               (entity
1453                (when (condition-case error
1454                          (elmo-message-fetch-internal folder number
1455                                                       strategy
1456                                                       section
1457                                                       unread)
1458                        (error (setq err error) nil))
1459                  (setq updated-server-flag t)
1460                  (when (and (elmo-fetch-strategy-save-cache strategy)
1461                             cache-path)
1462                    (elmo-file-cache-save cache-path section))
1463                  t)))
1464             method-priorities (cdr method-priorities)))
1465     (if result
1466         (when (and (not unread)
1467                    (elmo-message-flagged-p folder number 'unread))
1468           (elmo-message-unset-flag folder number 'unread updated-server-flag))
1469       (when err
1470         (signal (car err) (cdr err))))
1471     result))
1472
1473 (defun elmo-folder-kill-messages-range (folder beg end)
1474   (elmo-folder-set-killed-list-internal
1475    folder
1476    (nconc
1477     (elmo-folder-killed-list-internal folder)
1478     (list (cons beg end)))))
1479
1480 (defun elmo-folder-kill-messages (folder numbers)
1481   "Kill(hide) messages in the FOLDER with NUMBERS."
1482   (elmo-folder-set-killed-list-internal
1483    folder
1484    (elmo-number-set-append-list
1485     (elmo-folder-killed-list-internal folder)
1486     numbers))
1487   (elmo-folder-unset-flag folder numbers 'all 'local-only))
1488
1489 (luna-define-method elmo-folder-clear ((folder elmo-folder)
1490                                        &optional keep-killed)
1491   (unless keep-killed
1492     (elmo-folder-set-killed-list-internal folder nil))
1493   (if (eq elmo-msgdb-convert-type 'sync)
1494       (elmo-folder-set-msgdb-internal
1495        folder
1496        (elmo-make-msgdb (elmo-folder-msgdb-path folder)))
1497     (elmo-msgdb-clear (elmo-folder-msgdb folder))))
1498
1499 (luna-define-generic elmo-folder-synchronize (folder
1500                                               &optional
1501                                               disable-killed
1502                                               ignore-msgdb
1503                                               no-check
1504                                               mask)
1505   "Synchronize the folder data to the newest status.
1506 FOLDER is the ELMO folder structure.
1507
1508 If optional DISABLE-KILLED is non-nil, killed messages are also synchronized.
1509 If optional IGNORE-MSGDB is non-nil, current msgdb is thrown away except
1510 flag status.
1511 If NO-CHECK is non-nil, rechecking folder is skipped.
1512 If optional argument MASK is specified and is a list of message numbers,
1513 synchronize messages only which are contained the list.
1514 Return amount of cross-posted messages.
1515 If update process is interrupted, return nil.")
1516
1517 (luna-define-method elmo-folder-synchronize ((folder elmo-folder)
1518                                              &optional
1519                                              disable-killed
1520                                              ignore-msgdb
1521                                              no-check
1522                                              mask)
1523   (let ((old-msgdb (elmo-folder-msgdb folder))
1524         (killed-list (elmo-folder-killed-list-internal folder))
1525         (flag-table (elmo-flag-table-load (elmo-folder-msgdb-path folder)))
1526         (before-append t))
1527     (when ignore-msgdb
1528       (elmo-msgdb-flag-table (elmo-folder-msgdb folder) flag-table)
1529       (elmo-folder-clear folder (not disable-killed)))
1530     (unless no-check (elmo-folder-check folder))
1531     (condition-case nil
1532         (let ((killed-list (elmo-folder-killed-list-internal folder))
1533               diff-new diff-del
1534               delete-list new-list new-msgdb crossed)
1535           (message "Checking folder diff...")
1536           (elmo-set-list
1537            '(diff-new diff-del)
1538            (elmo-list-diff (elmo-folder-list-messages folder)
1539                            (elmo-folder-list-messages folder nil 'in-msgdb)))
1540           (when diff-new
1541             (unless disable-killed
1542               (setq diff-new (elmo-living-messages diff-new killed-list)))
1543             (when mask
1544               (setq diff-new (elmo-list-filter mask diff-new))))
1545           (message "Checking folder diff...done")
1546           (setq new-list (elmo-folder-confirm-appends diff-new))
1547           ;; Append to killed list as (MIN-OF-DISAPPEARED . MAX-OF-DISAPPEARED)
1548           (when (not (eq (length diff-new)
1549                          (length new-list)))
1550             (let* ((diff (elmo-list-diff diff-new new-list))
1551                    (disappeared (car diff)))
1552               (when disappeared
1553                 (elmo-folder-kill-messages-range folder
1554                                                  (car disappeared)
1555                                                  (elmo-last disappeared)))))
1556           (setq delete-list diff-del)
1557           (if (and (null diff-new) (null diff-del))
1558               (progn
1559                 (elmo-folder-update-number folder)
1560                 (elmo-folder-process-crosspost folder)
1561                 0)                      ; `0' means no updates.
1562             (when delete-list
1563               (elmo-folder-detach-messages folder delete-list))
1564             (when new-list
1565               (elmo-msgdb-out-of-date-messages (elmo-folder-msgdb folder))
1566               (setq new-msgdb (elmo-folder-msgdb-create
1567                                folder new-list flag-table))
1568               ;; Clear flag-table
1569               (if (elmo-folder-persistent-p folder)
1570                   (elmo-flag-table-save (elmo-folder-msgdb-path folder)
1571                                         nil))
1572               (setq before-append nil)
1573               (setq crossed (elmo-folder-append-msgdb folder new-msgdb))
1574               ;; process crosspost.
1575               ;; Return a cons cell of (NUMBER-CROSSPOSTS . NEW-FLAG-ALIST).
1576               (elmo-folder-process-crosspost folder))
1577             ;; return value.
1578             (or crossed 0)))
1579       (quit
1580        ;; Resume to the original status.
1581        (if before-append (elmo-folder-set-msgdb-internal folder old-msgdb))
1582        (elmo-folder-set-killed-list-internal folder killed-list)
1583        nil))))
1584
1585 (luna-define-generic elmo-folder-detach-messages (folder numbers)
1586   "Remove messages with NUMBERS from MSGDB.")
1587
1588 (luna-define-method elmo-folder-detach-messages ((folder elmo-folder)
1589                                                  numbers)
1590   (when (elmo-msgdb-delete-messages (elmo-folder-msgdb folder) numbers)
1591     ;; Remove NUMBERS from killed message list.
1592     (elmo-folder-set-killed-list-internal
1593      folder
1594      (elmo-number-set-delete-list
1595       (elmo-folder-killed-list-internal folder)
1596       numbers))
1597     t))
1598
1599 (luna-define-generic elmo-folder-length (folder)
1600   "Return number of messages in the FOLDER.")
1601
1602 (luna-define-method elmo-folder-length ((folder elmo-folder))
1603   (if (elmo-folder-msgdb-internal folder)
1604       (elmo-msgdb-length (elmo-folder-msgdb folder))
1605     0))
1606
1607 (defun elmo-folder-msgdb-load (folder &optional silent)
1608   (unless silent
1609     (message "Loading msgdb for %s..." (elmo-folder-name-internal folder)))
1610   (let ((msgdb (elmo-load-msgdb (elmo-folder-msgdb-path folder))))
1611     (elmo-folder-set-info-max-by-numdb
1612      folder
1613      (elmo-msgdb-list-messages msgdb))
1614     (unless silent
1615       (message "Loading msgdb for %s...done"
1616                (elmo-folder-name-internal folder)))
1617     msgdb))
1618
1619 (defun elmo-msgdb-delete-path (folder)
1620   (let ((path (elmo-folder-msgdb-path folder)))
1621     (if (file-directory-p path)
1622         (elmo-delete-directory path t))))
1623
1624 (defun elmo-msgdb-rename-path (old-folder new-folder)
1625   (let* ((old (directory-file-name (elmo-folder-msgdb-path old-folder)))
1626          (new (directory-file-name (elmo-folder-msgdb-path new-folder)))
1627          (new-dir (directory-file-name (file-name-directory new))))
1628     (if (not (file-directory-p old))
1629         ()
1630       (if (file-exists-p new)
1631           (error "Already exists directory: %s" new)
1632         (if (not (file-exists-p new-dir))
1633             (elmo-make-directory new-dir))
1634         (rename-file old new)))))
1635
1636 (defun elmo-setup-subscribed-newsgroups (groups)
1637   "Setup subscribed newsgroups.
1638 GROUPS is a list of newsgroup name string.
1639 Return a hashtable for newsgroups."
1640   (let ((hashtb (or elmo-newsgroups-hashtb
1641                     (setq elmo-newsgroups-hashtb
1642                           (elmo-make-hash (length groups))))))
1643     (dolist (group groups)
1644       (or (elmo-get-hash-val group hashtb)
1645           (elmo-set-hash-val group nil hashtb)))
1646     (setq elmo-newsgroups-hashtb hashtb)))
1647
1648 (defvar elmo-crosspost-message-alist-modified nil)
1649 (defun elmo-crosspost-message-alist-load ()
1650   "Load crosspost message alist."
1651   (setq elmo-crosspost-message-alist (elmo-crosspost-alist-load))
1652   (setq elmo-crosspost-message-alist-modified nil))
1653
1654 (defun elmo-crosspost-message-alist-save ()
1655   "Save crosspost message alist."
1656   (when elmo-crosspost-message-alist-modified
1657     (let ((alist elmo-crosspost-message-alist)
1658           newsgroups)
1659       (while alist
1660         (setq newsgroups
1661               (elmo-delete-if
1662                '(lambda (x)
1663                   (not (intern-soft x elmo-newsgroups-hashtb)))
1664                (nth 1 (car alist))))
1665         (if newsgroups
1666             (setcar (cdar alist) newsgroups)
1667           (setq elmo-crosspost-message-alist
1668                 (delete (car alist) elmo-crosspost-message-alist)))
1669         (setq alist (cdr alist)))
1670       (elmo-crosspost-alist-save elmo-crosspost-message-alist)
1671       (setq elmo-crosspost-message-alist-modified nil))))
1672
1673 (defun elmo-folder-make-temporary-directory (folder)
1674   ;; Make a temporary directory for FOLDER.
1675   (let ((temp-dir (make-temp-name
1676                    (concat
1677                     (file-name-as-directory (elmo-folder-msgdb-path folder))
1678                     "elmo"))))
1679     (elmo-make-directory temp-dir)
1680     temp-dir))
1681
1682 ;;;
1683 (defun elmo-init ()
1684   "Initialize ELMO module."
1685   (elmo-crosspost-message-alist-load)
1686   (elmo-resque-obsolete-variables)
1687   (elmo-dop-queue-load)
1688   (run-hooks 'elmo-init-hook))
1689
1690 (defun elmo-quit ()
1691   "Quit and cleanup ELMO."
1692   (elmo-crosspost-message-alist-save)
1693   (elmo-dop-queue-save)
1694   ;; Not implemented yet.
1695   (let ((types elmo-folder-type-alist)
1696         class)
1697     (while types
1698       (setq class
1699             (luna-find-class
1700              (intern (format "elmo-%s-folder"
1701                              (symbol-name (cdr (car types)))))))
1702       ;; Call all folder's `elmo-quit' method.
1703       (if class
1704           (dolist (func (luna-class-find-functions class 'elmo-quit))
1705             (funcall func nil)))
1706       (setq types (cdr types)))))
1707
1708 (luna-define-method elmo-folder-rename-internal ((folder elmo-folder)
1709                                                  new-folder)
1710   (error "Cannot rename %s folder"
1711          (symbol-name (elmo-folder-type-internal folder))))
1712
1713 ;;; Define folders.
1714 (elmo-define-folder ?% 'imap4)
1715 (elmo-define-folder ?-  'nntp)
1716 (elmo-define-folder ?\+ 'localdir)
1717 (elmo-define-folder ?\* 'multi)
1718 (elmo-define-folder ?\/ 'filter)
1719 (elmo-define-folder ?\$ 'archive)
1720 (elmo-define-folder ?&  'pop3)
1721 (elmo-define-folder ?=  'localnews)
1722 (elmo-define-folder ?|  'pipe)
1723 (elmo-define-folder ?.  'maildir)
1724 (elmo-define-folder ?'  'internal)
1725 (elmo-define-folder ?\[  'nmz)
1726 (elmo-define-folder ?@  'shimbun)
1727
1728 ;;; Obsolete variables.
1729 (elmo-define-obsolete-variable 'elmo-default-imap4-mailbox
1730                                'elmo-imap4-default-mailbox)
1731 (elmo-define-obsolete-variable 'elmo-default-imap4-server
1732                                'elmo-imap4-default-server)
1733 (elmo-define-obsolete-variable 'elmo-default-imap4-authenticate-type
1734                                'elmo-imap4-default-authenticate-type)
1735 (elmo-define-obsolete-variable 'elmo-default-imap4-user
1736                                'elmo-imap4-default-user)
1737 (elmo-define-obsolete-variable 'elmo-default-imap4-port
1738                                'elmo-imap4-default-port)
1739 (elmo-define-obsolete-variable 'elmo-default-imap4-stream-type
1740                                'elmo-imap4-default-stream-type)
1741 (elmo-define-obsolete-variable 'elmo-default-nntp-server
1742                                'elmo-nntp-default-server)
1743 (elmo-define-obsolete-variable 'elmo-default-nntp-user
1744                                'elmo-nntp-default-user)
1745 (elmo-define-obsolete-variable 'elmo-default-nntp-port
1746                                'elmo-nntp-default-port)
1747 (elmo-define-obsolete-variable 'elmo-default-nntp-stream-type
1748                                'elmo-nntp-default-stream-type)
1749 (elmo-define-obsolete-variable 'elmo-default-pop3-server
1750                                'elmo-pop3-default-server)
1751 (elmo-define-obsolete-variable 'elmo-default-pop3-user
1752                                'elmo-pop3-default-user)
1753 (elmo-define-obsolete-variable 'elmo-default-pop3-authenticate-type
1754                                'elmo-pop3-default-authenticate-type)
1755 (elmo-define-obsolete-variable 'elmo-default-pop3-port
1756                                'elmo-pop3-default-port)
1757 (elmo-define-obsolete-variable 'elmo-default-pop3-stream-type
1758                                'elmo-pop3-default-stream-type)
1759 (elmo-define-obsolete-variable 'elmo-cache-dirname
1760                                'elmo-cache-directory)
1761 (elmo-define-obsolete-variable 'elmo-msgdb-dir
1762                                'elmo-msgdb-directory)
1763 (elmo-define-obsolete-variable 'elmo-global-flag-list
1764                                'elmo-global-flags)
1765
1766 ;; Obsolete functions.
1767 ;; 2001-12-11: *-dir -> *-directory
1768 (defalias 'elmo-folder-make-temp-dir 'elmo-folder-make-temporary-directory)
1769 (make-obsolete 'elmo-folder-make-temp-dir
1770                'elmo-folder-make-temporary-directory)
1771
1772 (require 'product)
1773 (product-provide (provide 'elmo) (require 'elmo-version))
1774
1775 ;;; elmo.el ends here