wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore)
  45   (defalias-maybe 'itimer-function 'ignore)
  46   (defalias-maybe 'delete-itimer 'ignore)
  47   (defvar-maybe itimer-list))
  48
  49 (defvar wl-message-buffer-prefetch-get-next-function
  50   'wl-summary-default-get-next-msg)
  51
  52 (defvar wl-message-buffer-prefetch-debug nil)
  53 (defvar wl-message-buffer-prefetch-timer nil)
  54
  55 (defvar wl-message-buffer nil) ; message buffer.
  56
  57 (defvar wl-message-buffer-cur-folder nil)
  58 (defvar wl-message-buffer-cur-number nil)
  59 (defvar wl-message-buffer-cur-display-type nil)
  60 (defvar wl-message-buffer-cur-summary-buffer nil)
  61 (defvar wl-message-buffer-require-all-header nil)
  62 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  63 (defvar wl-message-buffer-mode-line-formatter nil)
  64 (defvar wl-message-buffer-flag-indicator nil)
  65
  66 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  67 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  68 (make-variable-buffer-local 'wl-message-buffer-cur-display-type)
  69 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  70 (make-variable-buffer-local 'wl-message-buffer-require-all-header)
  71 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  72 (make-variable-buffer-local 'wl-message-buffer-mode-line-formatter)
  73 (make-variable-buffer-local 'wl-message-buffer-flag-indicator)
  74
  75 (defvar wl-fixed-window-configuration nil)
  76
  77 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  78
  79 ;;; Message buffer cache.
  80
  81 (defvar wl-message-buffer-cache nil
  82   "Message cache.  (old ... new) order alist.
  83 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  84
  85 (defmacro wl-message-buffer-cache-buffer-get (entry)
  86   (` (cdr (, entry))))
  87
  88 (defmacro wl-message-buffer-cache-folder-get (entry)
  89   (` (car (car (, entry)))))
  90
  91 (defmacro wl-message-buffer-cache-message-get (entry)
  92   (` (cdr (car (, entry)))))
  93
  94 (defmacro wl-message-buffer-cache-entry-make (key buf)
  95   (` (cons (, key) (, buf))))
  96
  97 (defmacro wl-message-buffer-cache-hit (key)
  98   "Return value assosiated with key."
  99   (` (wl-message-buffer-cache-buffer-get
 100       (assoc (, key) wl-message-buffer-cache))))
 101
 102 (defun wl-message-buffer-cache-sort (entry)
 103   "Move ENTRY to the top of `wl-message-buffer-cache'."
 104   (setq wl-message-buffer-cache
 105         (cons entry (delete entry wl-message-buffer-cache))))
 106 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 107 ;        (top pointer))
 108 ;    (while (cdr pointer)
 109 ;      (if (equal (car (cdr pointer)) entry)
 110 ;         (setcdr pointer (cdr (cdr pointer)))
 111 ;       (setq pointer (cdr pointer))))
 112 ;    (setcdr pointer (list entry))
 113 ;    (setq wl-message-buffer-cache (cdr top))))
 114
 115 (defconst wl-original-message-buffer-name " *Original*")
 116
 117 (defun wl-original-message-mode ()
 118   "A major mode for original message buffer."
 119   (setq major-mode 'wl-original-message-mode)
 120   (setq buffer-read-only t)
 121   (set-buffer-multibyte nil)
 122   (setq mode-name "Wanderlust original message"))
 123
 124 (defun wl-original-message-buffer-get (name)
 125   "Get original message buffer for NAME.
 126 If original message buffer already exists, it is re-used."
 127   (let* ((name (concat wl-original-message-buffer-name name))
 128          (buffer (get-buffer name)))
 129     (unless (and buffer (buffer-live-p buffer))
 130       (with-current-buffer (setq buffer (get-buffer-create name))
 131         (wl-original-message-mode)))
 132     buffer))
 133
 134 (defun wl-message-buffer-create ()
 135   "Create a new message buffer."
 136   (let* ((buffer (generate-new-buffer wl-message-buffer-name))
 137          (name (buffer-name buffer)))
 138     (with-current-buffer buffer
 139       (setq wl-message-buffer-original-buffer
 140             (wl-original-message-buffer-get name))
 141       (when wl-message-use-header-narrowing
 142         (wl-message-header-narrowing-setup))
 143       (run-hooks 'wl-message-buffer-created-hook))
 144     buffer))
 145
 146 (defun wl-message-buffer-cache-add (key)
 147   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 148 Return its cache buffer."
 149   (let ((len (length wl-message-buffer-cache))
 150         (buf nil))
 151     (if (< len wl-message-buffer-cache-size)
 152         (setq buf (wl-message-buffer-create))
 153       (let ((entry (nth (1- len) wl-message-buffer-cache)))
 154         (if (buffer-live-p
 155              (setq buf (wl-message-buffer-cache-buffer-get entry)))
 156             (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil)
 157           (setq wl-message-buffer-cache (delq entry wl-message-buffer-cache))
 158           (setq buf (wl-message-buffer-create)))))
 159     (setq wl-message-buffer-cache
 160           (cons (wl-message-buffer-cache-entry-make key buf)
 161                 wl-message-buffer-cache))
 162     buf))
 163
 164 (defun wl-message-buffer-cache-delete (&optional key)
 165   "Delete the most recent cache entry"
 166   (if key
 167       (setq wl-message-buffer-cache
 168             (delq (assoc key wl-message-buffer-cache)
 169                   wl-message-buffer-cache))
 170     (let ((buf (wl-message-buffer-cache-buffer-get
 171                 (car wl-message-buffer-cache))))
 172       (setq wl-message-buffer-cache
 173             (nconc (cdr wl-message-buffer-cache)
 174                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 175
 176 (defun wl-message-buffer-cache-clean-up ()
 177   "A function to flush all decoded messages in cache list."
 178   (interactive)
 179   (if (and (eq major-mode 'wl-summary-mode)
 180            wl-message-buffer
 181            (get-buffer-window wl-message-buffer))
 182       (delete-window (get-buffer-window wl-message-buffer)))
 183   (wl-kill-buffers (regexp-quote wl-message-buffer-name))
 184   (setq wl-message-buffer-cache nil))
 185
 186 ;;; Message buffer handling from summary buffer.
 187
 188 (defun wl-message-buffer-window ()
 189   "Get message buffer window if any."
 190   (let* ((start-win (selected-window))
 191          (cur-win start-win))
 192     (catch 'found
 193       (while (progn
 194                (setq cur-win (next-window cur-win))
 195                (with-current-buffer (window-buffer cur-win)
 196                  (if (or (eq major-mode 'wl-message-mode)
 197                          (eq major-mode 'mime-view-mode))
 198                      (throw 'found cur-win)))
 199                (not (eq cur-win start-win)))))))
 200
 201 (defun wl-message-select-buffer (buffer)
 202   "Select BUFFER as a message buffer."
 203   (let ((window (get-buffer-window buffer))
 204         (sum (car wl-message-window-size))
 205         (mes (cdr wl-message-window-size))
 206         whi)
 207     (when (and window
 208                (not (eq (save-excursion (set-buffer (window-buffer window))
 209                                         wl-message-buffer-cur-summary-buffer)
 210                         (current-buffer))))
 211       (delete-window window)
 212       (run-hooks 'wl-message-window-deleted-hook)
 213       (setq window nil))
 214     (if window
 215         (select-window window)
 216       (when wl-fixed-window-configuration
 217         (delete-other-windows)
 218         (and wl-stay-folder-window
 219              (wl-summary-toggle-disp-folder)))
 220       ;; There's no buffer window. Search for message window and snatch it.
 221       (if (setq window (wl-message-buffer-window))
 222           (select-window window)
 223         (setq whi (1- (window-height)))
 224         (if mes
 225             (progn
 226               (let ((total (+ sum mes)))
 227                 (setq sum (max window-min-height (/ (* whi sum) total)))
 228                 (setq mes (max window-min-height (/ (* whi mes) total))))
 229               (if (< whi (+ sum mes))
 230                   (enlarge-window (- (+ sum mes) whi)))))
 231         (split-window (get-buffer-window (current-buffer)) sum)
 232         (other-window 1)))
 233     (switch-to-buffer buffer)))
 234
 235 (defun wl-message-narrow-to-page (&optional arg)
 236   "Narrow to page.
 237 If ARG is specified, narrow to ARGth page."
 238   (interactive "P")
 239   (setq arg (if arg (prefix-numeric-value arg) 0))
 240   (save-excursion
 241     (condition-case ()
 242         (forward-page -1)               ; Beginning of current page.
 243       (beginning-of-buffer
 244        (goto-char (point-min))))
 245     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 246     (widen)
 247     (cond
 248      ((> arg 0) (forward-page arg))
 249      ((< arg 0) (forward-page (1- arg))))
 250     (forward-page)
 251     (if wl-break-pages
 252         (narrow-to-region (point)
 253                           (progn
 254                             (forward-page -1)
 255                             (if (and (eolp) (not (bobp)))
 256                                 (forward-line))
 257                             (point))))))
 258
 259 (defun wl-message-prev-page (&optional lines)
 260   "Scroll down current message by LINES.
 261 Returns non-nil if top of message."
 262   (interactive)
 263   (let (top real-top)
 264     (save-selected-window
 265       (unless (eq major-mode 'mime-view-mode)
 266         (when (buffer-live-p wl-message-buffer)
 267           (wl-message-select-buffer wl-message-buffer)))
 268       (move-to-window-line 0)
 269       (if (and wl-break-pages
 270                (bobp)
 271                (not (setq real-top (save-restriction (widen) (bobp)))))
 272           (progn
 273             (wl-message-narrow-to-page -1)
 274             (goto-char (point-max))
 275             (recenter))
 276         (if (not (bobp))
 277             (condition-case nil
 278                 (scroll-down (or lines wl-message-scroll-amount))
 279               (error))
 280           (setq top t)))
 281       (if real-top
 282           (let ((f (assq (mime-preview-original-major-mode)
 283                          mime-preview-over-to-previous-method-alist)))
 284             (if f (funcall (cdr f))))))
 285     top))
 286
 287 (defun wl-message-next-page (&optional lines)
 288   "Scroll up current message by LINES.
 289 Returns non-nil if bottom of message."
 290   (interactive)
 291   (let (bottom)
 292     (save-selected-window
 293       (unless (eq major-mode 'mime-view-mode)
 294         (when (buffer-live-p wl-message-buffer)
 295           (wl-message-select-buffer wl-message-buffer)))
 296       (move-to-window-line -1)
 297       (if (save-excursion
 298             (end-of-line)
 299             (and (pos-visible-in-window-p)
 300                  (eobp)))
 301           (if (or (null wl-break-pages)
 302                   (save-excursion
 303                     (save-restriction
 304                       (widen) (forward-line) (eobp))))
 305               (setq bottom t)
 306             (wl-message-narrow-to-page 1)
 307             (setq bottom nil))
 308         (condition-case ()
 309             (static-if (boundp 'window-pixel-scroll-increment)
 310                 ;; XEmacs 21.2.20 and later.
 311                 (let (window-pixel-scroll-increment)
 312                   (scroll-up (or lines wl-message-scroll-amount)))
 313               (scroll-up (or lines wl-message-scroll-amount)))
 314           (end-of-buffer
 315            (goto-char (point-max))))
 316         (setq bottom nil))
 317       (if (eobp)
 318           (let ((f (assq (mime-preview-original-major-mode)
 319                          mime-preview-over-to-next-method-alist)))
 320             (if f (funcall (cdr f))))))
 321     bottom))
 322
 323
 324 (defun wl-message-follow-current-entity (buffer)
 325   "Follow to current message."
 326   (wl-draft-reply (wl-message-get-original-buffer)
 327                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 328   (let ((mail-reply-buffer buffer))
 329     (wl-draft-yank-from-mail-reply-buffer nil)))
 330
 331 ;;
 332
 333 (defun wl-message-mode ()
 334   "A major mode for message displaying."
 335   (interactive)
 336   (setq major-mode 'wl-message-mode)
 337   (setq buffer-read-only t)
 338   (setq mode-name "Message"))
 339
 340 (defun wl-message-exit ()
 341   "Move to summary buffer or mother buffer."
 342   (interactive)
 343   (let (summary-buf summary-win mother-buffer)
 344     (cond ((setq summary-buf wl-message-buffer-cur-summary-buffer)
 345            (if (setq summary-win (get-buffer-window summary-buf))
 346                (select-window summary-win)
 347              (switch-to-buffer summary-buf)
 348              (wl-message-select-buffer wl-message-buffer)
 349              (select-window (get-buffer-window summary-buf))))
 350           ((setq mother-buffer mime-mother-buffer)
 351            (kill-buffer (current-buffer))
 352            (switch-to-buffer mother-buffer)))
 353     (run-hooks 'wl-message-exit-hook)))
 354
 355 (defun wl-message-toggle-disp-summary ()
 356   (interactive)
 357   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 358         summary-win)
 359     (if (and summary-buf
 360              (buffer-live-p summary-buf))
 361         (if (setq summary-win (get-buffer-window summary-buf))
 362             (delete-window summary-win)
 363           (switch-to-buffer summary-buf)
 364           (wl-message-select-buffer wl-message-buffer))
 365       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 366                                    nil nil t)
 367                                         ; no summary-buf
 368       (let ((sum-buf (current-buffer)))
 369         (wl-message-select-buffer wl-message-buffer)
 370         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 371
 372 (defun wl-message-get-original-buffer ()
 373   "Get original buffer for current message buffer."
 374   (if (buffer-live-p wl-message-buffer-original-buffer)
 375       wl-message-buffer-original-buffer
 376     (wl-original-message-buffer-get (buffer-name (current-buffer)))))
 377
 378 (defun wl-message-add-buttons-to-body (start end)
 379   (save-excursion
 380     (save-restriction
 381       (narrow-to-region start end)
 382       (let ((case-fold-search t)
 383             (alist wl-message-body-button-alist)
 384             entry)
 385         (while alist
 386           (setq entry (car alist)
 387                 alist (cdr alist))
 388           (goto-char (point-min))
 389           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 390             (unless (get-text-property (point) 'keymap)
 391               (wl-message-add-button
 392                (match-beginning (nth 1 entry))
 393                (match-end (nth 1 entry))
 394                (nth 2 entry)
 395                (match-string (nth 3 entry))))))))))
 396
 397 (defun wl-message-add-buttons-to-header (start end)
 398   (save-excursion
 399     (save-restriction
 400       (narrow-to-region start end)
 401       (let ((case-fold-search t)
 402             (alist wl-message-header-button-alist)
 403             entry)
 404         (while alist
 405           (setq entry (car alist)
 406                 alist (cdr alist))
 407           (goto-char (point-min))
 408           (while (re-search-forward (car entry) nil t)
 409             (setq start (match-beginning 0)
 410                   end (if (re-search-forward "^[^ \t]" nil t)
 411                           (match-beginning 0)
 412                         (point-max)))
 413             (goto-char start)
 414             (while (re-search-forward (nth 1 entry) end t)
 415               (wl-message-add-button
 416                (match-beginning (nth 2 entry))
 417                (match-end (nth 2 entry))
 418                (nth 3 entry) (match-string (nth 4 entry))))
 419             (goto-char end)))))))
 420
 421 (defun wl-message-redisplay (folder number as-is all-header
 422                                     &optional force-reload)
 423   (let* ((default-mime-charset wl-mime-charset)
 424          (buffer-read-only nil)
 425          (summary-buf (current-buffer))
 426          message-buf
 427          strategy entity
 428          cache-used
 429          summary-win delim flags)
 430     (setq buffer-read-only nil)
 431     (setq cache-used (wl-message-buffer-display
 432                       folder number as-is all-header force-reload))
 433     (setq wl-message-buffer (car cache-used))
 434     (setq message-buf wl-message-buffer)
 435     (wl-message-select-buffer wl-message-buffer)
 436
 437     (set-buffer message-buf)
 438     (wl-deactivate-region)
 439     (make-local-variable 'truncate-partial-width-windows)
 440     (setq truncate-partial-width-windows nil)
 441     (setq truncate-lines wl-message-truncate-lines)
 442     (setq buffer-read-only nil)
 443     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 444     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 445     (setq wl-message-buffer-cur-number number)
 446     (setq wl-message-buffer-flag-indicator
 447           (if (setq flags (elmo-get-global-flags (elmo-message-flags
 448                                                   folder number)))
 449               (let ((fl wl-summary-flag-alist)
 450                     flag-strings flag-string face)
 451                 (while fl
 452                   (when (memq (car (car fl)) flags)
 453                     (setq flag-string (capitalize
 454                                        (symbol-name (car (car fl))))
 455                           flags (delq (car (car fl)) flags))
 456                     (when (facep (setq face
 457                                        (intern
 458                                         (format
 459                                          "wl-highlight-summary-%s-flag-face"
 460                                          (car (car fl))))))
 461                       (put-text-property 0 (length flag-string)
 462                                          'face face flag-string))
 463                     (setq flag-strings (nconc flag-strings
 464                                               (list flag-string))))
 465                   (setq fl (cdr fl)))
 466                 (setq flag-strings
 467                       (nconc flag-strings
 468                              (mapcar (lambda (flag)
 469                                        (capitalize (symbol-name flag)))
 470                                      flags)))
 471                 (concat " (" (mapconcat 'identity flag-strings ", ") ")"))
 472             ""))
 473     (wl-line-formatter-setup
 474      wl-message-buffer-mode-line-formatter
 475      wl-message-mode-line-format
 476      wl-message-mode-line-format-spec-alist)
 477     (setq mode-line-buffer-identification
 478           (funcall wl-message-buffer-mode-line-formatter))
 479     ;; highlight body
 480 ;    (when wl-highlight-body-too
 481 ;      (wl-highlight-body))
 482     (ignore-errors (wl-message-narrow-to-page))
 483     (setq cache-used (cdr cache-used))
 484     (goto-char (point-min))
 485     (when (re-search-forward "^$" nil t)
 486       (wl-message-add-buttons-to-header (point-min) (point))
 487       (wl-message-add-buttons-to-body (point) (point-max)))
 488     (when (and wl-message-use-header-narrowing
 489                (not all-header))
 490       (wl-message-header-narrowing))
 491     (goto-char (point-min))
 492     (ignore-errors (run-hooks 'wl-message-redisplay-hook))
 493     ;; go back to summary mode
 494     (set-buffer-modified-p nil)
 495     (setq buffer-read-only t)
 496     (set-buffer summary-buf)
 497     (setq summary-win (get-buffer-window summary-buf))
 498     (if (window-live-p summary-win)
 499         (select-window summary-win))
 500     cache-used))
 501
 502 (defun wl-message-buffer-display-type (as-is all-header)
 503   (let ((type ""))
 504     (if as-is
 505         (setq type (concat type "as-is"))
 506       (setq type (concat type "mime")))
 507     (when all-header (setq type (concat type "-all-header")))
 508     (intern type)))
 509
 510 ;; Use message buffer cache.
 511 (defun wl-message-buffer-display (folder number as-is all-header
 512                                          &optional force-reload unread)
 513   (let* ((msg-id (ignore-errors (elmo-message-field folder number
 514                                                     'message-id)))
 515          (fname (elmo-folder-name-internal folder))
 516          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 517          (read nil)
 518          cache-used)
 519     (when (and hit (not (buffer-live-p hit)))
 520       (wl-message-buffer-cache-delete (list fname number msg-id))
 521       (setq hit nil))
 522     (if hit
 523         (progn
 524           ;; move hit to the top.
 525           (wl-message-buffer-cache-sort
 526            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 527           ;; buffer cache is used.
 528           (setq cache-used t)
 529           (with-current-buffer hit
 530             ;; Rewind to the top page
 531             (widen)
 532             (goto-char (point-min))
 533             (ignore-errors (wl-message-narrow-to-page))
 534             (unless (eq wl-message-buffer-cur-display-type
 535                         (wl-message-buffer-display-type as-is all-header))
 536               (setq read t))))
 537       ;; delete tail and add new to the top.
 538       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 539       (setq read t))
 540     (if (or force-reload read)
 541         (condition-case err
 542             (save-excursion
 543               (set-buffer hit)
 544               (setq
 545                cache-used
 546                (wl-message-display-internal folder number as-is all-header
 547                                             force-reload unread))
 548               (setq wl-message-buffer-cur-display-type
 549                     (wl-message-buffer-display-type as-is all-header)))
 550           (quit
 551            (wl-message-buffer-cache-delete)
 552            (error "Display message %s/%s is quitted" fname number))
 553           (error
 554            (wl-message-buffer-cache-delete)
 555            (signal (car err) (cdr err))
 556            nil))) ;; will not be used
 557     (cons hit cache-used)))
 558
 559 (defun wl-message-display-internal (folder number as-is all-header
 560                                            &optional force-reload unread)
 561   (let ((default-mime-charset wl-mime-charset)
 562         (elmo-mime-charset wl-mime-charset))
 563     (setq wl-message-buffer-require-all-header all-header)
 564     (prog1
 565         (if as-is
 566             (let (wl-highlight-x-face-function)
 567               (prog1 (elmo-mime-display-as-is folder number
 568                                               (current-buffer)
 569                                               (wl-message-get-original-buffer)
 570                                               'wl-original-message-mode
 571                                               force-reload
 572                                               unread
 573                                               (wl-message-define-keymap))
 574                 (let (buffer-read-only)
 575                   (wl-highlight-message (point-min) (point-max) t))))
 576           (elmo-mime-message-display folder number
 577                                      (current-buffer)
 578                                      (wl-message-get-original-buffer)
 579                                      'wl-original-message-mode
 580                                      force-reload
 581                                      unread
 582                                      (wl-message-define-keymap)))
 583       (run-hooks 'wl-message-display-internal-hook)
 584       (setq buffer-read-only t))))
 585
 586 (defun wl-message-buffer-prefetch-p (folder &optional number)
 587   (and (or (not number)
 588            (elmo-message-file-p folder number)
 589            (let ((size (elmo-message-field folder number 'size)))
 590              (not (and (integerp size)
 591                        wl-message-buffer-prefetch-threshold
 592                        (>= size wl-message-buffer-prefetch-threshold)))))
 593        (or (not number)
 594            (elmo-folder-plugged-p folder)
 595            (elmo-file-cache-exists-p
 596                  (elmo-message-field folder number 'message-id)))
 597        (or (cond
 598             ((eq wl-message-buffer-prefetch-folder-type-list t)
 599              t)
 600             ((and number wl-message-buffer-prefetch-folder-type-list)
 601              (memq (elmo-folder-type-internal
 602                     (elmo-message-folder folder number))
 603                    wl-message-buffer-prefetch-folder-type-list))
 604             (wl-message-buffer-prefetch-folder-type-list
 605              (let ((list wl-message-buffer-prefetch-folder-type-list)
 606                    type)
 607                (catch 'done
 608                  (while (setq type (pop list))
 609                    (if (elmo-folder-contains-type folder type)
 610                        (throw 'done t)))))))
 611            (cond
 612             ((consp wl-message-buffer-prefetch-folder-list)
 613              (wl-string-match-member (elmo-folder-name-internal folder)
 614                                      wl-message-buffer-prefetch-folder-list))
 615             (t wl-message-buffer-prefetch-folder-list)))))
 616
 617 (defsubst wl-message-buffer-prefetch-clear-timer ()
 618 ;;;     cannot use for the bug of fsf-compat package (1.09).
 619 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 620   (if (fboundp 'run-with-idle-timer)
 621       (if (featurep 'xemacs)
 622           (let ((p itimer-list))
 623             (while (car p)
 624               (if (eq 'wl-message-buffer-prefetch-subr
 625                       (itimer-function (car p)))
 626                   (delete-itimer (car p)))
 627               (setq p (cdr p))))
 628         ;; FSF Emacs is correct
 629         (cancel-function-timers 'wl-message-buffer-prefetch-subr))))
 630
 631 (defsubst wl-message-buffer-prefetch-set-timer (folder number count
 632                                                        summary charset)
 633   (if (not (fboundp 'run-with-idle-timer))
 634       (when (sit-for wl-message-buffer-prefetch-idle-time)
 635         (wl-message-buffer-prefetch-subr
 636          folder number count summary charset))
 637     (run-with-idle-timer
 638      wl-message-buffer-prefetch-idle-time
 639      nil
 640      'wl-message-buffer-prefetch-subr
 641      folder number count summary charset)))
 642
 643 (defvar wl-message-buffer-prefetch-move-spec-alist nil)
 644
 645 (defun wl-message-buffer-prefetch-get-next (folder number summary)
 646   (if (buffer-live-p summary)
 647       (with-current-buffer summary
 648         (let ((wl-summary-move-spec-alist
 649                (or wl-message-buffer-prefetch-move-spec-alist
 650                    wl-summary-move-spec-alist))
 651               (next number))
 652           (while (and (setq next (funcall
 653                                   wl-message-buffer-prefetch-get-next-function
 654                                   next))
 655                       (not (wl-message-buffer-prefetch-p folder next))))
 656           next))))
 657
 658 (defun wl-message-buffer-prefetch (folder number count
 659                                           &optional summary charset)
 660   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 661          (num number))
 662     (when (and count
 663                (wl-message-buffer-prefetch-p folder))
 664       (unless (wl-message-buffer-prefetch-p folder number)
 665         (setq num
 666               (wl-message-buffer-prefetch-get-next folder number summary)))
 667       (when num
 668         (wl-message-buffer-prefetch-clear-timer)
 669         (wl-message-buffer-prefetch-set-timer
 670          folder num count summary charset)))))
 671
 672 (defun wl-message-buffer-prefetch-next (folder number count
 673                                                &optional summary charset)
 674   (let* ((summary (or summary (get-buffer wl-summary-buffer-name)))
 675          next)
 676     (when (and count
 677                (wl-message-buffer-prefetch-p folder))
 678       (setq next (wl-message-buffer-prefetch-get-next folder number summary))
 679       (when next
 680         (wl-message-buffer-prefetch-clear-timer)
 681         (wl-message-buffer-prefetch-set-timer
 682          folder next count summary charset)))))
 683
 684 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 685   (if (buffer-live-p summary)
 686       (with-current-buffer summary
 687         (if (and number
 688                  (numberp count)
 689                  (>= (setq count (- count 1)) 0)
 690                  (string= (elmo-folder-name-internal folder)
 691                           (wl-summary-buffer-folder-name)))
 692             (let* ((wl-mime-charset      charset)
 693                    (default-mime-charset charset)
 694                    (message-id (elmo-message-field folder number 'message-id))
 695                    (key (list (elmo-folder-name-internal folder)
 696                               number message-id))
 697                    (hit (wl-message-buffer-cache-hit key))
 698                    result time1 time2 sec micro)
 699               (when wl-message-buffer-prefetch-debug
 700                 (message "%d: count %d, hit %s" number count (buffer-name hit)))
 701               (if (and hit (buffer-live-p hit))
 702                   (progn
 703                     (wl-message-buffer-cache-sort
 704                      (wl-message-buffer-cache-entry-make key hit))
 705                     (wl-message-buffer-prefetch-subr
 706                      folder
 707                      (wl-message-buffer-prefetch-get-next
 708                       folder number summary)
 709                      count summary charset))
 710                 ;; prefetching
 711                 (when wl-message-buffer-prefetch-debug
 712                   (setq time1 (current-time))
 713                   (message "Prefetching %d..." number))
 714                 (setq result (wl-message-buffer-display
 715                               folder number 'mime nil 'unread))
 716                 (when wl-message-buffer-prefetch-debug
 717                   (setq time2 (current-time))
 718                   (setq sec  (- (nth 1 time2)(nth 1 time1)))
 719                   (setq micro (- (nth 2 time2)(nth 2 time1)))
 720                   (setq micro (+ micro (* 1000000 sec)))
 721                   (message "Prefetching %d...done(%f msec)."
 722                            number
 723                            (/ micro 1000.0))
 724                   (sit-for 0))
 725                 ;; set next prefetch
 726                 (wl-message-buffer-prefetch-set-timer
 727                  folder
 728                  (wl-message-buffer-prefetch-get-next
 729                   folder number summary)
 730                  count summary charset)
 731                 (sit-for 0)
 732                 ;; success prefetch
 733                 )))
 734         ;; finish prefetch
 735         (when wl-message-buffer-prefetch-debug
 736           (message "Buffer Cached Messages: %s"
 737                    (mapconcat
 738                     '(lambda (cache)
 739                        (if (numberp (nth 1 (car cache)))
 740                            (if (string=
 741                                 (nth 0 (car cache))
 742                                 (elmo-folder-name-internal folder))
 743                                (format "%d"
 744                                        (nth 1 (car cache)))
 745                              (format "*%d" (nth 1 (car cache))))
 746                          "-"))
 747                     wl-message-buffer-cache " "))) )))
 748
 749 (defvar wl-message-button-map (make-sparse-keymap))
 750
 751 (defun wl-message-add-button (from to function &optional data)
 752   "Create a button between FROM and TO with callback FUNCTION and DATA."
 753   (add-text-properties
 754    from to
 755    (nconc (list 'wl-message-button-callback function)
 756           (if data
 757               (list 'wl-message-button-data data))))
 758   (let ((ov (make-overlay from to)))
 759     (overlay-put ov 'mouse-face 'highlight)
 760     (overlay-put ov 'local-map wl-message-button-map)
 761     (overlay-put ov 'evaporate t)))
 762
 763 (defun wl-message-button-dispatcher (event)
 764   "Select the button under point."
 765   (interactive "@e")
 766   (mouse-set-point event)
 767   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 768         (data (get-text-property (point) 'wl-message-button-data)))
 769     (if callback
 770         (funcall callback data)
 771       (wl-message-button-dispatcher-internal event))))
 772
 773 (defun wl-message-button-refer-article (data)
 774   "Read article specified by Message-ID DATA at point."
 775   (switch-to-buffer-other-window
 776    wl-message-buffer-cur-summary-buffer)
 777   (if (wl-summary-jump-to-msg-by-message-id data)
 778       (wl-summary-redisplay)))
 779
 780 (defun wl-message-uu-substring (buf outbuf &optional first last)
 781   (save-excursion
 782     (set-buffer buf)
 783     (search-forward "\n\n")
 784     (let ((sp (point))
 785           ep filename case-fold-search)
 786       (catch 'done
 787         (if first
 788             (progn
 789               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 790                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 791                 (throw 'done nil)))
 792           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 793         (beginning-of-line)
 794         (setq sp (point))
 795         (goto-char (point-max))
 796         (if last
 797             (re-search-backward "^end" sp t)
 798           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 799         (forward-line 1)
 800         (setq ep (point))
 801         (set-buffer outbuf)
 802         (goto-char (point-max))
 803         (insert-buffer-substring buf sp ep)
 804         (set-buffer buf)
 805         filename))))
 806
 807 ;;; Header narrowing courtesy of Hideyuki Shirai.
 808 (defun wl-message-header-narrowing ()
 809   "Narrowing headers."
 810   (unless (eq this-command 'wl-summary-redisplay-all-header)
 811     (save-excursion
 812       (save-restriction
 813         (goto-char (point-min))
 814         (if (re-search-forward "^$" nil t)
 815             (beginning-of-line)
 816           (goto-char (point-max)))
 817         (narrow-to-region (point-min) (point))
 818         (let ((fields wl-message-header-narrowing-fields))
 819           (while fields
 820             (wl-message-header-narrowing-1 (concat "^" (car fields) ":"))
 821             (setq fields (cdr fields))))))))
 822
 823 (defvar wl-message-header-narrowing-map (make-sparse-keymap))
 824 (define-key wl-message-header-narrowing-map [mouse-2]
 825   'wl-message-header-narrowing-again-at-mouse)
 826
 827 (defvar wl-message-header-narrowing-widen-map (make-sparse-keymap))
 828 (define-key wl-message-header-narrowing-widen-map [mouse-2]
 829   'wl-message-header-narrowing-widen-at-mouse)
 830
 831 (defun wl-message-header-narrowing-again-at-mouse (event)
 832   (interactive "e")
 833   (save-window-excursion
 834     (save-excursion
 835       (mouse-set-point event)
 836       (wl-message-header-narrowing))))
 837
 838 (defun wl-message-header-narrowing-1 (hregexp)
 839   (let ((case-fold-search t)
 840         ov start end)
 841     (goto-char (point-min))
 842     (while (re-search-forward hregexp nil t)
 843       (setq start (match-beginning 0))
 844       (forward-line 1)
 845       (setq end (progn (while (looking-at "^[ \t]") (forward-line))
 846                        (forward-line -1)
 847                        (line-end-position)))
 848       (if (<= (count-lines start end) wl-message-header-narrowing-lines)
 849           (forward-line 1)
 850         (goto-char start)
 851         (forward-line (1- wl-message-header-narrowing-lines))
 852         (end-of-line)
 853         (setq start (point))
 854         (unless (eq (get-char-property start 'invisible)
 855                     'wl-message-header-narrowing)
 856           (setq ov (or
 857                     (let ((ovs (overlays-at start))
 858                           ov)
 859                       (while (and ovs (not (overlayp ov)))
 860                         (if (overlay-get (car ovs)
 861                                          'wl-message-header-narrowing)
 862                             (setq ov (car ovs)))
 863                         (setq ovs (cdr ovs)))
 864                       ov)
 865                     (make-overlay start end)))
 866           (overlay-put ov 'wl-message-header-narrowing t)
 867           (overlay-put ov 'evaporate t)
 868           (overlay-put ov 'invisible 'wl-message-header-narrowing)
 869           (overlay-put ov 'after-string
 870                        wl-message-header-narrowing-string))))))
 871
 872 (defun wl-message-header-narrowing-widen-at-mouse (event)
 873   (interactive "e")
 874   (save-selected-window
 875     (select-window (posn-window (event-start event)))
 876     (let* ((win (selected-window))
 877            (wpos (window-start win))
 878            (pos (mouse-set-point event))
 879            (ovs (overlays-in (1- pos) (1+ pos)))        ;; Uum...
 880            ov)
 881       (while (and ovs (not (overlayp ov)))
 882         (when (overlay-get (car ovs) 'wl-message-header-narrowing)
 883           (setq ov (car ovs)))
 884         (setq ovs (cdr ovs)))
 885       (when (overlayp ov)
 886         (overlay-put ov 'face 'wl-message-header-narrowing-face)
 887         (overlay-put ov 'local-map wl-message-header-narrowing-map)
 888         (overlay-put ov 'invisible nil)
 889         (overlay-put ov 'after-string nil))
 890       (set-window-start win wpos))))
 891
 892 (defun wl-message-header-narrowing-setup ()
 893   (when (boundp 'line-move-ignore-invisible)
 894     (set (make-local-variable 'line-move-ignore-invisible) t))
 895   (set-text-properties 0 (length wl-message-header-narrowing-string)
 896                        `(face
 897                          wl-message-header-narrowing-face
 898                          keymap
 899                          ,wl-message-header-narrowing-widen-map)
 900                        wl-message-header-narrowing-string))
 901
 902 (defun wl-message-header-narrowing-toggle ()
 903   "Toggle header narrowing."
 904   (interactive)
 905   (when wl-message-use-header-narrowing
 906     (save-excursion
 907       (goto-char (point-min))
 908       (if (re-search-forward "^$" nil t)
 909           (beginning-of-line)
 910         (goto-char (point-max)))
 911       (let ((ovs (overlays-in (point-min) (point)))
 912             ov hn-ovs)
 913         (while (setq ov (car ovs))
 914           (when (overlay-get ov 'wl-message-header-narrowing)
 915             (setq hn-ovs (cons ov hn-ovs)))
 916           (setq ovs (cdr ovs)))
 917         (if hn-ovs
 918             (while hn-ovs
 919               (delete-overlay (car hn-ovs))
 920               (setq hn-ovs (cdr hn-ovs)))
 921           (wl-message-header-narrowing))))))
 922
 923 (require 'product)
 924 (product-provide (provide 'wl-message) (require 'wl-version))
 925
 926 ;;; wl-message.el ends here