wl/wl-mime.el

   1 ;;; wl-mime.el --- SEMI implementations of MIME processing on Wanderlust.
   2
   3 ;; Copyright (C) 1998,1999,2000 Yuuichi Teranishi <teranisi@gohome.org>
   4
   5 ;; Author: Yuuichi Teranishi <teranisi@gohome.org>
   6 ;; Keywords: mail, net news
   7
   8 ;; This file is part of Wanderlust (Yet Another Message Interface on Emacsen).
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25
  26 ;;; Commentary:
  27 ;;
  28
  29 ;;; Code:
  30 ;;
  31 (require 'mime-view)
  32 (require 'mime-edit)
  33 (require 'mime-play)
  34 (require 'elmo)
  35 (require 'wl-vars)
  36
  37 ;;; Draft
  38
  39 (defalias 'wl-draft-editor-mode 'mime-edit-mode)
  40
  41 (defalias 'wl-draft-decode-message-in-buffer
  42   'mime-edit-decode-message-in-buffer)
  43
  44 (defun wl-draft-yank-current-message-entity ()
  45   "Yank currently displayed message entity.
  46 By setting following-method as yank-content.
  47
  48 If region is active, yank region contents instead. \(this feature is available
  49 if and only if `transient-mark-mode' \(GNU Emacs\) or `zmacs-regions' \(XEmacs\)
  50 has Non-nil value\)"
  51   (let ((wl-draft-buffer (current-buffer))
  52         (mime-view-following-method-alist
  53          (list (cons 'wl-original-message-mode
  54                      (function wl-draft-yank-to-draft-buffer))))
  55         (mime-preview-following-method-alist
  56          (list (cons 'wl-original-message-mode
  57                      (function wl-draft-yank-to-draft-buffer))))
  58         (message-buffer (wl-current-message-buffer)))
  59     (if message-buffer
  60         (save-excursion
  61           (set-buffer message-buffer)
  62           (save-restriction
  63             (widen)
  64             (cond
  65              ((wl-region-exists-p)
  66               (wl-mime-preview-follow-current-region))
  67              ((not (wl-message-mime-analysis-p
  68                     (wl-message-buffer-display-type)))
  69               (wl-mime-preview-follow-no-mime
  70                (wl-message-buffer-display-type)))
  71              (t
  72               (mime-preview-follow-current-entity)))))
  73       (error "No message."))))
  74
  75 ;; modified mime-preview-follow-current-entity from mime-view.el
  76 (defun wl-mime-preview-follow-no-mime (display-type)
  77   "Write follow message to current message, without mime.
  78 It calls following-method selected from variable
  79 `mime-preview-following-method-alist'."
  80   (interactive)
  81   (let* ((mode (mime-preview-original-major-mode 'recursive))
  82          (new-name (format "%s-no-mime" (buffer-name)))
  83          new-buf min beg end
  84          (entity (get-text-property (point-min) 'elmo-as-is-entity))
  85          (the-buf (current-buffer))
  86          fields)
  87     (save-excursion
  88       (goto-char (point-min))
  89       (setq min (point-min)
  90             beg (re-search-forward "^$" nil t)
  91             end (point-max)))
  92     (save-excursion
  93       (set-buffer (setq new-buf (get-buffer-create new-name)))
  94       (erase-buffer)
  95       (insert-buffer-substring the-buf beg end)
  96       (goto-char (point-min))
  97       ;; Insert all headers.
  98       (let ((elmo-mime-display-header-analysis
  99              (wl-message-mime-analysis-p display-type 'header)))
 100         (elmo-mime-insert-sorted-header entity))
 101       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 102         (if (functionp f)
 103             (funcall f new-buf)
 104           (message
 105            "Sorry, following method for %s is not implemented yet."
 106            mode))))))
 107
 108 ;; modified mime-preview-follow-current-entity from mime-view.el
 109 (defun wl-mime-preview-follow-current-region ()
 110   "Write follow message to current region.
 111 It calls following-method selected from variable
 112 `mime-preview-following-method-alist'."
 113   (interactive)
 114   (let ((r-beg (region-beginning))
 115         (r-end (region-end))
 116         (entity (get-text-property (point-min)
 117                                    'mime-view-entity)))
 118     (let* ((mode (mime-preview-original-major-mode 'recursive))
 119            (new-name
 120             (format "%s-active-region" (buffer-name)))
 121            new-buf
 122            (the-buf (current-buffer))
 123            fields)
 124       (save-excursion
 125         (set-buffer (setq new-buf (get-buffer-create new-name)))
 126         (erase-buffer)
 127         (insert ?\n)
 128         (insert-buffer-substring the-buf r-beg r-end)
 129         (goto-char (point-min))
 130         (let ((current-entity
 131                (if (and entity
 132                         (eq (mime-entity-media-type entity) 'message)
 133                         (eq (mime-entity-media-subtype entity) 'rfc822))
 134                    (car (mime-entity-children entity))
 135                  entity)))
 136           (while (and current-entity
 137                       (if (and (eq (mime-entity-media-type
 138                                     current-entity) 'message)
 139                                (eq (mime-entity-media-subtype
 140                                     current-entity) 'rfc822))
 141                           nil
 142                         (mime-insert-header current-entity fields)
 143                         t))
 144             (setq fields (std11-collect-field-names)
 145                   current-entity (mime-entity-parent current-entity))))
 146         (let ((rest mime-view-following-required-fields-list)
 147               field-name ret)
 148           (while rest
 149             (setq field-name (car rest))
 150             (or (std11-field-body field-name)
 151                 (progn
 152                   (save-excursion
 153                     (set-buffer the-buf)
 154                     (let ((entity (when mime-mother-buffer
 155                                     (set-buffer mime-mother-buffer)
 156                                     (get-text-property (point)
 157                                                        'mime-view-entity))))
 158                       (while (and entity
 159                                   (null (setq ret (mime-entity-fetch-field
 160                                                    entity field-name))))
 161                         (setq entity (mime-entity-parent entity)))))
 162                   (if ret
 163                       (insert (concat field-name ": " ret "\n")))))
 164             (setq rest (cdr rest)))))
 165       (let ((f (cdr (assq mode mime-preview-following-method-alist))))
 166         (if (functionp f)
 167             (funcall f new-buf)
 168           (message
 169            "Sorry, following method for %s is not implemented yet."
 170            mode))))))
 171
 172 (defalias 'wl-draft-enclose-digest-region 'mime-edit-enclose-digest-region)
 173
 174 (defun wl-draft-preview-attributes-list ()
 175   (if (listp (car wl-draft-preview-attributes-list))
 176       (elmo-uniq-list
 177        (nconc (and (wl-message-mail-p)
 178                    (copy-sequence
 179                     (cdr (assq 'mail wl-draft-preview-attributes-list))))
 180               (and (wl-message-news-p)
 181                    (copy-sequence
 182                     (cdr (assq 'news wl-draft-preview-attributes-list))))))
 183     wl-draft-preview-attributes-list))
 184
 185 (defun wl-draft-show-attributes-buffer (attribute-values)
 186   (let* ((cur-win (selected-window))
 187          (size (min
 188                 (- (window-height cur-win)
 189                    window-min-height 1)
 190                 (- (window-height cur-win)
 191                    (max
 192                     window-min-height
 193                     (1+ wl-draft-preview-attributes-buffer-lines))))))
 194     (split-window cur-win (if (> size 0) size window-min-height))
 195     (select-window (next-window))
 196     (let ((pop-up-windows nil))
 197       (switch-to-buffer (get-buffer-create
 198                          wl-draft-preview-attributes-buffer-name)))
 199     (with-current-buffer
 200         (get-buffer wl-draft-preview-attributes-buffer-name)
 201       (setq buffer-read-only t)
 202       (let (buffer-read-only)
 203         (erase-buffer)
 204         (dolist (pair attribute-values)
 205           (insert (capitalize (symbol-name (car pair))) ": "
 206                   (format "%s" (or (cdr pair) ""))
 207                   "\n"))
 208         (goto-char (point-min))
 209         (wl-highlight-headers)))
 210     (select-window cur-win)))
 211
 212 (defun wl-draft-hide-attributes-buffer ()
 213   (let (window buffer)
 214     (when (setq window (get-buffer-window
 215                         wl-draft-preview-attributes-buffer-name))
 216       (select-window window)
 217       (delete-window))
 218     (when (setq buffer (get-buffer wl-draft-preview-attributes-buffer-name))
 219       (kill-buffer buffer))))
 220
 221 (defun wl-draft-attribute-recipients ()
 222   (let (wl-draft-remove-group-list-contents)
 223     (mapconcat
 224      'identity
 225      (nconc
 226       (wl-draft-deduce-address-list
 227        (current-buffer)
 228        (point-min)
 229        (save-excursion
 230          (goto-char (point-min))
 231          (re-search-forward
 232           (concat
 233            "^"
 234            (regexp-quote mail-header-separator)
 235            "$")
 236           nil t)
 237          (point)))
 238       (wl-draft-parse-mailbox-list wl-draft-mime-bcc-field-name))
 239      ", ")))
 240
 241 (defun wl-draft-attribute-envelope-from ()
 242   (or wl-envelope-from
 243       (wl-address-header-extract-address wl-from)))
 244
 245 (defun wl-draft-attribute-smtp-posting-server ()
 246   (or wl-smtp-posting-server
 247       (progn (require 'smtp) smtp-server)
 248       "localhost"))
 249
 250 (defun wl-draft-attribute-smtp-posting-port ()
 251   (or wl-smtp-posting-port
 252       (progn (require 'smtp) smtp-service)))
 253
 254 (defun wl-draft-attribute-newsgroups ()
 255   (std11-field-body "Newsgroups"))
 256
 257 (defun wl-draft-nntp-attribute (attribute &optional alternatives)
 258   (let ((config (cdr (elmo-string-matched-assoc
 259                       (std11-field-body "newsgroups")
 260                       wl-nntp-posting-config-alist)))
 261         entry)
 262     (when (stringp config)
 263       (setq config (list (cons 'server config))))
 264     (if (setq entry (assq attribute config))
 265         ;; maybe nil
 266         (cdr entry)
 267       (let (value)
 268         (while alternatives
 269           (if (setq value (symbol-value (car alternatives)))
 270               (setq alternatives nil)
 271             (setq alternatives (cdr alternatives))))
 272         value))))
 273
 274 (defun wl-draft-attribute-nntp-posting-server ()
 275   (wl-draft-nntp-attribute
 276    'server
 277    '(wl-nntp-posting-server elmo-nntp-default-server)))
 278
 279 (defun wl-draft-attribute-nntp-posting-port ()
 280   (wl-draft-nntp-attribute
 281    'port
 282    '(wl-nntp-posting-port elmo-nntp-default-port)))
 283
 284 (defun wl-draft-attribute-value (attr)
 285   (let ((name (symbol-name attr))
 286         fsymbol symbol)
 287     (cond ((and (setq fsymbol (intern-soft
 288                                (format "wl-draft-attribute-%s" name)))
 289                 (fboundp fsymbol))
 290            (funcall fsymbol))
 291           ((and (setq symbol (intern-soft (format "wl-%s" name)))
 292                 (boundp symbol))
 293            (symbol-value symbol))
 294           ((boundp attr)
 295            (symbol-value attr)))))
 296
 297 (defun wl-mime-quit-preview ()
 298   "Quitting method for mime-view."
 299   (let* ((temp (and (boundp 'mime-edit-temp-message-buffer) ;; for SEMI <= 1.14.6
 300                     mime-edit-temp-message-buffer))
 301          (window (selected-window))
 302          buf)
 303     (mime-preview-kill-buffer)
 304     (set-buffer temp)
 305     (setq buf mime-edit-buffer)
 306     (kill-buffer temp)
 307     (select-window window)
 308     (switch-to-buffer buf)))
 309
 310 (defun wl-draft-preview-message ()
 311   "Preview editing message."
 312   (interactive)
 313   (let* (attribute-values
 314          (orig-buffer (current-buffer))
 315          (current-point (point))
 316          (config-exec-flag wl-draft-config-exec-flag)
 317          (parent-folder wl-draft-parent-folder)
 318          (mime-display-header-hook 'wl-highlight-headers)
 319          (mime-header-encode-method-alist
 320           (append
 321            '((wl-draft-eword-encode-address-list
 322               .  (To Cc Bcc Resent-To Resent-Cc Resent-Bcc From)))
 323            (if (boundp 'mime-header-encode-method-alist)
 324                (symbol-value 'mime-header-encode-method-alist))))
 325          mime-view-ignored-field-list   ; all header.
 326          (mime-edit-translate-buffer-hook
 327           (cons
 328            (lambda ()
 329              (let ((wl-draft-config-exec-flag config-exec-flag)
 330                    (wl-draft-parent-folder parent-folder)
 331                    (copy-buffer (current-buffer)))
 332                (wl-copy-local-variables
 333                 orig-buffer
 334                 copy-buffer
 335                 (with-current-buffer orig-buffer
 336                   (append wl-draft-config-variables
 337                           (wl-draft-clone-local-variables))))
 338                (goto-char current-point)
 339                (run-hooks 'wl-draft-send-hook)
 340                (condition-case err
 341                    (setq attribute-values
 342                          (mapcar
 343                           (lambda (attr)
 344                             (cons attr (wl-draft-attribute-value attr)))
 345                           (if wl-draft-preview-attributes
 346                               (wl-draft-preview-attributes-list)
 347                             '(recipients))))
 348                  (error
 349                   (kill-buffer (current-buffer))
 350                   (signal (car err) (cdr err))))))
 351            mime-edit-translate-buffer-hook)))
 352     (mime-edit-preview-message)
 353     (make-local-variable 'mime-preview-quitting-method-alist)
 354     (setq mime-preview-quitting-method-alist
 355           '((mime-temp-message-mode . wl-mime-quit-preview)))
 356     (let ((buffer-read-only nil))
 357       (when wl-highlight-body-too
 358         (wl-highlight-body))
 359       (run-hooks 'wl-draft-preview-message-hook))
 360     (make-local-hook 'kill-buffer-hook)
 361     (add-hook 'kill-buffer-hook #'wl-draft-hide-attributes-buffer nil t)
 362     (if wl-draft-preview-attributes
 363         (ignore-errors ; in case when the window is too small
 364          (wl-draft-show-attributes-buffer attribute-values))
 365       (message (concat "Recipients: "
 366                        (cdr (assq 'recipients attribute-values)))))))
 367
 368 (defalias 'wl-draft-caesar-region  'mule-caesar-region)
 369
 370 (defalias 'wl-draft-insert-message 'mime-edit-insert-message)
 371
 372 (defalias 'wl-draft-insert-mail 'mime-edit-insert-mail)
 373
 374 ;;; Message
 375
 376 (defun wl-message-decode-mode (outbuf inbuf)
 377   (let ((mime-view-content-header-filter-hook 'wl-highlight-headers)
 378         (mime-display-header-hook 'wl-highlight-headers))
 379     (mime-view-mode nil nil nil inbuf outbuf)))
 380
 381 (defun wl-message-decode-with-all-header (outbuf inbuf)
 382   (let ((mime-view-ignored-field-regexp "^:$")
 383         (mime-view-content-header-filter-hook 'wl-highlight-headers)
 384         (mime-display-header-hook 'wl-highlight-headers)
 385         mime-view-ignored-field-list)
 386     (mime-view-mode nil nil nil inbuf outbuf)))
 387
 388 (defun wl-message-delete-popup-windows ()
 389   (dolist (buffer wl-message-popup-buffers)
 390     (when (or (stringp buffer)
 391               (and (symbolp buffer)
 392                    (boundp buffer)
 393                    (setq buffer (symbol-value buffer))))
 394       (let ((window (get-buffer-window buffer)))
 395         (when window
 396           (delete-window window))))))
 397
 398 (defun wl-message-request-partial (folder number)
 399   (elmo-set-work-buf
 400    (elmo-message-fetch (wl-folder-get-elmo-folder folder)
 401                        number
 402                        (elmo-make-fetch-strategy 'entire)
 403                        'unread)
 404    (mime-parse-buffer nil)))
 405
 406 (defalias 'wl-message-read              'mime-preview-scroll-up-entity)
 407 (defalias 'wl-message-next-content      'mime-preview-move-to-next)
 408 (defalias 'wl-message-prev-content      'mime-preview-move-to-previous)
 409 (defalias 'wl-message-play-content      'mime-preview-play-current-entity)
 410 (defalias 'wl-message-extract-content   'mime-preview-extract-current-entity)
 411 (defalias 'wl-message-quit              'mime-preview-quit)
 412 (defalias 'wl-message-button-dispatcher-internal
 413   'mime-button-dispatcher)
 414
 415 (defsubst wl-mime-node-id-to-string (node-id)
 416   (if (consp node-id)
 417       (mapconcat (function (lambda (num) (format "%s" (1+ num))))
 418                  (reverse node-id)
 419                  ".")
 420     "0"))
 421
 422 (defun wl-message-delete-current-part ()
 423   "Delete a part under the cursor from the multipart message."
 424   (interactive)
 425   (save-restriction
 426     (widen)
 427     (let* ((entity (get-text-property (point) 'mime-view-entity))
 428            (node-id (mime-entity-node-id entity))
 429            (filename (mime-entity-safe-filename entity))
 430            (header-start (mime-buffer-entity-header-start-internal entity))
 431            (body-end (mime-buffer-entity-body-end-internal entity))
 432            (folder (wl-folder-get-elmo-folder wl-message-buffer-cur-folder))
 433            (number wl-message-buffer-cur-number)
 434            (msgid (elmo-message-field folder number 'message-id))
 435            (orig-buf wl-message-buffer-original-buffer))
 436       (if (eq (luna-class-name entity) 'mime-elmo-imap-entity)
 437           (error "Please fetch the entire message (by typing 'C-u .') and try again"))
 438       (with-current-buffer orig-buf
 439         (unless (string-equal
 440                  (buffer-string)
 441                  (elmo-message-fetch-string
 442                   folder number
 443                   (elmo-make-fetch-strategy 'entire)))
 444           (error "Buffer content differs from actual message")))
 445       (when (and (elmo-folder-writable-p folder)
 446                  (buffer-live-p orig-buf)
 447                  node-id
 448                  (yes-or-no-p
 449                   (format "Do you really want to delete part %s? "
 450                           (wl-mime-node-id-to-string node-id))))
 451         (when (with-temp-buffer
 452                 (insert-buffer orig-buf)
 453                 (delete-region header-start body-end)
 454                 (goto-char header-start)
 455                 (insert "Content-Type: text/plain; charset=US-ASCII\n")
 456                 (when filename
 457                   (insert
 458                    "Content-Disposition:"
 459                    (mime-encode-field-body
 460                          (concat ""
 461                                  (and filename
 462                                       (concat " inline; filename=" (std11-wrap-as-quoted-string filename))))
 463                          "Content-Disposition")
 464                    "\n"))
 465                 (insert "\n")
 466                 (insert "** This part has been removed by Wanderlust **\n\n")
 467                 (elmo-folder-append-buffer folder))
 468
 469           (elmo-folder-move-messages
 470            folder (list number)
 471            (wl-folder-get-elmo-folder wl-trash-folder))
 472           (when (and (elmo-cache-get-path msgid)
 473                      (file-exists-p (elmo-cache-get-path msgid)))
 474             (delete-file (elmo-cache-get-path msgid)))
 475
 476           (mime-preview-quit)
 477           (wl-summary-delete-messages-on-buffer (list number))
 478           (wl-summary-toggle-disp-msg 'off)
 479           (setq wl-message-buffer nil)
 480           (wl-summary-sync nil "update"))))))
 481
 482 ;; PGP
 483 (eval-when-compile
 484   (defmacro wl-define-dummy-functions (&rest symbols)
 485     `(dolist (symbol (quote ,symbols))
 486        (defalias symbol 'ignore)))
 487
 488   (condition-case nil
 489       (require 'epa)
 490     (error
 491      (wl-define-dummy-functions epg-make-context
 492                                 epg-decrypt-string
 493                                 epg-verify-string
 494                                 epg-context-set-progress-callback
 495                                 epg-context-result-for
 496                                 epg-verify-result-to-string
 497                                 epa-display-info)))
 498   (condition-case nil
 499       (require 'pgg)
 500     (error
 501      (wl-define-dummy-functions pgg-decrypt-region
 502                                 pgg-verify-region
 503                                 pgg-display-output-buffer))))
 504
 505 (defun wl-epg-progress-callback (context what char current total reporter)
 506   (let ((label (elmo-progress-counter-label reporter)))
 507     (when label
 508       (elmo-progress-notify label :set current :total total))))
 509
 510 (defun wl-mime-pgp-decrypt-region-with-epg (beg end &optional no-decode)
 511   (require 'epg)
 512   (let ((context (epg-make-context)))
 513     (elmo-with-progress-display (epg-decript nil reporter)
 514         "Decrypting"
 515       (epg-context-set-progress-callback context
 516                                          #'wl-epg-progress-callback
 517                                          reporter)
 518       (insert (prog1
 519                   (decode-coding-string
 520                    (epg-decrypt-string
 521                     context
 522                     (buffer-substring beg end))
 523                    (if no-decode 'raw-text wl-cs-autoconv))
 524                 (delete-region beg end)))))
 525   last-coding-system-used)
 526
 527 (defun wl-mime-pgp-verify-region-with-epg (beg end &optional coding-system)
 528   (require 'epa)
 529   (let ((context (epg-make-context)))
 530     (elmo-with-progress-display (epg-verify nil reporter)
 531         "Verifying"
 532       (epg-context-set-progress-callback context
 533                                          #'wl-epg-progress-callback
 534                                          reporter)
 535       (epg-verify-string
 536        context
 537        (encode-coding-string
 538         (buffer-substring beg end)
 539         (if coding-system
 540             (coding-system-change-eol-conversion coding-system 'dos)
 541           'raw-text-dos))))
 542     (when (epg-context-result-for context 'verify)
 543       (epa-display-info (epg-verify-result-to-string
 544                          (epg-context-result-for context 'verify))))))
 545
 546 (defun wl-mime-pgp-decrypt-region-with-pgg (beg end &optional no-decode)
 547   (require 'pgg)
 548   (let ((buffer-file-coding-system wl-cs-autoconv)
 549         status)
 550     (setq status (pgg-decrypt-region beg end))
 551     (if no-decode
 552         (when status
 553           (delete-region beg end)
 554           (insert-buffer-substring pgg-output-buffer))
 555       (pgg-display-output-buffer beg end status))
 556     (unless status
 557       (error "Decryption is failed"))
 558     last-coding-system-used))
 559
 560 (defun wl-mime-pgp-verify-region-with-pgg (beg end &optional coding-system)
 561   (require 'pgg)
 562   (let ((message-buffer (current-buffer))
 563         success)
 564     (with-temp-buffer
 565       (insert-buffer-substring message-buffer beg end)
 566       (when coding-system
 567         (encode-coding-region (point-min) (point-max) coding-system))
 568       (setq success (pgg-verify-region (point-min) (point-max) nil 'fetch)))
 569     (mime-show-echo-buffer)
 570     (set-buffer mime-echo-buffer-name)
 571     (set-window-start
 572      (get-buffer-window mime-echo-buffer-name)
 573      (point-max))
 574     (insert-buffer-substring
 575      (if success
 576          pgg-output-buffer
 577        pgg-errors-buffer))))
 578
 579 (defsubst wl-mime-pgp-decrypt-region (beg end &optional no-decode)
 580   (case wl-use-pgp-module
 581     (epg
 582      (wl-mime-pgp-decrypt-region-with-epg beg end no-decode))
 583     (pgg
 584      (wl-mime-pgp-decrypt-region-with-pgg beg end no-decode))
 585     (t
 586      (error "Don't support PGP decryption"))))
 587
 588 (defsubst wl-mime-pgp-verify-region (beg end &optional coding-system)
 589   (case wl-use-pgp-module
 590     (epg
 591      (wl-mime-pgp-verify-region-with-epg beg end coding-system))
 592     (pgg
 593      (wl-mime-pgp-verify-region-with-pgg beg end coding-system))
 594     (t
 595      (error "Don't support PGP decryption"))))
 596
 597 (defun wl-message-decrypt-pgp-nonmime ()
 598   "Decrypt PGP encrypted region"
 599   (interactive)
 600   (save-excursion
 601     (beginning-of-line)
 602     (let ((region (wl-find-region "^-+BEGIN PGP MESSAGE-+$"
 603                                   "^-+END PGP MESSAGE-+$"))
 604           (inhibit-read-only t)
 605           coding-system)
 606       (unless region
 607         (error "Cannot find pgp encrypted region"))
 608       (save-restriction
 609         (let ((props (text-properties-at (car region))))
 610           (narrow-to-region (car region) (cdr region))
 611           (when (setq coding-system
 612                       (wl-mime-pgp-decrypt-region (point-min) (point-max)))
 613             (setq props (plist-put props
 614                                    'wl-mime-decoded-coding-system
 615                                    coding-system)))
 616           (set-text-properties (point-min) (point-max) props))))))
 617
 618 (defun wl-message-verify-pgp-nonmime (&optional arg)
 619   "Verify PGP signed region.
 620 With ARG, ask coding system and encode the region with it before verifying."
 621   (interactive "P")
 622   (save-excursion
 623     (beginning-of-line)
 624     (let ((region (wl-find-region "^-+BEGIN PGP SIGNED MESSAGE-+$"
 625                                   "^-+END PGP SIGNATURE-+$"))
 626           coding-system)
 627       (setq coding-system
 628             (or (get-text-property (car region) 'wl-mime-decoded-coding-system)
 629                 (let* ((situation (mime-preview-find-boundary-info))
 630                        (entity (aref situation 2)))
 631                   (mime-charset-to-coding-system
 632                    (mime-content-type-parameter
 633                     (mime-entity-content-type entity)
 634                     "charset")))
 635                 buffer-file-coding-system))
 636       (when arg
 637         (setq coding-system (read-coding-system
 638                              (format "Coding system (%S): " coding-system)
 639                              coding-system)))
 640       (wl-mime-pgp-verify-region (car region) (cdr region) coding-system))))
 641
 642 ;; XXX: encrypted multipart isn't represented as multipart
 643 (defun wl-mime-preview-application/pgp (parent-entity entity situation)
 644   (goto-char (point-max))
 645   (let ((p (point))
 646         raw-buf to-buf representation-type child-entity)
 647     (goto-char p)
 648     (save-restriction
 649       (narrow-to-region p p)
 650       (setq to-buf (current-buffer))
 651       (with-temp-buffer
 652         (setq raw-buf (current-buffer))
 653         (mime-insert-entity entity)
 654         (when (progn
 655                 (goto-char (point-min))
 656                 (re-search-forward "^-+BEGIN PGP MESSAGE-+$" nil t))
 657           (wl-mime-pgp-decrypt-region (point-min) (point-max) 'no-decode)
 658           (setq representation-type 'elmo-buffer))
 659         (setq child-entity (mime-parse-message
 660                             (mm-expand-class-name representation-type)
 661                             nil
 662                             parent-entity
 663                             (mime-entity-node-id-internal parent-entity)))
 664         (mime-display-entity
 665          child-entity
 666          nil
 667          `((header . visible)
 668            (body . visible)
 669            (entity-button . invisible))
 670          to-buf)))))
 671
 672 (defun wl-mime-preview-application/pgp-encrypted (entity situation)
 673   (let* ((entity-node-id (mime-entity-node-id entity))
 674          (mother (mime-entity-parent entity))
 675          (knum (car entity-node-id))
 676          (onum (if (> knum 0)
 677                    (1- knum)
 678                  (1+ knum)))
 679          (orig-entity (nth onum (mime-entity-children mother))))
 680     (wl-mime-preview-application/pgp entity orig-entity situation)))
 681
 682 ;;; Summary
 683 (defun wl-summary-burst-subr (message-entity target number)
 684   ;; returns new number.
 685   (let (content-type entity)
 686     (setq content-type (mime-entity-content-type message-entity))
 687     (cond ((eq (cdr (assq 'type content-type)) 'multipart)
 688            (dolist (entity (mime-entity-children message-entity))
 689              (setq number (wl-summary-burst-subr
 690                            entity
 691                            target
 692                            number))))
 693           ((and (eq (cdr (assq 'type content-type)) 'message)
 694                 (eq (cdr (assq 'subtype content-type)) 'rfc822))
 695            (message "Bursting...%s" (setq number (+ 1 number)))
 696            (setq entity
 697                  (car (mime-entity-children message-entity)))
 698            (with-temp-buffer
 699              (set-buffer-multibyte nil)
 700              (insert (mime-entity-body message-entity))
 701              (elmo-folder-append-buffer target))))
 702     number))
 703
 704 (defun wl-summary-burst (&optional arg)
 705   "De-capsulate embedded messages in MIME format.
 706 With ARG, ask destination folder."
 707   (interactive "P")
 708   (let ((raw-buf (wl-summary-get-original-buffer))
 709         (view-buf wl-message-buffer)
 710         message-entity target)
 711     (save-excursion
 712       (when (and (null arg)
 713                  (elmo-folder-writable-p wl-summary-buffer-elmo-folder))
 714         (setq target wl-summary-buffer-elmo-folder))
 715       (while (null target)
 716         (let ((name (wl-summary-read-folder wl-default-folder
 717                                             "to extract to")))
 718           (setq target (wl-folder-get-elmo-folder name))
 719           (unless (elmo-folder-writable-p target)
 720             (message "%s is not writable" name)
 721             (setq target nil)
 722             (sit-for 1))))
 723       (wl-summary-set-message-buffer-or-redisplay)
 724       (with-current-buffer view-buf
 725         (setq message-entity
 726               (get-text-property (point-min) 'mime-view-entity)))
 727       (when message-entity
 728         (message "Bursting...")
 729         (with-current-buffer raw-buf
 730           (wl-summary-burst-subr message-entity target 0))
 731         (message "Bursting...done"))
 732       (if (elmo-folder-plugged-p target)
 733           (elmo-folder-check target)))
 734     (when (and target
 735                (string= wl-summary-buffer-folder-name
 736                         (elmo-folder-name-internal target)))
 737       (save-excursion (wl-summary-sync-update)))))
 738
 739 ;; internal variable.
 740 (defvar wl-mime-save-directory nil "Last saved directory.")
 741 ;;; Yet another save method.
 742 (defun wl-mime-save-content (entity situation)
 743   (let ((filename (expand-file-name
 744                    (read-file-name "Save to file: "
 745                                    (expand-file-name
 746                                     (or (mime-entity-safe-filename entity)
 747                                         ".")
 748                                     (or wl-mime-save-directory
 749                                         wl-temporary-file-directory))))))
 750     (while (file-directory-p filename)
 751       (setq filename (read-file-name "Please set filename (not directory): "
 752                                      filename)))
 753     (if (and (file-exists-p filename)
 754              (not (yes-or-no-p (format "File %s exists. Save anyway? "
 755                                        filename))))
 756         (message "Not saved")
 757       (setq wl-mime-save-directory (file-name-directory filename))
 758       (mime-write-entity-content entity filename))))
 759
 760 (defun wl-summary-extract-attachments-1 (message-entity directory number)
 761   ;; returns new number.
 762   (let (children filename)
 763     (cond
 764      ((setq children (mime-entity-children message-entity))
 765       (dolist (entity children)
 766         (setq number
 767               (wl-summary-extract-attachments-1 entity directory number))))
 768      ((and (eq (mime-content-disposition-type
 769                 (mime-entity-content-disposition message-entity))
 770                'attachment)
 771            (setq filename (mime-entity-safe-filename message-entity)))
 772       (let ((full (expand-file-name filename directory)))
 773         (when (or (not (file-exists-p full))
 774                   (yes-or-no-p
 775                    (format "File %s exists. Save anyway? " filename)))
 776           (message "Extracting...%s" (setq number (+ 1 number)))
 777           (mime-write-entity-content message-entity full)))))
 778     number))
 779
 780 (defun wl-summary-extract-attachments (directory)
 781   "Extract attachment parts in MIME format into the DIRECTORY."
 782   (interactive
 783    (let* ((default (or wl-mime-save-directory
 784                        wl-temporary-file-directory))
 785           (directory (read-directory-name "Extract to " default default t)))
 786      (list (if (> (length directory) 0) directory default))))
 787   (unless (and (file-writable-p directory)
 788                (file-directory-p directory))
 789     (error "%s is not writable" directory))
 790   (save-excursion
 791     (wl-summary-set-message-buffer-or-redisplay)
 792     (let ((entity (get-text-property (point-min) 'mime-view-entity)))
 793       (when entity
 794         (message "Extracting...")
 795         (wl-summary-extract-attachments-1 entity directory 0)
 796         (message "Extracting...done")))))
 797
 798 ;;; Yet another combine method.
 799 (defun wl-mime-combine-message/partial-pieces (entity situation)
 800   "Internal method for wl to combine message/partial messages automatically."
 801   (interactive)
 802   (let* ((folder (with-current-buffer wl-message-buffer-cur-summary-buffer
 803                    wl-summary-buffer-elmo-folder))
 804          (mime-display-header-hook 'wl-highlight-headers)
 805          (id (or (cdr (assoc "id" situation)) ""))
 806          (mother (current-buffer))
 807          (summary-buf wl-message-buffer-cur-summary-buffer)
 808          subject-id overviews
 809          (root-dir (expand-file-name
 810                     (concat "m-prts-" (user-login-name))
 811                     temporary-file-directory))
 812          full-file point)
 813     (setq root-dir (concat root-dir "/" (replace-as-filename id)))
 814     (setq full-file (concat root-dir "/FULL"))
 815     (if (or (file-exists-p full-file)
 816             (not (y-or-n-p "Merge partials? ")))
 817         (with-current-buffer mother
 818           (mime-store-message/partial-piece entity situation)
 819           (setq wl-message-buffer-cur-summary-buffer summary-buf)
 820           (make-local-variable 'mime-preview-over-to-next-method-alist)
 821           (setq mime-preview-over-to-next-method-alist
 822                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 823                       mime-preview-over-to-next-method-alist))
 824           (make-local-variable 'mime-preview-over-to-previous-method-alist)
 825           (setq mime-preview-over-to-previous-method-alist
 826                 (cons (cons 'mime-show-message-mode 'wl-message-exit)
 827                       mime-preview-over-to-previous-method-alist)))
 828       (setq subject-id
 829             (eword-decode-string
 830              (decode-mime-charset-string
 831               (mime-entity-read-field entity 'Subject)
 832               wl-summary-buffer-mime-charset)))
 833       (if (string-match "[0-9\n]+" subject-id)
 834           (setq subject-id (substring subject-id 0 (match-beginning 0))))
 835       (catch 'tag
 836         (elmo-folder-do-each-message-entity (entity folder)
 837           (when (string-match
 838                  (regexp-quote subject-id)
 839                  (elmo-message-entity-field entity 'subject))
 840             (let* ((message
 841                     ;; request message at the cursor in Subject buffer.
 842                     (wl-message-request-partial
 843                      (elmo-folder-name-internal folder)
 844                      (elmo-message-entity-number entity)))
 845                    (situation (mime-entity-situation message))
 846                    (the-id (or (cdr (assoc "id" situation)) "")))
 847               (when (string= (downcase the-id)
 848                              (downcase id))
 849                 (with-current-buffer mother
 850                   (mime-store-message/partial-piece message situation))
 851                 (if (file-exists-p full-file)
 852                     (throw 'tag nil))))))
 853         (message "Not all partials found.")))))
 854
 855 (defun wl-mime-display-text/plain (entity situation)
 856   (let ((beg (point)))
 857     (mime-display-text/plain entity situation)
 858     (wl-highlight-message beg (point-max) t t)))
 859
 860 (defun wl-mime-display-header (entity situation)
 861   (let ((elmo-message-ignored-field-list
 862          (if wl-message-buffer-require-all-header
 863              nil
 864            wl-message-ignored-field-list))
 865         (elmo-message-visible-field-list wl-message-visible-field-list)
 866         (elmo-message-sorted-field-list wl-message-sort-field-list))
 867     (elmo-mime-insert-header entity situation)
 868     (wl-highlight-headers)))
 869
 870 (defun wl-mime-decrypt-application/pgp-encrypted (entity situation)
 871   (let ((summary-buffer wl-message-buffer-cur-summary-buffer)
 872         (original-buffer wl-message-buffer-original-buffer))
 873     (mime-decrypt-application/pgp-encrypted entity situation)
 874     (setq wl-message-buffer-cur-summary-buffer summary-buffer)
 875     (setq wl-message-buffer-original-buffer original-buffer)))
 876
 877
 878 ;;; Setup methods.
 879 (defun wl-mime-setup ()
 880   (set-alist 'mime-preview-quitting-method-alist
 881              'wl-original-message-mode 'wl-message-exit)
 882   (set-alist 'mime-view-over-to-previous-method-alist
 883              'wl-original-message-mode 'wl-message-exit)
 884   (set-alist 'mime-view-over-to-next-method-alist
 885              'wl-original-message-mode 'wl-message-exit)
 886   (set-alist 'mime-preview-over-to-previous-method-alist
 887              'wl-original-message-mode 'wl-message-exit)
 888   (set-alist 'mime-preview-over-to-next-method-alist
 889              'wl-original-message-mode 'wl-message-exit)
 890   (add-hook 'wl-summary-toggle-disp-off-hook 'wl-message-delete-popup-windows)
 891   (add-hook 'wl-summary-redisplay-hook 'wl-message-delete-popup-windows)
 892   (add-hook 'wl-message-exit-hook 'wl-message-delete-popup-windows)
 893
 894   (ctree-set-calist-strictly
 895    'mime-preview-condition
 896    '((type . text) (subtype . plain)
 897      (body . visible)
 898      (body-presentation-method . wl-mime-display-text/plain)
 899      (major-mode . wl-original-message-mode)))
 900
 901   (ctree-set-calist-strictly
 902    'mime-preview-condition
 903    '((type . application)(subtype . pgp-encrypted)
 904      (encoding . t)
 905      (body . invisible)
 906      (body-presentation-method . wl-mime-preview-application/pgp-encrypted)
 907      (major-mode . wl-original-message-mode)))
 908
 909   (ctree-set-calist-strictly
 910    'mime-acting-condition
 911    '((type . message) (subtype . partial)
 912      (method .  wl-mime-combine-message/partial-pieces)
 913      (request-partial-message-method . wl-message-request-partial)
 914      (major-mode . wl-original-message-mode)))
 915
 916   (ctree-set-calist-strictly
 917    'mime-acting-condition
 918    '((type . application) (subtype . pgp-encrypted)
 919      (method . wl-mime-decrypt-application/pgp-encrypted)
 920      (major-mode . wl-original-message-mode)))
 921
 922   (ctree-set-calist-strictly
 923    'mime-acting-condition
 924    '((mode . "extract")
 925      (major-mode . wl-original-message-mode)
 926      (method . wl-mime-save-content)))
 927   (set-alist 'mime-preview-following-method-alist
 928              'wl-original-message-mode
 929              (function wl-message-follow-current-entity))
 930   (set-alist 'mime-view-following-method-alist
 931              'wl-original-message-mode
 932              (function wl-message-follow-current-entity))
 933   (set-alist 'mime-edit-message-inserter-alist
 934              'wl-draft-mode (function wl-draft-insert-current-message))
 935   (set-alist 'mime-edit-mail-inserter-alist
 936              'wl-draft-mode (function wl-draft-insert-get-message))
 937   (set-alist 'mime-edit-split-message-sender-alist
 938              'wl-draft-mode
 939              (cdr (assq 'mail-mode mime-edit-split-message-sender-alist)))
 940   (set-alist 'mime-raw-representation-type-alist
 941              'wl-original-message-mode 'binary)
 942   ;; Sort and highlight header fields.
 943   (or wl-message-ignored-field-list
 944       (setq wl-message-ignored-field-list
 945             mime-view-ignored-field-list))
 946   (or wl-message-visible-field-list
 947       (setq wl-message-visible-field-list
 948             mime-view-visible-field-list))
 949   (set-alist 'mime-header-presentation-method-alist
 950              'wl-original-message-mode
 951              'wl-mime-display-header)
 952   ;; To avoid overriding wl-draft-mode-map.
 953   (when (boundp 'mime-setup-signature-key-alist)
 954     (unless (assq 'wl-draft-mode mime-setup-signature-key-alist)
 955       (setq mime-setup-signature-key-alist
 956             (cons '(wl-draft-mode . "\C-c\C-w")
 957                   mime-setup-signature-key-alist)))))
 958
 959 (require 'product)
 960 (product-provide (provide 'wl-mime) (require 'wl-version))
 961
 962 ;;; wl-mime.el ends here