wl/wl-e21.el

   1 ;;; wl-e21.el --- Wanderlust modules for Emacs 21.
   2
   3 ;; Copyright (C) 2000,2001 Katsumi Yamaoka <yamaoka@jpl.org>
   4 ;; Copyright (C) 2000,2001 Yuuichi Teranishi <teranisi@gohome.org>
   5
   6 ;; Author: Katsumi Yamaoka <yamaoka@jpl.org>
   7 ;; Keywords: mail, net news
   8
   9 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
  10
  11 ;; This program is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; This program is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25 ;;
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This module uses `before-string' overlay property to show icon
  30 ;; images instead of `insert-image', so don't delete such overlays
  31 ;; sloppily.  Here is a sample code to show icons in the buffer.
  32 ;;
  33 ;;(let (image icon from to overlay)
  34 ;;  ;; The function `find-image' will look for an image first on `load-path'
  35 ;;  ;; and then in `data-directory'.
  36 ;;  (let ((load-path (cons wl-icon-directory load-path)))
  37 ;;    (setq image (find-image (list (list :type 'xpm :file wl-nntp-folder-icon
  38 ;;                                      :ascent 'center)))))
  39 ;;  ;; `propertize' is a convenient function in such a case.
  40 ;;  ;; String must have one or more length to wear an image.
  41 ;;  (setq icon (propertize "any string" 'display image))
  42 ;;  (pop-to-buffer (get-buffer-create "*wl-e21-demo*"))
  43 ;;  (erase-buffer)
  44 ;;  (insert "   ")
  45 ;;  (setq from (point))
  46 ;;  (insert "-fj.wanderlust:0/0/0")
  47 ;;  (setq to (point))
  48 ;;  (insert "\n")
  49 ;;  (setq overlay (make-overlay from to))
  50 ;;  ;; Put an image.
  51 ;;  (overlay-put overlay 'before-string icon)
  52 ;;  ;; Put a mark to indicate that this overlay is made by `wl-e21'.
  53 ;;  ;; It is not always necessarily.
  54 ;;  (overlay-put overlay 'wl-e21-icon t)
  55 ;;  ;; Make it to be removable.
  56 ;;  (overlay-put overlay 'evaporate t))
  57 ;;
  58 ;; Note that a port of Emacs to some platforms (e.g. MS-Windoze) does
  59 ;; not yet support images.  It is a pity that neither icons nor tool-
  60 ;; bars will not be displayed in such systems.
  61
  62 ;;; Code:
  63 ;;
  64
  65 (require 'elmo)
  66 (eval-when-compile
  67   (require 'wl-folder)
  68   (require 'wl-summary)
  69   (require 'wl-draft)
  70   (require 'wl-message)
  71   (require 'wl-highlight)
  72   (defvar-maybe wl-draft-mode-map (make-sparse-keymap)))
  73
  74 (add-hook 'wl-folder-mode-hook 'wl-setup-folder)
  75 (add-hook 'wl-folder-mode-hook 'wl-folder-init-icons)
  76
  77 (add-hook 'wl-init-hook 'wl-biff-init-icons)
  78 (add-hook 'wl-init-hook 'wl-plugged-init-icons)
  79
  80 (add-hook 'wl-summary-mode-hook 'wl-setup-summary)
  81
  82 (add-hook 'wl-message-display-internal-hook 'wl-setup-message)
  83
  84 (defvar wl-use-toolbar (image-type-available-p 'xpm))
  85 (defvar wl-plugged-image nil)
  86 (defvar wl-unplugged-image nil)
  87 (defvar wl-biff-mail-image nil)
  88 (defvar wl-biff-nomail-image nil)
  89
  90 (defvar wl-folder-toolbar
  91   '([wl-folder-jump-to-current-entity
  92      wl-folder-jump-to-current-entity t "Enter Current Folder"]
  93     [wl-folder-next-entity
  94      wl-folder-next-entity t "Next Folder"]
  95     [wl-folder-prev-entity
  96      wl-folder-prev-entity t "Previous Folder"]
  97     [wl-folder-check-current-entity
  98      wl-folder-check-current-entity t "Check Current Folder"]
  99     [wl-folder-sync-current-entity
 100      wl-folder-sync-current-entity t "Sync Current Folder"]
 101     [wl-draft
 102      wl-draft t "Write a New Message"]
 103     [wl-folder-goto-draft-folder
 104      wl-folder-goto-draft-folder t "Go to Draft Folder"]
 105     [wl-folder-empty-trash
 106      wl-folder-empty-trash t "Empty Trash"]
 107     [wl-exit
 108      wl-exit t "Quit Wanderlust"]
 109     )
 110   "The Folder buffer toolbar.")
 111
 112 (defvar wl-summary-toolbar
 113   '([wl-summary-read
 114      wl-summary-read t "Read Messages"]
 115     [wl-summary-next
 116      wl-summary-next t "Next Message"]
 117     [wl-summary-prev
 118      wl-summary-prev t "Previous Message"]
 119     [wl-summary-jump-to-current-message
 120      wl-summary-jump-to-current-message t "Jump to Current Message"]
 121     [wl-summary-sync-force-update
 122      wl-summary-sync-force-update t "Sync Current Folder"]
 123     [wl-summary-dispose
 124      wl-summary-dispose t "Dispose Current Message"]
 125     [wl-summary-set-flags
 126      wl-summary-set-flags t "Set Flags"]
 127     [wl-draft
 128      wl-summary-write-current-folder t "Write for Current Folder"]
 129     [wl-summary-reply
 130      wl-summary-reply t "Reply to Current Message" ]
 131     [wl-summary-reply-with-citation
 132      wl-summary-reply-with-citation t "Reply to Current Message with Citation"]
 133     [wl-summary-forward
 134      wl-summary-forward t "Forward Current Message"]
 135     [wl-summary-exit
 136      wl-summary-exit t "Exit Current Summary"]
 137     )
 138   "The Summary buffer toolbar.")
 139
 140 (defvar wl-message-toolbar
 141   '([wl-message-read
 142      wl-message-read t "Read Contents"]
 143     [wl-message-next-content
 144      wl-message-next-content t "Next Content"]
 145     [wl-message-prev-content
 146      wl-message-prev-content t "Previous Content"]
 147     [wl-message-quit
 148      wl-message-quit t "Back to Summary"]
 149     [wl-message-play-content
 150      wl-message-play-content t "Play Content"]
 151     [wl-message-extract-content
 152      wl-message-extract-content t "Extract Content"]
 153     )
 154   "The Message buffer toolbar.")
 155
 156 (defalias 'wl-draft-insert-signature 'insert-signature) ; for draft toolbar.
 157
 158 (defvar wl-draft-toolbar
 159   '([wl-draft-send-from-toolbar
 160      wl-draft-send-from-toolbar t "Send Current Draft"]
 161     [wl-draft-yank-original
 162      wl-draft-yank-original t "Yank Displaying Message"]
 163     [wl-draft-insert-signature
 164      wl-draft-insert-signature t "Insert Signature"]
 165     [wl-draft-kill
 166      wl-draft-kill t "Kill Current Draft"]
 167     [wl-draft-save-and-exit
 168      wl-draft-save-and-exit t "Save Draft and Exit"]
 169     )
 170   "The Draft buffer toolbar.")
 171
 172 (eval-when-compile
 173   (defmacro wl-e21-display-image-p ()
 174     '(and wl-highlight-folder-with-icon
 175           (image-type-available-p 'xpm))))
 176
 177 (eval-and-compile
 178   (if (boundp 'image-load-path)
 179       (defun wl-e21-find-image (specs)
 180         (let ((image-load-path (cons 'wl-icon-directory image-load-path)))
 181           (find-image specs)))
 182     (defun wl-e21-find-image (specs)
 183       (let ((load-path (cons wl-icon-directory load-path)))
 184         (find-image specs)))))
 185
 186 (defun wl-e21-setup-toolbar (bar)
 187   (when (and wl-use-toolbar
 188              (wl-e21-display-image-p))
 189     (let ((props '(:type xpm :ascent center
 190                          :color-symbols (("backgroundToolBarColor" . "None"))
 191                          :file))
 192           (success t)
 193           icon up down disabled name)
 194       (while bar
 195         (setq icon (aref (pop bar) 0))
 196         (unless (boundp icon)
 197           (setq name (symbol-name icon)
 198                 up (wl-e21-find-image `((,@props ,(concat name "-up.xpm")))))
 199           (if up
 200               (progn
 201                 (setq down (wl-e21-find-image
 202                             `((,@props ,(concat name "-down.xpm"))))
 203                       disabled (wl-e21-find-image
 204                                 `((,@props ,(concat name "-disabled.xpm")))))
 205                 (if (and down disabled)
 206                     (set icon (vector down up disabled disabled))
 207                   (set icon up)))
 208             (setq bar nil
 209                   success nil))))
 210       success)))
 211
 212 (defvar wl-e21-toolbar-configurations
 213   '((auto-resize-tool-bars       . t)
 214     (auto-raise-tool-bar-buttons . t)
 215     (tool-bar-button-margin      . 2)
 216     (tool-bar-button-relief      . 1)))
 217
 218 (defun wl-e21-make-toolbar-buttons (keymap defs)
 219   (let ((configs wl-e21-toolbar-configurations)
 220         config)
 221     (while (setq config (pop configs))
 222       (set (make-local-variable (car config)) (cdr config))))
 223   ;; Invalidate the default bindings.
 224   (let ((keys (cdr (key-binding [tool-bar] t)))
 225         item)
 226     (while (setq item (pop keys))
 227       (when (setq item (car-safe item))
 228         (define-key keymap (vector 'tool-bar item) 'undefined))))
 229   (let ((n (length defs))
 230         def)
 231     (while (>= n 0)
 232       (setq n (1- n)
 233             def (nth n defs))
 234       (define-key keymap (vector 'tool-bar (aref def 1))
 235         (list 'menu-item (aref def 3) (aref def 1)
 236               :enable (aref def 2)
 237               :image (symbol-value (aref def 0)))))))
 238
 239 (defun wl-e21-setup-folder-toolbar ()
 240   (when (wl-e21-setup-toolbar wl-folder-toolbar)
 241     (wl-e21-make-toolbar-buttons wl-folder-mode-map wl-folder-toolbar)))
 242
 243 (defun wl-e21-setup-summary-toolbar ()
 244   (when (wl-e21-setup-toolbar wl-summary-toolbar)
 245     (wl-e21-make-toolbar-buttons wl-summary-mode-map wl-summary-toolbar)))
 246
 247 (eval-when-compile
 248   (defsubst wl-e21-setup-draft-toolbar ()
 249     (when (wl-e21-setup-toolbar wl-draft-toolbar)
 250       (wl-e21-make-toolbar-buttons wl-draft-mode-map wl-draft-toolbar))))
 251
 252 (defun wl-e21-setup-message-toolbar ()
 253   (when (wl-e21-setup-toolbar wl-message-toolbar)
 254     (wl-e21-make-toolbar-buttons (current-local-map) wl-message-toolbar)))
 255
 256 (defvar wl-folder-toggle-icon-list
 257   '((wl-folder-opened-image       . wl-opened-group-folder-icon)
 258     (wl-folder-closed-image       . wl-closed-group-folder-icon)))
 259
 260 (eval-when-compile
 261   (defsubst wl-e21-highlight-folder-group-line (start end icon numbers)
 262     (let (image)
 263       (when (wl-e21-display-image-p)
 264         (let (overlay)
 265           (let ((overlays (overlays-in start end)))
 266             (while (and (setq overlay (pop overlays))
 267                         (not (overlay-get overlay 'wl-e21-icon)))))
 268           (unless overlay
 269             (setq overlay (make-overlay start end))
 270             (overlay-put overlay 'wl-e21-icon t)
 271             (overlay-put overlay 'evaporate t))
 272           (setq image (get icon 'image))
 273           (unless image
 274             (let ((name (symbol-value
 275                          (cdr (assq icon wl-folder-toggle-icon-list)))))
 276               (setq image (wl-e21-find-image
 277                            `((:type xpm :file ,name :ascent center))))))
 278           (overlay-put overlay 'display image)))
 279       (when (and wl-use-highlight-mouse-line (display-mouse-p))
 280         (let ((inhibit-read-only t))
 281           (put-text-property (if image
 282                                  (max (1- start) (line-beginning-position))
 283                                start)
 284                              (line-end-position)
 285                              'mouse-face 'highlight)))))
 286
 287   (defsubst wl-e21-highlight-folder-by-numbers (start end text-face numbers)
 288     (when (display-color-p)
 289       (let ((inhibit-read-only t))
 290         (if (and wl-highlight-folder-by-numbers
 291                  numbers (nth 0 numbers) (nth 1 numbers)
 292                  (re-search-forward "[-[:digit:]]+/[-[:digit:]]+/[-[:digit:]]+"
 293                                     (line-end-position) t))
 294             (let* ((unsync (nth 0 numbers))
 295                    (unread (nth 1 numbers))
 296                    (face (cond ((and unsync (zerop unsync))
 297                                 (if (and unread (zerop unread))
 298                                     'wl-highlight-folder-zero-face
 299                                   'wl-highlight-folder-unread-face))
 300                                ((and unsync
 301                                      (>= unsync
 302                                          wl-folder-many-unsync-threshold))
 303                                 'wl-highlight-folder-many-face)
 304                                (t
 305                                 'wl-highlight-folder-few-face))))
 306               (if (numberp wl-highlight-folder-by-numbers)
 307                   (progn
 308                     (put-text-property start (match-beginning 0)
 309                                        'face text-face)
 310                     (put-text-property (match-beginning 0) (match-end 0)
 311                                        'face face))
 312                 (put-text-property start (match-end 0) 'face face)))
 313           (put-text-property start (line-end-position) 'face text-face))))))
 314
 315 (defun wl-highlight-folder-current-line (&optional numbers)
 316   (interactive)
 317   (save-excursion
 318     (beginning-of-line)
 319     (let (fld-name start end)
 320       (cond
 321        ;; opened folder group
 322        ((and (wl-folder-buffer-group-p)
 323              (looking-at wl-highlight-folder-opened-regexp))
 324         (setq start (match-beginning 1)
 325               end (match-end 1))
 326         (wl-e21-highlight-folder-group-line start end
 327                                             'wl-folder-opened-image
 328                                             numbers)
 329         (wl-e21-highlight-folder-by-numbers start end
 330                                             'wl-highlight-folder-opened-face
 331                                             numbers))
 332        ;; closed folder group
 333        ((and (wl-folder-buffer-group-p)
 334              (looking-at wl-highlight-folder-closed-regexp))
 335         (setq start (match-beginning 1)
 336               end (match-end 1))
 337         (wl-e21-highlight-folder-group-line start end
 338                                             'wl-folder-closed-image
 339                                             numbers)
 340         (wl-e21-highlight-folder-by-numbers start end
 341                                             'wl-highlight-folder-closed-face
 342                                             numbers))
 343        ;; basic folder
 344        ((and (setq fld-name (wl-folder-get-folder-name-by-id
 345                              (get-text-property (point) 'wl-folder-entity-id)))
 346              (looking-at "[[:blank:]]+\\([^[:blank:]\n]+\\)"))
 347         (setq start (match-beginning 1)
 348               end (match-end 1))
 349         (let (image)
 350           (when (wl-e21-display-image-p)
 351             (let (overlay)
 352               (let ((overlays (overlays-in start end)))
 353                 (while (and (setq overlay (pop overlays))
 354                             (not (overlay-get overlay 'wl-e21-icon)))))
 355               (unless overlay
 356                 (setq overlay (make-overlay start end))
 357                 (overlay-put overlay 'wl-e21-icon t)
 358                 (overlay-put overlay 'evaporate t))
 359               (let (type)
 360                 (unless (get (caar wl-folder-internal-icon-list) 'image)
 361                   (wl-folder-init-icons))
 362                 (setq image
 363                       (cond
 364                        ;; trash folder
 365                        ((string= fld-name wl-trash-folder)
 366                         (let ((num (nth 2 numbers))) ; number of messages
 367                           (get (if (or (not num) (zerop num))
 368                                    'wl-folder-trash-empty-image
 369                                  'wl-folder-trash-image)
 370                                'image)))
 371                        ;; draft folder
 372                        ((string= fld-name wl-draft-folder)
 373                         (get 'wl-folder-draft-image 'image))
 374                        ;; queue folder
 375                        ((string= fld-name wl-queue-folder)
 376                         (get 'wl-folder-queue-image 'image))
 377                        ;; and one of many other folders
 378                        ((setq type (or (elmo-folder-type fld-name)
 379                                        (elmo-folder-type-internal
 380                                         (elmo-make-folder fld-name))))
 381                         (get (intern (format "wl-folder-%s-image" type))
 382                              'image)))))
 383               (overlay-put overlay 'before-string
 384                            (propertize " " 'display image
 385                                        'invisible t))))
 386           (when (and wl-use-highlight-mouse-line (display-mouse-p))
 387             (let ((inhibit-read-only t))
 388               (put-text-property (if image
 389                                      (max (1- start)
 390                                           (line-beginning-position))
 391                                    start)
 392                                  (line-end-position)
 393                                  'mouse-face 'highlight))))
 394         (when (display-color-p)
 395           (wl-e21-highlight-folder-by-numbers
 396            start end
 397            (if (looking-at (format "^[[:blank:]]*\\(?:%s\\|%s\\)"
 398                                    wl-folder-unsubscribe-mark
 399                                    wl-folder-removed-mark))
 400                'wl-highlight-folder-killed-face
 401              'wl-highlight-folder-unknown-face)
 402            numbers)))))))
 403
 404 (defun wl-highlight-plugged-current-line ()
 405   (interactive)
 406   (when (wl-e21-display-image-p)
 407     (save-excursion
 408       (beginning-of-line)
 409       (when (looking-at "[[:blank:]]*\\(\\[\\([^]]+\\)\\]\\)")
 410         (let* ((start (match-beginning 1))
 411                (end (match-end 1))
 412                (status (match-string-no-properties 2))
 413                (image (if (string-equal wl-plugged-plug-on status)
 414                           wl-plugged-image
 415                         wl-unplugged-image)))
 416           (when image
 417             (let (overlay)
 418               (let ((overlays (overlays-in start end)))
 419                 (while (and (setq overlay (pop overlays))
 420                             (not (overlay-get overlay 'wl-e21-icon)))))
 421               (unless overlay
 422                 (setq overlay (make-overlay start end))
 423                 (overlay-put overlay 'wl-e21-icon t)
 424                 (overlay-put overlay 'evaporate t))
 425               (overlay-put overlay 'display image))))))))
 426
 427 (defun wl-plugged-set-folder-icon (folder string)
 428   (let (image type)
 429     (when (wl-e21-display-image-p)
 430       (setq image
 431             (cond ((string= folder wl-queue-folder)
 432                    (get 'wl-folder-queue-image 'image))
 433                   ((setq type (or (elmo-folder-type folder)
 434                                   (elmo-folder-type-internal
 435                                    (elmo-make-folder folder))))
 436                    (get (intern (format "wl-folder-%s-image" type))
 437                         'image)))))
 438     (if image
 439         (concat (propertize " " 'display image 'invisible t) string)
 440       string)))
 441
 442 (defvar wl-folder-internal-icon-list
 443   ;; alist of (image . icon-file)
 444   '((wl-folder-nntp-image         . wl-nntp-folder-icon)
 445     (wl-folder-imap4-image        . wl-imap-folder-icon)
 446     (wl-folder-pop3-image         . wl-pop-folder-icon)
 447     (wl-folder-localdir-image     . wl-localdir-folder-icon)
 448     (wl-folder-localnews-image    . wl-localnews-folder-icon)
 449     (wl-folder-internal-image     . wl-internal-folder-icon)
 450     (wl-folder-multi-image        . wl-multi-folder-icon)
 451     (wl-folder-filter-image       . wl-filter-folder-icon)
 452     (wl-folder-archive-image      . wl-archive-folder-icon)
 453     (wl-folder-pipe-image         . wl-pipe-folder-icon)
 454     (wl-folder-maildir-image      . wl-maildir-folder-icon)
 455     (wl-folder-search-image       . wl-search-folder-icon)
 456     (wl-folder-shimbun-image      . wl-shimbun-folder-icon)
 457     (wl-folder-file-image         . wl-file-folder-icon)
 458     (wl-folder-access-image       . wl-access-folder-icon)
 459     (wl-folder-trash-empty-image  . wl-empty-trash-folder-icon)
 460     (wl-folder-draft-image        . wl-draft-folder-icon)
 461     (wl-folder-queue-image        . wl-queue-folder-icon)
 462     (wl-folder-trash-image        . wl-trash-folder-icon)))
 463
 464 (defun wl-folder-init-icons ()
 465   (when (wl-e21-display-image-p)
 466     (let ((icons wl-folder-internal-icon-list)
 467           icon name image)
 468       (while (setq icon (pop icons))
 469         (unless (get (car icon) 'image)
 470           (setq name (symbol-value (cdr icon))
 471                 image (wl-e21-find-image
 472                        `((:type xpm :file ,name :ascent center))))
 473           (when image
 474             (put (car icon) 'image image)))))))
 475
 476 (defun wl-plugged-init-icons ()
 477   (let ((props (when (display-mouse-p)
 478                  (list 'local-map (purecopy (make-mode-line-mouse-map
 479                                              'mouse-2 #'wl-toggle-plugged))
 480                        'help-echo "mouse-2 toggles plugged status"))))
 481     (if (wl-e21-display-image-p)
 482         (progn
 483           (unless wl-plugged-image
 484             (setq wl-plugged-image (wl-e21-find-image
 485                                     `((:type xpm
 486                                              :file ,wl-plugged-icon
 487                                              :ascent center)))
 488                   wl-unplugged-image (wl-e21-find-image
 489                                       `((:type xpm
 490                                                :file ,wl-unplugged-icon
 491                                                :ascent center)))))
 492           (setq wl-modeline-plug-state-on
 493                 (apply 'propertize wl-plug-state-indicator-on
 494                        `(display ,wl-plugged-image ,@props))
 495                 wl-modeline-plug-state-off
 496                 (apply 'propertize wl-plug-state-indicator-off
 497                        `(display ,wl-unplugged-image ,@props))))
 498       (if props
 499           (setq wl-modeline-plug-state-on
 500                 (apply 'propertize wl-plug-state-indicator-on props)
 501                 wl-modeline-plug-state-off
 502                 (apply 'propertize wl-plug-state-indicator-off props))
 503         (setq wl-modeline-plug-state-on wl-plug-state-indicator-on
 504               wl-modeline-plug-state-off wl-plug-state-indicator-off)))))
 505
 506 (defun wl-biff-init-icons ()
 507   (let ((props (when (display-mouse-p)
 508                  (list 'local-map (purecopy (make-mode-line-mouse-map
 509                                              'mouse-2 #'wl-biff-check-folders))
 510                        'help-echo "mouse-2 checks new mails"))))
 511     (if (wl-e21-display-image-p)
 512         (progn
 513           (unless wl-biff-mail-image
 514             (setq wl-biff-mail-image (wl-e21-find-image
 515                                       `((:type xpm
 516                                                :file ,wl-biff-mail-icon
 517                                                :ascent center)))
 518                   wl-biff-nomail-image (wl-e21-find-image
 519                                         `((:type xpm
 520                                                  :file ,wl-biff-nomail-icon
 521                                                  :ascent center)))))
 522           (setq wl-modeline-biff-state-on
 523                 (apply 'propertize wl-biff-state-indicator-on
 524                        `(display ,wl-biff-mail-image ,@props))
 525                 wl-modeline-biff-state-off
 526                 (apply 'propertize wl-biff-state-indicator-off
 527                        `(display ,wl-biff-nomail-image ,@props))))
 528       (if props
 529           (setq wl-modeline-biff-state-on
 530                 (apply 'propertize wl-biff-state-indicator-on props)
 531                 wl-modeline-biff-state-off
 532                 (apply 'propertize wl-biff-state-indicator-off props))
 533         (setq wl-modeline-biff-state-on wl-biff-state-indicator-on
 534               wl-modeline-biff-state-off wl-biff-state-indicator-off)))))
 535
 536 (defun wl-make-date-string ()
 537   (let ((system-time-locale "C"))
 538     (format-time-string "%a, %d %b %Y %T %z")))
 539
 540 (defalias 'wl-setup-folder 'wl-e21-setup-folder-toolbar)
 541
 542 (defalias 'wl-setup-summary 'wl-e21-setup-summary-toolbar)
 543
 544 (defun wl-message-define-keymap ()
 545   (let ((keymap (make-sparse-keymap)))
 546     (define-key keymap "D" 'wl-message-delete-current-part)
 547     (define-key keymap "l" 'wl-message-toggle-disp-summary)
 548     (define-key keymap "\C-c:d" 'wl-message-decrypt-pgp-nonmime)
 549     (define-key keymap "\C-c:v" 'wl-message-verify-pgp-nonmime)
 550     (define-key keymap "w" 'wl-draft)
 551     (define-key keymap [mouse-4] 'wl-message-wheel-down)
 552     (define-key keymap [mouse-5] 'wl-message-wheel-up)
 553     (define-key keymap [S-mouse-4] 'wl-message-wheel-down)
 554     (define-key keymap [S-mouse-5] 'wl-message-wheel-up)
 555     ;; Meadow2
 556     (define-key keymap [mouse-wheel1] 'wl-message-wheel-dispatcher)
 557     (define-key keymap [S-mouse-wheel1] 'wl-message-wheel-dispatcher)
 558     (set-keymap-parent wl-message-button-map keymap)
 559     (define-key wl-message-button-map
 560       [mouse-2] 'wl-message-button-dispatcher)
 561     keymap))
 562
 563 (defalias 'wl-setup-message 'wl-e21-setup-message-toolbar)
 564
 565 ;; Wheel handling for Meadow2
 566 (defun wl-message-wheel-dispatcher (event)
 567   (interactive "e")
 568   (if (< (nth 4 (nth 1 event)) 0)
 569       (wl-message-wheel-up event)
 570     (wl-message-wheel-down event)))
 571
 572 (defun wl-summary-wheel-dispatcher (event)
 573   (interactive "e")
 574   (if (< (nth 4 (nth 1 event)) 0)
 575       (if (memq 'shift (event-modifiers event))
 576           (wl-summary-down)
 577         (wl-summary-next))
 578     (if (memq 'shift (event-modifiers event))
 579         (wl-summary-up)
 580       (wl-summary-prev))))
 581
 582 (defun wl-message-wheel-up (event)
 583   (interactive "e")
 584   (if (string-match (regexp-quote wl-message-buffer-name)
 585                     (regexp-quote (buffer-name)))
 586       (wl-message-next-page)
 587     (let ((cur-buf (current-buffer))
 588           proceed)
 589       (save-selected-window
 590         (select-window (posn-window (event-start event)))
 591         (set-buffer cur-buf)
 592         (setq proceed (wl-message-next-page)))
 593       (if proceed
 594           (if (memq 'shift (event-modifiers event))
 595               (wl-summary-down t)
 596             (wl-summary-next t))))))
 597
 598 (defun wl-message-wheel-down (event)
 599   (interactive "e")
 600   (if (string-match (regexp-quote wl-message-buffer-name)
 601                     (regexp-quote (buffer-name)))
 602       (wl-message-prev-page)
 603     (let ((cur-buf (current-buffer))
 604           proceed)
 605       (save-selected-window
 606         (select-window (posn-window (event-start event)))
 607         (set-buffer cur-buf)
 608         (setq proceed (wl-message-prev-page)))
 609       (if proceed
 610           (if (memq 'shift (event-modifiers event))
 611               (wl-summary-up t)
 612             (wl-summary-prev t))))))
 613
 614 (defun wl-draft-overload-menubar ()
 615   (let ((keymap (current-local-map)))
 616     (define-key keymap [menu-bar mail send]
 617       '("Send Message" . wl-draft-send-and-exit))
 618     (define-key keymap [menu-bar mail send-stay]
 619       '("Send, Keep Editing" . wl-draft-send))
 620     (define-key-after (lookup-key keymap [menu-bar mail])
 621       [mail-sep-send] '("--")
 622       'send-stay)
 623     (define-key keymap [menu-bar mail cancel]
 624       '("Kill Current Draft" . wl-draft-kill))
 625     (define-key-after (lookup-key keymap [menu-bar mail])
 626       [save] '("Save Draft and Exit" . wl-draft-save-and-exit)
 627       'cancel)
 628     (define-key-after (lookup-key keymap [menu-bar mail])
 629       [mail-sep-exit] '("--")
 630       'save)
 631     (define-key-after (lookup-key keymap [menu-bar mail])
 632       [preview] '("Preview Message" . wl-draft-preview-message)
 633       'mail-sep-exit)
 634     (define-key keymap [menu-bar mail yank]
 635       '("Cite Message" . wl-draft-yank-original))
 636     (define-key keymap [menu-bar mail signature]
 637       '("Insert Signature" . insert-signature))
 638     (define-key keymap [menu-bar headers fcc]
 639       '("Fcc" . wl-draft-fcc))))
 640
 641 (defun wl-draft-mode-setup ()
 642   (require 'derived)
 643   (define-derived-mode wl-draft-mode mail-mode "Draft"
 644     "draft mode for Wanderlust derived from mail mode.
 645 See info under Wanderlust for full documentation.
 646
 647 Special commands:
 648 \\{wl-draft-mode-map}"
 649     (setq font-lock-defaults nil)))
 650
 651 (defun wl-draft-key-setup ()
 652   (define-key wl-draft-mode-map "\C-c\C-y" 'wl-draft-yank-original)
 653   (define-key wl-draft-mode-map "\C-c\C-s" 'wl-draft-send)
 654   (define-key wl-draft-mode-map "\C-c\C-c" 'wl-draft-send-and-exit)
 655   (define-key wl-draft-mode-map "\C-c\C-z" 'wl-draft-save-and-exit)
 656   (define-key wl-draft-mode-map "\C-c\C-k" 'wl-draft-kill)
 657   (define-key wl-draft-mode-map "\C-l" 'wl-draft-highlight-and-recenter)
 658   (define-key wl-draft-mode-map "\C-i" 'wl-complete-field-body-or-tab)
 659   (define-key wl-draft-mode-map "\C-c\C-r" 'wl-draft-caesar-region)
 660   (define-key wl-draft-mode-map "\M-t" 'wl-toggle-plugged)
 661   (define-key wl-draft-mode-map "\C-c\C-o" 'wl-jump-to-draft-buffer)
 662   (define-key wl-draft-mode-map "\C-c\C-e" 'wl-draft-config-exec)
 663   (define-key wl-draft-mode-map "\C-c\C-j" 'wl-template-select)
 664   (define-key wl-draft-mode-map "\C-c\C-p" 'wl-draft-preview-message)
 665   (define-key wl-draft-mode-map "\C-c\C-a" 'wl-addrmgr)
 666 ;;;  (define-key wl-draft-mode-map "\C-x\C-s" 'wl-draft-save)
 667   (define-key wl-draft-mode-map "\C-xk"    'wl-draft-mimic-kill-buffer)
 668   (define-key wl-draft-mode-map "\C-c\C-d" 'wl-draft-elide-region)
 669   (define-key wl-draft-mode-map "\C-a" 'wl-draft-beginning-of-line)
 670   (define-key wl-draft-mode-map "\M-p" 'wl-draft-previous-history-element)
 671   (define-key wl-draft-mode-map "\M-n" 'wl-draft-next-history-element))
 672
 673 (defun wl-draft-overload-functions ()
 674   (wl-mode-line-buffer-identification)
 675 ;;;  (local-set-key "\C-c\C-s" 'wl-draft-send) ; override
 676   (wl-e21-setup-draft-toolbar)
 677   (wl-draft-overload-menubar))
 678
 679 (defalias 'wl-defface 'defface)
 680
 681 (defun wl-read-event-char (&optional prompt)
 682   "Get the next event."
 683   (let ((event (read-event prompt)))
 684     (cons (and (numberp event) event) event)))
 685
 686 (put 'wl-modeline-biff-state-on 'risky-local-variable t)
 687 (put 'wl-modeline-biff-state-off 'risky-local-variable t)
 688 (put 'wl-modeline-plug-state-on 'risky-local-variable t)
 689 (put 'wl-modeline-plug-state-off 'risky-local-variable t)
 690
 691 (require 'product)
 692 (product-provide (provide 'wl-e21) (require 'wl-version))
 693
 694 ;;; wl-e21.el ends here