wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'mime-parse)
  35 (eval-when-compile (require 'mmbuffer))
  36 (require 'elmo)
  37 (require 'elmo-mime)
  38 (require 'wl-vars)
  39 (require 'wl-util)
  40 (eval-when-compile (require 'cl))
  41
  42 ;;; Draft
  43
  44 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  45
  46 (defalias 'wl-draft-decode-message-in-buffer
  47   'mime-edit-decode-message-in-buffer)
  48
  49 (defun wl-draft-yank-current-message-entity ()
  50   "Yank currently displayed message entity.
  51 By setting following-method as yank-content.
  52
  53 If region is active, yank region contents instead. \(this feature is available
  54 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  55 has Non-nil value\)"
  56   (let ((wl-draft-buffer (current-buffer))
  57         (mime-view-following-method-alist
  58          (list (cons 'wl-original-message-mode
  59                      (function wl-draft-yank-to-draft-buffer))))
  60         (mime-preview-following-method-alist
  61          (list (cons 'wl-original-message-mode
  62                      (function wl-draft-yank-to-draft-buffer))))
  63         (message-buffer (wl-current-message-buffer)))
  64     (if message-buffer
  65         (with-current-buffer message-buffer
  66           (save-restriction
  67             (widen)
  68             (cond
  69              ((wl-region-exists-p)
  70               (wl-mime-preview-follow-current-region))
  71              ((not (wl-message-mime-analysis-p
  72                     (wl-message-buffer-display-type)))
  73               (wl-mime-preview-follow-no-mime
  74                (wl-message-buffer-display-type)))
  75              (t
  76               (mime-preview-follow-current-entity)))))
  77       (error "No message."))))
  78
  79 ;; modified mime-preview-follow-current-entity from mime-view.el
  80 (defun wl-mime-preview-follow-no-mime (display-type)
  81   "Write follow message to current message, without mime.
  82 It calls following-method selected from variable
  83 `mime-preview-following-method-alist'."
  84   (interactive)
  85   (let* ((mode (mime-preview-original-major-mode 'recursive))
  86          (new-name (format "%s-no-mime" (buffer-name)))
  87          new-buf min beg end
  88          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  89          (the-buf (current-buffer))
  90          fields)
  91     (save-excursion
  92       (goto-char (point-min))
  93       (setq min (point-min)
  94             beg (re-search-forward "^$" nil t)
  95             end (point-max)))
  96     (with-current-buffer (setq new-buf (get-buffer-create new-name))
  97       (erase-buffer)
  98       (insert-buffer-substring the-buf beg end)
  99       (goto-char (point-min))
 100       ;; Insert all headers.
 101       (let ((elmo-mime-display-header-analysis
 102              (wl-message-mime-analysis-p display-type 'header)))
 103         (elmo-mime-insert-sorted-header entity))
 104       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 105         (if (functionp f)
 106             (funcall f new-buf)
 107           (message
 108            "Sorry, following method for %s is not implemented yet."
 109            mode))))))
 110
 111 ;; modified mime-preview-follow-current-entity from mime-view.el
 112 (defun wl-mime-preview-follow-current-region ()
 113   "Write follow message to current region.
 114 It calls following-method selected from variable
 115 `mime-preview-following-method-alist'."
 116   (interactive)
 117   (let ((r-beg (region-beginning))
 118         (r-end (region-end))
 119         (entity (get-text-property (point-min)
 120                                    'mime-view-entity)))
 121     (let* ((mode (mime-preview-original-major-mode 'recursive))
 122            (new-name
 123             (format "%s-active-region" (buffer-name)))
 124            new-buf
 125            (the-buf (current-buffer))
 126            fields)
 127       (with-current-buffer (setq new-buf (get-buffer-create new-name))
 128         (erase-buffer)
 129         (insert ?\n)
 130         (insert-buffer-substring the-buf r-beg r-end)
 131         (goto-char (point-min))
 132         (let ((current-entity
 133                (if (and entity
 134                         (eq (mime-entity-media-type entity) 'message)
 135                         (eq (mime-entity-media-subtype entity) 'rfc822))
 136                    (car (mime-entity-children entity))
 137                  entity)))
 138           (while (and current-entity
 139                       (if (and (eq (mime-entity-media-type
 140                                     current-entity) 'message)
 141                                (eq (mime-entity-media-subtype
 142                                     current-entity) 'rfc822))
 143                           nil
 144                         (mime-insert-header current-entity fields)
 145                         t))
 146             (setq fields (std11-collect-field-names)
 147                   current-entity (mime-entity-parent current-entity))))
 148         (let ((rest mime-view-following-required-fields-list)
 149               field-name ret)
 150           (while rest
 151             (setq field-name (car rest))
 152             (or (std11-field-body field-name)
 153                 (progn
 154                   (with-current-buffer the-buf
 155                     (let ((entity (when mime-mother-buffer
 156                                     (set-buffer mime-mother-buffer)
 157                                     (get-text-property (point)
 158                                                        'mime-view-entity))))
 159                       (while (and entity
 160                                   (null (setq ret (mime-entity-fetch-field
 161                                                    entity field-name))))
 162                         (setq entity (mime-entity-parent entity)))))
 163                   (if ret
 164                       (insert (concat field-name ": " ret "\n")))))
 165             (setq rest (cdr rest)))))
 166       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 167         (if (functionp f)
 168             (funcall f new-buf)
 169           (message
 170            "Sorry, following method for %s is not implemented yet."
 171            mode))))))
 172
 173 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 174
 175 (defun wl-draft-preview-attributes-list ()
 176   (if (listp (car wl-draft-preview-attributes-list))
 177       (elmo-uniq-list
 178        (nconc (and (wl-message-mail-p)
 179                    (copy-sequence
 180                     (cdr (assq 'mail wl-draft-preview-attributes-list))))
 181               (and (wl-message-news-p)
 182                    (copy-sequence
 183                     (cdr (assq 'news wl-draft-preview-attributes-list))))))
 184     wl-draft-preview-attributes-list))
 185
 186 (defun wl-draft-show-attributes-buffer (attribute-values)
 187   (let* ((cur-win (selected-window))
 188          (size (min
 189                 (- (window-height cur-win)
 190                    window-min-height 1)
 191                 (- (window-height cur-win)
 192                    (max
 193                     window-min-height
 194                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 195     (split-window cur-win (if (> size 0) size window-min-height))
 196     (select-window (next-window))
 197     (let ((pop-up-windows nil))
 198       (switch-to-buffer (get-buffer-create
 199                          wl-draft-preview-attributes-buffer-name)))
 200     (with-current-buffer
 201         (get-buffer wl-draft-preview-attributes-buffer-name)
 202       (setq buffer-read-only t)
 203       (let (buffer-read-only)
 204         (erase-buffer)
 205         (dolist (pair attribute-values)
 206           (insert (capitalize (symbol-name (car pair))) ": "
 207                   (format "%s" (or (cdr pair) ""))
 208                   "\n"))
 209         (goto-char (point-min))
 210         (wl-highlight-headers)))
 211     (select-window cur-win)))
 212
 213 (defun wl-draft-hide-attributes-buffer ()
 214   (let (window buffer)
 215     (when (setq window (get-buffer-window
 216                         wl-draft-preview-attributes-buffer-name))
 217       (select-window window)
 218       (delete-window))
 219     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 220       (kill-buffer buffer))))
 221
 222 (defun wl-draft-attribute-recipients ()
 223   (let (wl-draft-remove-group-list-contents)
 224     (mapconcat
 225      'identity
 226      (nconc
 227       (wl-draft-deduce-address-list
 228        (current-buffer)
 229        (point-min)
 230        (save-excursion
 231          (goto-char (point-min))
 232          (re-search-forward
 233           (concat
 234            "^"
 235            (regexp-quote mail-header-separator)
 236            "$")
 237           nil t)
 238          (point)))
 239       (wl-draft-parse-mailbox-list wl-draft-mime-bcc-field-name))
 240      ", ")))
 241
 242 (defun wl-draft-attribute-envelope-from ()
 243   (or wl-envelope-from
 244       (wl-address-header-extract-address wl-from)))
 245
 246 (defun wl-draft-attribute-smtp-posting-server ()
 247   (or wl-smtp-posting-server
 248       (progn (require 'smtp) smtp-server)
 249       "localhost"))
 250
 251 (defun wl-draft-attribute-smtp-posting-port ()
 252   (or wl-smtp-posting-port
 253       (progn (require 'smtp) smtp-service)))
 254
 255 (defun wl-draft-attribute-newsgroups ()
 256   (std11-field-body "Newsgroups"))
 257
 258 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 259   (let ((config (cdr (elmo-string-matched-assoc
 260                       (std11-field-body "newsgroups")
 261                       wl-nntp-posting-config-alist)))
 262         entry)
 263     (when (stringp config)
 264       (setq config (list (cons 'server config))))
 265     (if (setq entry (assq attribute config))
 266         ;; maybe nil
 267         (cdr entry)
 268       (let (value)
 269         (while alternatives
 270           (if (setq value (symbol-value (car alternatives)))
 271               (setq alternatives nil)
 272             (setq alternatives (cdr alternatives))))
 273         value))))
 274
 275 (defun wl-draft-attribute-nntp-posting-server ()
 276   (wl-draft-nntp-attribute
 277    'server
 278    '(wl-nntp-posting-server elmo-nntp-default-server)))
 279
 280 (defun wl-draft-attribute-nntp-posting-port ()
 281   (wl-draft-nntp-attribute
 282    'port
 283    '(wl-nntp-posting-port elmo-nntp-default-port)))
 284
 285 (defun wl-draft-attribute-value (attr)
 286   (let ((name (symbol-name attr))
 287         fsymbol symbol)
 288     (cond ((and (setq fsymbol (intern-soft
 289                                (format "wl-draft-attribute-%s" name)))
 290                 (fboundp fsymbol))
 291            (funcall fsymbol))
 292           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 293                 (boundp symbol))
 294            (symbol-value symbol))
 295           ((boundp attr)
 296            (symbol-value attr)))))
 297
 298 (defun wl-mime-quit-preview ()
 299   "Quitting method for mime-view."
 300   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 301                     mime-edit-temp-message-buffer))
 302          (window (selected-window))
 303          buf)
 304     (mime-preview-kill-buffer)
 305     (set-buffer temp)
 306     (setq buf mime-edit-buffer)
 307     (kill-buffer temp)
 308     (select-window window)
 309     (switch-to-buffer buf)))
 310
 311 (defun wl-draft-preview-message ()
 312   "Preview editing message."
 313   (interactive)
 314   (let* (attribute-values
 315          (orig-buffer (current-buffer))
 316          (current-point (point))
 317          (config-exec-flag wl-draft-config-exec-flag)
 318          (parent-folder wl-draft-parent-folder)
 319          (mime-display-header-hook 'wl-highlight-headers)
 320          (mime-header-encode-method-alist
 321           (append
 322            '((wl-draft-eword-encode-address-list
 323               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 324            (if (boundp 'mime-header-encode-method-alist)
 325                (symbol-value 'mime-header-encode-method-alist))))
 326          mime-view-ignored-field-list   ; all header.
 327          (mime-edit-translate-buffer-hook
 328           (cons
 329            (lambda ()
 330              (let ((wl-draft-config-exec-flag config-exec-flag)
 331                    (wl-draft-parent-folder parent-folder)
 332                    (copy-buffer (current-buffer)))
 333                (wl-copy-local-variables
 334                 orig-buffer
 335                 copy-buffer
 336                 (with-current-buffer orig-buffer
 337                   (append wl-draft-config-variables
 338                           (wl-draft-clone-local-variables))))
 339                (goto-char current-point)
 340                (run-hooks 'wl-draft-send-hook)
 341                (condition-case err
 342                    (setq attribute-values
 343                          (mapcar
 344                           (lambda (attr)
 345                             (cons attr (wl-draft-attribute-value attr)))
 346                           (if wl-draft-preview-attributes
 347                               (wl-draft-preview-attributes-list)
 348                             '(recipients))))
 349                  (error
 350                   (kill-buffer (current-buffer))
 351                   (signal (car err) (cdr err))))))
 352            mime-edit-translate-buffer-hook)))
 353     (mime-edit-preview-message)
 354     (make-local-variable 'mime-preview-quitting-method-alist)
 355     (setq mime-preview-quitting-method-alist
 356           '((mime-temp-message-mode . wl-mime-quit-preview)))
 357     (let ((buffer-read-only nil))
 358       (when wl-highlight-body-too
 359         (wl-highlight-body))
 360       (run-hooks 'wl-draft-preview-message-hook))
 361     (if (fboundp 'make-local-hook)
 362         (make-local-hook 'kill-buffer-hook))
 363     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 364     (if wl-draft-preview-attributes
 365         (ignore-errors ; in case when the window is too small
 366          (wl-draft-show-attributes-buffer attribute-values))
 367       (message (concat "Recipients: "
 368                        (cdr (assq 'recipients attribute-values)))))))
 369
 370 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 371
 372 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 373
 374 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 375
 376 ;;; Message
 377
 378 (defun wl-message-decode-mode (outbuf inbuf)
 379   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 380         (mime-display-header-hook 'wl-highlight-headers))
 381     (mime-view-mode nil nil nil inbuf outbuf)))
 382
 383 (defun wl-message-decode-with-all-header (outbuf inbuf)
 384   (let ((mime-view-ignored-field-regexp "^:$")
 385         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 386         (mime-display-header-hook 'wl-highlight-headers)
 387         mime-view-ignored-field-list)
 388     (mime-view-mode nil nil nil inbuf outbuf)))
 389
 390 (defun wl-message-delete-popup-windows ()
 391   (dolist (buffer wl-message-popup-buffers)
 392     (when (or (stringp buffer)
 393               (and (symbolp buffer)
 394                    (boundp buffer)
 395                    (setq buffer (symbol-value buffer))))
 396       (let ((window (get-buffer-window buffer)))
 397         (when window
 398           (delete-window window))))))
 399
 400 (defun wl-message-request-partial (folder number)
 401   (elmo-set-work-buf
 402    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 403                        number
 404                        (elmo-make-fetch-strategy 'entire)
 405                        'unread)
 406    (mime-parse-buffer nil)))
 407
 408 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 409 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 410 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 411 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 412 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 413 (defalias 'wl-message-quit              'mime-preview-quit)
 414 (defalias 'wl-message-button-dispatcher-internal
 415   'mime-button-dispatcher)
 416
 417 (defsubst wl-mime-node-id-to-string (node-id)
 418   (if (consp node-id)
 419       (mapconcat (lambda (num) (format "%s" (1+ num)))
 420                  (reverse node-id)
 421                  ".")
 422     "0"))
 423
 424 (defun wl-message-delete-current-part ()
 425   "Delete a part under the cursor from the multipart message."
 426   (interactive)
 427   (save-restriction
 428     (widen)
 429     (let* ((entity (get-text-property (point) 'mime-view-entity))
 430            (node-id (mime-entity-node-id entity))
 431            (filename (mime-entity-safe-filename entity))
 432            (header-start (mime-buffer-entity-header-start-internal entity))
 433            (body-end (mime-buffer-entity-body-end-internal entity))
 434            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 435            (number wl-message-buffer-cur-number)
 436            (msgid (elmo-message-field folder number 'message-id))
 437            (orig-buf wl-message-buffer-original-buffer))
 438       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 439           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 440       (with-current-buffer orig-buf
 441         (unless (string-equal
 442                  (buffer-string)
 443                  (elmo-message-fetch-string
 444                   folder number
 445                   (elmo-make-fetch-strategy 'entire)))
 446           (error "Buffer content differs from actual message")))
 447       (when (and (elmo-folder-writable-p folder)
 448                  (buffer-live-p orig-buf)
 449                  node-id
 450                  (yes-or-no-p
 451                   (format "Do you really want to delete part %s? "
 452                           (wl-mime-node-id-to-string node-id))))
 453         (when (with-temp-buffer
 454                 (insert-buffer-substring orig-buf)
 455                 (delete-region header-start body-end)
 456                 (goto-char header-start)
 457                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 458                 (when filename
 459                   (insert
 460                    "Content-Disposition:"
 461                    (mime-encode-field-body
 462                          (concat ""
 463                                  (and filename
 464                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 465                          "Content-Disposition")
 466                    "\n"))
 467                 (insert "\n")
 468                 (insert "** This part has been removed by Wanderlust **\n\n")
 469                 (elmo-folder-append-buffer folder))
 470
 471           (elmo-folder-move-messages
 472            folder (list number)
 473            (wl-folder-get-elmo-folder wl-trash-folder))
 474           (when (and (elmo-cache-get-path msgid)
 475                      (file-exists-p (elmo-cache-get-path msgid)))
 476             (delete-file (elmo-cache-get-path msgid)))
 477
 478           (mime-preview-quit)
 479           (wl-summary-delete-messages-on-buffer (list number))
 480           (wl-summary-toggle-disp-msg 'off)
 481           (setq wl-message-buffer nil)
 482           (wl-summary-sync nil "update"))))))
 483
 484 ;; PGP
 485 (eval-when-compile
 486   (defmacro wl-define-dummy-functions (&rest symbols)
 487     `(dolist (symbol (quote ,symbols))
 488        (defalias symbol 'ignore))))
 489
 490 (eval-when-compile
 491   ;; split eval-when-compile form for avoid error on `make compile-strict'
 492   (require 'mime-pgp)
 493   (condition-case nil
 494       (require 'epa)
 495     (error
 496      (wl-define-dummy-functions epg-make-context
 497                                 epg-decrypt-string
 498                                 epg-verify-string
 499                                 epg-context-set-progress-callback
 500                                 epg-context-result-for
 501                                 epg-verify-result-to-string
 502                                 epa-display-info)))
 503   (condition-case nil
 504       (require 'pgg)
 505     (error
 506      (wl-define-dummy-functions pgg-decrypt-region
 507                                 pgg-verify-region
 508                                 pgg-display-output-buffer))))
 509
 510 (defun wl-epg-progress-callback (context what char current total reporter)
 511   (let ((label (elmo-progress-counter-label reporter)))
 512     (when label
 513       (elmo-progress-notify label :set current :total total))))
 514
 515 (defun wl-mime-pgp-decrypt-region-with-epg (beg end &optional no-decode)
 516   (require 'epg)
 517   (let ((context (epg-make-context)))
 518     (elmo-with-progress-display (epg-decript nil reporter)
 519         "Decrypting"
 520       (epg-context-set-progress-callback context
 521                                          (cons #'wl-epg-progress-callback
 522                                                reporter))
 523       (insert (prog1
 524                   (decode-coding-string
 525                    (epg-decrypt-string
 526                     context
 527                     (buffer-substring beg end))
 528                    (if no-decode 'raw-text wl-cs-autoconv))
 529                 (delete-region beg end)))))
 530   last-coding-system-used)
 531
 532 (defun wl-mime-pgp-verify-region-with-epg (beg end &optional coding-system)
 533   (require 'epa)
 534   (let ((context (epg-make-context)))
 535     (elmo-with-progress-display (epg-verify nil reporter)
 536         "Verifying"
 537       (epg-context-set-progress-callback context
 538                                          (cons #'wl-epg-progress-callback
 539                                                reporter))
 540       (epg-verify-string
 541        context
 542        (encode-coding-string
 543         (buffer-substring beg end)
 544         (if coding-system
 545             (coding-system-change-eol-conversion coding-system 'dos)
 546           'raw-text-dos))))
 547     (when (epg-context-result-for context 'verify)
 548       (epa-display-info (epg-verify-result-to-string
 549                          (epg-context-result-for context 'verify))))))
 550
 551 (defun wl-mime-pgp-decrypt-region-with-pgg (beg end &optional no-decode)
 552   (require 'pgg)
 553   (let ((buffer-file-coding-system wl-cs-autoconv)
 554         status)
 555     (setq status (pgg-decrypt-region beg end))
 556     (if no-decode
 557         (when status
 558           (delete-region beg end)
 559           (insert-buffer-substring pgg-output-buffer))
 560       (pgg-display-output-buffer beg end status))
 561     (unless status
 562       (error "Decryption is failed"))
 563     last-coding-system-used))
 564
 565 (defun wl-mime-pgp-verify-region-with-pgg (beg end &optional coding-system)
 566   (require 'pgg)
 567   (let ((message-buffer (current-buffer))
 568         success)
 569     (with-temp-buffer
 570       (insert-buffer-substring message-buffer beg end)
 571       (when coding-system
 572         (encode-coding-region (point-min) (point-max) coding-system))
 573       (setq success (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 574     (mime-show-echo-buffer)
 575     (set-buffer mime-echo-buffer-name)
 576     (set-window-start
 577      (get-buffer-window mime-echo-buffer-name)
 578      (point-max))
 579     (insert-buffer-substring
 580      (if success
 581          pgg-output-buffer
 582        pgg-errors-buffer))))
 583
 584 (defsubst wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 585   (case wl-use-pgp-module
 586     (epg
 587      (wl-mime-pgp-decrypt-region-with-epg beg end no-decode))
 588     (pgg
 589      (wl-mime-pgp-decrypt-region-with-pgg beg end no-decode))
 590     (t
 591      (error "Don't support PGP decryption"))))
 592
 593 (defsubst wl-mime-pgp-verify-region (beg end &optional coding-system)
 594   (case wl-use-pgp-module
 595     (epg
 596      (wl-mime-pgp-verify-region-with-epg beg end coding-system))
 597     (pgg
 598      (wl-mime-pgp-verify-region-with-pgg beg end coding-system))
 599     (t
 600      (error "Don't support PGP decryption"))))
 601
 602 (defun wl-message-decrypt-pgp-nonmime ()
 603   "Decrypt PGP encrypted region"
 604   (interactive)
 605   (save-excursion
 606     (beginning-of-line)
 607     (let ((region (wl-find-region "^-+BEGIN PGP MESSAGE-+$"
 608                                   "^-+END PGP MESSAGE-+$"))
 609           (inhibit-read-only t)
 610           coding-system)
 611       (unless region
 612         (error "Cannot find PGP encrypted region"))
 613       (save-restriction
 614         (let ((props (text-properties-at (car region))))
 615           (narrow-to-region (car region) (cdr region))
 616           (when (setq coding-system
 617                       (wl-mime-pgp-decrypt-region (point-min) (point-max)))
 618             (setq props (plist-put props
 619                                    'wl-mime-decoded-coding-system
 620                                    coding-system)))
 621           (set-text-properties (point-min) (point-max) props))))))
 622
 623 (defun wl-message-verify-pgp-nonmime (&optional arg)
 624   "Verify PGP signed region.
 625 With ARG, ask coding system and encode the region with it before verifying."
 626   (interactive "P")
 627   (save-excursion
 628     (beginning-of-line)
 629     (let ((region (wl-find-region "^-+BEGIN PGP SIGNED MESSAGE-+$"
 630                                   "^-+END PGP SIGNATURE-+$"))
 631           coding-system)
 632       (unless region
 633         (error "Cannot find PGP signed region"))
 634       (setq coding-system
 635             (or (get-text-property (car region) 'wl-mime-decoded-coding-system)
 636                 (let* ((situation (mime-preview-find-boundary-info))
 637                        (entity (aref situation 2)))
 638                   (mime-charset-to-coding-system
 639                    (mime-content-type-parameter
 640                     (mime-entity-content-type entity)
 641                     "charset")))
 642                 buffer-file-coding-system))
 643       (when arg
 644         (setq coding-system (read-coding-system
 645                              (format "Coding system (%S): " coding-system)
 646                              coding-system)))
 647       (wl-mime-pgp-verify-region (car region) (cdr region) coding-system))))
 648
 649 ;; XXX: encrypted multipart isn't represented as multipart
 650 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 651   (goto-char (point-max))
 652   (let ((p (point))
 653         raw-buf to-buf representation-type child-entity)
 654     (goto-char p)
 655     (save-restriction
 656       (narrow-to-region p p)
 657       (setq to-buf (current-buffer))
 658       (with-temp-buffer
 659         (setq raw-buf (current-buffer))
 660         (mime-insert-entity entity)
 661         (when (progn
 662                 (goto-char (point-min))
 663                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 664           (wl-mime-pgp-decrypt-region (point-min) (point-max) 'no-decode)
 665           (setq representation-type 'elmo-buffer))
 666         (setq child-entity (mime-parse-message
 667                             (mm-expand-class-name representation-type)
 668                             nil
 669                             parent-entity
 670                             (mime-entity-node-id-internal parent-entity)))
 671         (mime-display-entity
 672          child-entity
 673          nil
 674          `((header . visible)
 675            (body . visible)
 676            (entity-button . invisible))
 677          to-buf)))))
 678
 679 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 680   (let* ((entity-node-id (mime-entity-node-id entity))
 681          (mother (mime-entity-parent entity))
 682          (knum (car entity-node-id))
 683          (onum (if (> knum 0)
 684                    (1- knum)
 685                  (1+ knum)))
 686          (orig-entity (nth onum (mime-entity-children mother))))
 687     (wl-mime-preview-application/pgp entity orig-entity situation)))
 688
 689 ;;; Summary
 690 (defun wl-summary-burst-subr (message-entity target number)
 691   ;; returns new number.
 692   (let (content-type entity)
 693     (setq content-type (mime-entity-content-type message-entity))
 694     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 695            (dolist (entity (mime-entity-children message-entity))
 696              (setq number (wl-summary-burst-subr
 697                            entity
 698                            target
 699                            number))))
 700           ((and (eq (cdr (assq 'type content-type)) 'message)
 701                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 702            (message "Bursting...%s" (setq number (+ 1 number)))
 703            (setq entity
 704                  (car (mime-entity-children message-entity)))
 705            (with-temp-buffer
 706              (set-buffer-multibyte nil)
 707              (insert (mime-entity-body message-entity))
 708              (elmo-folder-append-buffer target))))
 709     number))
 710
 711 (defun wl-summary-burst (&optional arg)
 712   "De-capsulate embedded messages in MIME format.
 713 With ARG, ask destination folder."
 714   (interactive "P")
 715   (let ((raw-buf (wl-summary-get-original-buffer))
 716         (view-buf wl-message-buffer)
 717         message-entity target)
 718     (save-excursion
 719       (when (and (null arg)
 720                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 721         (setq target wl-summary-buffer-elmo-folder))
 722       (while (null target)
 723         (let ((name (wl-summary-read-folder wl-default-folder
 724                                             "to extract to")))
 725           (setq target (wl-folder-get-elmo-folder name))
 726           (unless (elmo-folder-writable-p target)
 727             (message "%s is not writable" name)
 728             (setq target nil)
 729             (sit-for 1))))
 730       (wl-summary-set-message-buffer-or-redisplay)
 731       (with-current-buffer view-buf
 732         (setq message-entity
 733               (get-text-property (point-min) 'mime-view-entity)))
 734       (when message-entity
 735         (message "Bursting...")
 736         (with-current-buffer raw-buf
 737           (wl-summary-burst-subr message-entity target 0))
 738         (message "Bursting...done"))
 739       (if (elmo-folder-plugged-p target)
 740           (elmo-folder-check target)))
 741     (when (and target
 742                (string= wl-summary-buffer-folder-name
 743                         (elmo-folder-name-internal target)))
 744       (save-excursion (wl-summary-sync-update)))))
 745
 746 ;; internal variable.
 747 (defvar wl-mime-save-directory nil "Last saved directory.")
 748 ;;; Yet another save method.
 749 (defun wl-mime-save-content (entity situation)
 750   (let ((filename (expand-file-name
 751                    (read-file-name "Save to file: "
 752                                    (expand-file-name
 753                                     (or (mime-entity-safe-filename entity)
 754                                         ".")
 755                                     (or wl-mime-save-directory
 756                                         wl-temporary-file-directory))))))
 757     (while (file-directory-p filename)
 758       (setq filename (read-file-name "Please set filename (not directory): "
 759                                      filename)))
 760     (if (and (file-exists-p filename)
 761              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 762                                        filename))))
 763         (message "Not saved")
 764       (setq wl-mime-save-directory (file-name-directory filename))
 765       (mime-write-entity-content entity filename))))
 766
 767 (defun wl-summary-extract-attachments-1 (message-entity directory number)
 768   ;; returns new number.
 769   (let (children filename)
 770     (cond
 771      ((setq children (mime-entity-children message-entity))
 772       (dolist (entity children)
 773         (setq number
 774               (wl-summary-extract-attachments-1 entity directory number))))
 775      ((and (eq (mime-content-disposition-type
 776                 (mime-entity-content-disposition message-entity))
 777                'attachment)
 778            (setq filename (mime-entity-safe-filename message-entity)))
 779       (let ((full (expand-file-name filename directory)))
 780         (when (or (not (file-exists-p full))
 781                   (yes-or-no-p
 782                    (format "File %s exists. Save anyway? " filename)))
 783           (message "Extracting...%s" (setq number (+ 1 number)))
 784           (mime-write-entity-content message-entity full)))))
 785     number))
 786
 787 (defun wl-summary-extract-attachments (directory)
 788   "Extract attachment parts in MIME format into the DIRECTORY."
 789   (interactive
 790    (let* ((default (or wl-mime-save-directory
 791                        wl-temporary-file-directory))
 792           (directory (read-directory-name "Extract to " default default t)))
 793      (list (if (> (length directory) 0) directory default))))
 794   (unless (and (file-writable-p directory)
 795                (file-directory-p directory))
 796     (error "%s is not writable" directory))
 797   (save-excursion
 798     (wl-summary-set-message-buffer-or-redisplay)
 799     (let ((entity (get-text-property (point-min) 'mime-view-entity)))
 800       (when entity
 801         (message "Extracting...")
 802         (wl-summary-extract-attachments-1 entity directory 0)
 803         (message "Extracting...done")))))
 804
 805 ;;; Yet another combine method.
 806 (defun wl-mime-combine-message/partial-pieces (entity situation)
 807   "Internal method for wl to combine message/partial messages automatically."
 808   (interactive)
 809   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 810                    wl-summary-buffer-elmo-folder))
 811          (mime-display-header-hook 'wl-highlight-headers)
 812          (id (or (cdr (assoc "id" situation)) ""))
 813          (mother (current-buffer))
 814          (summary-buf wl-message-buffer-cur-summary-buffer)
 815          subject-id overviews
 816          (root-dir (expand-file-name
 817                     (concat "m-prts-" (user-login-name))
 818                     temporary-file-directory))
 819          full-file point)
 820     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 821     (setq full-file (concat root-dir "/FULL"))
 822     (if (or (file-exists-p full-file)
 823             (not (y-or-n-p "Merge partials? ")))
 824         (with-current-buffer mother
 825           (mime-store-message/partial-piece entity situation)
 826           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 827           (make-local-variable 'mime-preview-over-to-next-method-alist)
 828           (setq mime-preview-over-to-next-method-alist
 829                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 830                       mime-preview-over-to-next-method-alist))
 831           (make-local-variable 'mime-preview-over-to-previous-method-alist)
 832           (setq mime-preview-over-to-previous-method-alist
 833                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 834                       mime-preview-over-to-previous-method-alist)))
 835       (setq subject-id
 836             (eword-decode-string
 837              (decode-mime-charset-string
 838               (mime-entity-read-field entity 'Subject)
 839               wl-summary-buffer-mime-charset)))
 840       (if (string-match "[0-9\n]+" subject-id)
 841           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 842       (catch 'tag
 843         (elmo-folder-do-each-message-entity (entity folder)
 844           (when (string-match
 845                  (regexp-quote subject-id)
 846                  (elmo-message-entity-field entity 'subject))
 847             (let* ((message
 848                     ;; request message at the cursor in Subject buffer.
 849                     (wl-message-request-partial
 850                      (elmo-folder-name-internal folder)
 851                      (elmo-message-entity-number entity)))
 852                    (situation (mime-entity-situation message))
 853                    (the-id (or (cdr (assoc "id" situation)) "")))
 854               (when (string= (downcase the-id)
 855                              (downcase id))
 856                 (with-current-buffer mother
 857                   (mime-store-message/partial-piece message situation))
 858                 (if (file-exists-p full-file)
 859                     (throw 'tag nil))))))
 860         (message "Not all partials found.")))))
 861
 862 (defun wl-mime-display-text/plain (entity situation)
 863   (let ((beg (point)))
 864     (mime-display-text/plain entity situation)
 865     (wl-highlight-message beg (point-max) t t)))
 866
 867 (defun wl-mime-display-header (entity situation)
 868   (let ((elmo-message-ignored-field-list
 869          (if wl-message-buffer-require-all-header
 870              nil
 871            wl-message-ignored-field-list))
 872         (elmo-message-visible-field-list wl-message-visible-field-list)
 873         (elmo-message-sorted-field-list wl-message-sort-field-list))
 874     (elmo-mime-insert-header entity situation)
 875     (wl-highlight-headers)))
 876
 877 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 878   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 879         (original-buffer wl-message-buffer-original-buffer))
 880     (mime-decrypt-application/pgp-encrypted entity situation)
 881     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 882     (setq wl-message-buffer-original-buffer original-buffer)))
 883
 884
 885 ;;; Setup methods.
 886 (defun wl-mime-setup ()
 887   (set-alist 'mime-preview-quitting-method-alist
 888              'wl-original-message-mode 'wl-message-exit)
 889   (set-alist 'mime-view-over-to-previous-method-alist
 890              'wl-original-message-mode 'wl-message-exit)
 891   (set-alist 'mime-view-over-to-next-method-alist
 892              'wl-original-message-mode 'wl-message-exit)
 893   (set-alist 'mime-preview-over-to-previous-method-alist
 894              'wl-original-message-mode 'wl-message-exit)
 895   (set-alist 'mime-preview-over-to-next-method-alist
 896              'wl-original-message-mode 'wl-message-exit)
 897   (add-hook 'wl-summary-toggle-disp-off-hook 'wl-message-delete-popup-windows)
 898   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-popup-windows)
 899   (add-hook 'wl-message-exit-hook 'wl-message-delete-popup-windows)
 900
 901   (ctree-set-calist-strictly
 902    'mime-preview-condition
 903    '((type . text) (subtype . plain)
 904      (body . visible)
 905      (body-presentation-method . wl-mime-display-text/plain)
 906      (major-mode . wl-original-message-mode)))
 907
 908   (ctree-set-calist-strictly
 909    'mime-preview-condition
 910    '((type . application)(subtype . pgp-encrypted)
 911      (encoding . t)
 912      (body . invisible)
 913      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 914      (major-mode . wl-original-message-mode)))
 915
 916   (ctree-set-calist-strictly
 917    'mime-acting-condition
 918    '((type . message) (subtype . partial)
 919      (method .  wl-mime-combine-message/partial-pieces)
 920      (request-partial-message-method . wl-message-request-partial)
 921      (major-mode . wl-original-message-mode)))
 922
 923   (ctree-set-calist-strictly
 924    'mime-acting-condition
 925    '((type . application) (subtype . pgp-encrypted)
 926      (method . wl-mime-decrypt-application/pgp-encrypted)
 927      (major-mode . wl-original-message-mode)))
 928
 929   (ctree-set-calist-strictly
 930    'mime-acting-condition
 931    '((mode . "extract")
 932      (major-mode . wl-original-message-mode)
 933      (method . wl-mime-save-content)))
 934   (set-alist 'mime-preview-following-method-alist
 935              'wl-original-message-mode
 936              (function wl-message-follow-current-entity))
 937   (set-alist 'mime-view-following-method-alist
 938              'wl-original-message-mode
 939              (function wl-message-follow-current-entity))
 940   (set-alist 'mime-edit-message-inserter-alist
 941              'wl-draft-mode (function wl-draft-insert-current-message))
 942   (set-alist 'mime-edit-mail-inserter-alist
 943              'wl-draft-mode (function wl-draft-insert-get-message))
 944   (set-alist 'mime-edit-split-message-sender-alist
 945              'wl-draft-mode
 946              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 947   (set-alist 'mime-raw-representation-type-alist
 948              'wl-original-message-mode 'binary)
 949   ;; Sort and highlight header fields.
 950   (or wl-message-ignored-field-list
 951       (setq wl-message-ignored-field-list
 952             mime-view-ignored-field-list))
 953   (or wl-message-visible-field-list
 954       (setq wl-message-visible-field-list
 955             mime-view-visible-field-list))
 956   (set-alist 'mime-header-presentation-method-alist
 957              'wl-original-message-mode
 958              'wl-mime-display-header)
 959   ;; To avoid overriding wl-draft-mode-map.
 960   (when (boundp 'mime-setup-signature-key-alist)
 961     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 962       (setq mime-setup-signature-key-alist
 963             (cons '(wl-draft-mode . "\C-c\C-w")
 964                   mime-setup-signature-key-alist)))))
 965
 966 (require 'product)
 967 (product-provide (provide 'wl-mime) (require 'wl-version))
 968
 969 ;;; wl-mime.el ends here