wl/wl-message.el

   1 ;;; wl-message.el --- Message displaying modules for Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31
  32 (require 'wl-vars)
  33 (require 'wl-highlight)
  34 (require 'elmo)
  35 (require 'elmo-mime)
  36 (require 'timer)
  37
  38 (eval-when-compile
  39   (require 'wl-mime)
  40   (require 'mime-view)
  41   (defalias-maybe 'event-window 'ignore)
  42   (defalias-maybe 'posn-window 'ignore)
  43   (defalias-maybe 'event-start 'ignore)
  44   (defalias-maybe 'mime-open-entity 'ignore))
  45
  46 (defvar wl-message-buffer-prefetch-get-next-function
  47   'wl-summary-default-get-next-msg)
  48
  49 (defvar wl-message-buffer-prefetch-debug t)
  50 (defvar wl-message-buffer-prefetch-timer nil)
  51
  52 (defvar wl-message-buffer nil) ; message buffer.
  53
  54 (defvar wl-message-buffer-cur-summary-buffer nil)
  55 (defvar wl-message-buffer-cur-folder nil)
  56 (defvar wl-message-buffer-cur-number nil)
  57 (defvar wl-message-buffer-cur-flag nil)
  58 (defvar wl-message-buffer-cur-summary-buffer nil)
  59 (defvar wl-message-buffer-original-buffer nil) ; original buffer.
  60 (defvar wl-message-buffer-all-header-flag nil)
  61
  62 (make-variable-buffer-local 'wl-message-buffer-cur-folder)
  63 (make-variable-buffer-local 'wl-message-buffer-cur-number)
  64 (make-variable-buffer-local 'wl-message-buffer-cur-flag)
  65 (make-variable-buffer-local 'wl-message-buffer-cur-summary-buffer)
  66 (make-variable-buffer-local 'wl-message-buffer-original-buffer)
  67 (make-variable-buffer-local 'wl-message-buffer-all-header-flag)
  68
  69 (defvar wl-fixed-window-configuration nil)
  70
  71 (defvar wl-message-buffer-cache-size 10) ; At least 1.
  72
  73 ;;; Message buffer cache.
  74
  75 (defvar wl-message-buffer-cache nil
  76   "Message cache.  (old ... new) order alist.
  77 With association ((\"folder\" message \"message-id\") . cache-buffer).")
  78
  79 (defmacro wl-message-buffer-cache-buffer-get (entry)
  80   (` (cdr (, entry))))
  81
  82 (defmacro wl-message-buffer-cache-folder-get (entry)
  83   (` (car (car (, entry)))))
  84
  85 (defmacro wl-message-buffer-cache-message-get (entry)
  86   (` (cdr (car (, entry)))))
  87
  88 (defmacro wl-message-buffer-cache-entry-make (key buf)
  89   (` (cons (, key) (, buf))))
  90
  91 (defmacro wl-message-buffer-cache-hit (key)
  92   "Return value assosiated with key."
  93   (` (wl-message-buffer-cache-buffer-get
  94       (assoc (, key) wl-message-buffer-cache))))
  95
  96 (defun wl-message-buffer-cache-sort (entry)
  97   "Move ENTRY to the top of `wl-message-buffer-cache'."
  98   (setq wl-message-buffer-cache
  99         (cons entry (delete entry wl-message-buffer-cache))))
 100 ;  (let* ((pointer (cons nil wl-message-buffer-cache))
 101 ;        (top pointer))
 102 ;    (while (cdr pointer)
 103 ;      (if (equal (car (cdr pointer)) entry)
 104 ;         (setcdr pointer (cdr (cdr pointer)))
 105 ;       (setq pointer (cdr pointer))))
 106 ;    (setcdr pointer (list entry))
 107 ;    (setq wl-message-buffer-cache (cdr top))))
 108
 109 (defconst wl-message-buffer-cache-name    " *WL:Message*")
 110 (defconst wl-original-message-buffer-name " *Original*")
 111
 112 (defun wl-original-message-mode ()
 113   "A major mode for original message buffer."
 114   (setq major-mode 'wl-original-message-mode)
 115   (setq buffer-read-only t)
 116   (elmo-set-buffer-multibyte nil)
 117   (setq mode-name "Wanderlust original message"))
 118
 119 (defun wl-original-message-buffer-get (name)
 120   "Get original message buffer for NAME.
 121 If original message buffer already exists, it is re-used."
 122   (let* ((name (concat wl-original-message-buffer-name name))
 123          (buffer (get-buffer name)))
 124     (unless (and buffer (buffer-live-p buffer))
 125       (with-current-buffer (setq buffer (get-buffer-create name))
 126         (wl-original-message-mode)))
 127     buffer))
 128
 129 (defun wl-message-buffer-create ()
 130   "Create a new message buffer."
 131   (let* ((buffer (generate-new-buffer wl-message-buffer-cache-name))
 132          (name (buffer-name buffer)))
 133     (with-current-buffer buffer
 134       (setq wl-message-buffer-original-buffer
 135             (wl-original-message-buffer-get name)))
 136     buffer))
 137
 138 (defun wl-message-buffer-cache-add (key)
 139   "Add (KEY . buf) to the top of `wl-message-buffer-cache'.
 140 Return its cache buffer."
 141   (let ((len (length wl-message-buffer-cache))
 142         (buf nil))
 143     (if (< len wl-message-buffer-cache-size)
 144         (setq buf (wl-message-buffer-create))
 145       (setq buf (wl-message-buffer-cache-buffer-get
 146                  (nth (1- len) wl-message-buffer-cache)))
 147       (setcdr (nthcdr (- len 2) wl-message-buffer-cache) nil))
 148     (setq wl-message-buffer-cache
 149           (cons (wl-message-buffer-cache-entry-make key buf)
 150                 wl-message-buffer-cache))
 151     buf))
 152
 153 (defun wl-message-buffer-cache-delete (&optional key)
 154   "Delete the most recent cache entry"
 155   (if key
 156       (setq wl-message-buffer-cache
 157             (delq (assoc key wl-message-buffer-cache)
 158                   wl-message-buffer-cache))
 159     (let ((buf (wl-message-buffer-cache-buffer-get
 160                 (car wl-message-buffer-cache))))
 161       (setq wl-message-buffer-cache
 162             (nconc (cdr wl-message-buffer-cache)
 163                    (list (wl-message-buffer-cache-entry-make nil buf)))))))
 164
 165 (defun wl-message-buffer-cache-clean-up ()
 166   "A function to flush all decoded messages in cache list."
 167   (interactive)
 168   (if (and (eq major-mode 'wl-summary-mode)
 169            wl-message-buffer
 170            (get-buffer-window wl-message-buffer))
 171       (delete-window (get-buffer-window wl-message-buffer)))
 172   (wl-kill-buffers (regexp-quote wl-message-buffer-cache-name))
 173   (setq wl-message-buffer-cache nil))
 174
 175 ;;; Message buffer handling from summary buffer.
 176
 177 (defun wl-message-buffer-window ()
 178   "Get message buffer window if any."
 179   (let* ((start-win (selected-window))
 180          (cur-win start-win))
 181     (catch 'found
 182       (while (progn
 183                (setq cur-win (next-window cur-win))
 184                (with-current-buffer (window-buffer cur-win)
 185                  (if (or (eq major-mode 'wl-message-mode)
 186                          (eq major-mode 'mime-view-mode))
 187                      (throw 'found cur-win)))
 188                (not (eq cur-win start-win)))))))
 189
 190 (defun wl-message-select-buffer (buffer)
 191   "Select BUFFER as a message buffer."
 192   (let ((window (get-buffer-window buffer))
 193         (sum (car wl-message-window-size))
 194         (mes (cdr wl-message-window-size))
 195         whi)
 196     (when (and window
 197                (not (eq (save-excursion (set-buffer (window-buffer window))
 198                                         wl-message-buffer-cur-summary-buffer)
 199                         (current-buffer))))
 200       (delete-window window)
 201       (run-hooks 'wl-message-window-deleted-hook)
 202       (setq window nil))
 203     (if window
 204         (select-window window)
 205       (when wl-fixed-window-configuration
 206         (delete-other-windows)
 207         (and wl-stay-folder-window
 208              (wl-summary-toggle-disp-folder)))
 209       ;; There's no buffer window. Search for message window and snatch it.
 210       (if (setq window (wl-message-buffer-window))
 211           (select-window window)
 212         (setq whi (1- (window-height)))
 213         (if mes
 214             (progn
 215               (let ((total (+ sum mes)))
 216                 (setq sum (max window-min-height (/ (* whi sum) total)))
 217                 (setq mes (max window-min-height (/ (* whi mes) total))))
 218               (if (< whi (+ sum mes))
 219                   (enlarge-window (- (+ sum mes) whi)))))
 220         (split-window (get-buffer-window (current-buffer)) sum)
 221         (other-window 1)))
 222     (switch-to-buffer buffer)))
 223
 224 (defun wl-message-narrow-to-page (&optional arg)
 225   "Narrow to page.
 226 If ARG is specified, narrow to ARGth page."
 227   (interactive "P")
 228   (setq arg (if arg (prefix-numeric-value arg) 0))
 229   (save-excursion
 230     (condition-case ()
 231         (forward-page -1)               ; Beginning of current page.
 232       (beginning-of-buffer
 233        (goto-char (point-min))))
 234     (forward-char 1)  ; for compatibility with emacs-19.28 and emacs-19.29
 235     (widen)
 236     (cond
 237      ((> arg 0) (forward-page arg))
 238      ((< arg 0) (forward-page (1- arg))))
 239     (forward-page)
 240     (if wl-break-pages
 241         (narrow-to-region (point)
 242                           (progn
 243                             (forward-page -1)
 244                             (if (and (eolp) (not (bobp)))
 245                                 (forward-line))
 246                             (point))))))
 247
 248 (defun wl-message-prev-page (&optional lines)
 249   "Scroll down current message by LINES.
 250 Returns non-nil if top of message."
 251   (interactive)
 252   (let (cur-buf top real-top)
 253     (unless (eq major-mode 'mime-view-mode)
 254       (when (buffer-live-p wl-message-buffer)
 255         (setq cur-buf (current-buffer))
 256         (wl-message-select-buffer wl-message-buffer)))
 257     (move-to-window-line 0)
 258     (if (and wl-break-pages
 259              (bobp)
 260              (not (setq real-top (save-restriction (widen) (bobp)))))
 261         (progn
 262           (wl-message-narrow-to-page -1)
 263           (goto-char (point-max))
 264           (recenter))
 265       (if (not (bobp))
 266           (condition-case nil
 267               (scroll-down lines)
 268             (error))
 269         (setq top t)))
 270     (if real-top
 271         (let ((f (assq (mime-preview-original-major-mode)
 272                        mime-preview-over-to-previous-method-alist)))
 273           (if f (funcall (cdr f))))
 274       (when cur-buf
 275         (select-window (get-buffer-window cur-buf))))
 276     top))
 277
 278 (defun wl-message-next-page (&optional lines)
 279   "Scroll up current message by LINES.
 280 Returns non-nil if bottom of message."
 281   (interactive)
 282   (let (cur-buf bottom)
 283     (unless (eq major-mode 'mime-view-mode)
 284       (when (buffer-live-p wl-message-buffer)
 285         (setq cur-buf (current-buffer))
 286         (wl-message-select-buffer wl-message-buffer)))
 287     (move-to-window-line -1)
 288     (if (save-excursion
 289           (end-of-line)
 290           (and (pos-visible-in-window-p)
 291                (eobp)))
 292         (if (or (null wl-break-pages)
 293                 (save-excursion
 294                   (save-restriction
 295                     (widen) (forward-line) (eobp))))
 296             (setq bottom t)
 297           (wl-message-narrow-to-page 1)
 298           (setq bottom nil))
 299       (condition-case ()
 300           (static-if (boundp 'window-pixel-scroll-increment)
 301               ;; XEmacs 21.2.20 and later.
 302               (let (window-pixel-scroll-increment)
 303                 (scroll-up lines))
 304             (scroll-up lines))
 305         (end-of-buffer
 306          (goto-char (point-max))))
 307       (setq bottom nil))
 308     (if (eobp)
 309         (let ((f (assq (mime-preview-original-major-mode)
 310                        mime-preview-over-to-next-method-alist)))
 311           (if f (funcall (cdr f))))
 312       (when cur-buf
 313         (select-window (get-buffer-window cur-buf))))
 314     bottom))
 315
 316
 317 (defun wl-message-follow-current-entity (buffer)
 318   "Follow to current message."
 319   (wl-draft-reply (wl-message-get-original-buffer)
 320                   nil wl-message-buffer-cur-summary-buffer) ; reply to all
 321   (let ((mail-reply-buffer buffer))
 322     (wl-draft-yank-from-mail-reply-buffer nil)))
 323
 324 ;;
 325
 326 (defun wl-message-mode ()
 327   "A major mode for message displaying."
 328   (interactive)
 329   (setq major-mode 'wl-message-mode)
 330   (setq buffer-read-only t)
 331   (setq mode-name "Message"))
 332
 333 (defun wl-message-exit ()
 334   "Move to summary buffer."
 335   (interactive)
 336   (let (summary-buf summary-win)
 337     (if (setq summary-buf wl-message-buffer-cur-summary-buffer)
 338         (if (setq summary-win (get-buffer-window summary-buf))
 339             (select-window summary-win)
 340           (switch-to-buffer summary-buf)
 341           (wl-message-select-buffer wl-message-buffer)
 342           (select-window (get-buffer-window summary-buf))))
 343     (run-hooks 'wl-message-exit-hook)))
 344
 345 (defun wl-message-toggle-disp-summary ()
 346   (interactive)
 347   (let ((summary-buf (get-buffer wl-message-buffer-cur-summary-buffer))
 348         summary-win)
 349     (if (and summary-buf
 350              (buffer-live-p summary-buf))
 351         (if (setq summary-win (get-buffer-window summary-buf))
 352             (delete-window summary-win)
 353           (switch-to-buffer summary-buf)
 354           (wl-message-select-buffer wl-message-buffer))
 355       (wl-summary-goto-folder-subr wl-message-buffer-cur-folder 'no-sync
 356                                    nil nil t)
 357                                         ; no summary-buf
 358       (let ((sum-buf (current-buffer)))
 359         (wl-message-select-buffer wl-message-buffer)
 360         (setq wl-message-buffer-cur-summary-buffer sum-buf)))))
 361
 362 (defun wl-message-get-original-buffer ()
 363   "Get original buffer for current message buffer."
 364   wl-message-buffer-original-buffer)
 365
 366 (defun wl-message-add-buttons-to-body (start end)
 367   (save-excursion
 368     (save-restriction
 369       (narrow-to-region start end)
 370       (let ((case-fold-search t)
 371             (alist wl-message-body-button-alist)
 372             entry)
 373         (while alist
 374           (setq entry (car alist)
 375                 alist (cdr alist))
 376           (goto-char (point-min))
 377           (while (re-search-forward (car entry) (+ (point) (nth 4 entry)) t)
 378             (unless (get-text-property (point) 'keymap)
 379               (wl-message-add-button
 380                (match-beginning (nth 1 entry))
 381                (match-end (nth 1 entry))
 382                (nth 2 entry)
 383                (match-string (nth 3 entry))))))))))
 384
 385 (defun wl-message-add-buttons-to-header (start end)
 386   (save-excursion
 387     (save-restriction
 388       (narrow-to-region start end)
 389       (let ((case-fold-search t)
 390             (alist wl-message-header-button-alist)
 391             entry)
 392         (while alist
 393           (setq entry (car alist)
 394                 alist (cdr alist))
 395           (goto-char (point-min))
 396           (while (re-search-forward (car entry) nil t)
 397             (setq start (match-beginning 0)
 398                   end (if (re-search-forward "^[^ \t]" nil t)
 399                           (match-beginning 0)
 400                         (point-max)))
 401             (goto-char start)
 402             (while (re-search-forward (nth 1 entry) end t)
 403               (goto-char (match-end 0))
 404               (wl-message-add-button
 405                (match-beginning (nth 2 entry))
 406                (match-end (nth 2 entry))
 407                (nth 3 entry) (match-string (nth 4 entry))))
 408             (goto-char end)))))))
 409
 410 (defun wl-message-redisplay (folder number flag &optional force-reload)
 411   (let* ((default-mime-charset wl-mime-charset)
 412          (buffer-read-only nil)
 413          (summary-buf (current-buffer))
 414          message-buf
 415          strategy entity
 416          cache-used
 417          header-end real-fld-num summary-win delim)
 418     (setq buffer-read-only nil)
 419     (setq cache-used (wl-message-buffer-display
 420                       folder number flag force-reload))
 421     (setq wl-message-buffer (car cache-used))
 422     (setq message-buf wl-message-buffer)
 423     (wl-message-select-buffer wl-message-buffer)
 424
 425     (set-buffer message-buf)
 426     (make-local-variable 'truncate-partial-width-windows)
 427     (setq truncate-partial-width-windows nil)
 428     (setq truncate-lines wl-message-truncate-lines)
 429     (setq buffer-read-only nil)
 430     (setq wl-message-buffer-cur-summary-buffer summary-buf)
 431     (setq wl-message-buffer-cur-folder (elmo-folder-name-internal folder))
 432     (setq wl-message-buffer-cur-number number)
 433     (setq mode-line-buffer-identification
 434           (format "Wanderlust: << %s / %s >>"
 435                   (if (memq 'modeline wl-use-folder-petname)
 436                       (wl-folder-get-petname (elmo-folder-name-internal
 437                                               folder))
 438                     (elmo-folder-name-internal folder)) number))
 439     ;; highlight body
 440 ;    (when wl-highlight-body-too
 441 ;      (wl-highlight-body))
 442     (condition-case ()
 443         (wl-message-narrow-to-page)
 444       (error nil)); ignore errors.
 445     (setq cache-used (cdr cache-used))
 446     (goto-char (point-min))
 447     (when (re-search-forward "^$" nil t)
 448       (wl-message-add-buttons-to-header (point-min) (point))
 449       (wl-message-add-buttons-to-body (point) (point-max)))
 450     (goto-char (point-min))
 451     (unwind-protect
 452         (save-excursion
 453           (run-hooks 'wl-message-redisplay-hook))
 454       ;; go back to summary mode
 455       (set-buffer-modified-p nil)
 456       (setq buffer-read-only t)
 457       (set-buffer summary-buf)
 458       (setq summary-win (get-buffer-window summary-buf))
 459       (if (window-live-p summary-win)
 460           (select-window summary-win)))
 461     cache-used))
 462
 463 ;; Use message buffer cache.
 464 (defun wl-message-buffer-display (folder number flag
 465                                          &optional force-reload unread)
 466   (let* ((msg-id (elmo-message-field folder number 'message-id))
 467          (fname (elmo-folder-name-internal folder))
 468          (hit (wl-message-buffer-cache-hit (list fname number msg-id)))
 469          (read nil)
 470          cache-used)
 471     (when (and hit (not (buffer-live-p hit)))
 472       (wl-message-buffer-cache-delete (list fname number msg-id))
 473       (setq hit nil))
 474     (if hit
 475         (progn
 476           ;; move hit to the top.
 477           (wl-message-buffer-cache-sort
 478            (wl-message-buffer-cache-entry-make (list fname number msg-id) hit))
 479           ;; buffer cache is used.
 480           (setq cache-used t)
 481           (with-current-buffer hit
 482             (unless (eq wl-message-buffer-cur-flag flag)
 483               (setq read t))))
 484       ;; delete tail and add new to the top.
 485       (setq hit (wl-message-buffer-cache-add (list fname number msg-id)))
 486       (setq read t))
 487     (if (or force-reload read)
 488         (condition-case err
 489             (save-excursion
 490               (set-buffer hit)
 491               (setq
 492                cache-used
 493                (wl-message-display-internal folder number flag
 494                                             force-reload unread))
 495               (setq wl-message-buffer-cur-flag flag))
 496           (quit
 497            (wl-message-buffer-cache-delete)
 498            (error "Display message %s/%s is quitted" fname number))
 499           (error
 500            (wl-message-buffer-cache-delete)
 501            (signal (car err) (cdr err))
 502            nil))) ;; will not be used
 503     (cons hit cache-used)))
 504
 505 (defun wl-message-display-internal (folder number flag
 506                                            &optional force-reload unread)
 507   (let ((default-mime-charset wl-mime-charset))
 508     (setq wl-message-buffer-all-header-flag (eq flag 'all-header))
 509     (prog1
 510         (if (eq flag 'as-is)
 511             (let (wl-highlight-x-face-function)
 512               (prog1 (elmo-mime-display-as-is folder number
 513                                               (current-buffer)
 514                                               (wl-message-get-original-buffer)
 515                                               'wl-original-message-mode
 516                                               force-reload
 517                                               unread
 518                                               (wl-message-define-keymap))
 519                 (let (buffer-read-only)
 520                   (wl-highlight-message (point-min) (point-max) t))))
 521           (elmo-mime-message-display folder number
 522                                      (current-buffer)
 523                                      (wl-message-get-original-buffer)
 524                                      'wl-original-message-mode
 525                                      force-reload
 526                                      unread
 527                                      (wl-message-define-keymap)))
 528       (run-hooks 'wl-message-display-internal-hook)
 529       (setq buffer-read-only t))))
 530
 531 (defsubst wl-message-buffer-prefetch-p (folder &optional number)
 532   (or (cond
 533        ((eq wl-message-buffer-prefetch-folder-type-list t)
 534         t)
 535        ((and number wl-message-buffer-prefetch-folder-type-list)
 536         (memq (elmo-folder-type-internal
 537                (elmo-message-folder folder number))
 538               wl-message-buffer-prefetch-folder-type-list))
 539        (wl-message-buffer-prefetch-folder-type-list
 540         (let ((list wl-message-buffer-prefetch-folder-type-list)
 541               type)
 542           (catch 'done
 543             (while (setq type (pop list))
 544               (if (elmo-folder-contains-type folder type)
 545                   (throw 'done t)))))))
 546       (cond
 547        ((consp wl-message-buffer-prefetch-folder-list)
 548         (wl-string-match-member (elmo-folder-name-internal folder)
 549                                 wl-message-buffer-prefetch-folder-list))
 550        (t wl-message-buffer-prefetch-folder-list))))
 551
 552 (defun wl-message-buffer-prefetch-next (folder number &optional
 553                                                count summary charset)
 554   (if (wl-message-buffer-prefetch-p folder)
 555       (if (not (fboundp 'run-with-idle-timer))
 556           (when (sit-for wl-message-buffer-prefetch-idle-time)
 557             (wl-message-buffer-prefetch-subr
 558              folder number (or count 1) summary charset))
 559 ;;;     cannot use for the bug of fsf-compat package (1.09).
 560 ;;;     (cancel-function-timers 'wl-message-buffer-prefetch-subr)
 561         (if (featurep 'xemacs)
 562             (let ((p itimer-list))
 563               (while (car p)
 564                 (if (eq 'wl-message-buffer-prefetch-subr
 565                         (itimer-function (car p)))
 566                     (delete-itimer (car p)))
 567                 (setq p (cdr p))))
 568           ;; FSF Emacs is correct
 569           (cancel-function-timers 'wl-message-buffer-prefetch-subr))
 570         (run-with-idle-timer
 571          wl-message-buffer-prefetch-idle-time
 572          nil
 573          'wl-message-buffer-prefetch-subr
 574          folder number (or count 1) summary charset))))
 575
 576 (defun wl-message-buffer-prefetch-subr (folder number count summary charset)
 577   (if (buffer-live-p summary)
 578       (with-current-buffer summary
 579         ;(set-buffer summary)
 580         (let ((next (funcall wl-message-buffer-prefetch-get-next-function
 581                              number)))
 582           (if (and next (not (wl-message-buffer-prefetch-p folder next)))
 583               ;; for Multi folder
 584               (wl-message-buffer-prefetch-subr folder next count summary charset)
 585             (if (and next
 586                      (numberp count)
 587                      (>= (setq count (- count 1)) 0)
 588                      (string= (elmo-folder-name-internal folder)
 589                               (wl-summary-buffer-folder-name)))
 590                 (let* ((wl-mime-charset      charset)
 591                        (default-mime-charset charset)
 592                        (message-id (elmo-message-field folder next 'message-id))
 593                        (key (list (elmo-folder-name-internal folder)
 594                                   next message-id))
 595                        (hit (wl-message-buffer-cache-hit key)))
 596                   (when wl-message-buffer-prefetch-debug
 597                     (message "%S: count %S, hit %S" next count hit))
 598                   (if (and hit (buffer-live-p hit))
 599                       (progn
 600                         (wl-message-buffer-cache-sort
 601                          (wl-message-buffer-cache-entry-make key hit))
 602                         (wl-message-buffer-prefetch-subr folder next count summary charset))
 603                     (let* ((size (elmo-message-field folder next 'size))
 604                            result time1 time2 sec micro)
 605                       (when (or (elmo-message-file-p folder next)
 606                                 (not (and (integerp size)
 607                                           elmo-message-fetch-threshold
 608                                           (>= size
 609                                               elmo-message-fetch-threshold))))
 610                         (when wl-message-buffer-prefetch-debug
 611                           (setq time1 (current-time))
 612                           (message "Prefetching %d..." next))
 613                         (setq result (wl-message-buffer-display folder next
 614                                                                 'mime nil 'unread))
 615                         (when wl-message-buffer-prefetch-debug
 616                           (setq time2 (current-time))
 617                           (setq sec  (- (nth 1 time2)(nth 1 time1)))
 618                           (setq micro (- (nth 2 time2)(nth 2 time1)))
 619                           (setq micro (+ micro (* 1000000 sec)))
 620                           (message "Prefetching %d...done(%f msec)."
 621                                    next
 622                                    (/ micro 1000.0))
 623                           (sit-for 0))
 624                         ;; set next prefetch
 625                         (wl-message-buffer-prefetch-next
 626                          folder next count summary charset)
 627                         (sit-for 0)
 628                         ;; success prefetch
 629                         ))))))
 630           ;; finish prefetch
 631           (when wl-message-buffer-prefetch-debug
 632             (message "Buffer Cached Messages: %s"
 633                      (mapconcat
 634                       '(lambda (cache)
 635                          (if (string=
 636                               (nth 0 (car cache))
 637                               (elmo-folder-name-internal folder))
 638                              (format "%d"
 639                                      (nth 1 (car cache)))
 640                            (format "*%d" (nth 1 (car cache)))))
 641                       wl-message-buffer-cache " "))) ))))
 642
 643 (defvar wl-message-button-map (make-sparse-keymap))
 644
 645 (defun wl-message-add-button (from to function &optional data)
 646   "Create a button between FROM and TO with callback FUNCTION and DATA."
 647   (add-text-properties
 648    from to
 649    (nconc (list 'wl-message-button-callback function)
 650           (if data
 651               (list 'wl-message-button-data data))))
 652   (let ((ov (make-overlay from to)))
 653     (overlay-put ov 'mouse-face 'highlight)
 654     (overlay-put ov 'local-map wl-message-button-map)
 655     (overlay-put ov 'evaporate t)))
 656
 657 (defun wl-message-button-dispatcher (event)
 658   "Select the button under point."
 659   (interactive "@e")
 660   (mouse-set-point event)
 661   (let ((callback (get-text-property (point) 'wl-message-button-callback))
 662         (data (get-text-property (point) 'wl-message-button-data)))
 663     (if callback
 664         (funcall callback data)
 665       (wl-message-button-dispatcher-internal event))))
 666
 667 (defun wl-message-button-refer-article (data)
 668   "Read article specified by Message-ID DATA at point."
 669   (switch-to-buffer-other-window
 670    wl-message-buffer-cur-summary-buffer)
 671   (if (wl-summary-jump-to-msg-by-message-id data)
 672       (wl-summary-redisplay)))
 673
 674 (defun wl-message-uu-substring (buf outbuf &optional first last)
 675   (save-excursion
 676     (set-buffer buf)
 677     (search-forward "\n\n")
 678     (let ((sp (point))
 679           ep filename case-fold-search)
 680       (catch 'done
 681         (if first
 682             (progn
 683               (if (re-search-forward "^begin[ \t]+[0-9]+[ \t]+\\([^ ].*\\)" nil t)
 684                   (setq filename (buffer-substring (match-beginning 1)(match-end 1)))
 685                 (throw 'done nil)))
 686           (re-search-forward "^M.*$" nil t)) ; uuencoded string
 687         (beginning-of-line)
 688         (setq sp (point))
 689         (goto-char (point-max))
 690         (if last
 691             (re-search-backward "^end" sp t)
 692           (re-search-backward "^M.*$" sp t)) ; uuencoded string
 693         (forward-line 1)
 694         (setq ep (point))
 695         (set-buffer outbuf)
 696         (goto-char (point-max))
 697         (insert-buffer-substring buf sp ep)
 698         (set-buffer buf)
 699         filename))))
 700
 701 (require 'product)
 702 (product-provide (provide 'wl-message) (require 'wl-version))
 703
 704 ;;; wl-message.el ends here