wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-summary-buffer nil)
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-flag nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-all-header-flag nil)
  64
  65 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  66 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  69 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  71
  72 (defvar wl-fixed-window-configuration nil)
  73
  74 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  75
  76 ;;; Message buffer cache.
  77
  78 (defvar wl-message-buffer-cache nil
  79   "Message cache.  (old ... new) order alist.
  80 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  81
  82 (defmacro wl-message-buffer-cache-buffer-get (entry)
  83   (` (cdr (, entry))))
  84
  85 (defmacro wl-message-buffer-cache-folder-get (entry)
  86   (` (car (car (, entry)))))
  87
  88 (defmacro wl-message-buffer-cache-message-get (entry)
  89   (` (cdr (car (, entry)))))
  90
  91 (defmacro wl-message-buffer-cache-entry-make (key buf)
  92   (` (cons (, key) (, buf))))
  93
  94 (defmacro wl-message-buffer-cache-hit (key)
  95   "Return value assosiated with key."
  96   (` (wl-message-buffer-cache-buffer-get
  97       (assoc (, key) wl-message-buffer-cache))))
  98
  99 (defun wl-message-buffer-cache-sort (entry)
 100   "Move ENTRY to the top of `wl-message-buffer-cache'."
 101   (setq wl-message-buffer-cache
 102         (cons entry (delete entry wl-message-buffer-cache))))
 103 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 104 ;        (top pointer))
 105 ;    (while (cdr pointer)
 106 ;      (if (equal (car (cdr pointer)) entry)
 107 ;         (setcdr pointer (cdr (cdr pointer)))
 108 ;       (setq pointer (cdr pointer))))
 109 ;    (setcdr pointer (list entry))
 110 ;    (setq wl-message-buffer-cache (cdr top))))
 111
 112 (defconst wl-message-buffer-cache-name    " *WL:Message*")
 113 (defconst wl-original-message-buffer-name " *Original*")
 114
 115 (defun wl-original-message-mode ()
 116   "A major mode for original message buffer."
 117   (setq major-mode 'wl-original-message-mode)
 118   (setq buffer-read-only t)
 119   (elmo-set-buffer-multibyte nil)
 120   (setq mode-name "Wanderlust original message"))
 121
 122 (defun wl-original-message-buffer-get (name)
 123   "Get original message buffer for NAME.
 124 If original message buffer already exists, it is re-used."
 125   (let* ((name (concat wl-original-message-buffer-name name))
 126          (buffer (get-buffer name)))
 127     (unless (and buffer (buffer-live-p buffer))
 128       (with-current-buffer (setq buffer (get-buffer-create name))
 129         (wl-original-message-mode)))
 130     buffer))
 131
 132 (defun wl-message-buffer-create ()
 133   "Create a new message buffer."
 134   (let* ((buffer (generate-new-buffer wl-message-buffer-cache-name))
 135          (name (buffer-name buffer)))
 136     (with-current-buffer buffer
 137       (setq wl-message-buffer-original-buffer
 138             (wl-original-message-buffer-get name))
 139       (run-hooks 'wl-message-buffer-created-hook))
 140     buffer))
 141
 142 (defun wl-message-buffer-cache-add (key)
 143   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 144 Return its cache buffer."
 145   (let ((len (length wl-message-buffer-cache))
 146         (buf nil))
 147     (if (< len wl-message-buffer-cache-size)
 148         (setq buf (wl-message-buffer-create))
 149       (setq buf (wl-message-buffer-cache-buffer-get
 150                  (nth (1- len) wl-message-buffer-cache)))
 151       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 152     (setq wl-message-buffer-cache
 153           (cons (wl-message-buffer-cache-entry-make key buf)
 154                 wl-message-buffer-cache))
 155     buf))
 156
 157 (defun wl-message-buffer-cache-delete (&optional key)
 158   "Delete the most recent cache entry"
 159   (if key
 160       (setq wl-message-buffer-cache
 161             (delq (assoc key wl-message-buffer-cache)
 162                   wl-message-buffer-cache))
 163     (let ((buf (wl-message-buffer-cache-buffer-get
 164                 (car wl-message-buffer-cache))))
 165       (setq wl-message-buffer-cache
 166             (nconc (cdr wl-message-buffer-cache)
 167                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 168
 169 (defun wl-message-buffer-cache-clean-up ()
 170   "A function to flush all decoded messages in cache list."
 171   (interactive)
 172   (if (and (eq major-mode 'wl-summary-mode)
 173            wl-message-buffer
 174            (get-buffer-window wl-message-buffer))
 175       (delete-window (get-buffer-window wl-message-buffer)))
 176   (wl-kill-buffers (regexp-quote wl-message-buffer-cache-name))
 177   (setq wl-message-buffer-cache nil))
 178
 179 ;;; Message buffer handling from summary buffer.
 180
 181 (defun wl-message-buffer-window ()
 182   "Get message buffer window if any."
 183   (let* ((start-win (selected-window))
 184          (cur-win start-win))
 185     (catch 'found
 186       (while (progn
 187                (setq cur-win (next-window cur-win))
 188                (with-current-buffer (window-buffer cur-win)
 189                  (if (or (eq major-mode 'wl-message-mode)
 190                          (eq major-mode 'mime-view-mode))
 191                      (throw 'found cur-win)))
 192                (not (eq cur-win start-win)))))))
 193
 194 (defun wl-message-select-buffer (buffer)
 195   "Select BUFFER as a message buffer."
 196   (let ((window (get-buffer-window buffer))
 197         (sum (car wl-message-window-size))
 198         (mes (cdr wl-message-window-size))
 199         whi)
 200     (when (and window
 201                (not (eq (save-excursion (set-buffer (window-buffer window))
 202                                         wl-message-buffer-cur-summary-buffer)
 203                         (current-buffer))))
 204       (delete-window window)
 205       (run-hooks 'wl-message-window-deleted-hook)
 206       (setq window nil))
 207     (if window
 208         (select-window window)
 209       (when wl-fixed-window-configuration
 210         (delete-other-windows)
 211         (and wl-stay-folder-window
 212              (wl-summary-toggle-disp-folder)))
 213       ;; There's no buffer window. Search for message window and snatch it.
 214       (if (setq window (wl-message-buffer-window))
 215           (select-window window)
 216         (setq whi (1- (window-height)))
 217         (if mes
 218             (progn
 219               (let ((total (+ sum mes)))
 220                 (setq sum (max window-min-height (/ (* whi sum) total)))
 221                 (setq mes (max window-min-height (/ (* whi mes) total))))
 222               (if (< whi (+ sum mes))
 223                   (enlarge-window (- (+ sum mes) whi)))))
 224         (split-window (get-buffer-window (current-buffer)) sum)
 225         (other-window 1)))
 226     (switch-to-buffer buffer)))
 227
 228 (defun wl-message-narrow-to-page (&optional arg)
 229   "Narrow to page.
 230 If ARG is specified, narrow to ARGth page."
 231   (interactive "P")
 232   (setq arg (if arg (prefix-numeric-value arg) 0))
 233   (save-excursion
 234     (condition-case ()
 235         (forward-page -1)               ; Beginning of current page.
 236       (beginning-of-buffer
 237        (goto-char (point-min))))
 238     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 239     (widen)
 240     (cond
 241      ((> arg 0) (forward-page arg))
 242      ((< arg 0) (forward-page (1- arg))))
 243     (forward-page)
 244     (if wl-break-pages
 245         (narrow-to-region (point)
 246                           (progn
 247                             (forward-page -1)
 248                             (if (and (eolp) (not (bobp)))
 249                                 (forward-line))
 250                             (point))))))
 251
 252 (defun wl-message-prev-page (&optional lines)
 253   "Scroll down current message by LINES.
 254 Returns non-nil if top of message."
 255   (interactive)
 256   (let (cur-buf top real-top)
 257     (unless (eq major-mode 'mime-view-mode)
 258       (when (buffer-live-p wl-message-buffer)
 259         (setq cur-buf (current-buffer))
 260         (wl-message-select-buffer wl-message-buffer)))
 261     (move-to-window-line 0)
 262     (if (and wl-break-pages
 263              (bobp)
 264              (not (setq real-top (save-restriction (widen) (bobp)))))
 265         (progn
 266           (wl-message-narrow-to-page -1)
 267           (goto-char (point-max))
 268           (recenter))
 269       (if (not (bobp))
 270           (condition-case nil
 271               (scroll-down lines)
 272             (error))
 273         (setq top t)))
 274     (if real-top
 275         (let ((f (assq (mime-preview-original-major-mode)
 276                        mime-preview-over-to-previous-method-alist)))
 277           (if f (funcall (cdr f))))
 278       (when cur-buf
 279         (select-window (get-buffer-window cur-buf))))
 280     top))
 281
 282 (defun wl-message-next-page (&optional lines)
 283   "Scroll up current message by LINES.
 284 Returns non-nil if bottom of message."
 285   (interactive)
 286   (let (cur-buf bottom)
 287     (unless (eq major-mode 'mime-view-mode)
 288       (when (buffer-live-p wl-message-buffer)
 289         (setq cur-buf (current-buffer))
 290         (wl-message-select-buffer wl-message-buffer)))
 291     (move-to-window-line -1)
 292     (if (save-excursion
 293           (end-of-line)
 294           (and (pos-visible-in-window-p)
 295                (eobp)))
 296         (if (or (null wl-break-pages)
 297                 (save-excursion
 298                   (save-restriction
 299                     (widen) (forward-line) (eobp))))
 300             (setq bottom t)
 301           (wl-message-narrow-to-page 1)
 302           (setq bottom nil))
 303       (condition-case ()
 304           (static-if (boundp 'window-pixel-scroll-increment)
 305               ;; XEmacs 21.2.20 and later.
 306               (let (window-pixel-scroll-increment)
 307                 (scroll-up lines))
 308             (scroll-up lines))
 309         (end-of-buffer
 310          (goto-char (point-max))))
 311       (setq bottom nil))
 312     (if (eobp)
 313         (let ((f (assq (mime-preview-original-major-mode)
 314                        mime-preview-over-to-next-method-alist)))
 315           (if f (funcall (cdr f))))
 316       (when cur-buf
 317         (select-window (get-buffer-window cur-buf))))
 318     bottom))
 319
 320
 321 (defun wl-message-follow-current-entity (buffer)
 322   "Follow to current message."
 323   (wl-draft-reply (wl-message-get-original-buffer)
 324                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 325   (let ((mail-reply-buffer buffer))
 326     (wl-draft-yank-from-mail-reply-buffer nil)))
 327
 328 ;;
 329
 330 (defun wl-message-mode ()
 331   "A major mode for message displaying."
 332   (interactive)
 333   (setq major-mode 'wl-message-mode)
 334   (setq buffer-read-only t)
 335   (setq mode-name "Message"))
 336
 337 (defun wl-message-exit ()
 338   "Move to summary buffer."
 339   (interactive)
 340   (let (summary-buf summary-win)
 341     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 342         (if (setq summary-win (get-buffer-window summary-buf))
 343             (select-window summary-win)
 344           (switch-to-buffer summary-buf)
 345           (wl-message-select-buffer wl-message-buffer)
 346           (select-window (get-buffer-window summary-buf))))
 347     (run-hooks 'wl-message-exit-hook)))
 348
 349 (defun wl-message-toggle-disp-summary ()
 350   (interactive)
 351   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 352         summary-win)
 353     (if (and summary-buf
 354              (buffer-live-p summary-buf))
 355         (if (setq summary-win (get-buffer-window summary-buf))
 356             (delete-window summary-win)
 357           (switch-to-buffer summary-buf)
 358           (wl-message-select-buffer wl-message-buffer))
 359       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 360                                    nil nil t)
 361                                         ; no summary-buf
 362       (let ((sum-buf (current-buffer)))
 363         (wl-message-select-buffer wl-message-buffer)
 364         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 365
 366 (defun wl-message-get-original-buffer ()
 367   "Get original buffer for current message buffer."
 368   wl-message-buffer-original-buffer)
 369
 370 (defun wl-message-add-buttons-to-body (start end)
 371   (save-excursion
 372     (save-restriction
 373       (narrow-to-region start end)
 374       (let ((case-fold-search t)
 375             (alist wl-message-body-button-alist)
 376             entry)
 377         (while alist
 378           (setq entry (car alist)
 379                 alist (cdr alist))
 380           (goto-char (point-min))
 381           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 382             (unless (get-text-property (point) 'keymap)
 383               (wl-message-add-button
 384                (match-beginning (nth 1 entry))
 385                (match-end (nth 1 entry))
 386                (nth 2 entry)
 387                (match-string (nth 3 entry))))))))))
 388
 389 (defun wl-message-add-buttons-to-header (start end)
 390   (save-excursion
 391     (save-restriction
 392       (narrow-to-region start end)
 393       (let ((case-fold-search t)
 394             (alist wl-message-header-button-alist)
 395             entry)
 396         (while alist
 397           (setq entry (car alist)
 398                 alist (cdr alist))
 399           (goto-char (point-min))
 400           (while (re-search-forward (car entry) nil t)
 401             (setq start (match-beginning 0)
 402                   end (if (re-search-forward "^[^ \t]" nil t)
 403                           (match-beginning 0)
 404                         (point-max)))
 405             (goto-char start)
 406             (while (re-search-forward (nth 1 entry) end t)
 407               (wl-message-add-button
 408                (match-beginning (nth 2 entry))
 409                (match-end (nth 2 entry))
 410                (nth 3 entry) (match-string (nth 4 entry))))
 411             (goto-char end)))))))
 412
 413 (defun wl-message-redisplay (folder number flag &optional force-reload)
 414   (let* ((default-mime-charset wl-mime-charset)
 415          (buffer-read-only nil)
 416          (summary-buf (current-buffer))
 417          message-buf
 418          strategy entity
 419          cache-used
 420          header-end real-fld-num summary-win delim)
 421     (setq buffer-read-only nil)
 422     (setq cache-used (wl-message-buffer-display
 423                       folder number flag force-reload))
 424     (setq wl-message-buffer (car cache-used))
 425     (setq message-buf wl-message-buffer)
 426     (wl-message-select-buffer wl-message-buffer)
 427
 428     (set-buffer message-buf)
 429     (make-local-variable 'truncate-partial-width-windows)
 430     (setq truncate-partial-width-windows nil)
 431     (setq truncate-lines wl-message-truncate-lines)
 432     (setq buffer-read-only nil)
 433     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 434     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 435     (setq wl-message-buffer-cur-number number)
 436     (setq mode-line-buffer-identification
 437           (format "Wanderlust: << %s / %s >>"
 438                   (if (memq 'modeline wl-use-folder-petname)
 439                       (wl-folder-get-petname (elmo-folder-name-internal
 440                                               folder))
 441                     (elmo-folder-name-internal folder)) number))
 442     ;; highlight body
 443 ;    (when wl-highlight-body-too
 444 ;      (wl-highlight-body))
 445     (ignore-errors (wl-message-narrow-to-page))
 446     (setq cache-used (cdr cache-used))
 447     (goto-char (point-min))
 448     (when (re-search-forward "^$" nil t)
 449       (wl-message-add-buttons-to-header (point-min) (point))
 450       (wl-message-add-buttons-to-body (point) (point-max)))
 451     (goto-char (point-min))
 452     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 453     ;; go back to summary mode
 454     (set-buffer-modified-p nil)
 455     (setq buffer-read-only t)
 456     (set-buffer summary-buf)
 457     (setq summary-win (get-buffer-window summary-buf))
 458     (if (window-live-p summary-win)
 459         (select-window summary-win))
 460     cache-used))
 461
 462 ;; Use message buffer cache.
 463 (defun wl-message-buffer-display (folder number flag
 464                                          &optional force-reload unread)
 465   (let* ((msg-id (elmo-message-field folder number 'message-id))
 466          (fname (elmo-folder-name-internal folder))
 467          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 468          (read nil)
 469          cache-used)
 470     (when (and hit (not (buffer-live-p hit)))
 471       (wl-message-buffer-cache-delete (list fname number msg-id))
 472       (setq hit nil))
 473     (if hit
 474         (progn
 475           ;; move hit to the top.
 476           (wl-message-buffer-cache-sort
 477            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 478           ;; buffer cache is used.
 479           (setq cache-used t)
 480           (with-current-buffer hit
 481             (unless (eq wl-message-buffer-cur-flag flag)
 482               (setq read t))))
 483       ;; delete tail and add new to the top.
 484       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 485       (setq read t))
 486     (if (or force-reload read)
 487         (condition-case err
 488             (save-excursion
 489               (set-buffer hit)
 490               (setq
 491                cache-used
 492                (wl-message-display-internal folder number flag
 493                                             force-reload unread))
 494               (setq wl-message-buffer-cur-flag flag))
 495           (quit
 496            (wl-message-buffer-cache-delete)
 497            (error "Display message %s/%s is quitted" fname number))
 498           (error
 499            (wl-message-buffer-cache-delete)
 500            (signal (car err) (cdr err))
 501            nil))) ;; will not be used
 502     (cons hit cache-used)))
 503
 504 (defun wl-message-display-internal (folder number flag
 505                                            &optional force-reload unread)
 506   (let ((default-mime-charset wl-mime-charset)
 507         (elmo-mime-charset wl-mime-charset))
 508     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 509     (prog1
 510         (if (eq flag 'as-is)
 511             (let (wl-highlight-x-face-function)
 512               (prog1 (elmo-mime-display-as-is folder number
 513                                               (current-buffer)
 514                                               (wl-message-get-original-buffer)
 515                                               'wl-original-message-mode
 516                                               force-reload
 517                                               unread
 518                                               (wl-message-define-keymap))
 519                 (let (buffer-read-only)
 520                   (wl-highlight-message (point-min) (point-max) t))))
 521           (elmo-mime-message-display folder number
 522                                      (current-buffer)
 523                                      (wl-message-get-original-buffer)
 524                                      'wl-original-message-mode
 525                                      force-reload
 526                                      unread
 527                                      (wl-message-define-keymap)))
 528       (run-hooks 'wl-message-display-internal-hook)
 529       (setq buffer-read-only t))))
 530
 531 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 532   (and (or (not number)
 533            (elmo-message-file-p folder number)
 534            (let ((size (elmo-message-field folder number 'size)))
 535              (not (and (integerp size)
 536                        wl-message-buffer-prefetch-threshold
 537                        (>= size wl-message-buffer-prefetch-threshold)))))
 538        (or (not number)
 539            (elmo-folder-plugged-p folder)
 540            (elmo-file-cache-exists-p
 541                  (elmo-message-field folder number 'message-id)))
 542        (or (cond
 543             ((eq wl-message-buffer-prefetch-folder-type-list t)
 544              t)
 545             ((and number wl-message-buffer-prefetch-folder-type-list)
 546              (memq (elmo-folder-type-internal
 547                     (elmo-message-folder folder number))
 548                    wl-message-buffer-prefetch-folder-type-list))
 549             (wl-message-buffer-prefetch-folder-type-list
 550              (let ((list wl-message-buffer-prefetch-folder-type-list)
 551                    type)
 552                (catch 'done
 553                  (while (setq type (pop list))
 554                    (if (elmo-folder-contains-type folder type)
 555                        (throw 'done t)))))))
 556            (cond
 557             ((consp wl-message-buffer-prefetch-folder-list)
 558              (wl-string-match-member (elmo-folder-name-internal folder)
 559                                      wl-message-buffer-prefetch-folder-list))
 560             (t wl-message-buffer-prefetch-folder-list)))))
 561
 562 (defsubst wl-message-buffer-prefetch-clear-timer ()
 563 ;;;     cannot use for the bug of fsf-compat package (1.09).
 564 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 565   (if (fboundp 'run-with-idle-timer)
 566       (if (featurep 'xemacs)
 567           (let ((p itimer-list))
 568             (while (car p)
 569               (if (eq 'wl-message-buffer-prefetch-subr
 570                       (itimer-function (car p)))
 571                   (delete-itimer (car p)))
 572               (setq p (cdr p))))
 573         ;; FSF Emacs is correct
 574         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 575
 576 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 577                                                        summary charset)
 578   (if (not (fboundp 'run-with-idle-timer))
 579       (when (sit-for wl-message-buffer-prefetch-idle-time)
 580         (wl-message-buffer-prefetch-subr
 581          folder number count summary charset))
 582     (run-with-idle-timer
 583      wl-message-buffer-prefetch-idle-time
 584      nil
 585      'wl-message-buffer-prefetch-subr
 586      folder number count summary charset)))
 587
 588 (defvar wl-message-buffer-prefetch-move-spec-plugged-alist nil)
 589 (defvar wl-message-buffer-prefetch-move-spec-unplugged-alist nil)
 590
 591 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 592   (if (buffer-live-p summary)
 593       (with-current-buffer summary
 594         (let ((wl-summary-move-spec-plugged-alist
 595                (or wl-message-buffer-prefetch-move-spec-plugged-alist
 596                    wl-summary-move-spec-plugged-alist))
 597               (wl-summary-move-spec-unplugged-alist
 598                (or wl-message-buffer-prefetch-move-spec-unplugged-alist
 599                    wl-summary-move-spec-unplugged-alist))
 600               (next number))
 601           (while (and (setq next (funcall
 602                                   wl-message-buffer-prefetch-get-next-function
 603                                   next))
 604                       (not (wl-message-buffer-prefetch-p folder next))))
 605           next))))
 606
 607 (defun wl-message-buffer-prefetch (folder number count
 608                                           &optional summary charset)
 609   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 610          (num number))
 611     (when (and count
 612                (wl-message-buffer-prefetch-p folder))
 613       (unless (wl-message-buffer-prefetch-p folder number)
 614         (setq num
 615               (wl-message-buffer-prefetch-get-next folder number summary)))
 616       (when num
 617         (wl-message-buffer-prefetch-clear-timer)
 618         (wl-message-buffer-prefetch-set-timer
 619          folder num count summary charset)))))
 620
 621 (defun wl-message-buffer-prefetch-next (folder number count
 622                                                &optional summary charset)
 623   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 624          next)
 625     (when (and count
 626                (wl-message-buffer-prefetch-p folder))
 627       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 628       (when next
 629         (wl-message-buffer-prefetch-clear-timer)
 630         (wl-message-buffer-prefetch-set-timer
 631          folder next count summary charset)))))
 632
 633 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 634   (if (buffer-live-p summary)
 635       (with-current-buffer summary
 636         (if (and number
 637                  (numberp count)
 638                  (>= (setq count (- count 1)) 0)
 639                  (string= (elmo-folder-name-internal folder)
 640                           (wl-summary-buffer-folder-name)))
 641             (let* ((wl-mime-charset      charset)
 642                    (default-mime-charset charset)
 643                    (message-id (elmo-message-field folder number 'message-id))
 644                    (key (list (elmo-folder-name-internal folder)
 645                               number message-id))
 646                    (hit (wl-message-buffer-cache-hit key))
 647                    result time1 time2 sec micro)
 648               (when wl-message-buffer-prefetch-debug
 649                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 650               (if (and hit (buffer-live-p hit))
 651                   (progn
 652                     (wl-message-buffer-cache-sort
 653                      (wl-message-buffer-cache-entry-make key hit))
 654                     (wl-message-buffer-prefetch-subr
 655                      folder
 656                      (wl-message-buffer-prefetch-get-next
 657                       folder number summary)
 658                      count summary charset))
 659                 ;; prefetching
 660                 (when wl-message-buffer-prefetch-debug
 661                   (setq time1 (current-time))
 662                   (message "Prefetching %d..." number))
 663                 (setq result (wl-message-buffer-display
 664                               folder number 'mime nil 'unread))
 665                 (when wl-message-buffer-prefetch-debug
 666                   (setq time2 (current-time))
 667                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 668                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 669                   (setq micro (+ micro (* 1000000 sec)))
 670                   (message "Prefetching %d...done(%f msec)."
 671                            number
 672                            (/ micro 1000.0))
 673                   (sit-for 0))
 674                 ;; set next prefetch
 675                 (wl-message-buffer-prefetch-set-timer
 676                  folder
 677                  (wl-message-buffer-prefetch-get-next
 678                   folder number summary)
 679                  count summary charset)
 680                 (sit-for 0)
 681                 ;; success prefetch
 682                 )))
 683         ;; finish prefetch
 684         (when wl-message-buffer-prefetch-debug
 685           (message "Buffer Cached Messages: %s"
 686                    (mapconcat
 687                     '(lambda (cache)
 688                        (if (numberp (nth 1 (car cache)))
 689                            (if (string=
 690                                 (nth 0 (car cache))
 691                                 (elmo-folder-name-internal folder))
 692                                (format "%d"
 693                                        (nth 1 (car cache)))
 694                              (format "*%d" (nth 1 (car cache))))
 695                          "-"))
 696                     wl-message-buffer-cache " "))) )))
 697
 698 (defvar wl-message-button-map (make-sparse-keymap))
 699
 700 (defun wl-message-add-button (from to function &optional data)
 701   "Create a button between FROM and TO with callback FUNCTION and DATA."
 702   (add-text-properties
 703    from to
 704    (nconc (list 'wl-message-button-callback function)
 705           (if data
 706               (list 'wl-message-button-data data))))
 707   (let ((ov (make-overlay from to)))
 708     (overlay-put ov 'mouse-face 'highlight)
 709     (overlay-put ov 'local-map wl-message-button-map)
 710     (overlay-put ov 'evaporate t)))
 711
 712 (defun wl-message-button-dispatcher (event)
 713   "Select the button under point."
 714   (interactive "@e")
 715   (mouse-set-point event)
 716   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 717         (data (get-text-property (point) 'wl-message-button-data)))
 718     (if callback
 719         (funcall callback data)
 720       (wl-message-button-dispatcher-internal event))))
 721
 722 (defun wl-message-button-refer-article (data)
 723   "Read article specified by Message-ID DATA at point."
 724   (switch-to-buffer-other-window
 725    wl-message-buffer-cur-summary-buffer)
 726   (if (wl-summary-jump-to-msg-by-message-id data)
 727       (wl-summary-redisplay)))
 728
 729 (defun wl-message-uu-substring (buf outbuf &optional first last)
 730   (save-excursion
 731     (set-buffer buf)
 732     (search-forward "\n\n")
 733     (let ((sp (point))
 734           ep filename case-fold-search)
 735       (catch 'done
 736         (if first
 737             (progn
 738               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 739                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 740                 (throw 'done nil)))
 741           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 742         (beginning-of-line)
 743         (setq sp (point))
 744         (goto-char (point-max))
 745         (if last
 746             (re-search-backward "^end" sp t)
 747           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 748         (forward-line 1)
 749         (setq ep (point))
 750         (set-buffer outbuf)
 751         (goto-char (point-max))
 752         (insert-buffer-substring buf sp ep)
 753         (set-buffer buf)
 754         filename))))
 755
 756 (require 'product)
 757 (product-provide (provide 'wl-message) (require 'wl-version))
 758
 759 ;;; wl-message.el ends here