wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'wl-vars)
  34 (require 'wl-highlight)
  35 (require 'elmo)
  36 (require 'elmo-mime)
  37 (require 'timer)
  38
  39 (eval-when-compile
  40   (require 'wl-mime)
  41   (require 'mime-view)
  42   (defalias-maybe 'event-window 'ignore)
  43   (defalias-maybe 'posn-window 'ignore)
  44   (defalias-maybe 'event-start 'ignore)
  45   (defalias-maybe 'mime-open-entity 'ignore)
  46   (defalias-maybe 'itimer-function 'ignore)
  47   (defalias-maybe 'delete-itimer 'ignore)
  48   (defvar-maybe itimer-list))
  49
  50 (defvar wl-message-buffer-prefetch-get-next-function
  51   'wl-summary-default-get-next-msg)
  52
  53 (defvar wl-message-buffer-prefetch-debug nil)
  54 (defvar wl-message-buffer-prefetch-timer nil)
  55
  56 (defvar wl-message-buffer nil) ; message buffer.
  57
  58 (defvar wl-message-buffer-cur-folder nil)
  59 (defvar wl-message-buffer-cur-number nil)
  60 (defvar wl-message-buffer-cur-display-type nil)
  61 (defvar wl-message-buffer-cur-summary-buffer nil)
  62 (defvar wl-message-buffer-require-all-header nil)
  63 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  64 (defvar wl-message-buffer-mode-line-formatter nil)
  65 (defvar wl-message-buffer-flag-indicator nil)
  66 (defvar wl-message-buffer-mime-entity nil)
  67
  68 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  70 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  71 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  72 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  73 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  74 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  75 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  76 (make-variable-buffer-local 'wl-message-buffer-mime-entity)
  77
  78 (defvar wl-fixed-window-configuration nil)
  79
  80 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  81
  82 ;;; Message buffer cache.
  83
  84 (defvar wl-message-buffer-cache nil
  85   "Message cache.  (old ... new) order alist.
  86 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  87
  88 (defmacro wl-message-buffer-cache-buffer-get (entry)
  89   (` (cdr (, entry))))
  90
  91 (defmacro wl-message-buffer-cache-folder-get (entry)
  92   (` (car (car (, entry)))))
  93
  94 (defmacro wl-message-buffer-cache-message-get (entry)
  95   (` (cdr (car (, entry)))))
  96
  97 (defmacro wl-message-buffer-cache-entry-make (key buf)
  98   (` (cons (, key) (, buf))))
  99
 100 (defmacro wl-message-buffer-cache-hit (key)
 101   "Return value assosiated with key."
 102   (` (wl-message-buffer-cache-buffer-get
 103       (assoc (, key) wl-message-buffer-cache))))
 104
 105 (defun wl-message-buffer-cache-sort (entry)
 106   "Move ENTRY to the top of `wl-message-buffer-cache'."
 107   (setq wl-message-buffer-cache
 108         (cons entry (delete entry wl-message-buffer-cache))))
 109 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 110 ;        (top pointer))
 111 ;    (while (cdr pointer)
 112 ;      (if (equal (car (cdr pointer)) entry)
 113 ;         (setcdr pointer (cdr (cdr pointer)))
 114 ;       (setq pointer (cdr pointer))))
 115 ;    (setcdr pointer (list entry))
 116 ;    (setq wl-message-buffer-cache (cdr top))))
 117
 118 (defconst wl-original-message-buffer-name " *Original*")
 119
 120 (defun wl-original-message-mode ()
 121   "A major mode for original message buffer."
 122   (setq major-mode 'wl-original-message-mode)
 123   (setq buffer-read-only t)
 124   (set-buffer-multibyte nil)
 125   (setq mode-name "Wanderlust original message"))
 126
 127 (defun wl-original-message-buffer-get (name)
 128   "Get original message buffer for NAME.
 129 If original message buffer already exists, it is re-used."
 130   (let* ((name (concat wl-original-message-buffer-name name))
 131          (buffer (get-buffer name)))
 132     (unless (and buffer (buffer-live-p buffer))
 133       (with-current-buffer (setq buffer (get-buffer-create name))
 134         (wl-original-message-mode)))
 135     buffer))
 136
 137 (defun wl-message-buffer-create ()
 138   "Create a new message buffer."
 139   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 140          (name (buffer-name buffer)))
 141     (with-current-buffer buffer
 142       (setq wl-message-buffer-original-buffer
 143             (wl-original-message-buffer-get name))
 144       (when wl-message-use-header-narrowing
 145         (wl-message-header-narrowing-setup))
 146       (run-hooks 'wl-message-buffer-created-hook))
 147     buffer))
 148
 149 (defun wl-message-buffer-cache-add (key)
 150   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 151 Return its cache buffer."
 152   (let ((len (length wl-message-buffer-cache))
 153         (buf nil))
 154     (if (< len wl-message-buffer-cache-size)
 155         (setq buf (wl-message-buffer-create))
 156       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 157         (if (buffer-live-p
 158              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 159             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 160           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 161           (setq buf (wl-message-buffer-create)))))
 162     (setq wl-message-buffer-cache
 163           (cons (wl-message-buffer-cache-entry-make key buf)
 164                 wl-message-buffer-cache))
 165     buf))
 166
 167 (defun wl-message-buffer-cache-delete (&optional key)
 168   "Delete the most recent cache entry"
 169   (if key
 170       (setq wl-message-buffer-cache
 171             (delq (assoc key wl-message-buffer-cache)
 172                   wl-message-buffer-cache))
 173     (let ((buf (wl-message-buffer-cache-buffer-get
 174                 (car wl-message-buffer-cache))))
 175       (setq wl-message-buffer-cache
 176             (nconc (cdr wl-message-buffer-cache)
 177                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 178
 179 (defun wl-message-buffer-cache-clean-up ()
 180   "A function to flush all decoded messages in cache list."
 181   (interactive)
 182   (if (and (eq major-mode 'wl-summary-mode)
 183            wl-message-buffer
 184            (get-buffer-window wl-message-buffer))
 185       (delete-window (get-buffer-window wl-message-buffer)))
 186   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 187   (setq wl-message-buffer-cache nil))
 188
 189 ;;; Message buffer handling from summary buffer.
 190
 191 (defun wl-message-buffer-window ()
 192   "Get message buffer window if any."
 193   (let* ((start-win (selected-window))
 194          (cur-win start-win))
 195     (catch 'found
 196       (while (progn
 197                (setq cur-win (next-window cur-win))
 198                (with-current-buffer (window-buffer cur-win)
 199                  (if (or (eq major-mode 'wl-message-mode)
 200                          (eq major-mode 'mime-view-mode))
 201                      (throw 'found cur-win)))
 202                (not (eq cur-win start-win)))))))
 203
 204 (defun wl-message-select-buffer (buffer)
 205   "Select BUFFER as a message buffer."
 206   (let ((window (get-buffer-window buffer))
 207         (sum (car wl-message-window-size))
 208         (mes (cdr wl-message-window-size))
 209         whi)
 210     (when (and window
 211                (not (eq (save-excursion (set-buffer (window-buffer window))
 212                                         wl-message-buffer-cur-summary-buffer)
 213                         (current-buffer))))
 214       (delete-window window)
 215       (run-hooks 'wl-message-window-deleted-hook)
 216       (setq window nil))
 217     (if window
 218         (select-window window)
 219       (when wl-fixed-window-configuration
 220         (delete-other-windows)
 221         (and wl-stay-folder-window
 222              (wl-summary-toggle-disp-folder)))
 223       ;; There's no buffer window. Search for message window and snatch it.
 224       (if (setq window (wl-message-buffer-window))
 225           (select-window window)
 226         (setq whi (1- (window-height)))
 227         (if mes
 228             (progn
 229               (let ((total (+ sum mes)))
 230                 (setq sum (max window-min-height (/ (* whi sum) total)))
 231                 (setq mes (max window-min-height (/ (* whi mes) total))))
 232               (if (< whi (+ sum mes))
 233                   (enlarge-window (- (+ sum mes) whi)))))
 234         (split-window (get-buffer-window (current-buffer)) sum)
 235         (other-window 1)))
 236     (switch-to-buffer buffer)))
 237
 238 (defun wl-message-narrow-to-page (&optional arg)
 239   "Narrow to page.
 240 If ARG is specified, narrow to ARGth page."
 241   (interactive "P")
 242   (setq arg (if arg (prefix-numeric-value arg) 0))
 243   (save-excursion
 244     (condition-case ()
 245         (forward-page -1)               ; Beginning of current page.
 246       (beginning-of-buffer
 247        (goto-char (point-min))))
 248     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 249     (widen)
 250     (cond
 251      ((> arg 0) (forward-page arg))
 252      ((< arg 0) (forward-page (1- arg))))
 253     (forward-page)
 254     (if wl-break-pages
 255         (narrow-to-region (point)
 256                           (progn
 257                             (forward-page -1)
 258                             (if (and (eolp) (not (bobp)))
 259                                 (forward-line))
 260                             (point))))))
 261
 262 (defun wl-message-prev-page (&optional lines)
 263   "Scroll down current message by LINES.
 264 Returns non-nil if top of message."
 265   (interactive)
 266   (let (top real-top)
 267     (save-selected-window
 268       (unless (eq major-mode 'mime-view-mode)
 269         (when (buffer-live-p wl-message-buffer)
 270           (wl-message-select-buffer wl-message-buffer)))
 271       (move-to-window-line 0)
 272       (if (and wl-break-pages
 273                (bobp)
 274                (not (setq real-top (save-restriction (widen) (bobp)))))
 275           (progn
 276             (wl-message-narrow-to-page -1)
 277             (goto-char (point-max))
 278             (recenter))
 279         (if (not (bobp))
 280             (condition-case nil
 281                 (scroll-down (or lines wl-message-scroll-amount))
 282               (error))
 283           (setq top t)))
 284       (if real-top
 285           (let ((f (assq (mime-preview-original-major-mode)
 286                          mime-preview-over-to-previous-method-alist)))
 287             (if f (funcall (cdr f))))))
 288     top))
 289
 290 (defun wl-message-next-page (&optional lines)
 291   "Scroll up current message by LINES.
 292 Returns non-nil if bottom of message."
 293   (interactive)
 294   (let (bottom)
 295     (save-selected-window
 296       (unless (eq major-mode 'mime-view-mode)
 297         (when (buffer-live-p wl-message-buffer)
 298           (wl-message-select-buffer wl-message-buffer)))
 299       (move-to-window-line -1)
 300       (if (save-excursion
 301             (end-of-line)
 302             (and (pos-visible-in-window-p)
 303                  (eobp)))
 304           (if (or (null wl-break-pages)
 305                   (save-excursion
 306                     (save-restriction
 307                       (widen) (forward-line) (eobp))))
 308               (setq bottom t)
 309             (wl-message-narrow-to-page 1)
 310             (setq bottom nil))
 311         (condition-case ()
 312             (static-if (boundp 'window-pixel-scroll-increment)
 313                 ;; XEmacs 21.2.20 and later.
 314                 (let (window-pixel-scroll-increment)
 315                   (scroll-up (or lines wl-message-scroll-amount)))
 316               (scroll-up (or lines wl-message-scroll-amount)))
 317           (end-of-buffer
 318            (goto-char (point-max))))
 319         (setq bottom nil))
 320       (if (eobp)
 321           (let ((f (assq (mime-preview-original-major-mode)
 322                          mime-preview-over-to-next-method-alist)))
 323             (if f (funcall (cdr f))))))
 324     bottom))
 325
 326
 327 (defun wl-message-follow-current-entity (buffer)
 328   "Follow to current message."
 329   (wl-draft-reply (wl-message-get-original-buffer)
 330                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 331   (let ((mail-reply-buffer buffer))
 332     (wl-draft-yank-from-mail-reply-buffer nil)))
 333
 334 ;;
 335
 336 (defun wl-message-mode ()
 337   "A major mode for message displaying."
 338   (interactive)
 339   (setq major-mode 'wl-message-mode)
 340   (setq buffer-read-only t)
 341   (setq mode-name "Message"))
 342
 343 (defun wl-message-exit ()
 344   "Move to summary buffer or mother buffer."
 345   (interactive)
 346   (let (summary-buf summary-win mother-buffer)
 347     (cond ((setq summary-buf wl-message-buffer-cur-summary-buffer)
 348            (if (setq summary-win (get-buffer-window summary-buf))
 349                (select-window summary-win)
 350              (switch-to-buffer summary-buf)
 351              (wl-message-select-buffer wl-message-buffer)
 352              (select-window (get-buffer-window summary-buf))))
 353           ((setq mother-buffer mime-mother-buffer)
 354            (kill-buffer (current-buffer))
 355            (switch-to-buffer mother-buffer)))
 356     (run-hooks 'wl-message-exit-hook)))
 357
 358 (defun wl-message-toggle-disp-summary ()
 359   (interactive)
 360   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 361         summary-win)
 362     (if (and summary-buf
 363              (buffer-live-p summary-buf))
 364         (if (setq summary-win (get-buffer-window summary-buf))
 365             (delete-window summary-win)
 366           (switch-to-buffer summary-buf)
 367           (wl-message-select-buffer wl-message-buffer))
 368       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 369                                    nil nil t)
 370                                         ; no summary-buf
 371       (let ((sum-buf (current-buffer)))
 372         (wl-message-select-buffer wl-message-buffer)
 373         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 374
 375 (defun wl-message-get-original-buffer ()
 376   "Get original buffer for current message buffer."
 377   (if (buffer-live-p wl-message-buffer-original-buffer)
 378       wl-message-buffer-original-buffer
 379     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 380
 381 (defun wl-message-add-buttons-to-body (start end)
 382   (save-excursion
 383     (save-restriction
 384       (narrow-to-region start end)
 385       (let ((case-fold-search t)
 386             (alist wl-message-body-button-alist)
 387             entry)
 388         (while alist
 389           (setq entry (car alist)
 390                 alist (cdr alist))
 391           (goto-char (point-min))
 392           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 393             (unless (get-text-property (point) 'keymap)
 394               (wl-message-add-button
 395                (match-beginning (nth 1 entry))
 396                (match-end (nth 1 entry))
 397                (nth 2 entry)
 398                (match-string (nth 3 entry))))))))))
 399
 400 (defun wl-message-add-buttons-to-header (start end)
 401   (save-excursion
 402     (save-restriction
 403       (narrow-to-region start end)
 404       (let ((case-fold-search t)
 405             (alist wl-message-header-button-alist)
 406             entry)
 407         (while alist
 408           (setq entry (car alist)
 409                 alist (cdr alist))
 410           (goto-char (point-min))
 411           (while (re-search-forward (car entry) nil t)
 412             (setq start (match-beginning 0)
 413                   end (if (re-search-forward "^[^ \t]" nil t)
 414                           (match-beginning 0)
 415                         (point-max)))
 416             (goto-char start)
 417             (while (re-search-forward (nth 1 entry) end t)
 418               (wl-message-add-button
 419                (match-beginning (nth 2 entry))
 420                (match-end (nth 2 entry))
 421                (nth 3 entry) (match-string (nth 4 entry))))
 422             (goto-char end)))))))
 423
 424 ;; display-type object definition.
 425 (defun wl-message-make-display-type (mime header)
 426   (let (symbol)
 427     (prog1
 428         (setq symbol (intern (format "%s-%s-header" mime header)))
 429       (put symbol
 430            'wl-message-display-type
 431            (list :mime mime :header header)))))
 432
 433 (defun wl-message-display-type-property (display-type prop)
 434   (plist-get (get display-type 'wl-message-display-type) prop))
 435
 436 (defun wl-message-mime-analysis-p (display-type &optional header-or-body)
 437   (let ((mode (wl-message-display-type-property display-type :mime)))
 438     (case header-or-body
 439       (header
 440        (memq mode '(mime header-only)))
 441       (t
 442        (eq mode 'mime)))))
 443
 444 (defun wl-message-display-all-header-p (display-type)
 445   (eq (wl-message-display-type-property display-type :header) 'all))
 446
 447 (defun wl-message-display-no-merge-p (display-type)
 448   (eq (wl-message-display-type-property display-type :mime) 'no-merge))
 449
 450 (defun wl-message-buffer-display-type (&optional message-buffer)
 451   (if message-buffer
 452       (with-current-buffer message-buffer
 453         wl-message-buffer-cur-display-type)
 454     wl-message-buffer-cur-display-type))
 455
 456 (defun wl-message-flag-indicator (flags)
 457   (let ((flags (elmo-get-global-flags flags)))
 458     (if (null flags)
 459         ""
 460       (concat
 461        " ("
 462        (mapconcat
 463         (lambda (flag)
 464           (let ((indicator (capitalize (symbol-name flag)))
 465                 face)
 466             (when (and (assq flag wl-summary-flag-alist)
 467                        (facep
 468                         (setq face (intern
 469                                     (format "wl-highlight-summary-%s-flag-face"
 470                                             flag)))))
 471               (put-text-property 0 (length indicator) 'face face indicator))
 472             indicator))
 473         (sort flags
 474               (lambda (l r)
 475                 (> (length (memq (assq l wl-summary-flag-alist)
 476                                  wl-summary-flag-alist))
 477                    (length (memq (assq r wl-summary-flag-alist)
 478                                  wl-summary-flag-alist)))))
 479         ", ")
 480        ")"))))
 481
 482 (defun wl-message-redisplay (folder number display-type &optional force-reload)
 483   (let* ((default-mime-charset wl-mime-charset)
 484          (buffer-read-only nil)
 485          (summary-buf (current-buffer))
 486          message-buf entity summary-win flags)
 487     (setq buffer-read-only nil)
 488     (setq wl-message-buffer (wl-message-buffer-display
 489                              folder number display-type force-reload))
 490     (setq message-buf wl-message-buffer)
 491     (wl-message-select-buffer wl-message-buffer)
 492
 493     (set-buffer message-buf)
 494     (wl-deactivate-region)
 495     (make-local-variable 'truncate-partial-width-windows)
 496     (setq truncate-partial-width-windows nil)
 497     (setq truncate-lines wl-message-truncate-lines)
 498     (setq buffer-read-only nil)
 499     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 500     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 501     (setq wl-message-buffer-cur-number number)
 502     (setq wl-message-buffer-flag-indicator
 503           (wl-message-flag-indicator (elmo-message-flags folder number)))
 504     (wl-line-formatter-setup
 505      wl-message-buffer-mode-line-formatter
 506      wl-message-mode-line-format
 507      wl-message-mode-line-format-spec-alist)
 508     (setq mode-line-buffer-identification
 509           (funcall wl-message-buffer-mode-line-formatter))
 510     ;; highlight body
 511 ;    (when wl-highlight-body-too
 512 ;      (wl-highlight-body))
 513     (ignore-errors (wl-message-narrow-to-page))
 514     (goto-char (point-min))
 515     (when (re-search-forward "^$" nil t)
 516       (wl-message-add-buttons-to-header (point-min) (point))
 517       (wl-message-add-buttons-to-body (point) (point-max)))
 518     (when (and wl-message-use-header-narrowing
 519                (not (wl-message-display-all-header-p display-type)))
 520       (wl-message-header-narrowing))
 521     (goto-char (point-min))
 522     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 523     ;; go back to summary mode
 524     (set-buffer-modified-p nil)
 525     (setq buffer-read-only t)
 526     (set-buffer summary-buf)
 527     (setq summary-win (get-buffer-window summary-buf))
 528     (if (window-live-p summary-win)
 529         (select-window summary-win))))
 530
 531 ;; Use message buffer cache.
 532 (defun wl-message-buffer-display (folder number display-type
 533                                          &optional force-reload unread)
 534   (let* ((msg-id (ignore-errors
 535                    (elmo-message-field folder number 'message-id)))
 536          (fname (elmo-folder-name-internal folder))
 537          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 538          (redisplay nil)
 539          entity)
 540     (when (and hit (not (buffer-live-p hit)))
 541       (wl-message-buffer-cache-delete (list fname number msg-id))
 542       (setq hit nil))
 543     (if hit
 544         (progn
 545           ;; move hit to the top.
 546           (wl-message-buffer-cache-sort
 547            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 548           (with-current-buffer hit
 549             ;; Rewind to the top page
 550             (widen)
 551             (goto-char (point-min))
 552             (ignore-errors (wl-message-narrow-to-page))
 553             (setq entity wl-message-buffer-mime-entity)
 554             (unless (eq wl-message-buffer-cur-display-type display-type)
 555               (setq redisplay t))))
 556       ;; delete tail and add new to the top.
 557       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 558       (setq redisplay t))
 559     (when (or force-reload redisplay)
 560       (condition-case err
 561           (with-current-buffer hit
 562             (when (or force-reload
 563                       (null entity)
 564                       (not (elmo-mime-entity-display-p
 565                             entity
 566                             (if (wl-message-mime-analysis-p display-type)
 567                                 'mime
 568                               'as-is)))
 569                       (if (wl-message-display-no-merge-p display-type)
 570                           (elmo-mime-entity-reassembled-p entity)
 571                         (elmo-mime-entity-fragment-p entity)))
 572               (setq entity (elmo-message-mime-entity
 573                             folder
 574                             number
 575                             (wl-message-get-original-buffer)
 576                             (and wl-message-auto-reassemble-message/partial
 577                                  (not (wl-message-display-no-merge-p
 578                                        display-type)))
 579                             force-reload
 580                             unread
 581                             (not (wl-message-mime-analysis-p display-type)))))
 582             (unless entity
 583               (error "Cannot display message %s/%s" fname number))
 584             (wl-message-display-internal entity display-type))
 585         (quit
 586          (wl-message-buffer-cache-delete)
 587          (error "Display message %s/%s is quitted" fname number))
 588         (error
 589          (wl-message-buffer-cache-delete)
 590          (signal (car err) (cdr err))
 591          nil))) ;; will not be used
 592     hit))
 593
 594 (defun wl-message-display-internal (entity display-type)
 595   (let ((default-mime-charset wl-mime-charset)
 596         (elmo-mime-charset wl-mime-charset)
 597         (wl-message-buffer-require-all-header
 598          (wl-message-display-all-header-p display-type)))
 599     (if (wl-message-mime-analysis-p display-type)
 600         (elmo-mime-entity-display entity
 601                                   (current-buffer)
 602                                   'wl-original-message-mode
 603                                   (wl-message-define-keymap))
 604       (let* ((elmo-mime-display-header-analysis
 605               (wl-message-mime-analysis-p display-type 'header))
 606              (wl-highlight-x-face-function
 607               (and elmo-mime-display-header-analysis
 608                    wl-highlight-x-face-function)))
 609         (elmo-mime-entity-display-as-is entity
 610                                         (current-buffer)
 611                                         'wl-original-message-mode
 612                                         (wl-message-define-keymap))
 613         (let (buffer-read-only)
 614           (wl-highlight-message (point-min) (point-max) t))))
 615     (setq wl-message-buffer-cur-display-type display-type
 616           wl-message-buffer-mime-entity entity)
 617     (run-hooks 'wl-message-display-internal-hook)
 618     (setq buffer-read-only t)))
 619
 620 (defun wl-message-buffer-prefetch-p (folder &optional number)
 621   (and (or (not number)
 622            (elmo-message-file-p folder number)
 623            (let ((size (elmo-message-field folder number 'size)))
 624              (not (and (integerp size)
 625                        wl-message-buffer-prefetch-threshold
 626                        (>= size wl-message-buffer-prefetch-threshold)))))
 627        (or (not number)
 628            (elmo-folder-plugged-p folder)
 629            (elmo-file-cache-exists-p
 630                  (elmo-message-field folder number 'message-id)))
 631        (or (cond
 632             ((eq wl-message-buffer-prefetch-folder-type-list t)
 633              t)
 634             ((and number wl-message-buffer-prefetch-folder-type-list)
 635              (memq (elmo-folder-type-internal
 636                     (elmo-message-folder folder number))
 637                    wl-message-buffer-prefetch-folder-type-list))
 638             (wl-message-buffer-prefetch-folder-type-list
 639              (let ((list wl-message-buffer-prefetch-folder-type-list)
 640                    type)
 641                (catch 'done
 642                  (while (setq type (pop list))
 643                    (if (elmo-folder-contains-type folder type)
 644                        (throw 'done t)))))))
 645            (cond
 646             ((consp wl-message-buffer-prefetch-folder-list)
 647              (wl-string-match-member (elmo-folder-name-internal folder)
 648                                      wl-message-buffer-prefetch-folder-list))
 649             (t wl-message-buffer-prefetch-folder-list)))))
 650
 651 (defsubst wl-message-buffer-prefetch-clear-timer ()
 652 ;;;     cannot use for the bug of fsf-compat package (1.09).
 653 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 654   (if (fboundp 'run-with-idle-timer)
 655       (if (featurep 'xemacs)
 656           (let ((p itimer-list))
 657             (while (car p)
 658               (if (eq 'wl-message-buffer-prefetch-subr
 659                       (itimer-function (car p)))
 660                   (delete-itimer (car p)))
 661               (setq p (cdr p))))
 662         ;; FSF Emacs is correct
 663         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 664
 665 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 666                                                        summary charset)
 667   (if (not (fboundp 'run-with-idle-timer))
 668       (when (sit-for wl-message-buffer-prefetch-idle-time)
 669         (wl-message-buffer-prefetch-subr
 670          folder number count summary charset))
 671     (run-with-idle-timer
 672      wl-message-buffer-prefetch-idle-time
 673      nil
 674      'wl-message-buffer-prefetch-subr
 675      folder number count summary charset)))
 676
 677 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 678
 679 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 680   (if (buffer-live-p summary)
 681       (with-current-buffer summary
 682         (let ((wl-summary-move-spec-alist
 683                (or wl-message-buffer-prefetch-move-spec-alist
 684                    wl-summary-move-spec-alist))
 685               (next number))
 686           (while (and (setq next (funcall
 687                                   wl-message-buffer-prefetch-get-next-function
 688                                   next))
 689                       (not (wl-message-buffer-prefetch-p folder next))))
 690           next))))
 691
 692 (defun wl-message-buffer-prefetch (folder number count
 693                                           &optional summary charset)
 694   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 695          (num number))
 696     (when (and (> count 0)
 697                (wl-message-buffer-prefetch-p folder))
 698       (unless (wl-message-buffer-prefetch-p folder number)
 699         (setq num
 700               (wl-message-buffer-prefetch-get-next folder number summary)))
 701       (when num
 702         (wl-message-buffer-prefetch-clear-timer)
 703         (wl-message-buffer-prefetch-set-timer
 704          folder num count summary charset)))))
 705
 706 (defun wl-message-buffer-prefetch-next (folder number count
 707                                                &optional summary charset)
 708   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 709          next)
 710     (when (and (> count 0)
 711                (wl-message-buffer-prefetch-p folder))
 712       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 713       (when next
 714         (wl-message-buffer-prefetch-clear-timer)
 715         (wl-message-buffer-prefetch-set-timer
 716          folder next count summary charset)))))
 717
 718 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 719   (if (buffer-live-p summary)
 720       (with-current-buffer summary
 721         (if (and number
 722                  (numberp count)
 723                  (>= (setq count (- count 1)) 0)
 724                  (string= (elmo-folder-name-internal folder)
 725                           (wl-summary-buffer-folder-name)))
 726             (let* ((wl-mime-charset      charset)
 727                    (default-mime-charset charset)
 728                    (message-id (elmo-message-field folder number 'message-id))
 729                    (key (list (elmo-folder-name-internal folder)
 730                               number message-id))
 731                    (hit (wl-message-buffer-cache-hit key))
 732                    (display-type (wl-message-make-display-type
 733                                   wl-summary-buffer-display-mime-mode
 734                                   wl-summary-buffer-display-header-mode))
 735                    time1 time2 sec micro)
 736               (when wl-message-buffer-prefetch-debug
 737                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 738               (if (and hit (buffer-live-p hit))
 739                   (progn
 740                     (wl-message-buffer-cache-sort
 741                      (wl-message-buffer-cache-entry-make key hit))
 742                     (wl-message-buffer-prefetch-subr
 743                      folder
 744                      (wl-message-buffer-prefetch-get-next
 745                       folder number summary)
 746                      count summary charset))
 747                 ;; prefetching
 748                 (when wl-message-buffer-prefetch-debug
 749                   (setq time1 (current-time))
 750                   (message "Prefetching %d..." number))
 751                 (wl-message-buffer-display folder number
 752                                            display-type nil 'unread)
 753                 (when (elmo-message-use-cache-p folder number)
 754                   (elmo-message-set-cached folder number t))
 755                 (when wl-message-buffer-prefetch-debug
 756                   (setq time2 (current-time))
 757                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 758                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 759                   (setq micro (+ micro (* 1000000 sec)))
 760                   (message "Prefetching %d...done(%f msec)."
 761                            number
 762                            (/ micro 1000.0))
 763                   (sit-for 0))
 764                 ;; set next prefetch
 765                 (wl-message-buffer-prefetch-set-timer
 766                  folder
 767                  (wl-message-buffer-prefetch-get-next
 768                   folder number summary)
 769                  count summary charset)
 770                 (sit-for 0)
 771                 ;; success prefetch
 772                 )))
 773         ;; finish prefetch
 774         (when wl-message-buffer-prefetch-debug
 775           (message "Buffer Cached Messages: %s"
 776                    (mapconcat
 777                     '(lambda (cache)
 778                        (if (numberp (nth 1 (car cache)))
 779                            (if (string=
 780                                 (nth 0 (car cache))
 781                                 (elmo-folder-name-internal folder))
 782                                (format "%d"
 783                                        (nth 1 (car cache)))
 784                              (format "*%d" (nth 1 (car cache))))
 785                          "-"))
 786                     wl-message-buffer-cache " "))) )))
 787
 788 (defvar wl-message-button-map (make-sparse-keymap))
 789
 790 (defun wl-message-add-button (from to function &optional data)
 791   "Create a button between FROM and TO with callback FUNCTION and DATA."
 792   (add-text-properties
 793    from to
 794    (nconc (list 'wl-message-button-callback function)
 795           (if data
 796               (list 'wl-message-button-data data))))
 797   (let ((ov (make-overlay from to)))
 798     (overlay-put ov 'mouse-face 'highlight)
 799     (overlay-put ov 'local-map wl-message-button-map)
 800     (overlay-put ov 'evaporate t)))
 801
 802 (defun wl-message-button-dispatcher (event)
 803   "Select the button under point."
 804   (interactive "@e")
 805   (mouse-set-point event)
 806   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 807         (data (get-text-property (point) 'wl-message-button-data)))
 808     (if callback
 809         (funcall callback data)
 810       (wl-message-button-dispatcher-internal event))))
 811
 812 (defun wl-message-button-refer-article (data)
 813   "Read article specified by Message-ID DATA at point."
 814   (switch-to-buffer-other-window
 815    wl-message-buffer-cur-summary-buffer)
 816   (if (wl-summary-jump-to-msg-by-message-id data)
 817       (wl-summary-redisplay)))
 818
 819 (defun wl-message-uu-substring (buf outbuf &optional first last)
 820   (save-excursion
 821     (set-buffer buf)
 822     (search-forward "\n\n")
 823     (let ((sp (point))
 824           ep filename case-fold-search)
 825       (catch 'done
 826         (if first
 827             (progn
 828               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 829                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 830                 (throw 'done nil)))
 831           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 832         (beginning-of-line)
 833         (setq sp (point))
 834         (goto-char (point-max))
 835         (if last
 836             (re-search-backward "^end" sp t)
 837           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 838         (forward-line 1)
 839         (setq ep (point))
 840         (set-buffer outbuf)
 841         (goto-char (point-max))
 842         (insert-buffer-substring buf sp ep)
 843         (set-buffer buf)
 844         filename))))
 845
 846 ;;; Header narrowing courtesy of Hideyuki Shirai.
 847 (defun wl-message-header-narrowing ()
 848   "Narrowing headers."
 849   (unless (eq this-command 'wl-summary-redisplay-all-header)
 850     (save-excursion
 851       (save-restriction
 852         (goto-char (point-min))
 853         (if (re-search-forward "^$" nil t)
 854             (beginning-of-line)
 855           (goto-char (point-max)))
 856         (narrow-to-region (point-min) (point))
 857         (let ((fields wl-message-header-narrowing-fields))
 858           (while fields
 859             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 860             (setq fields (cdr fields))))))))
 861
 862 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 863 (define-key wl-message-header-narrowing-map [mouse-2]
 864   'wl-message-header-narrowing-again-at-mouse)
 865
 866 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 867 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 868   'wl-message-header-narrowing-widen-at-mouse)
 869
 870 (defun wl-message-header-narrowing-again-at-mouse (event)
 871   (interactive "e")
 872   (save-window-excursion
 873     (save-excursion
 874       (mouse-set-point event)
 875       (wl-message-header-narrowing))))
 876
 877 (defun wl-message-header-narrowing-1 (hregexp)
 878   (let ((case-fold-search t)
 879         ov start end)
 880     (goto-char (point-min))
 881     (while (re-search-forward hregexp nil t)
 882       (setq start (match-beginning 0))
 883       (forward-line 1)
 884       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 885                        (forward-line -1)
 886                        (line-end-position)))
 887       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 888           (forward-line 1)
 889         (goto-char start)
 890         (forward-line (1- wl-message-header-narrowing-lines))
 891         (end-of-line)
 892         (setq start (point))
 893         (unless (eq (get-char-property start 'invisible)
 894                     'wl-message-header-narrowing)
 895           (setq ov (or
 896                     (let ((ovs (overlays-at start))
 897                           ov)
 898                       (while (and ovs (not (overlayp ov)))
 899                         (if (overlay-get (car ovs)
 900                                          'wl-message-header-narrowing)
 901                             (setq ov (car ovs)))
 902                         (setq ovs (cdr ovs)))
 903                       ov)
 904                     (make-overlay start end)))
 905           (overlay-put ov 'wl-message-header-narrowing t)
 906           (overlay-put ov 'evaporate t)
 907           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 908           (overlay-put ov 'after-string
 909                        wl-message-header-narrowing-string))))))
 910
 911 (defun wl-message-header-narrowing-widen-at-mouse (event)
 912   (interactive "e")
 913   (save-selected-window
 914     (select-window (posn-window (event-start event)))
 915     (let* ((win (selected-window))
 916            (wpos (window-start win))
 917            (pos (mouse-set-point event))
 918            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 919            ov)
 920       (while (and ovs (not (overlayp ov)))
 921         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 922           (setq ov (car ovs)))
 923         (setq ovs (cdr ovs)))
 924       (when (overlayp ov)
 925         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 926         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 927         (overlay-put ov 'invisible nil)
 928         (overlay-put ov 'after-string nil))
 929       (set-window-start win wpos))))
 930
 931 (defun wl-message-header-narrowing-setup ()
 932   (when (boundp 'line-move-ignore-invisible)
 933     (set (make-local-variable 'line-move-ignore-invisible) t))
 934   (set-text-properties 0 (length wl-message-header-narrowing-string)
 935                        `(face
 936                          wl-message-header-narrowing-face
 937                          keymap
 938                          ,wl-message-header-narrowing-widen-map)
 939                        wl-message-header-narrowing-string))
 940
 941 (defun wl-message-header-narrowing-toggle ()
 942   "Toggle header narrowing."
 943   (interactive)
 944   (when wl-message-use-header-narrowing
 945     (save-excursion
 946       (goto-char (point-min))
 947       (if (re-search-forward "^$" nil t)
 948           (beginning-of-line)
 949         (goto-char (point-max)))
 950       (let ((ovs (overlays-in (point-min) (point)))
 951             ov hn-ovs)
 952         (while (setq ov (car ovs))
 953           (when (overlay-get ov 'wl-message-header-narrowing)
 954             (setq hn-ovs (cons ov hn-ovs)))
 955           (setq ovs (cdr ovs)))
 956         (if hn-ovs
 957             (while hn-ovs
 958               (delete-overlay (car hn-ovs))
 959               (setq hn-ovs (cdr hn-ovs)))
 960           (wl-message-header-narrowing))))))
 961
 962 (require 'product)
 963 (product-provide (provide 'wl-message) (require 'wl-version))
 964
 965 ;;; wl-message.el ends here