git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31 (require 'wid-edit)
  32
  33 (defgroup gnus-xmas nil
  34   "XEmacsoid support for Gnus"
  35   :group 'gnus)
  36
  37 (defcustom gnus-xmas-glyph-directory nil
  38   "Directory where Gnus logos and icons are located.
  39 If this variable is nil, Gnus will try to locate the directory
  40 automatically."
  41   :type '(choice (const :tag "autodetect" nil)
  42                  directory)
  43   :group 'gnus-xmas)
  44
  45 ;;(format "%02x%02x%02x" 114 66 20) "724214"
  46
  47 (defvar gnus-xmas-logo-color-alist
  48   '((flame "#cc3300" "#ff2200")
  49     (pine "#c0cc93" "#f8ffb8")
  50     (moss "#a1cc93" "#d2ffb8")
  51     (irish "#04cc90" "#05ff97")
  52     (sky "#049acc" "#05deff")
  53     (tin "#6886cc" "#82b6ff")
  54     (velvet "#7c68cc" "#8c82ff")
  55     (grape "#b264cc" "#cf7df")
  56     (labia "#cc64c2" "#fd7dff")
  57     (berry "#cc6485" "#ff7db5")
  58     (dino "#724214" "#1e3f03")
  59     (neutral "#b4b4b4" "#878787")
  60     (september "#bf9900" "#ffcc00"))
  61   "Color alist used for the Gnus logo.")
  62
  63 (defcustom gnus-xmas-logo-color-style 'dino
  64   "*Color styles used for the Gnus logo."
  65   :type '(choice (const flame) (const pine) (const moss)
  66                  (const irish) (const sky) (const tin)
  67                  (const velvet) (const grape) (const labia)
  68                  (const berry) (const neutral) (const september)
  69                  (const dino))
  70   :group 'gnus-xmas)
  71
  72 (defvar gnus-xmas-logo-colors
  73   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  74   "Colors used for the Gnus logo.")
  75
  76 (defcustom gnus-article-x-face-command
  77   (if (or (featurep 'xface)
  78           (featurep 'xpm))
  79       'gnus-xmas-article-display-xface
  80     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  81   "*String or function to be executed to display an X-Face header.
  82 If it is a string, the command will be executed in a sub-shell
  83 asynchronously.  The compressed face will be piped to this command."
  84   :type '(choice string function))
  85
  86 ;;; Internal variables.
  87
  88 ;; Don't warn about these undefined variables.
  89
  90 (defvar gnus-group-mode-hook)
  91 (defvar gnus-summary-mode-hook)
  92 (defvar gnus-article-mode-hook)
  93
  94 ;;defined in gnus.el
  95 (defvar gnus-active-hashtb)
  96 (defvar gnus-article-buffer)
  97 (defvar gnus-auto-center-summary)
  98 (defvar gnus-current-headers)
  99 (defvar gnus-level-killed)
 100 (defvar gnus-level-zombie)
 101 (defvar gnus-newsgroup-bookmarks)
 102 (defvar gnus-newsgroup-dependencies)
 103 (defvar gnus-newsgroup-selected-overlay)
 104 (defvar gnus-newsrc-hashtb)
 105 (defvar gnus-read-mark)
 106 (defvar gnus-refer-article-method)
 107 (defvar gnus-reffed-article-number)
 108 (defvar gnus-unread-mark)
 109 (defvar gnus-version)
 110 (defvar gnus-view-pseudos)
 111 (defvar gnus-view-pseudos-separately)
 112 (defvar gnus-visual)
 113 (defvar gnus-zombie-list)
 114 ;;defined in gnus-msg.el
 115 (defvar gnus-article-copy)
 116 (defvar gnus-check-before-posting)
 117 ;;defined in gnus-vis.el
 118 (defvar gnus-article-button-face)
 119 (defvar gnus-article-mouse-face)
 120 (defvar gnus-summary-selected-face)
 121 (defvar gnus-group-reading-menu)
 122 (defvar gnus-group-group-menu)
 123 (defvar gnus-group-misc-menu)
 124 (defvar gnus-summary-article-menu)
 125 (defvar gnus-summary-thread-menu)
 126 (defvar gnus-summary-misc-menu)
 127 (defvar gnus-summary-post-menu)
 128 (defvar gnus-summary-kill-menu)
 129 (defvar gnus-article-article-menu)
 130 (defvar gnus-article-treatment-menu)
 131 (defvar gnus-mouse-2)
 132 (defvar standard-display-table)
 133 (defvar gnus-tree-minimize-window)
 134
 135 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 136   "You should NEVER use this function.  It is ideologically blasphemous.
 137 It is provided only to ease porting of broken FSF Emacs programs."
 138   (if (stringp buffer)
 139       nil
 140     (map-extents (lambda (extent ignored)
 141                    (remove-text-properties
 142                     start end
 143                     (list (extent-property extent 'text-prop) nil)
 144                     buffer)
 145                    nil)
 146                  buffer start end nil nil 'text-prop)
 147     (gnus-add-text-properties start end props buffer)))
 148
 149 (defun gnus-xmas-highlight-selected-summary ()
 150   ;; Highlight selected article in summary buffer
 151   (when gnus-summary-selected-face
 152     (when gnus-newsgroup-selected-overlay
 153       (delete-extent gnus-newsgroup-selected-overlay))
 154     (setq gnus-newsgroup-selected-overlay
 155           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 156     (set-extent-face gnus-newsgroup-selected-overlay
 157                      gnus-summary-selected-face)))
 158
 159 (defcustom gnus-xmas-force-redisplay nil
 160   "*If non-nil, force a redisplay before recentering the summary buffer.
 161 This is ugly, but it works around a bug in `window-displayed-height'."
 162   :type 'boolean
 163   :group 'gnus-xmas)
 164
 165 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 166   (when (featurep 'scrollbar)
 167     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 168
 169 (defun gnus-xmas-summary-recenter ()
 170   "\"Center\" point in the summary window.
 171 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 172 displayed, no centering will be performed."
 173   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 174   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 175   ;; Force redisplay to get properly computed window height.
 176   (when gnus-xmas-force-redisplay
 177     (sit-for 0))
 178   (when gnus-auto-center-summary
 179     (let* ((height (if (fboundp 'window-displayed-height)
 180                        (window-displayed-height)
 181                      (- (window-height) 2)))
 182            (top (cond ((< height 4) 0)
 183                       ((< height 7) 1)
 184                       (t 2)))
 185            (bottom (save-excursion (goto-char (point-max))
 186                                    (forward-line (- height))
 187                                    (point)))
 188            (window (get-buffer-window (current-buffer))))
 189       (when (get-buffer-window gnus-article-buffer)
 190         ;; Only do recentering when the article buffer is displayed,
 191         ;; Set the window start to either `bottom', which is the biggest
 192         ;; possible valid number, or the second line from the top,
 193         ;; whichever is the least.
 194         (set-window-start
 195          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 196       ;; Do horizontal recentering while we're at it.
 197       (when (and (get-buffer-window (current-buffer) t)
 198                  (not (eq gnus-auto-center-summary 'vertical)))
 199         (let ((selected (selected-window)))
 200           (select-window (get-buffer-window (current-buffer) t))
 201           (gnus-summary-position-point)
 202           (gnus-horizontal-recenter)
 203           (select-window selected))))))
 204
 205 (defun gnus-xmas-summary-set-display-table ()
 206   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 207   ;; but done in an XEmacsish way.
 208   (let ((table (make-display-table))
 209         (i 32))
 210     ;; Nix out all the control chars...
 211     (while (>= (setq i (1- i)) 0)
 212       (aset table i [??]))
 213     ;; ... but not newline and cr, of course.  (cr is necessary for the
 214     ;; selective display).
 215     (aset table ?\n nil)
 216     (aset table ?\r nil)
 217     ;; We keep TAB as well.
 218     (aset table ?\t nil)
 219     ;; We nix out any glyphs over 126 below ctl-arrow.
 220     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 221       (while (>= (setq i (1- i)) 127)
 222         (unless (aref table i)
 223           (aset table i [??]))))
 224     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 225     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 226
 227 (defun gnus-xmas-add-text-properties (start end props &optional object)
 228   (add-text-properties start end props object)
 229   (put-text-property start end 'start-closed nil object))
 230
 231 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 232   (put-text-property start end prop value object)
 233   (put-text-property start end 'start-closed nil object))
 234
 235 (defun gnus-xmas-extent-start-open (point)
 236   (map-extents (lambda (extent arg)
 237                  (set-extent-property extent 'start-open t))
 238                nil point (min (1+ (point)) (point-max))))
 239
 240 (defun gnus-xmas-article-push-button (event)
 241   "Check text under the mouse pointer for a callback function.
 242 If the text under the mouse pointer has a `gnus-callback' property,
 243 call it with the value of the `gnus-data' text property."
 244   (interactive "e")
 245   (set-buffer (window-buffer (event-window event)))
 246   (let* ((pos (event-closest-point event))
 247          (data (get-text-property pos 'gnus-data))
 248          (fun (get-text-property pos 'gnus-callback)))
 249     (goto-char pos)
 250     (when fun
 251       (funcall fun data))))
 252
 253 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 254   (set-extent-endpoints extent start end buffer))
 255
 256 (defun gnus-xmas-kill-all-overlays ()
 257   "Delete all extents in the current buffer."
 258   (map-extents (lambda (extent ignore)
 259                  (delete-extent extent)
 260                  nil)))
 261
 262 (defun gnus-xmas-window-top-edge (&optional window)
 263   (nth 1 (window-pixel-edges window)))
 264
 265 (defun gnus-xmas-tree-minimize ()
 266   (when (and gnus-tree-minimize-window
 267              (not (one-window-p)))
 268     (let* ((window-min-height 2)
 269            (height (1+ (count-lines (point-min) (point-max))))
 270            (min (max (1- window-min-height) height))
 271            (tot (if (numberp gnus-tree-minimize-window)
 272                     (min gnus-tree-minimize-window min)
 273                   min))
 274            (win (get-buffer-window (current-buffer)))
 275            (wh (and win (1- (window-height win)))))
 276       (when (and win
 277                  (not (eq tot wh)))
 278         (let ((selected (selected-window)))
 279           (select-window win)
 280           (enlarge-window (- tot wh))
 281           (select-window selected))))))
 282
 283 ;; Select the lowest window on the frame.
 284 (defun gnus-xmas-appt-select-lowest-window ()
 285   (let* ((lowest-window (selected-window))
 286          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 287          (last-window (previous-window))
 288          (window-search t))
 289     (while window-search
 290       (let* ((this-window (next-window))
 291              (next-bottom-edge (car (cdr (cdr (cdr
 292                                                (window-pixel-edges
 293                                                 this-window)))))))
 294         (when (< bottom-edge next-bottom-edge)
 295           (setq bottom-edge next-bottom-edge)
 296           (setq lowest-window this-window))
 297
 298         (select-window this-window)
 299         (when (eq last-window this-window)
 300           (select-window lowest-window)
 301           (setq window-search nil))))))
 302
 303 (defmacro gnus-xmas-menu-add (type &rest menus)
 304   `(gnus-xmas-menu-add-1 ',type ',menus))
 305 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 306
 307 (defun gnus-xmas-menu-add-1 (type menus)
 308   (when (and menu-bar-mode
 309              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 310     (while menus
 311       (easy-menu-add (symbol-value (pop menus))))))
 312
 313 (defun gnus-xmas-group-menu-add ()
 314   (gnus-xmas-menu-add group
 315     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 316
 317 (defun gnus-xmas-summary-menu-add ()
 318   (gnus-xmas-menu-add summary
 319     gnus-summary-misc-menu gnus-summary-kill-menu
 320     gnus-summary-article-menu gnus-summary-thread-menu
 321     gnus-summary-post-menu ))
 322
 323 (defun gnus-xmas-article-menu-add ()
 324   (gnus-xmas-menu-add article
 325     gnus-article-article-menu gnus-article-treatment-menu))
 326
 327 (defun gnus-xmas-score-menu-add ()
 328   (gnus-xmas-menu-add score
 329     gnus-score-menu))
 330
 331 (defun gnus-xmas-pick-menu-add ()
 332   (gnus-xmas-menu-add pick
 333     gnus-pick-menu))
 334
 335 (defun gnus-xmas-topic-menu-add ()
 336   (gnus-xmas-menu-add topic
 337     gnus-topic-menu))
 338
 339 (defun gnus-xmas-binary-menu-add ()
 340   (gnus-xmas-menu-add binary
 341     gnus-binary-menu))
 342
 343 (defun gnus-xmas-agent-summary-menu-add ()
 344   (gnus-xmas-menu-add agent-summary
 345     gnus-agent-summary-menu))
 346
 347 (defun gnus-xmas-agent-group-menu-add ()
 348   (gnus-xmas-menu-add agent-group
 349     gnus-agent-group-menu))
 350
 351 (defun gnus-xmas-agent-server-menu-add ()
 352   (gnus-xmas-menu-add agent-server
 353     gnus-agent-server-menu))
 354
 355 (defun gnus-xmas-tree-menu-add ()
 356   (gnus-xmas-menu-add tree
 357     gnus-tree-menu))
 358
 359 (defun gnus-xmas-draft-menu-add ()
 360   (gnus-xmas-menu-add draft
 361     gnus-draft-menu))
 362
 363 (defun gnus-xmas-server-menu-add ()
 364   (gnus-xmas-menu-add menu
 365     gnus-server-server-menu gnus-server-connections-menu))
 366
 367 (defun gnus-xmas-browse-menu-add ()
 368   (gnus-xmas-menu-add browse
 369     gnus-browse-menu))
 370
 371 (defun gnus-xmas-grouplens-menu-add ()
 372   (gnus-xmas-menu-add grouplens
 373     gnus-grouplens-menu))
 374
 375 (defun gnus-xmas-read-event-char ()
 376   "Get the next event."
 377   (let ((event (next-command-event)))
 378     (sit-for 0)
 379     ;; We junk all non-key events.  Is this naughty?
 380     (while (not (or (key-press-event-p event)
 381                     (button-press-event-p event)))
 382       (dispatch-event event)
 383       (setq event (next-command-event)))
 384     (cons (and (key-press-event-p event)
 385                (event-to-character event))
 386           event)))
 387
 388 (defun gnus-xmas-define ()
 389   (setq gnus-mouse-2 [button2])
 390   (setq gnus-mouse-3 [button3])
 391   (setq gnus-widget-button-keymap widget-button-keymap)
 392
 393   (unless (memq 'underline (face-list))
 394     (and (fboundp 'make-face)
 395          (funcall (intern "make-face") 'underline)))
 396   ;; Must avoid calling set-face-underline-p directly, because it
 397   ;; is a defsubst in emacs19, and will make the .elc files non
 398   ;; portable!
 399   (unless (face-differs-from-default-p 'underline)
 400     (funcall (intern "set-face-underline-p") 'underline t))
 401
 402   (cond
 403    ((fboundp 'char-or-char-int-p)
 404     ;; Handle both types of marks for XEmacs-20.x.
 405     (fset 'gnus-characterp 'char-or-char-int-p))
 406    ;; V19 of XEmacs, probably.
 407    (t
 408     (fset 'gnus-characterp 'characterp)))
 409
 410   (fset 'gnus-make-overlay 'make-extent)
 411   (fset 'gnus-delete-overlay 'delete-extent)
 412   (fset 'gnus-overlay-put 'set-extent-property)
 413   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 414   (fset 'gnus-overlay-end 'extent-end-position)
 415   (fset 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 416   (fset 'gnus-extent-detached-p 'extent-detached-p)
 417   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 418   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 419   (fset 'gnus-deactivate-mark 'ignore)
 420   (fset 'gnus-window-edges 'window-pixel-edges)
 421
 422   (if (and (<= emacs-major-version 19)
 423            (< emacs-minor-version 14))
 424       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 425
 426   (when (fboundp 'turn-off-scroll-in-place)
 427     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 428
 429   (unless (boundp 'standard-display-table)
 430     (setq standard-display-table nil))
 431
 432   (defvar gnus-mouse-face-prop 'highlight)
 433
 434   (defun gnus-byte-code (func)
 435     "Return a form that can be `eval'ed based on FUNC."
 436     (let ((fval (indirect-function func)))
 437       (if (byte-code-function-p fval)
 438           (list 'funcall fval)
 439         (cons 'progn (cdr (cdr fval))))))
 440
 441   (fset 'gnus-x-color-values
 442         (if (fboundp 'x-color-values)
 443             'x-color-values
 444           (lambda (color)
 445             (color-instance-rgb-components
 446              (make-color-instance color))))))
 447
 448 (defun gnus-xmas-redefine ()
 449   "Redefine lots of Gnus functions for XEmacs."
 450   (fset 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 451   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 452   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 453   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 454   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 455   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 456   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 457   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 458   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 459   (fset 'gnus-appt-select-lowest-window
 460         'gnus-xmas-appt-select-lowest-window)
 461   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 462   (fset 'gnus-character-to-event 'character-to-event)
 463   (fset 'gnus-mode-line-buffer-identification
 464         'gnus-xmas-mode-line-buffer-identification)
 465   (fset 'gnus-key-press-event-p 'key-press-event-p)
 466   (fset 'gnus-region-active-p 'region-active-p)
 467   (fset 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 468   (fset 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 469
 470   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 471   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 472   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 473   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 474
 475   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 476   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 477   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 478   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 479   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 480   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 481   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 482
 483   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 484   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 485
 486   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add)
 487   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add)
 488   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add)
 489
 490   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 491   (add-hook 'gnus-summary-mode-hook
 492             'gnus-xmas-switch-horizontal-scrollbar-off)
 493   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off))
 494
 495
 496 ;;; XEmacs logo and toolbar.
 497
 498 (defun gnus-xmas-group-startup-message (&optional x y)
 499   "Insert startup message in current buffer."
 500   ;; Insert the message.
 501   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 502   (erase-buffer)
 503   (cond
 504    ((and (console-on-window-system-p)
 505          (or (featurep 'xpm)
 506              (featurep 'xbm)))
 507     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 508            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 509            (glyph (make-glyph
 510                    (cond ((featurep 'xpm)
 511                           `[xpm
 512                             :file ,logo-xpm
 513                             :color-symbols
 514                             (("thing" . ,(car gnus-xmas-logo-colors))
 515                              ("shadow" . ,(cadr gnus-xmas-logo-colors))
 516                              ("background" . ,(face-background 'default)))])
 517                          ((featurep 'xbm)
 518                           `[xbm :file ,logo-xbm])
 519                          (t [nothing])))))
 520       (insert " ")
 521       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 522       (goto-char (point-min))
 523       (while (not (eobp))
 524         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 525                              ?\ ))
 526         (forward-line 1))
 527       (setq gnus-simple-splash nil))
 528     (goto-char (point-min))
 529     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 530            (wheight (window-height))
 531            (rest (- wheight pheight)))
 532       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 533    (t
 534     (insert
 535      (format "              %s
 536           _    ___ _             _
 537           _ ___ __ ___  __    _ ___
 538           __   _     ___    __  ___
 539               _           ___     _
 540              _  _ __             _
 541              ___   __            _
 542                    __           _
 543                     _      _   _
 544                    _      _    _
 545                       _  _    _
 546                   __  ___
 547                  _   _ _     _
 548                 _   _
 549               _    _
 550              _    _
 551             _
 552           __
 553
 554 "
 555              ""))
 556     ;; And then hack it.
 557     (gnus-indent-rigidly (point-min) (point-max)
 558                          (/ (max (- (window-width) (or x 46)) 0) 2))
 559     (goto-char (point-min))
 560     (forward-line 1)
 561     (let* ((pheight (count-lines (point-min) (point-max)))
 562            (wheight (window-height))
 563            (rest (- wheight pheight)))
 564       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 565     ;; Paint it.
 566     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 567   (setq modeline-buffer-identification
 568         (list (concat gnus-version ": *Group*")))
 569   (set-buffer-modified-p t))
 570
 571
 572 ;;; The toolbar.
 573
 574 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 575                                 'default-toolbar
 576                               nil)
 577   "*If nil, do not use a toolbar.
 578 If it is non-nil, it must be a toolbar.  The five legal values are
 579 `default-toolbar', `top-toolbar', `bottom-toolbar',
 580 `right-toolbar', and `left-toolbar'."
 581   :type '(choice (const default-toolbar)
 582                  (const top-toolbar) (const bottom-toolbar)
 583                  (const left-toolbar) (const right-toolbar)
 584                  (const :tag "no toolbar" nil))
 585   :group 'gnus-xmas)
 586
 587 (defvar gnus-group-toolbar
 588   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 589     [gnus-group-get-new-news-this-group
 590      gnus-group-get-new-news-this-group t "Get new news in this group"]
 591     [gnus-group-catchup-current
 592      gnus-group-catchup-current t "Catchup group"]
 593     [gnus-group-describe-group
 594      gnus-group-describe-group t "Describe group"]
 595     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 596     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 597     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 598     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 599     )
 600   "The group buffer toolbar.")
 601
 602 (defvar gnus-summary-toolbar
 603   '([gnus-summary-prev-unread
 604      gnus-summary-prev-page-or-article t "Page up"]
 605     [gnus-summary-next-unread
 606      gnus-summary-next-page t "Page down"]
 607     [gnus-summary-post-news
 608      gnus-summary-post-news t "Post an article"]
 609     [gnus-summary-followup-with-original
 610      gnus-summary-followup-with-original t
 611      "Post a followup and yank the original"]
 612     [gnus-summary-followup
 613      gnus-summary-followup t "Post a followup"]
 614     [gnus-summary-reply-with-original
 615      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 616     [gnus-summary-reply
 617      gnus-summary-reply t "Mail a reply"]
 618     [gnus-summary-caesar-message
 619      gnus-summary-caesar-message t "Rot 13"]
 620     [gnus-uu-decode-uu
 621      gnus-uu-decode-uu t "Decode uuencoded articles"]
 622     [gnus-summary-save-article-file
 623      gnus-summary-save-article-file t "Save article in file"]
 624     [gnus-summary-save-article
 625      gnus-summary-save-article t "Save article"]
 626     [gnus-uu-post-news
 627      gnus-uu-post-news t "Post a uuencoded article"]
 628     [gnus-summary-cancel-article
 629      gnus-summary-cancel-article t "Cancel article"]
 630     [gnus-summary-catchup
 631      gnus-summary-catchup t "Catchup"]
 632     [gnus-summary-catchup-and-exit
 633      gnus-summary-catchup-and-exit t "Catchup and exit"]
 634     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 635     )
 636   "The summary buffer toolbar.")
 637
 638 (defvar gnus-summary-mail-toolbar
 639   '(
 640     [gnus-summary-prev-unread
 641      gnus-summary-prev-unread-article t "Prev unread article"]
 642     [gnus-summary-next-unread
 643      gnus-summary-next-unread-article t "Next unread article"]
 644     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 645 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 646     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 647     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 648     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 649 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 650     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 651 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 652 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 653     [gnus-summary-caesar-message
 654      gnus-summary-caesar-message t "Rot 13"]
 655     [gnus-uu-decode-uu
 656      gnus-uu-decode-uu t "Decode uuencoded articles"]
 657     [gnus-summary-save-article-file
 658      gnus-summary-save-article-file t "Save article in file"]
 659     [gnus-summary-save-article
 660      gnus-summary-save-article t "Save article"]
 661     [gnus-summary-catchup
 662      gnus-summary-catchup t "Catchup"]
 663     [gnus-summary-catchup-and-exit
 664      gnus-summary-catchup-and-exit t "Catchup and exit"]
 665     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 666     )
 667   "The summary buffer mail toolbar.")
 668
 669 (defun gnus-xmas-setup-group-toolbar ()
 670   (and gnus-use-toolbar
 671        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 672        (set-specifier (symbol-value gnus-use-toolbar)
 673                       (cons (current-buffer) gnus-group-toolbar))))
 674
 675 (defun gnus-xmas-setup-summary-toolbar ()
 676   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 677                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 678     (and gnus-use-toolbar
 679          (message-xmas-setup-toolbar bar nil "gnus")
 680          (set-specifier (symbol-value gnus-use-toolbar)
 681                         (cons (current-buffer) bar)))))
 682
 683 (defun gnus-xmas-mail-strip-quoted-names (address)
 684   "Protect mail-strip-quoted-names from NIL input.
 685 XEmacs compatibility workaround."
 686   (if (null address)
 687       nil
 688     (mail-strip-quoted-names address)))
 689
 690 (defun gnus-xmas-call-region (command &rest args)
 691   (apply
 692    'call-process-region (point-min) (point-max) command t '(t nil) nil
 693    args))
 694
 695 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 696   "Face to show X face"
 697   :group 'gnus-xmas)
 698
 699 (defun gnus-xmas-article-display-xface (beg end)
 700   "Display any XFace headers in the current article."
 701   (save-excursion
 702     (let ((xface-glyph
 703            (cond ((featurep 'xface)
 704                   (make-glyph (vector 'xface :data
 705                                       (concat "X-Face: "
 706                                               (buffer-substring beg end)))))
 707                  ((featurep 'xpm)
 708                   (let ((cur (current-buffer)))
 709                     (save-excursion
 710                       (gnus-set-work-buffer)
 711                       (insert (format "%s" (buffer-substring beg end cur)))
 712                       (gnus-xmas-call-region "uncompface")
 713                       (goto-char (point-min))
 714                       (insert "/* Width=48, Height=48 */\n")
 715                       (gnus-xmas-call-region "icontopbm")
 716                       (gnus-xmas-call-region "ppmtoxpm")
 717                       (make-glyph
 718                        (vector 'xpm :data (buffer-string))))))
 719                  (t
 720                   (make-glyph [nothing]))))
 721           (ext (make-extent (progn
 722                               (goto-char (point-min))
 723                               (re-search-forward "^From:" nil t)
 724                               (point))
 725                             (1+ (point)))))
 726       (set-glyph-face xface-glyph 'gnus-x-face)
 727       (set-extent-begin-glyph ext xface-glyph)
 728       (set-extent-property ext 'duplicable t))))
 729
 730 ;;(defvar gnus-xmas-pointer-glyph
 731 ;;  (progn
 732 ;;    (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory
 733 ;;                                     "gnus"))
 734 ;;    (let ((file-xpm (expand-file-name "gnus-pointer.xpm"
 735 ;;                                    gnus-xmas-glyph-directory))
 736 ;;        (file-xbm (expand-file-name "gnus-pointer.xbm"
 737 ;;                                    gnus-xmas-glyph-directory)))
 738 ;;      (make-pointer-glyph
 739 ;;       (list (vector 'xpm ':file file-xpm)
 740 ;;           (vector 'xbm ':file file-xbm))))))
 741
 742 (defvar gnus-xmas-modeline-left-extent
 743   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 744 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 745     ext))
 746
 747 (defvar gnus-xmas-modeline-right-extent
 748   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 749 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 750     ext))
 751
 752 (defvar gnus-xmas-modeline-glyph
 753   (progn
 754     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 755     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 756                                        gnus-xmas-glyph-directory))
 757            (file-xbm (expand-file-name "gnus-pointer.xbm"
 758                                        gnus-xmas-glyph-directory))
 759            (glyph (make-glyph
 760                    ;; Gag gag gag.
 761                    (cond ((featurep 'xpm)
 762                           ;; Let's try a nifty XPM
 763                           `[xpm :file ,file-xpm])
 764                          ((featurep 'xbm)
 765                           ;; Then a not-so-nifty XBM
 766                           [xbm :file ,file-xbm])
 767                          ;; Then the simple string
 768                          (t [string :data "Gnus:"])))))
 769       (set-glyph-face glyph 'modeline-buffer-id)
 770       glyph)))
 771
 772 (defun gnus-xmas-mode-line-buffer-identification (line)
 773   (let ((line (car line))
 774         chop)
 775     (cond
 776      ;; This is some weird type of id.
 777      ((not (stringp line))
 778       (list line))
 779      ;; This is non-standard, so we just pass it through.
 780      ((not (string-match "^Gnus:" line))
 781       (list line))
 782      ;; We have a standard line, so we colorize and glyphize it a bit.
 783      (t
 784       (setq chop (match-end 0))
 785       (list
 786        (if gnus-xmas-modeline-glyph
 787            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 788          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 789        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 790
 791 (defun gnus-xmas-splash ()
 792   (when (eq (device-type) 'x)
 793     (gnus-splash)))
 794
 795 (defun gnus-xmas-annotation-in-region-p (b e)
 796   (map-extents (lambda (e u) t) nil b e nil nil 'mm t))
 797
 798 (defun gnus-xmas-mime-button-menu (event)
 799   "Construct a context-sensitive menu of MIME commands."
 800   (interactive "e")
 801   (let ((response (get-popup-menu-response
 802                    `("MIME Part"
 803                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 804                                gnus-mime-button-commands)))))
 805     (set-buffer (event-buffer event))
 806     (goto-char (event-point event))
 807     (funcall (event-function response) (event-object response))))
 808
 809 (provide 'gnus-xmas)
 810
 811 ;;; gnus-xmas.el ends here